qcsrc/gamec/w_shotgun.c

   1 void() shotgun_ready_01;
   2 void() shotgun_fire1_01;
   3 void() shotgun_fire2_01;
   4 void() shotgun_deselect_01;
   5 void() shotgun_select_01;
   6
   7 float() shotgun_check =
   8 {
   9         if (self.ammo_shells >= 1)
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 void(float req) w_shotgun =
  15 {
  16         if (req == WR_IDLE)
  17                 shotgun_ready_01();
  18         else if (req == WR_FIRE1)
  19                 weapon_prepareattack(shotgun_check, shotgun_check, shotgun_fire1_01, cvar("g_balance_shotgun_refire"));
  20         else if (req == WR_FIRE2)
  21                 weapon_prepareattack(shotgun_check, shotgun_check, shotgun_fire2_01, cvar("g_balance_shotgun_refire2"));
  22         else if (req == WR_RAISE)
  23                 shotgun_select_01();
  24         else if (req == WR_UPDATECOUNTS)
  25                 self.currentammo = self.ammo_shells;
  26         else if (req == WR_DROP)
  27                 shotgun_deselect_01();
  28         else if (req == WR_SETUP)
  29                 weapon_setup(WEP_SHOTGUN, "w_shotgun.zym", IT_SHELLS);
  30         else if (req == WR_CHECKAMMO)
  31                 weapon_hasammo = shotgun_check();
  32 };
  33
  34 void W_Shotgun_Attack (void)
  35 {
  36         local vector org;
  37         float   sc;
  38         float   bullets;
  39         float   d;
  40         float   spread;
  41
  42         sound (self, CHAN_WEAPON, "weapons/shotgun_fire.wav", 1, ATTN_NORM);
  43         bullets = cvar("g_balance_shotgun_bullets");
  44         d = cvar("g_balance_shotgun_damage");
  45
  46         org = self.origin + self.view_ofs + (v_right * 6) - (v_up * 8) + (v_forward * 5);
  47         spread = cvar("g_balance_shotgun_spread");
  48         for (sc = 0;sc < bullets;sc = sc + 1)
  49                 fireBullet (org, v_forward, spread, d, IT_SHOTGUN, sc < 3);
  50         self.ammo_shells = self.ammo_shells - 1;
  51
  52         // casing code
  53         if (cvar("g_casings") == 1)
  54         {
  55                 org = self.origin + self.view_ofs + (v_right * 6) - (v_up * 8) + (v_forward * 10);
  56                 SpawnCasing (org, ((random () * 50 + 50) * v_right) - ((random () * 25 + 25) * v_forward) - ((random () * 5 + 10) * v_up), 2, v_forward,'0 250 0', 100, 1);
  57         }
  58
  59         org = self.origin + self.view_ofs + (v_right * 6) - (v_up * 8) + (v_forward * 20);
  60         W_Smoke(org, v_forward, 12);
  61         //te_smallflash(org);
  62
  63         self.punchangle_x = -5;
  64 }
  65
  66 // weapon frames
  67
  68 void()  shotgun_ready_01 =      {weapon_thinkf(WFRAME_IDLE, 0.1, shotgun_ready_01); self.weaponentity.state = WS_READY;};
  69 void()  shotgun_select_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
  70 void()  shotgun_deselect_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
  71 void()  shotgun_fire1_01 =
  72 {
  73         weapon_doattack(shotgun_check, shotgun_check, W_Shotgun_Attack);
  74         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_refire3"), shotgun_ready_01);
  75 };
  76 void()  shotgun_fire2_03 =
  77 {
  78         weapon_doattack(shotgun_check, shotgun_check, W_Shotgun_Attack);
  79         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_refire3"), shotgun_ready_01);
  80 }
  81 void()  shotgun_fire2_02 =
  82 {
  83         weapon_doattack(shotgun_check, shotgun_check, W_Shotgun_Attack);
  84         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_refire3"), shotgun_fire2_03);
  85 }
  86 void()  shotgun_fire2_01 =
  87 {
  88         weapon_doattack(shotgun_check, shotgun_check, W_Shotgun_Attack);
  89         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_refire3"), shotgun_fire2_02);
  90 }