data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(!good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, 0);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.health = -666;
 443         self.takedamage = DAMAGE_NO;
 444         self.solid = SOLID_NOT;
 445         self.movetype = MOVETYPE_NOCLIP;
 446         self.flags = FL_CLIENT | FL_NOTARGET;
 447         self.armorvalue = 666;
 448         self.effects = 0;
 449         self.armorvalue = cvar("g_balance_armor_start");
 450         self.pauserotarmor_finished = 0;
 451         self.pauserothealth_finished = 0;
 452         self.pauseregen_finished = 0;
 453         self.damageforcescale = 0;
 454         self.death_time = 0;
 455         self.dead_frame = 0;
 456         self.alpha = 0;
 457         self.scale = 0;
 458         self.fade_time = 0;
 459         self.pain_frame = 0;
 460         self.pain_finished = 0;
 461         self.strength_finished = 0;
 462         self.invincible_finished = 0;
 463         self.pushltime = 0;
 464         self.think = SUB_Null;
 465         self.nextthink = 0;
 466         self.hook_time = 0;
 467         self.runes = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         self.view_ofs = PL_VIEW_OFS;
 475         setorigin (self, spot.origin);
 476         setsize (self, '0 0 0', '0 0 0');
 477         self.oldorigin = self.origin;
 478         self.items = 0;
 479         self.weapons = 0;
 480         self.model = "";
 481         self.modelindex = 0;
 482         self.weapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.killcount = -666;
 486         self.velocity = '0 0 0';
 487         self.avelocity = '0 0 0';
 488         self.punchangle = '0 0 0';
 489         self.punchvector = '0 0 0';
 490         self.oldvelocity = self.velocity;
 491         self.customizeentityforclient = Client_customizeentityforclient;
 492         self.wantswelcomemessage = 1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         Spawnqueue_Unmark(self);
 499                         Spawnqueue_Remove(self);
 500                 }
 501                 else
 502                 {
 503                         Spawnqueue_Insert(self);
 504                 }
 505         }
 506         else if(g_lms)
 507         {
 508                 // Only if the player cannot play at all
 509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 510                         self.frags = -666;
 511                 else
 512                         self.frags = -667;
 513         }
 514         else
 515                 self.frags = -666;
 516 }
 517
 518 float RestrictSkin(float s)
 519 {
 520         if(!teams_matter)
 521                 return s;
 522         if(s == 6)
 523                 return 6;
 524         return mod(s, 3);
 525 }
 526
 527 void FixPlayermodel()
 528 {
 529         local string defaultmodel;
 530         local float defaultskin;
 531         local vector m1, m2;
 532
 533         defaultmodel = "";
 534
 535         if(cvar("sv_defaultcharacter") == 1) {
 536                 defaultskin = 0;
 537
 538                 if(teams_matter)
 539                 {
 540                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 541                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 542                 }
 543
 544                 if(defaultmodel == "")
 545                 {
 546                         defaultmodel = cvar_string("sv_defaultplayermodel");
 547                         defaultskin = cvar("sv_defaultplayerskin");
 548                 }
 549         }
 550
 551         if(defaultmodel != "")
 552         {
 553                 if (defaultmodel != self.model)
 554                 {
 555                         m1 = self.mins;
 556                         m2 = self.maxs;
 557                         setmodel_lod (self, defaultmodel);
 558                         setsize (self, m1, m2);
 559                 }
 560
 561                 self.skin = defaultskin;
 562         } else {
 563                 if (self.playermodel != self.model)
 564                 {
 565                         self.playermodel = CheckPlayerModel(self.playermodel);
 566                         m1 = self.mins;
 567                         m2 = self.maxs;
 568                         setmodel_lod (self, self.playermodel);
 569                         setsize (self, m1, m2);
 570                 }
 571
 572                 self.skin = RestrictSkin(stof(self.playerskin));
 573         }
 574
 575         if(!teams_matter)
 576                 if(strlen(cvar_string("sv_defaultplayercolors")))
 577                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 578                                 setcolor(self, cvar("sv_defaultplayercolors"));
 579 }
 580
 581 /*
 582 =============
 583 PutClientInServer
 584
 585 Called when a client spawns in the server
 586 =============
 587 */
 588 //void() ctf_playerchanged;
 589 void PutClientInServer (void)
 590 {
 591         if(clienttype(self) == CLIENTTYPE_BOT)
 592         {
 593                 self.classname = "player";
 594         }
 595         else if(clienttype(self) == CLIENTTYPE_REAL)
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         // player is dead and becomes observer
 603         // FIXME fix LMS scoring for new system
 604         if(g_lms)
 605         {
 606                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 607                         self.classname = "observer";
 608         }
 609
 610         if(g_arena)
 611         if(!self.spawned)
 612                 self.classname = "observer";
 613
 614         if(self.classname == "player") {
 615                 entity  spot;
 616
 617                 race_PreSpawn();
 618
 619                 spot = SelectSpawnPoint (FALSE);
 620                 if(!spot)
 621                 {
 622                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 623                         return; // spawn failed
 624                 }
 625
 626                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 627
 628                 self.classname = "player";
 629                 self.iscreature = TRUE;
 630                 self.movetype = MOVETYPE_WALK;
 631                 self.solid = SOLID_SLIDEBOX;
 632                 if(independent_players)
 633                         MAKE_INDEPENDENT_PLAYER(self);
 634                 self.flags = FL_CLIENT;
 635                 self.takedamage = DAMAGE_AIM;
 636                 if(g_minstagib)
 637                         self.effects = EF_FULLBRIGHT;
 638                 else
 639                         self.effects = 0;
 640                 self.air_finished = time + 12;
 641                 self.dmg = 2;
 642
 643                 if(inWarmupStage)
 644                 {
 645                         self.ammo_shells = warmup_start_ammo_shells;
 646                         self.ammo_nails = warmup_start_ammo_nails;
 647                         self.ammo_rockets = warmup_start_ammo_rockets;
 648                         self.ammo_cells = warmup_start_ammo_cells;
 649                         self.health = warmup_start_health;
 650                         self.armorvalue = warmup_start_armorvalue;
 651                         self.weapons = warmup_start_weapons;
 652                 }
 653                 else
 654                 {
 655                         self.ammo_shells = start_ammo_shells;
 656                         self.ammo_nails = start_ammo_nails;
 657                         self.ammo_rockets = start_ammo_rockets;
 658                         self.ammo_cells = start_ammo_cells;
 659                         self.health = start_health;
 660                         self.armorvalue = start_armorvalue;
 661                         self.weapons = start_weapons;
 662                 }
 663                 self.items = start_items;
 664                 self.switchweapon = w_getbestweapon(self);
 665                 self.cnt = self.switchweapon;
 666                 self.weapon = 0;
 667                 self.jump_interval = time;
 668
 669                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 670                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 671                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 672                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 673                 //extend the pause of rotting if client was reset at the beginning of the countdown
 674                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 675                         self.spawnshieldtime += RESTART_COUNTDOWN;
 676                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 677                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 678                         self.pauseregen_finished += RESTART_COUNTDOWN;
 679                 }
 680                 self.damageforcescale = 2;
 681                 self.death_time = 0;
 682                 self.dead_frame = 0;
 683                 self.alpha = 0;
 684                 self.scale = 0;
 685                 self.fade_time = 0;
 686                 self.pain_frame = 0;
 687                 self.pain_finished = 0;
 688                 self.strength_finished = 0;
 689                 self.invincible_finished = 0;
 690                 self.pushltime = 0;
 691                 //self.speed_finished = 0;
 692                 //self.slowmo_finished = 0;
 693                 // players have no think function
 694                 self.think = SUB_Null;
 695                 self.nextthink = 0;
 696                 self.hook_time = 0;
 697
 698                 self.runes = 0;
 699
 700                 self.deadflag = DEAD_NO;
 701
 702                 self.angles = spot.angles;
 703
 704                 self.angles_z = 0; // never spawn tilted even if the spot says to
 705                 self.fixangle = TRUE; // turn this way immediately
 706                 self.velocity = '0 0 0';
 707                 self.avelocity = '0 0 0';
 708                 self.punchangle = '0 0 0';
 709                 self.punchvector = '0 0 0';
 710                 self.oldvelocity = self.velocity;
 711
 712                 msg_entity = self;
 713                 WRITESPECTATABLE_MSG_ONE({
 714                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 715                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 716                 });
 717
 718                 self.customizeentityforclient = Client_customizeentityforclient;
 719
 720                 self.model = "";
 721                 FixPlayermodel();
 722
 723                 self.crouch = FALSE;
 724                 self.view_ofs = PL_VIEW_OFS;
 725                 setsize (self, PL_MIN, PL_MAX);
 726                 self.spawnorigin = spot.origin;
 727                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 728                 // don't reset back to last position, even if new position is stuck in solid
 729                 self.oldorigin = self.origin;
 730
 731                 if(g_arena)
 732                 {
 733                         Spawnqueue_Remove(self);
 734                         Spawnqueue_Mark(self);
 735                 }
 736
 737                 self.event_damage = PlayerDamage;
 738
 739                 self.bot_attack = TRUE;
 740
 741                 self.statdraintime = time + 5;
 742                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 743
 744                 if(self.killcount == -666) {
 745                         PlayerScore_Clear(self);
 746                         self.killcount = 0;
 747                         self.frags = 0;
 748                 }
 749
 750                 self.cnt = WEP_LASER;
 751                 self.nixnex_lastchange_id = -1;
 752
 753                 CL_SpawnWeaponentity();
 754                 self.alpha = default_player_alpha;
 755                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 756                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 757
 758                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 759                 self.lms_traveled_distance = 0;
 760                 self.speedrunning = FALSE;
 761
 762                 race_PostSpawn(spot);
 763
 764                 if(cvar("spawn_debug"))
 765                 {
 766                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 768                 }
 769
 770                 //stuffcmd(self, "chase_active 0");
 771                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 772
 773                 if (cvar("g_spawnsound"))
 774                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 775
 776                 if(g_assault) {
 777                         if(self.team == assault_attacker_team)
 778                                 centerprint(self, "You are attacking!\n");
 779                         else
 780                                 centerprint(self, "You are defending!\n");
 781                 }
 782
 783         } else if(self.classname == "observer") {
 784                 PutObserverInServer ();
 785         }
 786
 787         //if(g_ctf)
 788         //      ctf_playerchanged();
 789 }
 790
 791 /*
 792 =============
 793 SendCSQCInfo
 794
 795 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 796 =============
 797 */
 798 void SendCSQCInfo(void)
 799 {
 800         float i;
 801         if(clienttype(self) != CLIENTTYPE_REAL)
 802                 return;
 803         msg_entity = self;
 804         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 805         WriteByte(MSG_ONE, TE_CSQC_INIT);
 806         WriteShort(MSG_ONE, CSQC_REVISION);
 807         WriteByte(MSG_ONE, maxclients);
 808         for(i = 1; i <= 24; ++i)
 809                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 810 }
 811
 812 /*
 813 =============
 814 SetNewParms
 815 =============
 816 */
 817 void SetNewParms (void)
 818 {
 819         // initialize parms for a new player
 820         parm1 = -(86400 * 366);
 821 }
 822
 823 /*
 824 =============
 825 SetChangeParms
 826 =============
 827 */
 828 void SetChangeParms (void)
 829 {
 830         // save parms for level change
 831         parm1 = self.parm_idlesince - time;
 832 }
 833
 834 /*
 835 =============
 836 DecodeLevelParms
 837 =============
 838 */
 839 void DecodeLevelParms (void)
 840 {
 841         // load parms
 842         self.parm_idlesince = parm1;
 843         if(self.parm_idlesince == -(86400 * 366))
 844                 self.parm_idlesince = time;
 845 }
 846
 847 /*
 848 =============
 849 ClientKill
 850
 851 Called when a client types 'kill' in the console
 852 =============
 853 */
 854
 855 void ClientKill_Now_TeamChange()
 856 {
 857         if(self.killindicator_teamchange == -1)
 858         {
 859                 self.team = -1;
 860                 JoinBestTeam( self, FALSE, FALSE );
 861         }
 862         else
 863         {
 864                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 865         }
 866 }
 867
 868 void ClientKill_Now()
 869 {
 870         if(self.killindicator_teamchange)
 871                 ClientKill_Now_TeamChange();
 872
 873         // in any case:
 874         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 875
 876         if(self.killindicator)
 877         {
 878                 dprint("Cleaned up after a leaked kill indicator.\n");
 879                 remove(self.killindicator);
 880                 self.killindicator = world;
 881         }
 882 }
 883 void KillIndicator_Think()
 884 {
 885         if (!self.owner.modelindex)
 886         {
 887                 self.owner.killindicator = world;
 888                 remove(self);
 889                 return;
 890         }
 891
 892         if(self.cnt <= 0)
 893         {
 894                 self = self.owner;
 895                 ClientKill_Now(); // no oldself needed
 896                 return;
 897         }
 898         else
 899         {
 900                 if(self.cnt <= 10)
 901                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 902                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 903                 {
 904                         if(self.cnt <= 10)
 905                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 906                         if(self.owner.killindicator_teamchange)
 907                         {
 908                                 if(self.owner.killindicator_teamchange == -1)
 909                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 910                                 else
 911                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 912                         }
 913                         else
 914                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 915                 }
 916                 self.nextthink = time + 1;
 917                 self.cnt -= 1;
 918         }
 919 }
 920
 921 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 922 {
 923         float killtime;
 924         entity e;
 925         killtime = cvar("g_balance_kill_delay");
 926
 927         self.killindicator_teamchange = targetteam;
 928
 929         if(!self.killindicator)
 930         {
 931                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 932                 {
 933                         ClientKill_Now();
 934                 }
 935                 else
 936                 {
 937                         self.killindicator = spawn();
 938                         self.killindicator.owner = self;
 939                         self.killindicator.scale = 0.5;
 940                         setattachment(self.killindicator, self, "");
 941                         setorigin(self.killindicator, '0 0 52');
 942                         self.killindicator.think = KillIndicator_Think;
 943                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 944                         self.killindicator.cnt = ceil(killtime);
 945                         self.killindicator.count = bound(0, ceil(killtime), 10);
 946                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 947
 948                         for(e = world; (e = find(e, classname, "body")) != world; )
 949                         {
 950                                 if(e.enemy != self)
 951                                         continue;
 952                                 e.killindicator = spawn();
 953                                 e.killindicator.owner = e;
 954                                 e.killindicator.scale = 0.5;
 955                                 setattachment(e.killindicator, e, "");
 956                                 setorigin(e.killindicator, '0 0 52');
 957                                 e.killindicator.think = KillIndicator_Think;
 958                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 959                                 e.killindicator.cnt = ceil(killtime);
 960                         }
 961                         self.lip = 0;
 962                 }
 963         }
 964         if(self.killindicator)
 965         {
 966                 if(targetteam)
 967                         self.killindicator.colormod = TeamColor(targetteam);
 968                 else
 969                         self.killindicator.colormod = '0 0 0';
 970         }
 971 }
 972
 973 void ClientKill (void)
 974 {
 975         ClientKill_TeamChange(0);
 976 }
 977
 978 void DoTeamChange(float destteam)
 979 {
 980         float t, c0;
 981         if(!cvar("teamplay"))
 982         {
 983                 if(destteam >= 0)
 984                         SetPlayerColors(self, destteam);
 985                 return;
 986         }
 987         if(self.classname == "player")
 988         if(destteam == -1)
 989         {
 990                 CheckAllowedTeams(self);
 991                 t = FindSmallestTeam(self, TRUE);
 992                 switch(self.team)
 993                 {
 994                         case COLOR_TEAM1: c0 = c1; break;
 995                         case COLOR_TEAM2: c0 = c2; break;
 996                         case COLOR_TEAM3: c0 = c3; break;
 997                         case COLOR_TEAM4: c0 = c4; break;
 998                         default:          c0 = 999;
 999                 }
1000                 switch(t)
1001                 {
1002                         case 1:
1003                                 if(c0 > c1)
1004                                         destteam = COLOR_TEAM1;
1005                                 break;
1006                         case 2:
1007                                 if(c0 > c2)
1008                                         destteam = COLOR_TEAM2;
1009                                 break;
1010                         case 3:
1011                                 if(c0 > c3)
1012                                         destteam = COLOR_TEAM3;
1013                                 break;
1014                         case 4:
1015                                 if(c0 > c4)
1016                                         destteam = COLOR_TEAM4;
1017                                 break;
1018                 }
1019                 if(destteam == -1)
1020                         return;
1021         }
1022         if(destteam == self.team && !self.killindicator)
1023                 return;
1024         ClientKill_TeamChange(destteam);
1025 }
1026
1027 void FixClientCvars(entity e)
1028 {
1029         // send prediction settings to the client
1030         stuffcmd(e, "\nin_bindmap 0 0\n");
1031         /*
1032          * we no longer need to stuff this. Remove this comment block if you feel
1033          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1034         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1035         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1036         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1037         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1038         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1039         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1040         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1041         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1042         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1043         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1044         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1045         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1046         stuffcmd(e, "cl_movement_edgefriction 1\n");
1047          */
1048 }
1049
1050 /*
1051 =============
1052 ClientConnect
1053
1054 Called when a client connects to the server
1055 =============
1056 */
1057 //void ctf_clientconnect();
1058 string ColoredTeamName(float t);
1059 void DecodeLevelParms (void);
1060 //void dom_player_join_team(entity pl);
1061 void ClientConnect (void)
1062 {
1063         local string s;
1064
1065         if(self.flags & FL_CLIENT)
1066         {
1067                 print("Warning: ClientConnect, but already connected!\n");
1068                 return;
1069         }
1070
1071         if(Ban_IsClientBanned(self))
1072         {
1073                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1074                 dropclient(self);
1075                 bprint(s);
1076                 return;
1077         }
1078
1079         DecodeLevelParms();
1080
1081         self.classname = "player_joining";
1082
1083         self.flags = self.flags | FL_CLIENT;
1084         self.version_nagtime = time + 10 + random() * 10;
1085
1086         if(player_count<0)
1087         {
1088                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1089                 player_count = 0;
1090         }
1091
1092         PlayerScore_Attach(self);
1093
1094         bot_clientconnect();
1095
1096         race_PreSpawnObserver();
1097
1098         //if(g_domination)
1099         //      dom_player_join_team(self);
1100
1101         //JoinBestTeam(self, FALSE, FALSE);
1102         //
1103         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1104                 self.classname = "observer";
1105         } else {
1106                 self.classname = "player";
1107                 campaign_bots_may_start = 1;
1108         }
1109
1110         self.playerid = (playerid_last = playerid_last + 1);
1111         if(cvar("sv_eventlog"))
1112         {
1113                 if(clienttype(self) == CLIENTTYPE_REAL)
1114                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1115                 else
1116                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1117                 s = strcat(":team:", ftos(self.playerid), ":");
1118                 s = strcat(s, ftos(self.team));
1119                 GameLogEcho(s);
1120         }
1121         self.netname_previous = strzone(self.netname);
1122
1123         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1124
1125         bprint ("^4",self.netname);
1126         bprint ("^4 connected");
1127
1128         if(g_domination || g_ctf)
1129         {
1130                 bprint(" and joined the ");
1131                 bprint(ColoredTeamName(self.team));
1132         }
1133
1134         bprint("\n");
1135
1136         self.welcomemessage_time = 0;
1137
1138         stuffcmd(self, strcat(clientstuff, "\n"));
1139         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1140         stuffcmd(self, "cl_particles_reloadeffects\n");
1141
1142         FixClientCvars(self);
1143
1144         // spawnfunc_waypoint sprites
1145         WaypointSprite_InitClient(self);
1146
1147         // Wazat's grappling hook
1148         SetGrappleHookBindings();
1149
1150         // get autoswitch state from player when he toggles it
1151         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1152
1153         // get version info from player
1154         stuffcmd(self, "cmd clientversion $gameversion\n");
1155
1156         // get other cvars from player
1157         GetCvars(0);
1158
1159         // set cvar for team scoreboard
1160         if (teams_matter)
1161         {
1162                 local float t;
1163                 t = cvar("teamplay");
1164                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1165                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1166         }
1167         else
1168                 stuffcmd(self, "set teamplay 0\n");
1169
1170         // notify about available teams
1171         if(teamplay)
1172         {
1173                 CheckAllowedTeams(self);
1174                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1175                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1176         }
1177         else
1178                 stuffcmd(self, "set _teams_available 0\n");
1179
1180         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1181
1182         if(g_arena)
1183         {
1184                 self.classname = "observer";
1185                 Spawnqueue_Insert(self);
1186         }
1187         /*else if(g_ctf)
1188         {
1189                 ctf_clientconnect();
1190         }*/
1191
1192         if(entcs_start)
1193                 attach_entcs();
1194
1195         bot_relinkplayerlist();
1196
1197         self.spectatortime = time;
1198         if(blockSpectators)
1199         {
1200                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1201         }
1202
1203         self.jointime = time;
1204         self.allowedTimeouts = cvar("sv_timeout_number");
1205
1206         if(clienttype(self) == CLIENTTYPE_REAL)
1207         {
1208                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1209                 SendCSQCInfo();
1210                 msg_entity = self;
1211                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1212                 {
1213                         MapVote_SendData(MSG_ONE);
1214                         MapVote_UpdateData(MSG_ONE);
1215                 }
1216                 ScoreInfo_Write(MSG_ONE);
1217         }
1218
1219         if(inWarmupStage)
1220         {
1221                 msg_entity = self;
1222                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1223                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1224                 WriteByte(MSG_ONE, 1);
1225         }
1226
1227         if(g_lms)
1228         {
1229                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1230                 {
1231                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1232                         self.frags = -666; // FIXME do we still need this?
1233                 }
1234         }
1235 }
1236
1237 /*
1238 =============
1239 ClientDisconnect
1240
1241 Called when a client disconnects from the server
1242 =============
1243 */
1244 .entity chatbubbleentity;
1245 .entity teambubbleentity;
1246 void ReadyCount();
1247 //void() ctf_clientdisconnect;
1248 void ClientDisconnect (void)
1249 {
1250         float save;
1251
1252         if not(self.flags & FL_CLIENT)
1253         {
1254                 print("Warning: ClientDisconnect without ClientConnect\n");
1255                 return;
1256         }
1257
1258         bot_clientdisconnect();
1259
1260         if(entcs_start)
1261                 detach_entcs();
1262
1263         if(cvar("sv_eventlog"))
1264                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1265         bprint ("^4",self.netname);
1266         bprint ("^4 disconnected\n");
1267
1268         if (self.chatbubbleentity)
1269         {
1270                 remove (self.chatbubbleentity);
1271                 self.chatbubbleentity = world;
1272         }
1273
1274         if (self.teambubbleentity)
1275         {
1276                 remove (self.teambubbleentity);
1277                 self.teambubbleentity = world;
1278         }
1279
1280         if (self.killindicator)
1281         {
1282                 remove (self.killindicator);
1283                 self.killindicator = world;
1284         }
1285
1286         WaypointSprite_PlayerGone();
1287
1288         DropAllRunes(self);
1289         kh_Key_DropAll(self, TRUE);
1290
1291         Portal_ClearAll(self);
1292
1293         if(self.flagcarried)
1294                 DropFlag(self.flagcarried, 0);
1295
1296         save = self.flags;
1297         self.flags = self.flags - (self.flags & FL_CLIENT);
1298         bot_relinkplayerlist();
1299         self.flags = save;
1300
1301         // remove laserdot
1302         if(self.weaponentity)
1303                 if(self.weaponentity.lasertarget)
1304                         remove(self.weaponentity.lasertarget);
1305
1306         if(g_arena)
1307         {
1308                 Spawnqueue_Unmark(self);
1309                 Spawnqueue_Remove(self);
1310         }
1311         /*if(g_ctf)
1312         {
1313                 ctf_clientdisconnect();
1314         }
1315         */
1316
1317         PlayerScore_Detach(self);
1318
1319         if(self.netname_previous)
1320                 strunzone(self.netname_previous);
1321
1322         ClearPlayerSounds();
1323
1324         // free cvars
1325         GetCvars(-1);
1326         self.playerid = 0;
1327
1328         ReadyCount();
1329 }
1330
1331 .float BUTTON_CHAT;
1332 void ChatBubbleThink()
1333 {
1334         self.nextthink = time;
1335         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1336         {
1337                 self.owner.chatbubbleentity = world;
1338                 remove(self);
1339                 return;
1340         }
1341         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1342         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1343                 self.model = self.mdl;
1344         else
1345                 self.model = "";
1346 };
1347
1348 void UpdateChatBubble()
1349 {
1350         if (!self.modelindex)
1351                 return;
1352         // spawn a chatbubble entity if needed
1353         if (!self.chatbubbleentity)
1354         {
1355                 self.chatbubbleentity = spawn();
1356                 self.chatbubbleentity.owner = self;
1357                 self.chatbubbleentity.exteriormodeltoclient = self;
1358                 self.chatbubbleentity.think = ChatBubbleThink;
1359                 self.chatbubbleentity.nextthink = time;
1360                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1361                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1362                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1363                 self.chatbubbleentity.model = "";
1364                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1365         }
1366 }
1367
1368
1369 void TeamBubbleThink()
1370 {
1371         self.nextthink = time;
1372         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1373         {
1374                 self.owner.teambubbleentity = world;
1375                 remove(self);
1376                 return;
1377         }
1378 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1379         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1380                 self.model = "";
1381         else
1382                 self.model = self.mdl;
1383
1384 };
1385
1386 float TeamBubble_customizeentityforclient()
1387 {
1388         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1389 }
1390
1391 void UpdateTeamBubble()
1392 {
1393         if (!self.modelindex || !cvar("teamplay"))
1394                 return;
1395         // spawn a teambubble entity if needed
1396         if (!self.teambubbleentity && cvar("teamplay"))
1397         {
1398                 self.teambubbleentity = spawn();
1399                 self.teambubbleentity.owner = self;
1400                 self.teambubbleentity.exteriormodeltoclient = self;
1401                 self.teambubbleentity.think = TeamBubbleThink;
1402                 self.teambubbleentity.nextthink = time;
1403                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1404 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1405                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1406                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1407                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1408                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1409                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1410                 self.teambubbleentity.effects = EF_LOWPRECISION;
1411         }
1412 }
1413
1414 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1415 // added to the model skins
1416 /*void UpdateColorModHack()
1417 {
1418         local float c;
1419         c = self.clientcolors & 15;
1420         // LordHavoc: only bothering to support white, green, red, yellow, blue
1421              if (teamplay == 0) self.colormod = '0 0 0';
1422         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1423         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1424         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1425         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1426         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1427         else self.colormod = '1 1 1';
1428 };*/
1429
1430 void respawn(void)
1431 {
1432         CopyBody(1);
1433         self.effects |= EF_NODRAW; // prevent another CopyBody
1434         PutClientInServer();
1435 }
1436
1437 /**
1438  * When sv_timeout is used this function returs strings like
1439  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1440  * Called by centerprint functions
1441  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1442  */
1443 string getTimeoutText(float addOneSecond) {
1444         if (!cvar("sv_timeout") || !timeoutStatus)
1445                 return "";
1446
1447         local string retStr;
1448         if (timeoutStatus == 1) {
1449                 if (addOneSecond == 1) {
1450                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1451                 }
1452                 else {
1453                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1454                 }
1455                 return retStr;
1456         }
1457         else if (timeoutStatus == 2) {
1458                 if (addOneSecond) {
1459                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1460                         //don't show messages like "Timeout ends in 0 seconds"...
1461                         if ((remainingTimeoutTime + 1) > 0)
1462                                 return retStr;
1463                         else
1464                                 return "";
1465                 }
1466                 else {
1467                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1468                         //don't show messages like "Timeout ends in 0 seconds"...
1469                         if (remainingTimeoutTime > 0)
1470                                 return retStr;
1471                         else
1472                                 return "";
1473                 }
1474         }
1475         else return "";
1476 }
1477
1478 void player_powerups (void)
1479 {
1480         if (g_minstagib)
1481         {
1482                 if (self.items & IT_STRENGTH)
1483                 {
1484                         if (time > self.strength_finished)
1485                         {
1486                                 if (g_minstagib_invis_alpha > 0)
1487                                 {
1488                                         self.alpha = default_player_alpha;
1489                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1490                                         self.effects = self.effects | EF_FULLBRIGHT;
1491                                 }
1492                                 else
1493                                 {
1494                                         self.effects -= self.effects & EF_NODRAW;
1495                                 }
1496                                 self.items = self.items - (self.items & IT_STRENGTH);
1497                                 sprint(self, "^3Invisibility has worn off\n");
1498                         }
1499                 }
1500                 else
1501                 {
1502                         if (time < self.strength_finished)
1503                         {
1504                                 if (g_minstagib_invis_alpha > 0)
1505                                 {
1506                                         self.alpha = g_minstagib_invis_alpha;
1507                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1508                                         self.effects -= self.effects & EF_FULLBRIGHT;
1509                                 }
1510                                 else
1511                                 {
1512                                         self.effects = self.effects | EF_NODRAW;
1513                                 }
1514                                 self.items = self.items | IT_STRENGTH;
1515                                 sprint(self, "^3You are invisible\n");
1516                         }
1517                 }
1518
1519                 if (self.items & IT_INVINCIBLE)
1520                 {
1521                         if (time > self.invincible_finished)
1522                         {
1523                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1524                                 sprint(self, "^3Speed has worn off\n");
1525                         }
1526                 }
1527                 else
1528                 {
1529                         if (time < self.invincible_finished)
1530                         {
1531                                 self.items = self.items | IT_INVINCIBLE;
1532                                 sprint(self, "^3You are on speed\n");
1533                         }
1534                 }
1535                 return;
1536         }
1537
1538         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1539         if (self.items & IT_STRENGTH)
1540         {
1541                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1542                 if (time > self.strength_finished)
1543                 {
1544                         self.items = self.items - (self.items & IT_STRENGTH);
1545                         sprint(self, "^3Strength has worn off\n");
1546                 }
1547         }
1548         else
1549         {
1550                 if (time < self.strength_finished)
1551                 {
1552                         self.items = self.items | IT_STRENGTH;
1553                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1554                 }
1555         }
1556         if (self.items & IT_INVINCIBLE)
1557         {
1558                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1559                 if (time > self.invincible_finished)
1560                 {
1561                         self.items = self.items - (self.items & IT_INVINCIBLE);
1562                         sprint(self, "^3Shield has worn off\n");
1563                 }
1564         }
1565         else
1566         {
1567                 if (time < self.invincible_finished)
1568                 {
1569                         self.items = self.items | IT_INVINCIBLE;
1570                         sprint(self, "^3Shield surrounds you\n");
1571                 }
1572         }
1573
1574         if (cvar("g_fullbrightplayers"))
1575                 self.effects = self.effects | EF_FULLBRIGHT;
1576
1577         // midair gamemode: damage only while in the air
1578         // if in midair mode, being on ground grants temporary invulnerability
1579         // (this is so that multishot weapon don't clear the ground flag on the
1580         // first damage in the frame, leaving the player vulnerable to the
1581         // remaining hits in the same frame)
1582         if (self.flags & FL_ONGROUND)
1583         if (g_midair)
1584                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1585
1586         if (time > restart_countdown)
1587         if (time < self.spawnshieldtime)
1588                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1589 }
1590
1591 float CalcRegen(float current, float stable, float regenfactor)
1592 {
1593         if(current > stable)
1594                 return current;
1595         else if(current > stable - 0.25) // when close enough, "snap"
1596                 return stable;
1597         else
1598                 return min(stable, current + (stable - current) * regenfactor * frametime);
1599 }
1600
1601 void player_regen (void)
1602 {
1603         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1604         maxh = cvar("g_balance_health_stable");
1605         maxa = cvar("g_balance_armor_stable");
1606         limith = cvar("g_balance_health_limit");
1607         limita = cvar("g_balance_armor_limit");
1608
1609         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1610                 return;
1611
1612         max_mod = regen_mod = rot_mod = limit_mod = 1;
1613
1614         if (self.runes & RUNE_REGEN)
1615         {
1616                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1617                 {
1618                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1619                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1620                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1621                 }
1622                 else
1623                 {
1624                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1625                         max_mod = cvar("g_balance_rune_regen_hpmod");
1626                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1627                 }
1628         }
1629         else if (self.runes & CURSE_VENOM)
1630         {
1631                 max_mod = cvar("g_balance_curse_venom_hpmod");
1632                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1633                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1634                 else
1635                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1636                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1637                 //if (!self.runes & RUNE_REGEN)
1638                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1639         }
1640         maxh = maxh * max_mod;
1641         //maxa = maxa * max_mod;
1642         limith = limith * limit_mod;
1643         limita = limita * limit_mod;
1644
1645         if (self.armorvalue > maxa)
1646         {
1647                 if (time > self.pauserotarmor_finished)
1648                 {
1649                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1650                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1651                 }
1652         }
1653         else if (self.armorvalue < maxa)
1654         {
1655                 if (time > self.pauseregen_finished)
1656                 {
1657                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1658                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1659                 }
1660         }
1661         if (self.health > maxh)
1662         {
1663                 if (time > self.pauserothealth_finished)
1664                 {
1665                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1666                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1667                 }
1668         }
1669         else if (self.health < maxh)
1670         {
1671                 if (time > self.pauseregen_finished)
1672                 {
1673                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1674                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1675                 }
1676         }
1677
1678         if (self.health > limith)
1679                 self.health = limith;
1680         if (self.armorvalue > limita)
1681                 self.armorvalue = limita;
1682
1683         // if player rotted to death...  die!
1684         if(self.health < 1)
1685                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1686 }
1687
1688 .float zoomstate;
1689 float zoomstate_set;
1690 void SetZoomState(float z)
1691 {
1692         if(z != self.zoomstate)
1693         {
1694                 msg_entity = self;
1695                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1696                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1697                 WriteByte(MSG_ONE, z);
1698                 self.zoomstate = z;
1699         }
1700         zoomstate_set = 1;
1701 }
1702
1703 /*
1704 ======================
1705 spectate mode routines
1706 ======================
1707 */
1708 void SpectateCopy(entity spectatee) {
1709         self.armortype = spectatee.armortype;
1710         self.armorvalue = spectatee.armorvalue;
1711         self.currentammo = spectatee.currentammo;
1712         self.effects = spectatee.effects;
1713         self.health = spectatee.health;
1714         self.impulse = 0;
1715         self.items = spectatee.items;
1716         self.weapons = spectatee.weapons;
1717         self.punchangle = spectatee.punchangle;
1718         self.view_ofs = spectatee.view_ofs;
1719         self.v_angle = spectatee.v_angle;
1720         self.velocity = spectatee.velocity;
1721         self.dmg_take = spectatee.dmg_take;
1722         self.dmg_save = spectatee.dmg_save;
1723         self.dmg_inflictor = spectatee.dmg_inflictor;
1724         self.angles = spectatee.v_angle;
1725         self.fixangle = TRUE;
1726         setorigin(self, spectatee.origin);
1727         setsize(self, spectatee.mins, spectatee.maxs);
1728         SetZoomState(spectatee.zoomstate);
1729 }
1730
1731 float SpectateUpdate() {
1732         if(!self.enemy)
1733                 return 0;
1734
1735         if (self == self.enemy)
1736                 return 0;
1737
1738         if(self.enemy.flags & FL_NOTARGET)
1739                 return 0;
1740
1741         SpectateCopy(self.enemy);
1742
1743         return 1;
1744 }
1745
1746 float SpectateNext() {
1747         other = find(self.enemy, classname, "player");
1748         if (!other) {
1749                 other = find(other, classname, "player");
1750         }
1751         if (other) {
1752                 self.enemy = other;
1753         }
1754         if(self.enemy.classname == "player") {
1755                 msg_entity = self;
1756                 WriteByte(MSG_ONE, SVC_SETVIEW);
1757                 WriteEntity(MSG_ONE, self.enemy);
1758                 self.wantswelcomemessage = 1;
1759                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1760                 if(!SpectateUpdate())
1761                         PutObserverInServer();
1762                 return 1;
1763         } else {
1764                 return 0;
1765         }
1766 }
1767
1768 /*
1769 =============
1770 ShowRespawnCountdown()
1771
1772 Update a respawn countdown display.
1773 =============
1774 */
1775 void ShowRespawnCountdown()
1776 {
1777         float number;
1778         if(self.deadflag == DEAD_NO) // just respawned?
1779                 return;
1780         else
1781         {
1782                 number = ceil(self.death_time - time);
1783                 if(number <= 0)
1784                         return;
1785                 if(number <= self.respawn_countdown)
1786                 {
1787                         self.respawn_countdown = number - 1;
1788                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1789                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1790                 }
1791         }
1792 }
1793
1794 void LeaveSpectatorMode()
1795 {
1796         if(isJoinAllowed()) {
1797                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1798                         self.classname = "player";
1799                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1800                                 JoinBestTeam(self, FALSE, TRUE);
1801                         if(cvar("g_campaign"))
1802                                 campaign_bots_may_start = 1;
1803                         PutClientInServer();
1804                         if(!(self.flags & FL_NOTARGET))
1805                                 bprint ("^4", self.netname, "^4 is playing now\n");
1806                         centerprint(self,"");
1807                         return;
1808                 } else {
1809                         stuffcmd(self,"menu_showteamselect\n");
1810                         return;
1811                 }
1812         }
1813         else {
1814                 //player may not join because of g_maxplayers is set
1815                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1816         }
1817 }
1818
1819 /**
1820  * Determines whether the player is allowed to join. This depends on cvar
1821  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1822  * it checks whether the number of currently playing players exceeds g_maxplayers.
1823  * @return bool TRUE if the player is allowed to join, false otherwise
1824  */
1825 float isJoinAllowed() {
1826         if (!cvar("g_maxplayers"))
1827                 return TRUE;
1828
1829         local entity e;
1830         local float currentlyPlaying;
1831         FOR_EACH_REALPLAYER(e) {
1832                 if(e.classname == "player")
1833                         currentlyPlaying += 1;
1834         }
1835         if(currentlyPlaying < cvar("g_maxplayers"))
1836                 return TRUE;
1837
1838         return FALSE;
1839 }
1840
1841 /**
1842  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1843  * g_maxplayers_spectator_blocktime seconds
1844  */
1845 void checkSpectatorBlock() {
1846         if(self.classname == "spectator" || self.classname == "observer") {
1847                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1848                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1849                         dropclient(self);
1850                 }
1851         }
1852 }
1853
1854 float vercmp_recursive(string v1, string v2)
1855 {
1856         float dot1, dot2;
1857         string s1, s2;
1858         float r;
1859
1860         dot1 = strstrofs(v1, ".", 0);
1861         dot2 = strstrofs(v2, ".", 0);
1862         if(dot1 == -1)
1863                 s1 = v1;
1864         else
1865                 s1 = substring(v1, 0, dot1);
1866         if(dot2 == -1)
1867                 s2 = v2;
1868         else
1869                 s2 = substring(v2, 0, dot2);
1870
1871         r = stof(s1) - stof(s2);
1872         if(r != 0)
1873                 return r;
1874
1875         r = strcasecmp(s1, s2);
1876         if(r != 0)
1877                 return r;
1878
1879         if(dot1 == -1)
1880                 if(dot2 == -1)
1881                         return 0;
1882                 else
1883                         return -1;
1884         else
1885                 if(dot2 == -1)
1886                         return 1;
1887                 else
1888                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1889 }
1890
1891 float vercmp(string v1, string v2)
1892 {
1893         if(strcasecmp(v1, v2) == 0) // early out check
1894                 return 0;
1895         return vercmp_recursive(v1, v2);
1896 }
1897
1898 void ObserverThink()
1899 {
1900         if (self.flags & FL_JUMPRELEASED) {
1901                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1902                         self.welcomemessage_time = 0;
1903                         self.flags = self.flags - FL_JUMPRELEASED;
1904                         LeaveSpectatorMode();
1905                         return;
1906                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1907                         self.welcomemessage_time = 0;
1908                         self.flags = self.flags - FL_JUMPRELEASED;
1909                         if(SpectateNext() == 1) {
1910                                 self.classname = "spectator";
1911                         }
1912                 }
1913         } else {
1914                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1915                         self.flags = self.flags | FL_JUMPRELEASED;
1916                 }
1917         }
1918         if(self.BUTTON_ZOOM)
1919                 self.wantswelcomemessage = 0;
1920         if(self.wantswelcomemessage)
1921                 PrintWelcomeMessage(self);
1922 }
1923
1924 void SpectatorThink()
1925 {
1926         if (self.flags & FL_JUMPRELEASED) {
1927                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1928                         self.welcomemessage_time = 0;
1929                         self.flags = self.flags - FL_JUMPRELEASED;
1930                         LeaveSpectatorMode();
1931                         return;
1932                 } else if(self.BUTTON_ATCK) {
1933                         self.welcomemessage_time = 0;
1934                         self.flags = self.flags - FL_JUMPRELEASED;
1935                         if(SpectateNext() == 1) {
1936                                 self.classname = "spectator";
1937                         } else {
1938                                 self.classname = "observer";
1939                                 PutClientInServer();
1940                         }
1941                 } else if (self.BUTTON_ATCK2) {
1942                         self.welcomemessage_time = 0;
1943                         self.flags = self.flags - FL_JUMPRELEASED;
1944                         self.classname = "observer";
1945                         PutClientInServer();
1946                 } else {
1947                         if(!SpectateUpdate())
1948                                 PutObserverInServer();
1949                 }
1950         } else {
1951                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1952                         self.flags = self.flags | FL_JUMPRELEASED;
1953                 }
1954         }
1955         if(self.BUTTON_ZOOM)
1956                 self.wantswelcomemessage = 0;
1957         if(self.wantswelcomemessage)
1958                 PrintWelcomeMessage(self);
1959         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1960 }
1961
1962 /*
1963 =============
1964 PlayerPreThink
1965
1966 Called every frame for each client before the physics are run
1967 =============
1968 */
1969 void() ctf_setstatus;
1970 .float vote_nagtime;
1971 .float spectatee_status;
1972 void PlayerPreThink (void)
1973 {
1974         self.stat_sys_ticrate = cvar("sys_ticrate");
1975         if(blockSpectators)
1976                 checkSpectatorBlock();
1977
1978         zoomstate_set = 0;
1979
1980         if(self.netname_previous != self.netname)
1981         {
1982                 if(cvar("sv_eventlog"))
1983                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1984                 if(self.netname_previous)
1985                         strunzone(self.netname_previous);
1986                 self.netname_previous = strzone(self.netname);
1987         }
1988
1989         // version nagging
1990         if(self.version_nagtime)
1991                 if(self.cvar_g_nexuizversion)
1992                         if(time > self.version_nagtime)
1993                         {
1994                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1995                                 {
1996                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1997                                         {
1998                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1999                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2000                                         }
2001                                         else
2002                                         {
2003                                                 float r;
2004                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2005                                                 if(r < 0)
2006                                                 {
2007                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2008                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2009                                                 }
2010                                                 else if(r > 0)
2011                                                 {
2012                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2013                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2014                                                 }
2015                                         }
2016                                 }
2017                                 self.version_nagtime = 0;
2018                         }
2019
2020         // vote nagging
2021         if(self.cvar_scr_centertime)
2022                 if(time > self.vote_nagtime)
2023                 {
2024                         VoteNag();
2025                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
2026                 }
2027
2028         // GOD MODE info
2029         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2030         {
2031                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2032                 self.max_armorvalue = 0;
2033         }
2034
2035         if(frametime)
2036                 antilag_record(self);
2037
2038         if(self.classname == "player") {
2039 //              if(self.netname == "Wazat")
2040 //                      bprint(self.classname, "\n");
2041
2042                 CheckRules_Player();
2043
2044                 if(self.BUTTON_INFO)
2045                         PrintWelcomeMessage(self);
2046
2047                 if(g_lms || !cvar("sv_spectate"))
2048                 if((time - self.jointime) <= cvar("welcome_message_time"))
2049                         PrintWelcomeMessage(self);
2050
2051                 if (intermission_running)
2052                 {
2053                         IntermissionThink ();   // otherwise a button could be missed between
2054                         return;                                 // the think tics
2055                 }
2056
2057                 if(self.teleport_time)
2058                 if(time > self.teleport_time)
2059                 {
2060                         self.teleport_time = 0;
2061                         self.effects = self.effects - (self.effects & EF_NODRAW);
2062                         if(self.weaponentity)
2063                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2064                 }
2065
2066                 Nixnex_GiveCurrentWeapon();
2067
2068                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2069                         UpdateSelectedPlayer();
2070
2071                 //don't allow the player to turn around while game is paused!
2072                 if(timeoutStatus == 2) {
2073                         self.v_angle = self.lastV_angle;
2074                         self.angles = self.lastV_angle;
2075                         self.fixangle = TRUE;
2076                 }
2077
2078                 if (self.deadflag != DEAD_NO)
2079                 {
2080                         float button_pressed, force_respawn;
2081                         player_anim();
2082                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2083                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2084                         if (self.deadflag == DEAD_DYING)
2085                         {
2086                                 if(force_respawn)
2087                                         self.deadflag = DEAD_RESPAWNING;
2088                                 else if(!button_pressed)
2089                                         self.deadflag = DEAD_DEAD;
2090                         }
2091                         else if (self.deadflag == DEAD_DEAD)
2092                         {
2093                                 if(button_pressed)
2094                                         self.deadflag = DEAD_RESPAWNABLE;
2095                         }
2096                         else if (self.deadflag == DEAD_RESPAWNABLE)
2097                         {
2098                                 if(!button_pressed)
2099                                         self.deadflag = DEAD_RESPAWNING;
2100                         }
2101                         else if (self.deadflag == DEAD_RESPAWNING)
2102                         {
2103                                 if(time > self.death_time)
2104                                 {
2105                                         self.death_time = time + 1; // only retry once a second
2106                                         respawn();
2107                                 }
2108                         }
2109                         ShowRespawnCountdown();
2110                         return;
2111                 }
2112
2113                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2114                 {
2115                         vector dist;
2116
2117                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2118                         dist = self.oldorigin - self.origin;
2119                         dist_z = 0;
2120                         self.lms_traveled_distance += fabs(vlen(dist));
2121
2122                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2123                         {
2124                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2125                                 self.lms_traveled_distance = 0;
2126                         }
2127
2128                         if(time > self.lms_nextcheck)
2129                         {
2130                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2131                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2132                                 {
2133                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2134                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2135                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2136                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2137                                 }
2138                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2139                                 self.lms_traveled_distance = 0;
2140                         }
2141                 }
2142
2143                 if (self.BUTTON_CROUCH && !self.hook.state)
2144                 {
2145                         if (!self.crouch)
2146                         {
2147                                 self.crouch = TRUE;
2148                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2149                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2150                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2151                         }
2152                 }
2153                 else
2154                 {
2155                         if (self.crouch)
2156                         {
2157                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2158                                 if (!trace_startsolid)
2159                                 {
2160                                         self.crouch = FALSE;
2161                                         self.view_ofs = PL_VIEW_OFS;
2162                                         setsize (self, PL_MIN, PL_MAX);
2163                                 }
2164                         }
2165                 }
2166
2167                 FixPlayermodel();
2168
2169                 GrapplingHookFrame();
2170
2171                 W_WeaponFrame();
2172
2173                 player_powerups();
2174                 player_regen();
2175                 player_anim();
2176
2177                 if (g_minstagib)
2178                         minstagib_ammocheck();
2179
2180                 ctf_setstatus();
2181                 kh_setstatus();
2182
2183                 //self.angles_y=self.v_angle_y + 90;   // temp
2184
2185                 //if (TetrisPreFrame()) return;
2186         } else if(gameover) {
2187                 if (intermission_running)
2188                         IntermissionThink ();   // otherwise a button could be missed between
2189                 return;
2190         } else if(self.classname == "observer") {
2191                 ObserverThink();
2192         } else if(self.classname == "spectator") {
2193                 SpectatorThink();
2194         }
2195
2196         if(!zoomstate_set)
2197                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2198
2199         float oldspectatee_status;
2200         oldspectatee_status = self.spectatee_status;
2201         if(self.classname == "spectator")
2202                 self.spectatee_status = num_for_edict(self.enemy);
2203         else if(self.classname == "observer")
2204                 self.spectatee_status = num_for_edict(self);
2205         else
2206                 self.spectatee_status = 0;
2207         if(self.spectatee_status != oldspectatee_status)
2208         {
2209                 msg_entity = self;
2210                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2211                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2212                 WriteByte(MSG_ONE, self.spectatee_status);
2213                 if(g_race)
2214                         race_InitSpectator();
2215         }
2216 }
2217
2218
2219 /*
2220 =============
2221 PlayerPostThink
2222
2223 Called every frame for each client after the physics are run
2224 =============
2225 */
2226 .float idlekick_lasttimeleft;
2227 .float race_penalty;
2228 .float race_penalty_nagged;
2229 void PlayerPostThink (void)
2230 {
2231         // Savage: Check for nameless players
2232         if (strlen(self.netname) < 1) {
2233                 self.netname = "Player";
2234                 stuffcmd(self, "seta _cl_name Player\n");
2235         }
2236
2237         if(sv_maxidle)
2238         {
2239                 float timeleft;
2240                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2241                 if(timeleft <= 0)
2242                 {
2243                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2244                         announce(self, "announcer/robotic/terminated.ogg");
2245                         dropclient(self);
2246                         return;
2247                 }
2248                 else if(timeleft <= 10)
2249                 {
2250                         if(timeleft != self.idlekick_lasttimeleft)
2251                         {
2252                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2253                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2254                         }
2255                 }
2256                 else
2257                 {
2258                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2259                 }
2260                 self.idlekick_lasttimeleft = timeleft;
2261         }
2262
2263         if(self.classname == "player") {
2264                 CheckRules_Player();
2265                 UpdateChatBubble();
2266                 UpdateTeamBubble();
2267                 if (self.impulse)
2268                         ImpulseCommands();
2269                 if (intermission_running)
2270                         return;         // intermission or finale
2271
2272                 //PrintWelcomeMessage(self);
2273                 //if (TetrisPostFrame()) return;
2274
2275                 // restart countdown
2276                 if (restart_countdown) {
2277                         if(time < restart_countdown) {
2278                                 if (!cvar("sv_ready_restart_after_countdown"))
2279                                 {
2280                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2281                                         {
2282                                                 if(time < restart_countdown - 2)
2283                                                 {
2284                                                         if(!self.race_penalty_nagged)
2285                                                         {
2286                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2287                                                                 self.race_penalty_nagged = 1;
2288                                                         }
2289                                                 }
2290                                                 else if(!self.race_penalty)
2291                                                 {
2292                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2293                                                         self.race_penalty = time + 5;
2294                                                 }
2295                                         }
2296                                         self.movetype = MOVETYPE_NONE;
2297                                         self.velocity = '0 0 0';
2298                                         self.avelocity = '0 0 0';
2299                                         self.movement = '0 0 0';
2300                                 }
2301                         }
2302                         else if (time < self.race_penalty)
2303                         {
2304                                 self.movetype = MOVETYPE_NONE;
2305                                 self.velocity = '0 0 0';
2306                                 self.avelocity = '0 0 0';
2307                                 self.movement = '0 0 0';
2308                         }
2309                         else
2310                         {
2311                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2312                                 if (!cvar("sv_ready_restart_after_countdown"))
2313                                 {
2314                                         if(self.movetype == MOVETYPE_NONE)
2315                                         {
2316                                                 self.movetype = MOVETYPE_WALK;
2317                                         }
2318                                         self.race_penalty = 0;
2319                                         self.race_penalty_nagged = 0;
2320                                 }
2321                         }
2322                 }
2323
2324         } else if (self.classname == "observer") {
2325                 //do nothing
2326         } else if (self.classname == "spectator") {
2327                 //do nothing
2328         }
2329
2330         /*
2331         float i;
2332         for(i = 0; i < 1000; ++i)
2333         {
2334                 vector end;
2335                 end = self.origin + '0 0 1024' + 512 * randomvec();
2336                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2337                 if(trace_fraction < 1)
2338                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2339                 {
2340                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2341                         break;
2342                 }
2343         }
2344         */
2345
2346         Arena_Warmup();
2347 }