data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 0.015625;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44
  45 string kh_sound_capture = "sound/ctf/capture.wav";
  46 string kh_sound_destroy = "sound/ctf/return.wav";
  47 string kh_sound_drop = "sound/misc/mouseclick.wav";
  48 string kh_sound_collect = "sound/ctf/take.wav";
  49
  50 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  51 float kh_key_dropped, kh_key_carried;
  52
  53 float kh_GetCarrierSprite(float t, float e)
  54 {
  55         if(t == e)           return kh_sprite_friend;
  56         if(t == COLOR_TEAM1) return kh_sprite_red;
  57         if(t == COLOR_TEAM2) return kh_sprite_blue;
  58         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  59         if(t == COLOR_TEAM4) return kh_sprite_pink;
  60         return 0;
  61 }
  62
  63 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  64 {
  65         kh_Controller_Thinkfunc = func;
  66         kh_controller.cnt = t;
  67         if(kh_Controller_Waitmsg != "")
  68                 strunzone(kh_Controller_Waitmsg);
  69         if(msg == "")
  70                 kh_Controller_Waitmsg = "";
  71         else
  72                 kh_Controller_Waitmsg = strzone(msg);
  73         if(t == 0)
  74                 kh_controller.nextthink = time; // force
  75 }
  76
  77 void kh_Controller_Think()
  78 {
  79         entity e;
  80         if(intermission_running)
  81                 return;
  82         if(self.cnt > 0)
  83         {
  84                 if(kh_Controller_Waitmsg != "")
  85                 {
  86                         string s;
  87                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  88                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  89                         else
  90                                 s = kh_Controller_Waitmsg;
  91
  92                         //dprint(s, "\n");
  93
  94                         FOR_EACH_PLAYER(e)
  95                                 if(clienttype(e) == CLIENTTYPE_REAL)
  96                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  97                 }
  98                 self.cnt -= 1;
  99         }
 100         else if(self.cnt == 0)
 101         {
 102                 self.cnt -= 1;
 103                 kh_Controller_Thinkfunc();
 104         }
 105         self.nextthink = time + 1;
 106 }
 107
 108 // frags f: take from cvar * f
 109 // frags 0: no frags
 110 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 111 {
 112         string s;
 113         if(intermission_running)
 114                 return;
 115         if(frags_player)
 116                 player.frags = player.frags + floor(0.5 + frags_player);
 117         if(frags_owner)
 118                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 119         if(!cvar("sv_eventlog"))
 120                 return;
 121         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 122         s = strcat(s, ":", ftos(frags_player));
 123         if(key && key.owner)
 124                 s = strcat(s, ":", ftos(key.owner.playerid));
 125         else
 126                 s = strcat(s, ":0");
 127         s = strcat(s, ":", ftos(frags_owner), ":");
 128         if(key)
 129                 s = strcat(s, key.netname);
 130         GameLogEcho(s, FALSE);
 131 }
 132
 133 vector kh_AttachedOrigin(entity e)
 134 {
 135         if(e.tag_entity)
 136         {
 137                 makevectors(e.tag_entity.angles);
 138                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 139         }
 140         else
 141                 return e.origin;
 142 }
 143
 144 void kh_Key_Attach(entity key)
 145 {
 146 #ifdef KH_PLAYER_USE_ATTACHMENT
 147         entity first;
 148         first = key.owner.kh_next;
 149         if(key == first)
 150         {
 151                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 152                 if(key.kh_next)
 153                 {
 154                         setattachment(key.kh_next, key, "");
 155                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 156                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 157                         key.kh_next.angles = '0 0 0';
 158                 }
 159                 else
 160                         setorigin(key, KH_PLAYER_ATTACHMENT);
 161                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 162         }
 163         else
 164         {
 165                 setattachment(key, key.kh_prev, "");
 166                 if(key.kh_next)
 167                         setattachment(key.kh_next, key, "");
 168                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 169                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 170                 key.angles = '0 0 0';
 171         }
 172 #else
 173         setattachment(key, key.owner, "");
 174         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 175         key.angles_y -= key.owner.angles_y;
 176 #endif
 177         key.flags = 0;
 178         key.solid = SOLID_NOT;
 179         key.movetype = MOVETYPE_NONE;
 180         key.team = key.owner.team;
 181         key.nextthink = time;
 182         key.damageforcescale = 0;
 183         key.modelindex = kh_key_carried;
 184 }
 185
 186 void kh_Key_Detach(entity key)
 187 {
 188 #ifdef KH_PLAYER_USE_ATTACHMENT
 189         entity first;
 190         first = key.owner.kh_next;
 191         if(key == first)
 192         {
 193                 if(key.kh_next)
 194                 {
 195                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 196                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 197                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 198                 }
 199         }
 200         else
 201         {
 202                 if(key.kh_next)
 203                         setattachment(key.kh_next, key.kh_prev, "");
 204                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 205         }
 206         // in any case:
 207         setattachment(key, world, "");
 208         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 209         key.angles = key.owner.angles;
 210 #else
 211         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 212         setattachment(key, world, "");
 213         key.angles_y += key.owner.angles_y;
 214 #endif
 215         key.aiment = world;
 216         key.flags = FL_ITEM;
 217         key.solid = SOLID_TRIGGER;
 218         key.movetype = MOVETYPE_TOSS;
 219         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 220         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 221         // let key.team stay
 222         key.modelindex = kh_key_dropped;
 223 }
 224
 225 void kh_Key_AssignTo(entity key, entity player)
 226 {
 227         if(key.owner == player)
 228                 return;
 229
 230         if(key.owner)
 231         {
 232                 kh_Key_Detach(key);
 233
 234                 // remove from linked list
 235                 if(key.kh_next)
 236                         key.kh_next.kh_prev = key.kh_prev;
 237                 key.kh_prev.kh_next = key.kh_next;
 238                 key.kh_next = world;
 239                 key.kh_prev = world;
 240
 241                 if(key.owner.kh_next == world)
 242                 {
 243                         // No longer a key carrier
 244                         WaypointSprite_DetachCarrier(key.owner);
 245                 }
 246         }
 247
 248         key.owner = player;
 249
 250         if(player)
 251         {
 252                 // insert into linked list
 253                 key.kh_next = player.kh_next;
 254                 key.kh_prev = player;
 255                 player.kh_next = key;
 256                 if(key.kh_next)
 257                         key.kh_next.kh_prev = key;
 258
 259                 kh_Key_Attach(key);
 260
 261                 if(key.kh_next == world)
 262                 {
 263                         // player is now a key carrier
 264                         WaypointSprite_AttachCarrier("", player);
 265                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 266                         player.waypointsprite_attachedforcarrier.team = player.team;
 267                 }
 268         }
 269
 270         key.pusher = world;
 271 }
 272
 273 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 274 {
 275         if(self.owner)
 276                 return;
 277         if(vlen(force) <= 0)
 278                 return;
 279         if(time > self.pushltime)
 280                 if(attacker.classname == "player")
 281                         self.team = attacker.team;
 282 }
 283
 284 void kh_Key_Spawn(entity initial_owner, float angle)
 285 {
 286         entity key;
 287         key = spawn();
 288         key.classname = STR_ITEM_KH_KEY;
 289         key.touch = kh_Key_Touch;
 290         key.think = kh_Key_Think;
 291         key.nextthink = time;
 292         key.items = IT_KEY1 | IT_KEY2;
 293         key.cnt = angle;
 294         key.angles = '0 360 0' * random();
 295         key.event_damage = kh_Key_Damage;
 296         key.modelindex = kh_key_dropped;
 297         key.model = "key";
 298         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 299
 300         switch(initial_owner.team)
 301         {
 302                 case COLOR_TEAM1:
 303                         key.netname = "^1red key";
 304                         key.colormod = '103 0 0' * KH_KEY_BRIGHTNESS;
 305                         break;
 306                 case COLOR_TEAM2:
 307                         key.netname = "^4blue key";
 308                         key.colormod = '35 35 191' * KH_KEY_BRIGHTNESS;
 309                         break;
 310                 case COLOR_TEAM3:
 311                         key.netname = "^3yellow key";
 312                         key.colormod = '187 167 15' * KH_KEY_BRIGHTNESS;
 313                         break;
 314                 case COLOR_TEAM4:
 315                         key.netname = "^6pink key";
 316                         key.colormod = '139 79 107' * KH_KEY_BRIGHTNESS;
 317                         break;
 318                 default:
 319                         key.netname = "NETGIER key";
 320                         key.colormod = '1 1 1';
 321                         break;
 322         }
 323
 324         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 325
 326         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 327         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 328
 329         kh_Key_AssignTo(key, initial_owner);
 330 }
 331
 332 void kh_Key_Remove(entity key)
 333 {
 334         entity o;
 335         o = key.owner;
 336         kh_Key_AssignTo(key, world);
 337         if(o) // it was attached
 338                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 339         else // it was dropped
 340                 WaypointSprite_DetachCarrier(key);
 341
 342         remove(key);
 343 }
 344
 345 // -1 when no team completely owns all keys yet
 346 float kh_Key_AllOwnedByWhichTeam()
 347 {
 348         entity key;
 349         float teem;
 350
 351         teem = -1;
 352         FOR_EACH_KH_KEY(key)
 353         {
 354                 if(!key.owner)
 355                         return -1;
 356                 if(teem == -1)
 357                         teem = key.team;
 358                 else if(teem != key.team)
 359                         return -1;
 360         }
 361         return teem;
 362 }
 363
 364 void kh_Key_Collect(entity key, entity player)
 365 {
 366         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 367
 368         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 369         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 370         kh_Key_AssignTo(key, player);
 371
 372         if(kh_Key_AllOwnedByWhichTeam() != -1)
 373         {
 374                 kh_interferemsg_time = time + 0.2;
 375                 kh_interferemsg_team = player.team;
 376         }
 377 }
 378
 379 void kh_Key_DropAll(entity player)
 380 {
 381         entity key;
 382         entity mypusher;
 383         if(player.kh_next)
 384         {
 385                 mypusher = world;
 386                 if(player.pusher)
 387                         if(time < player.pushltime)
 388                                 mypusher = player.pusher;
 389                 while((key = player.kh_next))
 390                 {
 391                         kh_Scores_Event(player, key, "losekey", 0, 0);
 392                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 393                         kh_Key_AssignTo(key, world);
 394                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 395                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 396                         key.pusher = mypusher;
 397                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 398                 }
 399                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 400         }
 401 }
 402
 403 void kh_Key_Touch()
 404 {
 405         if(intermission_running)
 406                 return;
 407
 408         if(self.owner) // already carried
 409                 return;
 410         if(other.classname != "player")
 411                 return;
 412         if(other.deadflag != DEAD_NO)
 413                 return;
 414         if(other == self.enemy)
 415                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 416                         return; // you just dropped it!
 417         kh_Key_Collect(self, other);
 418 }
 419
 420 void kh_Key_Think()
 421 {
 422         entity head;
 423
 424         if(intermission_running)
 425                 return;
 426
 427 #ifdef KH_KEY_ATTACHMENT_DEBUG
 428         if(self.kh_prev == self.owner)
 429         {
 430                 if(cvar_string("_angles") != "")
 431                 {
 432                         self.angles = stov(cvar_string("_angles"));
 433                         self.origin = stov(cvar_string("_origin"));
 434                 }
 435         }
 436 #endif
 437
 438         if(self.owner)
 439         {
 440 #ifndef KH_PLAYER_USE_ATTACHMENT
 441                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 442                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 443 #endif
 444
 445                 if(self.owner.buttonuse)
 446                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 447                 {
 448                         self.owner.kh_droptime = time;
 449                         self.kh_droptime = time; // prevent collecting this one for some time
 450                         self.enemy = self.owner;
 451                         self.pusher = world;
 452                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 453                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 454                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 455                         makevectors(self.owner.v_angle);
 456                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 457                         kh_Key_AssignTo(self, world);
 458                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 459                 }
 460         }
 461
 462         // if in nodrop or time over, end the round
 463         if(!self.owner)
 464                 if(time > self.pain_finished)
 465                         kh_LoserTeam(self.team, self);
 466
 467         if(self.owner)
 468         if(kh_Key_AllOwnedByWhichTeam() != -1)
 469         {
 470                 entity key;
 471                 vector p;
 472                 p = self.owner.origin;
 473                 FOR_EACH_KH_KEY(key)
 474                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 475                                 goto not_winning;
 476                 kh_WinnerTeam(self.team);
 477 :not_winning
 478         }
 479
 480         if(kh_interferemsg_time && time > kh_interferemsg_time)
 481         {
 482                 kh_interferemsg_time = 0;
 483                 FOR_EACH_PLAYER(head)
 484                 {
 485                         if(head.team == kh_interferemsg_team)
 486                                 if(head.kh_next)
 487                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 488                                 else
 489                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 490                         else
 491                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 492                 }
 493         }
 494
 495         self.nextthink = time + 0.05;
 496 }
 497
 498 void kh_WinnerTeam(float teem)
 499 {
 500         // all key carriers get some points
 501         vector firstorigin, lastorigin;
 502         float first;
 503         entity key;
 504         float score;
 505         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 506         DistributeEvenly_Init(score, kh_teams);
 507         // twice the score for 3 team games, three times the score for 4 team games!
 508         // note: for a win by destroying the key, this should NOT be applied
 509         FOR_EACH_KH_KEY(key)
 510                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 511
 512         first = TRUE;
 513         FOR_EACH_KH_KEY(key)
 514                 if(key.owner.kh_next == key)
 515                 {
 516                         if(!first)
 517                                 bprint("^7, ");
 518                         bprint(key.owner.netname);
 519                         first = FALSE;
 520                 }
 521         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 522
 523         first = TRUE;
 524         FOR_EACH_KH_KEY(key)
 525         {
 526                 vector thisorigin;
 527
 528                 thisorigin = kh_AttachedOrigin(key);
 529
 530                 if(!first)
 531                         te_lightning2(world, lastorigin, thisorigin);
 532                 lastorigin = thisorigin;
 533                 if(first)
 534                         firstorigin = thisorigin;
 535                 first = FALSE;
 536         }
 537         if(kh_teams > 2)
 538         {
 539                 te_lightning2(world, lastorigin, firstorigin);
 540         }
 541
 542         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 543         kh_FinishRound();
 544 }
 545
 546 void kh_LoserTeam(float teem, entity lostkey)
 547 {
 548         entity player, key, attacker;
 549         float players;
 550         float keys;
 551
 552         attacker = world;
 553         if(lostkey.pusher)
 554                 if(lostkey.pusher.team != teem)
 555                         if(lostkey.pusher.classname == "player")
 556                                 attacker = lostkey.pusher;
 557
 558         players = keys = 0;
 559
 560         if(attacker)
 561         {
 562                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 563                 centerprint(attacker, "Your push is the best!\n\n\n");
 564                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 565         }
 566         else
 567         {
 568                 float of, fragsleft, i, j, thisteam;
 569                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 570
 571                 FOR_EACH_PLAYER(player)
 572                         if(player.team != teem)
 573                                 ++players;
 574
 575                 FOR_EACH_KH_KEY(key)
 576                         if(key.owner && key.team != teem)
 577                                 ++keys;
 578
 579                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 580
 581                 FOR_EACH_KH_KEY(key)
 582                         if(key.owner && key.team != teem)
 583                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 584
 585                 fragsleft = DistributeEvenly_Get(players);
 586
 587                 // Now distribute these among all other teams...
 588                 j = kh_teams - 1;
 589                 for(i = 0; i < kh_teams; ++i)
 590                 {
 591                         thisteam = kh_Team_ByID(i);
 592                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 593                                 continue;
 594
 595                         players = 0;
 596                         FOR_EACH_PLAYER(player)
 597                                 if(player.team == thisteam)
 598                                         ++players;
 599
 600                         DistributeEvenly_Init(fragsleft, j);
 601                         fragsleft = DistributeEvenly_Get(j - 1);
 602                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 603
 604                         FOR_EACH_PLAYER(player)
 605                                 if(player.team == thisteam)
 606                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 607
 608                         --j;
 609                 }
 610
 611                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 612         }
 613         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 614
 615         kh_FinishRound();
 616 }
 617
 618 void kh_FinishRound()
 619 {
 620         // prepare next round
 621         kh_interferemsg_time = 0;
 622         entity key;
 623         FOR_EACH_KH_KEY(key)
 624                 kh_Key_Remove(key);
 625
 626         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 627 }
 628
 629 string kh_CheckEnoughPlayers()
 630 {
 631         float i, players, teem;
 632         entity player;
 633         string result;
 634         result = "";
 635
 636         // find a random player per team
 637         for(i = 0; i < kh_teams; ++i)
 638         {
 639                 teem = kh_Team_ByID(i);
 640                 players = 0;
 641                 FOR_EACH_PLAYER(player)
 642                         if(player.deadflag == DEAD_NO)
 643                                 if(!player.buttonchat)
 644                                         if(player.team == teem)
 645                                                 ++players;
 646                 if(players == 0)
 647                 {
 648                         if(result != "")
 649                                 result = strcat(result, ", ");
 650                         result = strcat(result, ColoredTeamName(teem));
 651                 }
 652         }
 653         return result;
 654 }
 655
 656 void kh_WaitForPlayers()
 657 {
 658         string teams_missing;
 659         teams_missing = kh_CheckEnoughPlayers();
 660         if(teams_missing == "")
 661                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 662         else
 663                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 664 }
 665
 666 void kh_StartRound()
 667 {
 668         string teams_missing;
 669         float i, players, teem;
 670         entity player;
 671
 672         teams_missing = kh_CheckEnoughPlayers();
 673         if(teams_missing != "")
 674         {
 675                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 676                 return;
 677         }
 678
 679         FOR_EACH_PLAYER(player)
 680                 if(clienttype(player) == CLIENTTYPE_REAL)
 681                         centerprint_expire(player, CENTERPRIO_SPAM);
 682
 683         for(i = 0; i < kh_teams; ++i)
 684         {
 685                 teem = kh_Team_ByID(i);
 686                 players = 0;
 687                 entity my_player;
 688                 FOR_EACH_PLAYER(player)
 689                         if(player.deadflag == DEAD_NO)
 690                                 if(!player.buttonchat)
 691                                         if(player.team == teem)
 692                                         {
 693                                                 ++players;
 694                                                 if(random() * players <= 1)
 695                                                         my_player = player;
 696                                         }
 697                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 698                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 699                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 700         }
 701
 702         kh_tracking_enabled = FALSE;
 703         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 704 }
 705
 706 void kh_setstatus()
 707 {
 708         if(kh_teams)
 709         {
 710                 float kh_KEY;
 711                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 712                 if(self.kh_next)
 713                         self.items = self.items | kh_KEY;
 714                 else
 715                         self.items = self.items - (self.items & kh_KEY);
 716         }
 717 }
 718
 719 void kh_EnableTrackingDevice()
 720 {
 721         entity player;
 722
 723         FOR_EACH_PLAYER(player)
 724                 if(clienttype(player) == CLIENTTYPE_REAL)
 725                         centerprint_expire(player, CENTERPRIO_SPAM);
 726
 727         kh_tracking_enabled = TRUE;
 728 }
 729
 730 float kh_Key_waypointsprite_for_player(entity e)
 731 {
 732         if(!kh_tracking_enabled)
 733                 return 0;
 734         if(!self.owner)
 735                 return kh_sprite_dropped;
 736         if(!self.owner.owner)
 737                 return kh_sprite_dropped;
 738         return 0; // draw only when key is not owned
 739 }
 740
 741 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 742 {
 743         if(e.classname != "player" || self.team != e.team)
 744                 if(!kh_tracking_enabled)
 745                         return 0;
 746
 747         // e is spectator? That's no team mate...
 748         if(e.classname != "player")
 749                 return kh_GetCarrierSprite(self.team, -1);
 750
 751         // e is no key carrier: simple case...
 752         if(!e.kh_next)
 753                 return kh_GetCarrierSprite(self.team, e.team);
 754
 755         // e is a key carrier: if any key is dropped or owned by another team, show
 756         // the carrier sprite; otherwise show run here
 757         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 758                 return kh_sprite_finish;
 759
 760         return kh_GetCarrierSprite(self.team, e.team);
 761 }
 762
 763 float kh_HandleFrags(entity attacker, entity targ, float f)
 764 {
 765         if(f <= 0)
 766                 return f;
 767         if(attacker == targ)
 768                 return f;
 769
 770         if(targ.kh_next)
 771                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 772
 773         return f;
 774 }
 775
 776 void kh_init()
 777 {
 778         precache_sound(kh_sound_capture);
 779         precache_sound(kh_sound_destroy);
 780         precache_sound(kh_sound_drop);
 781         precache_sound(kh_sound_collect);
 782
 783         precache_model("models/sprites/key-dropped.sp2");
 784         precache_model("models/sprites/keycarrier-finish.sp2");
 785         precache_model("models/sprites/keycarrier-friend.sp2");
 786         precache_model("models/sprites/keycarrier-red.sp2");
 787         precache_model("models/sprites/keycarrier-blue.sp2");
 788         precache_model("models/sprites/keycarrier-yellow.sp2");
 789         precache_model("models/sprites/keycarrier-pink.sp2");
 790 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 791         precache_model("models/keyhunt/key-carried.md3");
 792 #endif
 793         precache_model("models/keyhunt/key.md3");
 794
 795         // setup variables
 796         kh_teams = cvar("g_keyhunt_teams_override");
 797         if(kh_teams < 2)
 798                 kh_teams = cvar("g_keyhunt_teams");
 799         kh_teams = bound(2, kh_teams, 4);
 800
 801         // make a KH entity for controlling the game
 802         kh_controller = spawn();
 803         kh_controller.think = kh_Controller_Think;
 804         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 805
 806         setmodel(kh_controller, "models/keyhunt/key.md3");
 807         kh_key_dropped = kh_controller.modelindex;
 808         /*
 809         dprint(vtos(kh_controller.mins));
 810         dprint(vtos(kh_controller.maxs));
 811         dprint("\n");
 812         */
 813 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 814         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 815         kh_key_carried = kh_controller.modelindex;
 816 #else
 817         kh_key_carried = kh_key_dropped;
 818 #endif
 819         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 820         kh_sprite_dropped = kh_controller.modelindex;
 821         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 822         kh_sprite_finish = kh_controller.modelindex;
 823         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 824         kh_sprite_friend = kh_controller.modelindex;
 825         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 826         kh_sprite_red = kh_controller.modelindex;
 827         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 828         kh_sprite_blue = kh_controller.modelindex;
 829         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 830         kh_sprite_pink = kh_controller.modelindex;
 831         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 832         kh_sprite_yellow = kh_controller.modelindex;
 833         setmodel(kh_controller, "");
 834 }
 835
 836 void kh_finalize()
 837 {
 838         // to be called before intermission
 839         kh_FinishRound();
 840         remove(kh_controller);
 841         kh_controller = world;
 842 }