data/qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2
   3 void make_mapinfo_Think()
   4 {
   5         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 1))
   6         {
   7                 print("Done rebuiling mapinfos.\n");
   8                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
   9                 remove(self);
  10         }
  11         else
  12         {
  13                 self.think = make_mapinfo_Think;
  14                 self.nextthink = time;
  15         }
  16 }
  17
  18 void GameCommand(string command)
  19 {
  20         float argc;
  21         entity client;
  22         float entno;
  23         argc = tokenize(command);
  24
  25         if(argv(0) == "help" || argc == 0)
  26         {
  27                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
  28                 print("  adminmsg clientnumber \"message\"\n");
  29                 print("  teamstatus\n");
  30                 print("  printstats\n");
  31                 print("  make_mapinfo\n");
  32                 print("  gametype dm|ctf|...\n");
  33                 print("  savedb filename\n");
  34                 print("  dumpdb filename\n");
  35                 print("  loaddb filename\n");
  36                 GameCommand_Vote("help", world);
  37                 GameCommand_Ban("help");
  38                 GameCommand_Generic("help");
  39                 return;
  40         }
  41
  42         if(GameCommand_Vote(command, world))
  43                 return;
  44
  45         if(GameCommand_Ban(command))
  46                 return;
  47
  48         if(GameCommand_Generic(command))
  49                 return;
  50
  51         if(argv(0) == "teamstatus")
  52         {
  53                 PrintScoreboard(world);
  54                 return;
  55         }
  56
  57         if(argv(0) == "printstats")
  58         {
  59                 DumpStats(FALSE);
  60                 return;
  61         }
  62
  63         if(argv(0) == "make_mapinfo")
  64         {
  65                 entity e;
  66                 e = spawn();
  67                 e.classname = "make_mapinfo";
  68                 e.think = make_mapinfo_Think;
  69                 e.nextthink = time;
  70                 MapInfo_Enumerate();
  71                 return;
  72         }
  73
  74         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
  75         {
  76                 CampaignLevelWarp(stof(argv(1)));
  77                 return;
  78         }
  79
  80         if(argv(0) == "gotomap") if(argc == 2)
  81         {
  82                 print(GotoMap(argv(1)), "\n");
  83                 return;
  84         }
  85
  86 #ifdef MAPINFO
  87         if(argv(0) == "gametype") if(argc == 2)
  88         {
  89                 float t, tsave;
  90                 string s;
  91                 s = argv(1);
  92                 t = MapInfo_Type_FromString(s);
  93                 tsave = MapInfo_CurrentGametype();
  94                 if(t)
  95                 {
  96                         MapInfo_SwitchGameType(t);
  97                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
  98                         if(MapInfo_count > 0)
  99                         {
 100                                 bprint("Game type successfully switched to ", s, "\n");
 101                         }
 102                         else
 103                         {
 104                                 bprint("Cannot use this game type: no map for it found\n");
 105                                 MapInfo_SwitchGameType(tsave);
 106                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 107                         }
 108                 }
 109                 else
 110                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 111                 return;
 112         }
 113 #endif
 114
 115         if(argv(0) == "adminmsg") if(argc == 3)
 116         {
 117                 entno = stof(argv(1));
 118                 client = world;
 119                 if(entno <= maxclients)
 120                         client = edict_num(entno);
 121                 if(client.flags & FL_CLIENT)
 122                 {
 123                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
 124                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
 125                         print("Message sent to ", client.netname, "\n");
 126                 }
 127                 else
 128                         print("Client not found\n");
 129                 return;
 130         }
 131
 132         if(argv(0) == "savedb") if(argc == 2)
 133         {
 134                 db_save(ServerProgsDB, argv(1));
 135                 print("DB saved.\n");
 136                 return;
 137         }
 138
 139         if(argv(0) == "dumpdb") if(argc == 2)
 140         {
 141                 db_dump(ServerProgsDB, argv(1));
 142                 print("DB dumped.\n");
 143                 return;
 144         }
 145
 146         if(argv(0) == "loaddb") if(argc == 2)
 147         {
 148                 db_close(ServerProgsDB);
 149                 ServerProgsDB = db_load(argv(1));
 150                 print("DB loaded.\n");
 151                 return;
 152         }
 153         if (argv(0) == "nospectators")
 154         {
 155                 blockSpectators = 1;
 156                 local entity plr;
 157                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 158                 {
 159                         if(plr.classname == "spectator" || plr.classname == "observer")
 160                         {
 161                                 plr.spectatortime = time;
 162                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 163                         }
 164                 }
 165                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
 166                 return;
 167         }
 168         if (argv(0) == "lockteams")
 169         {
 170                 if(teamplay)
 171                 {
 172                         lockteams = 1;
 173                         bprint("^1The teams are now locked.\n");
 174                 }
 175                 else
 176                         bprint("That command can only be used in a team-based gamemode.\n");
 177                 return;
 178         }
 179         if (argv(0) == "unlockteams")
 180         {
 181                 if(teamplay)
 182                 {
 183                         lockteams = 0;
 184                         bprint("^1The teams are now unlocked.\n");
 185                 }
 186                 else
 187                         bprint("That command can only be used in a team-based gamemode.\n");
 188                 return;
 189         }
 190         if (argv(0) == "movetoteam") if(argc == 3)
 191         {
 192                 entno = stof(argv(1));
 193                 client = world;
 194                 if(entno <= maxclients)
 195                         client = edict_num(entno);
 196                 if(client.flags & FL_CLIENT)
 197                 {
 198                         float lt;
 199                         lt = lockteams;
 200                         lockteams = 0;
 201
 202                         self = client;
 203                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
 204
 205                         lockteams = lt;
 206                 }
 207                 else
 208                         print("Client not found\n");
 209                 return;
 210         }
 211
 212         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
 213 }
 214