qcsrc/gamec/w_laser.c

   1 void() laser_ready_01;
   2 void() laser_fire1_01;
   3 void() laser_deselect_01;
   4 void() laser_select_01;
   5
   6 float() laser_check = {return TRUE;};
   7
   8 void(float req) w_laser =
   9 {
  10         if (req == WR_IDLE)
  11                 laser_ready_01();
  12         else if (req == WR_FIRE1)
  13                 weapon_prepareattack(laser_check, laser_check, laser_fire1_01, cvar("g_balance_laser_refire"));
  14         else if (req == WR_RAISE)
  15                 laser_select_01();
  16         else if (req == WR_UPDATECOUNTS)
  17                 self.currentammo = 1;
  18         else if (req == WR_DROP)
  19                 laser_deselect_01();
  20         else if (req == WR_SETUP)
  21                 weapon_setup(WEP_LASER, "w_laser.zym", 0);
  22         else if (req == WR_CHECKAMMO)
  23                 weapon_hasammo = laser_check();
  24 };
  25
  26 void W_Laser_Touch (void)
  27 {
  28         vector  dir;
  29
  30         if (other == self.owner)
  31                 return;
  32         else if (pointcontents (self.origin) == CONTENT_SKY)
  33         {
  34                 remove (self);
  35                 return;
  36         }
  37
  38         dir = normalize (self.owner.origin - self.origin);
  39
  40         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  41         WriteByte (MSG_BROADCAST, TE_FLAMEJET);
  42         WriteCoord (MSG_BROADCAST, self.origin_x);
  43         WriteCoord (MSG_BROADCAST, self.origin_y);
  44         WriteCoord (MSG_BROADCAST, self.origin_z);
  45         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  46         WriteCoord (MSG_BROADCAST, 0);
  47         WriteCoord (MSG_BROADCAST, 0);
  48         WriteByte (MSG_BROADCAST, 155);
  49
  50         te_customflash(self.origin, 160, 0.2, '1 0 0');
  51
  52
  53         self.event_damage = SUB_Null;
  54         RadiusDamage (self, self.owner, cvar("g_balance_laser_damage"), cvar("g_balance_laser_edgedamage"), cvar("g_balance_laser_radius"), world, cvar("g_balance_laser_force"), IT_LASER);
  55         sound (self, CHAN_BODY, "weapons/laserimpact.wav", 1, ATTN_NORM);
  56
  57         remove (self);
  58 }
  59
  60 void W_Laser_Attack (void)
  61 {
  62         local entity missile;
  63         local vector org;
  64
  65         sound (self, CHAN_WEAPON, "weapons/lasergun_fire.wav", 1, ATTN_NORM);
  66         org = self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -12;
  67         //te_customflash(org, 160, 0.2, '1 0 0');
  68
  69         missile = spawn ();
  70         missile.owner = self;
  71         missile.classname = "laserbolt";
  72
  73         missile.movetype = MOVETYPE_FLY;
  74         missile.solid = SOLID_BBOX;
  75
  76         setmodel (missile, "models/laser.mdl");
  77         setsize (missile, '0 0 0', '0 0 0');
  78         setorigin (missile, org);
  79
  80         missile.velocity = v_forward * cvar("g_balance_laser_speed");
  81         missile.angles = vectoangles (missile.velocity);
  82         //missile.glow_color = 250; // 244, 250
  83         //missile.glow_size = 120;
  84         missile.touch = W_Laser_Touch;
  85         missile.think = SUB_Remove;
  86         missile.nextthink = time + 9;
  87
  88         missile.effects = EF_FULLBRIGHT | EF_FULLBRIGHT | EF_LOWPRECISION;
  89 }
  90
  91 // weapon frames
  92
  93 void()  laser_ready_01 =        {weapon_thinkf(WFRAME_IDLE, 0.1, laser_ready_01); self.weaponentity.state = WS_READY;};
  94 void()  laser_select_01 =       {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
  95 void()  laser_deselect_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
  96 void()  laser_fire1_01 =
  97 {
  98         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
  99         weapon_thinkf(WFRAME_FIRE1, 0.3, laser_ready_01);
 100 };
 101