data/qcsrc/server/cl_weapons.qc

   1 // switch between weapons
   2 void W_SwitchWeapon(float imp)
   3 {
   4         if (self.weapon != imp)
   5         if (client_hasweapon(self, imp, TRUE, TRUE))
   6                 W_SwitchWeapon_Force(self, imp);
   7 };
   8
   9 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain)
  10 {
  11         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast;
  12         n = tokenize(weaponorder);
  13         switchtonext = switchtolast = 0;
  14         first_valid = prev_valid = 0;
  15
  16         if(dir == 0)
  17                 switchtonext = 1;
  18
  19         for(i = 0; i < n; ++i)
  20         {
  21                 weaponwant = stof(argv(i));
  22
  23                 if(imp >= 0)
  24                         if((get_weaponinfo(weaponwant)).impulse != imp)
  25                                 continue;
  26
  27                 if(client_hasweapon(pl, weaponwant, TRUE, FALSE))
  28                 {
  29                         if(switchtonext)
  30                                 return weaponwant;
  31                         if(!first_valid)
  32                                 first_valid = weaponwant;
  33                         if(weaponwant == pl.switchweapon)
  34                         {
  35                                 if(dir >= 0)
  36                                         switchtonext = 1;
  37                                 else if(prev_valid)
  38                                         return prev_valid;
  39                                 else
  40                                         switchtolast = 1;
  41                         }
  42                         prev_valid = weaponwant;
  43                 }
  44         }
  45         if(first_valid)
  46         {
  47                 if(switchtolast)
  48                         return prev_valid;
  49                 else
  50                         return first_valid;
  51         }
  52         // complain
  53         if(complain)
  54         {
  55                 for(i = 0; i < n; ++i)
  56                 {
  57                         weaponwant = stof(argv(i));
  58                         if(imp >= 0)
  59                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  60                                         continue;
  61                         client_hasweapon(pl, weaponwant, TRUE, TRUE);
  62                 }
  63         }
  64         return 0;
  65 }
  66
  67 void W_CycleWeapon(string weaponorder, float dir)
  68 {
  69         float w;
  70         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1);
  71         if(w > 0)
  72                 W_SwitchWeapon(w);
  73 }
  74
  75 void W_NextWeaponOnImpulse(float imp)
  76 {
  77         float w;
  78         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1);
  79         if(w > 0)
  80                 W_SwitchWeapon(w);
  81 }
  82
  83 // next weapon
  84 void W_NextWeapon()
  85 {
  86         W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
  87 }
  88
  89 // prev weapon
  90 void W_PreviousWeapon()
  91 {
  92         W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
  93 }
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         string neworder;
  98         float i, n, w;
  99
 100         n = tokenize(order);
 101         for(i = 0; i < n; ++i)
 102         {
 103                 w = stof(argv(i));
 104                 if(w >= WEP_FIRST && w <= WEP_LAST && w == floor(w))
 105                         neworder = strcat(neworder, ftos(w), " ");
 106         }
 107
 108         if(complete)
 109         {
 110                 n = tokenize(neworder);
 111                 for(w = WEP_LAST; w >= WEP_FIRST; --w)
 112                 {
 113                         for(i = 0; i < n; ++i)
 114                                 if(stof(argv(i)) == w)
 115                                         break;
 116                         if(i == n) // not found
 117                                 neworder = strcat(neworder, ftos(w), " ");
 118                 }
 119         }
 120
 121         return substring(neworder, 0, strlen(neworder) - 1);
 122 }
 123
 124 string W_FixWeaponOrder_AllowIncomplete(string order)
 125 {
 126         return W_FixWeaponOrder(order, 0);
 127 }
 128
 129 string W_FixWeaponOrder_ForceComplete(string order)
 130 {
 131         if(order == "")
 132                 order = cvar_string("cl_weaponpriority");
 133         return W_FixWeaponOrder(order, 1);
 134 }
 135
 136 float w_getbestweapon(entity e)
 137 {
 138         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, 0);
 139 };
 140
 141 // generic weapons table
 142 // TODO should they be macros instead?
 143 float weapon_action(float wpn, float wrequest)
 144 {
 145         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 146 };
 147
 148 string W_Name(float weaponid)
 149 {
 150         return (get_weaponinfo(weaponid)).message;
 151 }
 152
 153 float W_WeaponBit(float wpn)
 154 {
 155         return (get_weaponinfo(wpn)).weapons;
 156 }
 157
 158 float W_AmmoItemCode(float wpn)
 159 {
 160         return (get_weaponinfo(wpn)).items;
 161 }
 162
 163 // think function for tossed weapons
 164 void thrown_wep_think()
 165 {
 166         self.solid = SOLID_TRIGGER;
 167         self.owner = world;
 168         SUB_SetFade(self, time + 20, 1);
 169         setorigin(self, self.origin);
 170 };
 171
 172 // toss current weapon
 173 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 174 {
 175         local float w, ammo, wb, wa;
 176         local entity wep, e;
 177         local .float ammofield;
 178
 179         w = self.weapon;
 180         if (w == 0)
 181                 return; // just in case
 182         if (w == WEP_LASER)
 183                 return;
 184         if (g_rocketarena)
 185                 return;
 186         if (g_lms)
 187                 return;
 188         if (g_nixnex)
 189                 return;
 190         if (!cvar("g_pickup_items"))
 191                 return;
 192
 193         e = self;
 194         wep = spawn();
 195         self = wep;
 196
 197         setorigin(wep, e.origin + delta);
 198         makevectors(e.angles);
 199         wep.classname = "droppedweapon";
 200         wep.velocity = velo; // e.velocity * 0.5 + v_forward * 750;
 201         SUB_SetFade(wep, time + 20, 1);
 202
 203         wa = W_AmmoItemCode(w);
 204         if(wa == IT_SUPERWEAPON || wa == 0)
 205         {
 206                 wb = W_WeaponBit(w);
 207                 if(!(e.weapons & wb))
 208                 {
 209                         remove(wep);
 210                         goto leave;
 211                 }
 212                 Item_SpawnByWeaponCode(w);
 213                 if(startitem_failed)
 214                         goto leave;
 215                 if(e.weapons & wb)
 216                         if(e.health >= 1)
 217                                 sprint(e, strcat("You dropped the ^2", wep.netname, "\n"));
 218         }
 219         else
 220         {
 221                 ammofield = Item_CounterField(wa);
 222                 wb = W_WeaponBit(w);
 223                 if(!(e.weapons & wb))
 224                 {
 225                         remove(wep);
 226                         goto leave;
 227                 }
 228                 Item_SpawnByWeaponCode(w);
 229                 if(startitem_failed)
 230                         goto leave;
 231                 if(doreduce)
 232                 {
 233                         ammo = min(e.ammofield, wep.ammofield);
 234                         wep.ammofield = ammo;
 235                         e.ammofield -= ammo;
 236                 }
 237                 if(e.weapons & wb)
 238                         if(e.health >= 1)
 239                                 sprint(e, strcat("You dropped the ^2", wep.netname, " with ", ftos(wep.ammofield), " ammo", "\n"));
 240         }
 241
 242         wep.owner = e;
 243         setorigin(wep, wep.origin);
 244         wep.nextthink = time + 0.5;
 245         wep.think = thrown_wep_think;
 246         wep.classname = "droppedweapon";
 247         wep.flags = wep.flags | FL_TOSSED;
 248         e.weapons = e.weapons - (e.weapons & wb);
 249         wep.colormap = e.colormap;
 250         W_SwitchWeapon_Force(e, w_getbestweapon(e));
 251
 252 :leave
 253         self = e;
 254 };
 255
 256 // Bringed back weapon frame
 257 void W_WeaponFrame()
 258 {
 259         if((arena_roundbased && time < warmup) || ((time < restart_countdown) && !cvar("sv_ready_restart_after_countdown")))
 260                 return;
 261
 262         if (!self.weaponentity || self.health < 1)
 263                 return; // Dead player can't use weapons and injure impulse commands
 264
 265         if(!self.switchweapon)
 266         {
 267                 self.weapon = 0;
 268                 self.weaponentity.state = WS_CLEAR;
 269                 return;
 270         }
 271
 272         makevectors(self.v_angle);
 273
 274         // Change weapon
 275         if (self.weapon != self.switchweapon)
 276         {
 277                 if (self.weaponentity.state == WS_CLEAR)
 278                 {
 279                         player_setanim(self.anim_draw, FALSE, TRUE, TRUE);
 280                         self.weaponentity.state = WS_RAISE;
 281                         weapon_action(self.switchweapon, WR_SETUP);
 282                         // VorteX: add player model weapon select frame here
 283                         // setcustomframe(PlayerWeaponRaise);
 284                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 285                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 286                 }
 287                 else if (self.weaponentity.state == WS_READY)
 288                 {
 289 #ifndef INDEPENDENT_ATTACK_FINISHED
 290                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 291                         {
 292 #endif
 293                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 294                         self.weaponentity.state = WS_DROP;
 295                         // set up weapon switch think in the future, and start drop anim
 296                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 297                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 298 #ifndef INDEPENDENT_ATTACK_FINISHED
 299                         }
 300 #endif
 301                 }
 302         }
 303
 304         float wb;
 305         wb = W_WeaponBit(self.weapon);
 306
 307         // call the think code which may fire the weapon
 308         // and do so multiple times to resolve framerate dependency issues if the
 309         // server framerate is very low and the weapon fire rate very high
 310         local float c;
 311         c = 0;
 312         while (c < 5)
 313         {
 314                 c = c + 1;
 315                 if(wb && self.weapons & wb == 0)
 316                 {
 317                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 318                         wb = 0;
 319                 }
 320                 if(wb)
 321                         weapon_action(self.weapon, WR_THINK);
 322                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 323                         self.weapon_think();
 324         }
 325
 326         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 327         //if (ATTACK_FINISHED(self) < time)
 328         //      ATTACK_FINISHED(self) = time;
 329
 330         //if (self.weapon_nextthink < time)
 331         //      self.weapon_nextthink = time;
 332
 333         // update currentammo incase it has changed
 334         if (self.items & IT_CELLS)
 335                 self.currentammo = self.ammo_cells;
 336         else if (self.items & IT_ROCKETS)
 337                 self.currentammo = self.ammo_rockets;
 338         else if (self.items & IT_NAILS)
 339                 self.currentammo = self.ammo_nails;
 340         else if (self.items & IT_SHELLS)
 341                 self.currentammo = self.ammo_shells;
 342         else
 343                 self.currentammo = 1;
 344
 345 };
 346
 347 float nixnex_weapon;
 348 float nixnex_nextchange;
 349 float nixnex_nextweapon;
 350 .float nixnex_lastchange_id;
 351 .float nixnex_lastinfotime;
 352 .float nixnex_nextincr;
 353
 354 void Nixnex_ChooseNextWeapon()
 355 {
 356         float numberof, id;
 357         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 358         if(g_nixnex_with_laser)
 359                 numberof = numberof - 1;
 360         id = WEP_FIRST + ceil(random() * numberof) - 1;
 361
 362         if(g_nixnex_with_laser) // skip the laser if needed
 363                 id = id + 1;
 364
 365         if(id >= nixnex_weapon) // skip the current weapon
 366                 id = id + 1;
 367
 368         if(id < WEP_FIRST) // can't happen, but to be sure...
 369         {
 370                 dprint("Won't happen (id < WEP_FIRST)\n");
 371                 id = WEP_FIRST;
 372         }
 373         if(id > WEP_LAST) // either
 374         {
 375                 dprint("Won't happen (id > WEP_LAST)\n");
 376                 id = WEP_LAST;
 377         }
 378
 379         nixnex_nextweapon = id;
 380 }
 381
 382 void Nixnex_GiveCurrentWeapon()
 383 {
 384         float dt;
 385         if(g_nixnex)
 386         {
 387                 if(!nixnex_nextweapon)
 388                         Nixnex_ChooseNextWeapon();
 389
 390                 dt = ceil(nixnex_nextchange - time);
 391
 392                 if(dt <= 0)
 393                 {
 394                         nixnex_weapon = nixnex_nextweapon;
 395                         nixnex_nextweapon = 0;
 396                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 397                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 398                 }
 399
 400                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 401                 {
 402                         self.nixnex_lastchange_id = nixnex_nextchange;
 403                         if (cvar("g_use_ammunition"))
 404                         {
 405                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 406                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 407                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 408                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 409                         }
 410                         else
 411                         {
 412                                 self.ammo_shells = cvar("g_pickup_shells_max");
 413                                 self.ammo_nails = cvar("g_pickup_nails_max");
 414                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 415                                 self.ammo_cells = cvar("g_pickup_cells_max");
 416                         }
 417                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 418                         if(dt >= 1 && dt <= 5)
 419                                 self.nixnex_lastinfotime = -42;
 420                         else
 421                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 422                 }
 423                 if(self.nixnex_lastinfotime != dt)
 424                 {
 425                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 426                         if(dt >= 1 && dt <= 5)
 427                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 428                 }
 429
 430                 if(cvar("g_use_ammunition") && time > self.nixnex_nextincr)
 431                 {
 432                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 433                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 434                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 435                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 436                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 437                 }
 438
 439                 self.weapons = 0;
 440                 if(g_nixnex_with_laser)
 441                         self.weapons = self.weapons | WEPBIT_LASER;
 442                 self.weapons = self.weapons | W_WeaponBit(nixnex_weapon);
 443
 444                 if(self.switchweapon != nixnex_weapon)
 445                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 446                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 447                                         W_SwitchWeapon(nixnex_weapon);
 448         }
 449 }
 450
 451 void RegisterWeapons()
 452 {
 453         // %weaponaddpoint
 454         register_weapon(WEP_LASER,            w_laser,     0,              1, 1, "laser",     "laser",           "Laser");
 455         register_weapon(WEP_SHOTGUN,          w_shotgun,   IT_SHELLS,      2, 1, "shotgun",   "shotgun",         "Shotgun");
 456         register_weapon(WEP_UZI,              w_uzi,       IT_NAILS,       3, 1, "uzi",       "uzi",             "Machine Gun");
 457         register_weapon(WEP_GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS,     4, 1, "gl",        "grenadelauncher", "Mortar");
 458         register_weapon(WEP_ELECTRO,          w_electro,   IT_CELLS,       5, 1, "electro",   "electro",         "Electro");
 459         register_weapon(WEP_CRYLINK,          w_crylink,   IT_CELLS,       6, 1, "crylink",   "crylink",         "Crylink");
 460         register_weapon(WEP_NEX,              w_nex,       IT_CELLS,       7, 1, "nex",       "nex",             "Nex");
 461         register_weapon(WEP_HAGAR,            w_hagar,     IT_ROCKETS,     8, 1, "hagar",     "hagar",           "Hagar");
 462         register_weapon(WEP_ROCKET_LAUNCHER,  w_rlauncher, IT_ROCKETS,     9, 1, "rl",        "rocketlauncher",  "Rocket Launcher");
 463         register_weapon(WEP_PORTO,            w_porto,     IT_SUPERWEAPON, 0, 0, "porto" ,    "porto",           "Port-O-Launch");
 464         register_weapon(WEP_MINSTANEX,        w_minstanex, IT_CELLS,       7, 0, "minstanex", "minstanex",       "MinstaNex");
 465 }