Scaled the weapon models down about 30% to match 2.5.2 sizes. Except the tuba, I...
[divverent/nexuiz.git] / data / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         msg_entity = e;
17         WriteByte(MSG_ONE, SVC_TEMPENTITY);
18         WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ONE, snd);
20 }
21
22 float ClientData_Send(entity to, float sf)
23 {
24         if(to != self.owner)
25         {
26                 error("wtf");
27                 return FALSE;
28         }
29
30         entity e;
31
32         e = to;
33         if(to.classname == "spectator")
34                 e = to.enemy;
35
36         sf = 0;
37
38         if(e.race_completed)
39                 sf |= 1; // forced scoreboard
40         if(to.spectatee_status)
41                 sf |= 2; // spectator ent number follows
42         if(e.zoomstate)
43                 sf |= 4; // zoomed
44         if(e.porto_v_angle_held)
45                 sf |= 8; // angles held
46
47         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
48         WriteByte(MSG_ENTITY, sf);
49
50         if(sf & 2)
51                 WriteByte(MSG_ENTITY, to.spectatee_status);
52
53         if(sf & 8)
54         {
55                 WriteAngle(MSG_ENTITY, e.v_angle_x);
56                 WriteAngle(MSG_ENTITY, e.v_angle_y);
57         }
58
59         return TRUE;
60 }
61
62 void ClientData_Attach()
63 {
64         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
65         self.clientdata.drawonlytoclient = self;
66         self.clientdata.owner = self;
67 }
68
69 void ClientData_Detach()
70 {
71         remove(self.clientdata);
72         self.clientdata = world;
73 }
74
75 void ClientData_Touch(entity e)
76 {
77         e.clientdata.SendFlags = 1;
78
79         // make it spectatable
80         entity e2;
81         FOR_EACH_REALCLIENT(e2)
82         {
83                 if(e2 != e)
84                         if(e2.classname == "spectator")
85                                 if(e2.enemy == e)
86                                         e2.clientdata.SendFlags = 1;
87         }
88 }
89
90
91 .vector spawnpoint_score;
92 .string netname_previous;
93
94 void spawnfunc_info_player_survivor (void)
95 {
96         spawnfunc_info_player_deathmatch();
97 }
98
99 void spawnfunc_info_player_start (void)
100 {
101         spawnfunc_info_player_deathmatch();
102 }
103
104 void spawnfunc_info_player_deathmatch (void)
105 {
106         self.classname = "info_player_deathmatch";
107         relocate_spawnpoint();
108 }
109
110 void spawnpoint_use()
111 {
112         if(teams_matter)
113         if(have_team_spawns > 0)
114         {
115                 self.team = activator.team;
116                 some_spawn_has_been_used = 1;
117         }
118 };
119
120 // Returns:
121 //   _x: prio (-1 if unusable)
122 //   _y: weight
123 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
124 {
125         float shortest, thisdist;
126         float prio;
127         entity player;
128
129         prio = 0;
130
131         // filter out spots for the wrong team
132         if(teamcheck)
133         if(spot.team != teamcheck)
134                 return '-1 0 0';
135
136         if(race_spawns)
137                 if(spot.target == "")
138                         return '-1 0 0';
139
140         if(clienttype(self) == CLIENTTYPE_REAL)
141         {
142                 if(spot.restriction == 1)
143                         return '-1 0 0';
144         }
145         else
146         {
147                 if(spot.restriction == 2)
148                         return '-1 0 0';
149         }
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 local entity ent;
154                 float good, found;
155                 ent = find(world, targetname, spot.target);
156
157                 while(ent) {
158                         if(ent.classname == "target_objective")
159                         {
160                                 found = 1;
161                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
162                                         return '-1 0 0';
163                                 good = 1;
164                         }
165                         else if(ent.classname == "trigger_race_checkpoint")
166                         {
167                                 found = 1;
168                                 if(!anypoint) // spectators may spawn everywhere
169
170                                 {
171                                         if(g_race_qualifying)
172                                         {
173                                                 // spawn at first
174                                                 if(ent.race_checkpoint != 0)
175                                                         return '-1 0 0';
176                                                 if(spot.race_place != race_lowest_place_spawn)
177                                                         return '-1 0 0';
178                                         }
179                                         else
180                                         {
181                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
182                                                         return '-1 0 0';
183                                                 // try reusing the previous spawn
184                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
185                                                         prio += 1;
186                                                 if(ent.race_checkpoint == 0)
187                                                 {
188                                                         float pl;
189                                                         pl = self.race_place;
190                                                         if(pl > race_highest_place_spawn)
191                                                                 pl = 0;
192                                                         if(pl == 0 && !self.race_started)
193                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
194                                                         if(spot.race_place != pl)
195                                                                 return '-1 0 0';
196                                                 }
197                                         }
198                                 }
199                                 good = 1;
200                         }
201                         ent = find(ent, targetname, spot.target);
202                 }
203
204                 if(found && !good)
205                         return '-1 0 0';
206         }
207
208         player = playerlist;
209         shortest = vlen(world.maxs - world.mins);
210         for(player = playerlist; player; player = player.chain)
211                 if (player != self)
212                 {
213                         thisdist = vlen(player.origin - spot.origin);
214                         if (thisdist < shortest)
215                                 shortest = thisdist;
216                 }
217         return prio * '1 0 0' + shortest * '0 1 0';
218 }
219
220 float spawn_allbad;
221 float spawn_allgood;
222 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
223 {
224         local entity spot, spotlist, spotlistend;
225         spawn_allgood = TRUE;
226         spawn_allbad = TRUE;
227
228         spotlist = world;
229         spotlistend = world;
230
231         for(spot = firstspot; spot; spot = spot.chain)
232         {
233                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
234
235                 if(cvar("spawn_debugview"))
236                 {
237                         setmodel(spot, "models/runematch/rune.mdl");
238                         if(spot.spawnpoint_score_y < mindist)
239                         {
240                                 spot.colormod = '1 0 0';
241                                 spot.scale = 1;
242                         }
243                         else
244                         {
245                                 spot.colormod = '0 1 0';
246                                 spot.scale = spot.spawnpoint_score_y / mindist;
247                         }
248                 }
249
250                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
251                 {
252                         if(spot.spawnpoint_score_y < mindist)
253                         {
254                                 // too short distance
255                                 spawn_allgood = FALSE;
256                         }
257                         else
258                         {
259                                 // perfect
260                                 spawn_allbad = FALSE;
261
262                                 if(spotlistend)
263                                         spotlistend.chain = spot;
264                                 spotlistend = spot;
265                                 if(!spotlist)
266                                         spotlist = spot;
267
268                                 /*
269                                 if(teamcheck)
270                                 if(spot.team != teamcheck)
271                                         error("invalid spawn added");
272
273                                 print("added ", etos(spot), "\n");
274                                 */
275                         }
276                 }
277         }
278         if(spotlistend)
279                 spotlistend.chain = world;
280
281         /*
282                 entity e;
283                 if(teamcheck)
284                         for(e = spotlist; e; e = e.chain)
285                         {
286                                 print("seen ", etos(e), "\n");
287                                 if(e.team != teamcheck)
288                                         error("invalid spawn found");
289                         }
290         */
291
292         return spotlist;
293 }
294
295 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
296 {
297         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
298         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
299         local entity spot;
300
301         RandomSelection_Init();
302         for(spot = firstspot; spot; spot = spot.chain)
303                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
304
305         return RandomSelection_chosen_ent;
306 }
307
308 /*
309 =============
310 SelectSpawnPoint
311
312 Finds a point to respawn
313 =============
314 */
315 entity SelectSpawnPoint (float anypoint)
316 {
317         local float teamcheck;
318         local entity firstspot_new;
319         local entity spot, firstspot, playerlist;
320
321         spot = find (world, classname, "testplayerstart");
322         if (spot)
323                 return spot;
324
325         teamcheck = 0;
326
327         if(!anypoint && have_team_spawns > 0)
328                 teamcheck = self.team;
329
330         // get the list of players
331         playerlist = findchain(classname, "player");
332         // get the entire list of spots
333         firstspot = findchain(classname, "info_player_deathmatch");
334         // filter out the bad ones
335         // (note this returns the original list if none survived)
336         if(anypoint)
337         {
338                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
339         }
340         else
341         {
342                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
343                 if(!firstspot_new)
344                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
345                 firstspot = firstspot_new;
346
347                 // there is 50/50 chance of choosing a random spot or the furthest spot
348                 // (this means that roughly every other spawn will be furthest, so you
349                 // usually won't get fragged at spawn twice in a row)
350                 if (arena_roundbased && !g_ca)
351                 {
352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
353                         if(firstspot_new)
354                                 firstspot = firstspot_new;
355                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
356                 }
357                 else if (random() > cvar("g_spawn_furthest"))
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 else
360                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
361         }
362
363         if(cvar("spawn_debugview"))
364         {
365                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
366
367                 entity e;
368                 if(teamcheck)
369                         for(e = firstspot; e; e = e.chain)
370                                 if(e.team != teamcheck)
371                                         error("invalid spawn found");
372         }
373
374         if (!spot)
375         {
376                 if(cvar("spawn_debug"))
377                         GotoNextMap();
378                 else
379                 {
380                         if(some_spawn_has_been_used)
381                                 return world; // team can't spawn any more, because of actions of other team
382                         else
383                                 error("Cannot find a spawn point - please fix the map!");
384                 }
385         }
386
387         return spot;
388 }
389
390 /*
391 =============
392 CheckPlayerModel
393
394 Checks if the argument string can be a valid playermodel.
395 Returns a valid one in doubt.
396 =============
397 */
398 string FallbackPlayerModel = "models/player/marine.zym";
399 string CheckPlayerModel(string plyermodel) {
400         if(strlen(plyermodel) < 4)
401                 return FallbackPlayerModel;
402         if( substring(plyermodel,0,14) != "models/player/")
403                 return FallbackPlayerModel;
404         else if(cvar("sv_servermodelsonly"))
405         {
406                 if(substring(plyermodel,-4,4) != ".zym")
407                 if(substring(plyermodel,-4,4) != ".dpm")
408                 if(substring(plyermodel,-4,4) != ".md3")
409                 if(substring(plyermodel,-4,4) != ".psk")
410                         return FallbackPlayerModel;
411                 // forbid the LOD models
412                 if(substring(plyermodel, -9,5) == "_lod1")
413                         return FallbackPlayerModel;
414                 if(substring(plyermodel, -9,5) == "_lod2")
415                         return FallbackPlayerModel;
416                 if(plyermodel != strtolower(plyermodel))
417                         return FallbackPlayerModel;
418                 if(!fexists(plyermodel))
419                         return FallbackPlayerModel;
420         }
421         return plyermodel;
422 }
423
424 /*
425 =============
426 Client_customizeentityforclient
427
428 LOD reduction
429 =============
430 */
431 void Client_uncustomizeentityforclient()
432 {
433         if(self.modelindex == 0) // no need to uncustomize then
434                 return;
435         self.modelindex = self.modelindex_lod0;
436         self.skin = self.skinindex;
437 }
438
439 float Client_customizeentityforclient()
440 {
441         entity modelsource;
442
443         if(self.modelindex == 0)
444                 return TRUE;
445
446         // forcemodel stuff
447
448 #ifdef PROFILING
449         float t0;
450         t0 = gettime(GETTIME_HIRES); // reference
451 #endif
452
453         modelsource = self;
454
455 #ifdef ALLOW_FORCEMODELS
456         if(other.cvar_cl_forceplayermodelsfromnexuiz)
457                 if not(self.modelindex_lod0_from_nexuiz)
458                         modelsource = other;
459         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
460                 modelsource = other;
461 #endif
462
463         self.skin = modelsource.skinindex;
464
465 #if 0
466         if(modelsource == self)
467                 self.skin = modelsource.skinindex;
468         else
469                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
470 #endif
471
472         // self: me
473         // other: the player viewing me
474         float distance;
475         float f;
476
477         if(other.cvar_cl_playerdetailreduction <= 0)
478         {
479                 if(other.cvar_cl_playerdetailreduction <= -2)
480                         self.modelindex = modelsource.modelindex_lod2;
481                 else if(other.cvar_cl_playerdetailreduction <= -1)
482                         self.modelindex = modelsource.modelindex_lod1;
483                 else
484                         self.modelindex = modelsource.modelindex_lod0;
485         }
486         else
487         {
488                 distance = vlen(self.origin - other.origin);
489                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
490                 if(f > sv_loddistance2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(f > sv_loddistance1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497
498 #ifdef PROFILING
499         float t1;
500         t1 = gettime(GETTIME_HIRES); // reference
501         client_cefc_accumulator += (t1 - t0);
502 #endif
503
504         return TRUE;
505 }
506
507 void UpdatePlayerSounds();
508 void setmodel_lod(entity e, string modelname)
509 {
510         string s;
511
512         if(sv_loddistance1)
513         {
514                 // FIXME: this only supports 3-letter extensions
515                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
516                 if(fexists(s))
517                 {
518                         setmodel(e, s); // players have high precision
519                         self.modelindex_lod1 = self.modelindex;
520                 }
521                 else
522                         self.modelindex_lod1 = -1;
523
524                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
525                 if(fexists(s))
526                 {
527                         setmodel(e, s); // players have high precision
528                         self.modelindex_lod2 = self.modelindex;
529                 }
530                 else
531                         self.modelindex_lod2 = -1;
532
533                 precache_model(modelname);
534                 setmodel(e, modelname); // players have high precision
535                 self.modelindex_lod0 = self.modelindex;
536
537                 if(self.modelindex_lod1 < 0)
538                         self.modelindex_lod1 = self.modelindex;
539
540                 if(self.modelindex_lod2 < 0)
541                         self.modelindex_lod2 = self.modelindex;
542         }
543         else
544         {
545                 precache_model(modelname);
546                 setmodel(e, modelname); // players have high precision
547                 self.modelindex_lod0 = self.modelindex;
548                         // save it for possible player model forcing
549         }
550
551         s = whichpack(self.model);
552         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
553
554         player_setupanimsformodel();
555         UpdatePlayerSounds();
556 }
557
558 /*
559 =============
560 PutObserverInServer
561
562 putting a client as observer in the server
563 =============
564 */
565 void FixPlayermodel();
566 void PutObserverInServer (void)
567 {
568         entity  spot;
569
570         race_PreSpawnObserver();
571
572         spot = SelectSpawnPoint (TRUE);
573         if(!spot)
574                 error("No spawnpoints for observers?!?\n");
575         RemoveGrapplingHook(self); // Wazat's Grappling Hook
576
577         if(clienttype(self) == CLIENTTYPE_REAL)
578         {
579                 msg_entity = self;
580                 WriteByte(MSG_ONE, SVC_SETVIEW);
581                 WriteEntity(MSG_ONE, self);
582         }
583
584         DropAllRunes(self);
585         kh_Key_DropAll(self, TRUE);
586
587         Portal_ClearAll(self);
588
589         if(self.flagcarried)
590                 DropFlag(self.flagcarried, world, world);
591
592         if(self.ballcarried)
593                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
594
595         WaypointSprite_PlayerDead();
596
597         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
598                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
599
600         if(self.killcount != -666) {
601                 if(g_lms) {
602                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
603                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
604                         else
605                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
606                 } else
607                         bprint ("^4", self.netname, "^4 is spectating now\n");
608
609                 if(self.just_joined == FALSE) {
610                         LogTeamchange(self.playerid, -1, 4);
611                 } else
612                         self.just_joined = FALSE;
613         }
614
615         PlayerScore_Clear(self); // clear scores when needed
616
617         self.spectatortime = time;
618
619         self.classname = "observer";
620         self.iscreature = FALSE;
621         self.health = -666;
622         self.takedamage = DAMAGE_NO;
623         self.solid = SOLID_NOT;
624         self.movetype = MOVETYPE_NOCLIP;
625         self.flags = FL_CLIENT | FL_NOTARGET;
626         self.armorvalue = 666;
627         self.effects = 0;
628         self.armorvalue = cvar("g_balance_armor_start");
629         self.pauserotarmor_finished = 0;
630         self.pauserothealth_finished = 0;
631         self.pauseregen_finished = 0;
632         self.damageforcescale = 0;
633         self.death_time = 0;
634         self.dead_frame = 0;
635         self.alpha = 0;
636         self.scale = 0;
637         self.fade_time = 0;
638         self.pain_frame = 0;
639         self.pain_finished = 0;
640         self.strength_finished = 0;
641         self.invincible_finished = 0;
642         self.pushltime = 0;
643         self.think = SUB_Null;
644         self.nextthink = 0;
645         self.hook_time = 0;
646         self.runes = 0;
647         self.deadflag = DEAD_NO;
648         self.angles = spot.angles;
649         self.angles_z = 0;
650         self.fixangle = TRUE;
651         self.crouch = FALSE;
652
653         self.view_ofs = PL_VIEW_OFS;
654         setorigin (self, spot.origin);
655         setsize (self, '0 0 0', '0 0 0');
656         self.prevorigin = self.origin;
657         self.items = 0;
658         self.weapons = 0;
659         self.model = "";
660         FixPlayermodel();
661         self.model = "";
662         self.modelindex = 0;
663         self.weapon = 0;
664         self.weaponmodel = "";
665         self.weaponentity = world;
666         self.exteriorweaponentity = world;
667         self.killcount = -666;
668         self.velocity = '0 0 0';
669         self.avelocity = '0 0 0';
670         self.punchangle = '0 0 0';
671         self.punchvector = '0 0 0';
672         self.oldvelocity = self.velocity;
673         self.fire_endtime = -1;
674
675         if(sv_loddistance1)
676                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
677
678         if(g_arena)
679         {
680                 if(self.version_mismatch)
681                 {
682                         Spawnqueue_Unmark(self);
683                         Spawnqueue_Remove(self);
684                 }
685                 else
686                 {
687                         Spawnqueue_Insert(self);
688                 }
689         }
690         else if(g_lms)
691         {
692                 // Only if the player cannot play at all
693                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
694                         self.frags = FRAGS_SPECTATOR;
695                 else
696                         self.frags = FRAGS_LMS_LOSER;
697         }
698         else
699                 self.frags = FRAGS_SPECTATOR;
700 }
701
702 float RestrictSkin(float s)
703 {
704         if(!teams_matter)
705                 return s;
706         if(s == 6)
707                 return 6;
708         return mod(s, 3);
709 }
710
711 void FixPlayermodel()
712 {
713         local string defaultmodel;
714         local float defaultskin, chmdl, oldskin;
715         local vector m1, m2;
716
717         defaultmodel = "";
718
719         if(cvar("sv_defaultcharacter") == 1) {
720                 defaultskin = 0;
721
722                 if(teams_matter)
723                 {
724                         string s;
725                         s = Team_ColorNameLowerCase(self.team);
726                         if(s != "neutral")
727                         {
728                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
729                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
730                         }
731                 }
732
733                 if(defaultmodel == "")
734                 {
735                         defaultmodel = cvar_string("sv_defaultplayermodel");
736                         defaultskin = cvar("sv_defaultplayerskin");
737                 }
738         }
739
740         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
741         {
742                 if(self.model != "")
743                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
744                 self.model = ""; // force the != checks to return true
745         }
746
747         if(defaultmodel != "")
748         {
749                 if (defaultmodel != self.model)
750                 {
751                         m1 = self.mins;
752                         m2 = self.maxs;
753                         setmodel_lod (self, defaultmodel);
754                         setsize (self, m1, m2);
755                         chmdl = TRUE;
756                 }
757
758                 oldskin = self.skinindex;
759                 self.skinindex = defaultskin;
760         } else {
761                 if (self.playermodel != self.model || self.playermodel == "")
762                 {
763                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
764                         m1 = self.mins;
765                         m2 = self.maxs;
766                         setmodel_lod (self, self.playermodel);
767                         setsize (self, m1, m2);
768                         chmdl = TRUE;
769                 }
770
771                 oldskin = self.skinindex;
772                 self.skinindex = RestrictSkin(stof(self.playerskin));
773         }
774
775         if(chmdl || oldskin != self.skinindex)
776                 self.species = player_getspecies(); // model or skin has changed
777
778         if(!teams_matter)
779                 if(strlen(cvar_string("sv_defaultplayercolors")))
780                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
781                                 setcolor(self, cvar("sv_defaultplayercolors"));
782 }
783
784 void PlayerTouchExplode(entity p1, entity p2)
785 {
786         vector org;
787         org = (p1.origin + p2.origin) * 0.5;
788         org_z += (p1.mins_z + p2.mins_z) * 0.5;
789
790         te_explosion(org);
791
792         entity e;
793         e = spawn();
794         setorigin(e, org);
795         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
796         remove(e);
797 }
798
799 /*
800 =============
801 PutClientInServer
802
803 Called when a client spawns in the server
804 =============
805 */
806 //void() ctf_playerchanged;
807 void PutClientInServer (void)
808 {
809         if(clienttype(self) == CLIENTTYPE_BOT)
810         {
811                 self.classname = "player";
812         }
813         else if(clienttype(self) == CLIENTTYPE_REAL)
814         {
815                 msg_entity = self;
816                 WriteByte(MSG_ONE, SVC_SETVIEW);
817                 WriteEntity(MSG_ONE, self);
818         }
819
820         // player is dead and becomes observer
821         // FIXME fix LMS scoring for new system
822         if(g_lms)
823         {
824                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
825                         self.classname = "observer";
826         }
827
828         if(g_arena || (g_ca && !allowed_to_spawn))
829         if(!self.spawned)
830                 self.classname = "observer";
831
832         if(gameover)
833                 self.classname = "observer";
834
835         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
836                 entity spot, oldself;
837                 float j;
838
839                 if(self.team < 0)
840                         JoinBestTeam(self, FALSE, TRUE);
841
842                 race_PreSpawn();
843
844                 spot = SelectSpawnPoint (FALSE);
845                 if(!spot)
846                 {
847                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
848                         return; // spawn failed
849                 }
850
851                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
852
853                 self.classname = "player";
854                 self.wasplayer = TRUE;
855                 self.iscreature = TRUE;
856                 self.movetype = MOVETYPE_WALK;
857                 self.solid = SOLID_SLIDEBOX;
858                 if(cvar("g_playerclip_collisions"))
859                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
860                 else
861                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
862                 self.frags = FRAGS_PLAYER;
863                 if(independent_players)
864                         MAKE_INDEPENDENT_PLAYER(self);
865                 self.flags = FL_CLIENT;
866                 self.takedamage = DAMAGE_AIM;
867                 if(g_minstagib)
868                         self.effects = EF_FULLBRIGHT;
869                 else
870                         self.effects = 0;
871                 self.air_finished = time + 12;
872                 self.dmg = 2;
873
874                 if(inWarmupStage)
875                 {
876                         self.ammo_shells = warmup_start_ammo_shells;
877                         self.ammo_nails = warmup_start_ammo_nails;
878                         self.ammo_rockets = warmup_start_ammo_rockets;
879                         self.ammo_cells = warmup_start_ammo_cells;
880                         self.ammo_fuel = warmup_start_ammo_fuel;
881                         self.health = warmup_start_health;
882                         self.armorvalue = warmup_start_armorvalue;
883                         self.weapons = warmup_start_weapons;
884                 }
885                 else
886                 {
887                         self.ammo_shells = start_ammo_shells;
888                         self.ammo_nails = start_ammo_nails;
889                         self.ammo_rockets = start_ammo_rockets;
890                         self.ammo_cells = start_ammo_cells;
891                         self.ammo_fuel = start_ammo_fuel;
892                         self.health = start_health;
893                         self.armorvalue = start_armorvalue;
894                         self.weapons = start_weapons;
895                 }
896
897                 if(g_weaponarena_random)
898                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
899
900                 self.items = start_items;
901                 self.switchweapon = w_getbestweapon(self);
902                 self.cnt = self.switchweapon;
903                 self.weapon = 0;
904                 self.jump_interval = time;
905
906                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
907                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
908                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
909                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
910                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
911                 //extend the pause of rotting if client was reset at the beginning of the countdown
912                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
913                         self.spawnshieldtime += game_starttime - time;
914                         self.pauserotarmor_finished += game_starttime - time;
915                         self.pauserothealth_finished += game_starttime - time;
916                         self.pauseregen_finished += game_starttime - time;
917                 }
918                 self.damageforcescale = 2;
919                 self.death_time = 0;
920                 self.dead_frame = 0;
921                 self.alpha = 0;
922                 self.scale = 0;
923                 self.fade_time = 0;
924                 self.pain_frame = 0;
925                 self.pain_finished = 0;
926                 self.strength_finished = 0;
927                 self.invincible_finished = 0;
928                 self.pushltime = 0;
929                 // players have no think function
930                 self.think = SUB_Null;
931                 self.nextthink = 0;
932                 self.hook_time = 0;
933                 self.dmg_team = 0;
934
935                 self.metertime = 0;
936
937                 self.runes = 0;
938
939                 self.deadflag = DEAD_NO;
940
941                 self.angles = spot.angles;
942
943                 self.angles_z = 0; // never spawn tilted even if the spot says to
944                 self.fixangle = TRUE; // turn this way immediately
945                 self.velocity = '0 0 0';
946                 self.avelocity = '0 0 0';
947                 self.punchangle = '0 0 0';
948                 self.punchvector = '0 0 0';
949                 self.oldvelocity = self.velocity;
950                 self.fire_endtime = -1;
951
952                 msg_entity = self;
953                 WRITESPECTATABLE_MSG_ONE({
954                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
955                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
956                 });
957
958                 if(sv_loddistance1)
959                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
960
961                 self.model = "";
962                 FixPlayermodel();
963
964                 self.crouch = FALSE;
965                 self.view_ofs = PL_VIEW_OFS;
966                 setsize (self, PL_MIN, PL_MAX);
967                 self.spawnorigin = spot.origin;
968                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
969                 // don't reset back to last position, even if new position is stuck in solid
970                 self.oldorigin = self.origin;
971                 self.prevorigin = self.origin;
972                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
973
974                 if(g_arena)
975                 {
976                         Spawnqueue_Remove(self);
977                         Spawnqueue_Mark(self);
978                 }
979
980                 else if(g_ca)
981                         self.caplayer = 1;
982
983                 self.event_damage = PlayerDamage;
984
985                 self.bot_attack = TRUE;
986
987                 self.statdraintime = time + 5;
988                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
989
990                 if(self.killcount == -666) {
991                         PlayerScore_Clear(self);
992                         self.killcount = 0;
993                 }
994
995                 self.cnt = WEP_LASER;
996                 self.nixnex_lastchange_id = -1;
997
998                 CL_SpawnWeaponentity();
999                 self.alpha = default_player_alpha;
1000                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1001                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1002
1003                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1004                 self.lms_traveled_distance = 0;
1005                 self.speedrunning = FALSE;
1006
1007                 race_PostSpawn(spot);
1008
1009                 if(cvar("spawn_debug"))
1010                 {
1011                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1012                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1013                 }
1014
1015                 //stuffcmd(self, "chase_active 0");
1016                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1017
1018                 if (cvar("g_spawnsound"))
1019                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1020
1021                 if(g_assault) {
1022                         if(self.team == assault_attacker_team)
1023                                 centerprint(self, "You are attacking!");
1024                         else
1025                                 centerprint(self, "You are defending!");
1026                 }
1027
1028                 target_voicescript_clear(self);
1029
1030                 // reset fields the weapons may use
1031         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1032             weapon_action(j, WR_RESETPLAYER);
1033
1034                 oldself = self;
1035                 self = spot;
1036                         activator = oldself;
1037                                 SUB_UseTargets();
1038                         activator = world;
1039                 self = oldself;
1040         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1041                 PutObserverInServer ();
1042         }
1043
1044         //if(g_ctf)
1045         //      ctf_playerchanged();
1046 }
1047
1048 float ClientInit_SendEntity(entity to, float sf)
1049 {
1050         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1051         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1052         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1053         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1054         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1055
1056         if(sv_foginterval && world.fog != "")
1057                 WriteString(MSG_ENTITY, world.fog);
1058         else
1059                 WriteString(MSG_ENTITY, "");
1060         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1061         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1062         return TRUE;
1063 }
1064
1065 void ClientInit_Spawn()
1066 {
1067         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1068 }
1069
1070 /*
1071 =============
1072 SetNewParms
1073 =============
1074 */
1075 void SetNewParms (void)
1076 {
1077         // initialize parms for a new player
1078         parm1 = -(86400 * 366);
1079 }
1080
1081 /*
1082 =============
1083 SetChangeParms
1084 =============
1085 */
1086 void SetChangeParms (void)
1087 {
1088         // save parms for level change
1089         parm1 = self.parm_idlesince - time;
1090 }
1091
1092 /*
1093 =============
1094 DecodeLevelParms
1095 =============
1096 */
1097 void DecodeLevelParms (void)
1098 {
1099         // load parms
1100         self.parm_idlesince = parm1;
1101         if(self.parm_idlesince == -(86400 * 366))
1102                 self.parm_idlesince = time;
1103
1104         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1105         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1106 }
1107
1108 /*
1109 =============
1110 ClientKill
1111
1112 Called when a client types 'kill' in the console
1113 =============
1114 */
1115
1116 void ClientKill_Now_TeamChange()
1117 {
1118         if(self.killindicator_teamchange == -1)
1119         {
1120                 self.team = -1;
1121                 JoinBestTeam( self, FALSE, FALSE );
1122         }
1123         else
1124                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1125 }
1126
1127 void ClientKill_Now()
1128 {
1129         if(self.killindicator_teamchange)
1130                 ClientKill_Now_TeamChange();
1131
1132         // in any case:
1133         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1134
1135         if(self.killindicator)
1136         {
1137                 dprint("Cleaned up after a leaked kill indicator.\n");
1138                 remove(self.killindicator);
1139                 self.killindicator = world;
1140         }
1141 }
1142 void KillIndicator_Think()
1143 {
1144         if (!self.owner.modelindex)
1145         {
1146                 self.owner.killindicator = world;
1147                 remove(self);
1148                 return;
1149         }
1150
1151         if(self.cnt <= 0)
1152         {
1153                 self = self.owner;
1154                 ClientKill_Now(); // no oldself needed
1155                 return;
1156         }
1157         else
1158         {
1159                 if(self.cnt <= 10)
1160                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1161                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1162                 {
1163                         if(self.cnt <= 10)
1164                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1165                         if(self.owner.killindicator_teamchange)
1166                         {
1167                                 if(self.owner.killindicator_teamchange == -1)
1168                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1169                                 else
1170                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1171                         }
1172                         else
1173                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1174                 }
1175                 self.nextthink = time + 1;
1176                 self.cnt -= 1;
1177         }
1178 }
1179
1180 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1181 {
1182         float killtime;
1183         entity e;
1184         killtime = cvar("g_balance_kill_delay");
1185
1186         if(g_race_qualifying)
1187                 killtime = 0;
1188
1189         self.killindicator_teamchange = targetteam;
1190
1191         if(!self.killindicator)
1192         {
1193                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1194                 {
1195                         ClientKill_Now();
1196                 }
1197                 else
1198                 {
1199                         self.killindicator = spawn();
1200                         self.killindicator.owner = self;
1201                         self.killindicator.scale = 0.5;
1202                         setattachment(self.killindicator, self, "");
1203                         setorigin(self.killindicator, '0 0 52');
1204                         self.killindicator.think = KillIndicator_Think;
1205                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1206                         self.killindicator.cnt = ceil(killtime);
1207                         self.killindicator.count = bound(0, ceil(killtime), 10);
1208                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1209
1210                         for(e = world; (e = find(e, classname, "body")) != world; )
1211                         {
1212                                 if(e.enemy != self)
1213                                         continue;
1214                                 e.killindicator = spawn();
1215                                 e.killindicator.owner = e;
1216                                 e.killindicator.scale = 0.5;
1217                                 setattachment(e.killindicator, e, "");
1218                                 setorigin(e.killindicator, '0 0 52');
1219                                 e.killindicator.think = KillIndicator_Think;
1220                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1221                                 e.killindicator.cnt = ceil(killtime);
1222                         }
1223                         self.lip = 0;
1224                 }
1225         }
1226         if(self.killindicator)
1227         {
1228                 if(targetteam)
1229                         self.killindicator.colormod = TeamColor(targetteam);
1230                 else
1231                         self.killindicator.colormod = '0 0 0';
1232         }
1233 }
1234
1235 void ClientKill (void)
1236 {
1237         ClientKill_TeamChange(0);
1238 }
1239
1240 void DoTeamChange(float destteam)
1241 {
1242         float t, c0;
1243         if(!teams_matter)
1244         {
1245                 if(destteam >= 0)
1246                         SetPlayerColors(self, destteam);
1247                 return;
1248         }
1249         if(self.classname == "player")
1250         if(destteam == -1)
1251         {
1252                 CheckAllowedTeams(self);
1253                 t = FindSmallestTeam(self, TRUE);
1254                 switch(self.team)
1255                 {
1256                         case COLOR_TEAM1: c0 = c1; break;
1257                         case COLOR_TEAM2: c0 = c2; break;
1258                         case COLOR_TEAM3: c0 = c3; break;
1259                         case COLOR_TEAM4: c0 = c4; break;
1260                         default:          c0 = 999;
1261                 }
1262                 switch(t)
1263                 {
1264                         case 1:
1265                                 if(c0 > c1)
1266                                         destteam = COLOR_TEAM1;
1267                                 break;
1268                         case 2:
1269                                 if(c0 > c2)
1270                                         destteam = COLOR_TEAM2;
1271                                 break;
1272                         case 3:
1273                                 if(c0 > c3)
1274                                         destteam = COLOR_TEAM3;
1275                                 break;
1276                         case 4:
1277                                 if(c0 > c4)
1278                                         destteam = COLOR_TEAM4;
1279                                 break;
1280                 }
1281                 if(destteam == -1)
1282                         return;
1283         }
1284         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1285                 return;
1286         ClientKill_TeamChange(destteam);
1287 }
1288
1289 void FixClientCvars(entity e)
1290 {
1291         // send prediction settings to the client
1292         stuffcmd(e, "\nin_bindmap 0 0\n");
1293         if(g_race || g_cts)
1294                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1295         if(cvar("g_antilag") == 3) // client side hitscan
1296                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1297                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1298         /*
1299          * we no longer need to stuff this. Remove this comment block if you feel
1300          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1301         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1302         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1303         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1304         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1305         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1306         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1312         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1313         stuffcmd(e, "cl_movement_edgefriction 1\n");
1314          */
1315 }
1316
1317 /*
1318 =============
1319 ClientConnect
1320
1321 Called when a client connects to the server
1322 =============
1323 */
1324 //void ctf_clientconnect();
1325 string ColoredTeamName(float t);
1326 void DecodeLevelParms (void);
1327 //void dom_player_join_team(entity pl);
1328 #ifdef UID
1329 .float uid_kicktime;
1330 .string uid;
1331 #endif
1332 void ClientConnect (void)
1333 {
1334         float t;
1335
1336         if(self.flags & FL_CLIENT)
1337         {
1338                 print("Warning: ClientConnect, but already connected!\n");
1339                 return;
1340         }
1341
1342         if(Ban_MaybeEnforceBan(self))
1343                 return;
1344
1345         DecodeLevelParms();
1346
1347         self.classname = "player_joining";
1348
1349         self.flags = FL_CLIENT;
1350         self.version_nagtime = time + 10 + random() * 10;
1351
1352         if(player_count<0)
1353         {
1354                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1355                 player_count = 0;
1356         }
1357
1358         PlayerScore_Attach(self);
1359         ClientData_Attach();
1360
1361         bot_clientconnect();
1362
1363         playerdemo_init();
1364
1365         anticheat_init();
1366         
1367         race_PreSpawnObserver();
1368
1369         //if(g_domination)
1370         //      dom_player_join_team(self);
1371
1372         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1373
1374         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1375                 self.classname = "observer";
1376         } else {
1377                 if(teams_matter)
1378                 {
1379                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1380                         {
1381                                 self.classname = "player";
1382                                 campaign_bots_may_start = 1;
1383                         }
1384                         else
1385                         {
1386                                 self.classname = "observer"; // do it anyway
1387                         }
1388                 }
1389                 else
1390                 {
1391                         self.classname = "player";
1392                         campaign_bots_may_start = 1;
1393                 }
1394         }
1395
1396         self.playerid = (playerid_last = playerid_last + 1);
1397
1398         if(cvar("sv_eventlog"))
1399                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1400
1401         LogTeamchange(self.playerid, self.team, 1);
1402
1403         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1404
1405         self.netname_previous = strzone(self.netname);
1406
1407         bprint("^4", self.netname, "^4 connected");
1408
1409         if(self.classname != "observer" && (g_domination || g_ctf))
1410                 bprint(" and joined the ", ColoredTeamName(self.team));
1411
1412         bprint("\n");
1413
1414         self.welcomemessage_time = 0;
1415
1416         stuffcmd(self, strcat(clientstuff, "\n"));
1417         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1418         stuffcmd(self, "cl_particles_reloadeffects\n");
1419
1420         FixClientCvars(self);
1421
1422         // spawnfunc_waypoint sprites
1423         WaypointSprite_InitClient(self);
1424
1425         // Wazat's grappling hook
1426         SetGrappleHookBindings();
1427
1428         // get autoswitch state from player when he toggles it
1429         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1430
1431         // get version info from player
1432         stuffcmd(self, "cmd clientversion $gameversion\n");
1433
1434         // get other cvars from player
1435         GetCvars(0);
1436
1437         // set cvar for team scoreboard
1438         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1439
1440         // notify about available teams
1441         if(teams_matter)
1442         {
1443                 CheckAllowedTeams(self);
1444                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1445                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1446         }
1447         else
1448                 stuffcmd(self, "set _teams_available 0\n");
1449
1450         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1451
1452         if(g_arena || g_ca)
1453         {
1454                 self.classname = "observer";
1455                 if(g_arena)
1456                         Spawnqueue_Insert(self);
1457         }
1458         /*else if(g_ctf)
1459         {
1460                 ctf_clientconnect();
1461         }*/
1462
1463         if(teams_matter || radar_showennemies)
1464                 attach_entcs();
1465
1466         bot_relinkplayerlist();
1467
1468         self.spectatortime = time;
1469         if(blockSpectators)
1470         {
1471                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1472         }
1473
1474         self.jointime = time;
1475         self.allowedTimeouts = cvar("sv_timeout_number");
1476
1477         if(clienttype(self) == CLIENTTYPE_REAL)
1478         {
1479                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1480                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1481         }
1482
1483         if(g_lms)
1484         {
1485                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1486                 {
1487                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1488                         self.frags = FRAGS_SPECTATOR;
1489                 }
1490         }
1491
1492         if(!sv_foginterval && world.fog != "")
1493                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1494
1495         SoundEntity_Attach(self);
1496
1497         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1498         {
1499                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1500                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1501         }
1502         else
1503                 self.hitplotfh = -1;
1504
1505 #ifdef UID
1506         if(clienttype(self) == CLIENTTYPE_REAL)
1507         if not(self.uid)
1508                 self.uid_kicktime = time + 60;
1509 #endif
1510
1511         if(g_race || g_cts) {
1512                 string rr;
1513                 if(g_cts)
1514                         rr = CTS_RECORD;
1515                 else
1516                         rr = RACE_RECORD;
1517                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1518
1519                 race_send_recordtime(MSG_ONE);
1520                 race_send_speedaward(MSG_ONE);
1521
1522                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1523                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1524                 race_send_speedaward_alltimebest(MSG_ONE);
1525
1526                 float i;
1527                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1528                         race_SendRankings(i, 0, 0, MSG_ONE);
1529                 }
1530         }
1531         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1532                 send_CSQC_teamnagger();
1533
1534         CheatInitClient();
1535 }
1536
1537 /*
1538 =============
1539 ClientDisconnect
1540
1541 Called when a client disconnects from the server
1542 =============
1543 */
1544 .entity chatbubbleentity;
1545 .entity teambubbleentity;
1546 void ReadyCount();
1547 void ClientDisconnect (void)
1548 {
1549         if not(self.flags & FL_CLIENT)
1550         {
1551                 print("Warning: ClientDisconnect without ClientConnect\n");
1552                 return;
1553         }
1554
1555         CheatShutdownClient();
1556
1557         if(self.hitplotfh >= 0)
1558         {
1559                 fclose(self.hitplotfh);
1560                 self.hitplotfh = -1;
1561         }
1562
1563         anticheat_report();
1564         anticheat_shutdown();
1565
1566         playerdemo_shutdown();
1567
1568         bot_clientdisconnect();
1569
1570         if(self.entcs)
1571                 detach_entcs();
1572
1573         if(cvar("sv_eventlog"))
1574                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1575         bprint ("^4",self.netname);
1576         bprint ("^4 disconnected\n");
1577
1578         SoundEntity_Detach(self);
1579
1580         DropAllRunes(self);
1581         kh_Key_DropAll(self, TRUE);
1582
1583         Portal_ClearAll(self);
1584
1585         if(self.flagcarried)
1586                 DropFlag(self.flagcarried, world, world);
1587         if(self.ballcarried)
1588                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1589
1590         // Here, everything has been done that requires this player to be a client.
1591
1592         self.flags &~= FL_CLIENT;
1593
1594         if (self.chatbubbleentity)
1595                 remove (self.chatbubbleentity);
1596
1597         if (self.teambubbleentity)
1598                 remove (self.teambubbleentity);
1599
1600         if (self.killindicator)
1601                 remove (self.killindicator);
1602
1603         WaypointSprite_PlayerGone();
1604
1605         bot_relinkplayerlist();
1606
1607         // remove laserdot
1608         if(self.weaponentity)
1609                 if(self.weaponentity.lasertarget)
1610                         remove(self.weaponentity.lasertarget);
1611
1612         if(g_arena)
1613         {
1614                 Spawnqueue_Unmark(self);
1615                 Spawnqueue_Remove(self);
1616         }
1617
1618         ClientData_Detach();
1619         PlayerScore_Detach(self);
1620
1621         if(self.netname_previous)
1622                 strunzone(self.netname_previous);
1623         if(self.clientstatus)
1624                 strunzone(self.clientstatus);
1625
1626         ClearPlayerSounds();
1627
1628         if(self.personal)
1629                 remove(self.personal);
1630
1631         self.playerid = 0;
1632         ReadyCount();
1633
1634         // free cvars
1635         GetCvars(-1);
1636 }
1637
1638 .float BUTTON_CHAT;
1639 void ChatBubbleThink()
1640 {
1641         self.nextthink = time;
1642         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1643         {
1644                 if(self.owner) // but why can that ever be world?
1645                         self.owner.chatbubbleentity = world;
1646                 remove(self);
1647                 return;
1648         }
1649         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1650 #ifdef TETRIS
1651                 || self.owner.tetris_on
1652 #endif
1653         )
1654                 self.model = self.mdl;
1655         else
1656                 self.model = "";
1657 };
1658
1659 void UpdateChatBubble()
1660 {
1661         if (!self.modelindex)
1662                 return;
1663         // spawn a chatbubble entity if needed
1664         if (!self.chatbubbleentity)
1665         {
1666                 self.chatbubbleentity = spawn();
1667                 self.chatbubbleentity.owner = self;
1668                 self.chatbubbleentity.exteriormodeltoclient = self;
1669                 self.chatbubbleentity.think = ChatBubbleThink;
1670                 self.chatbubbleentity.nextthink = time;
1671                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1672                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1673                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1674                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1675                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1676                 self.chatbubbleentity.model = "";
1677                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1678         }
1679 }
1680
1681
1682 void TeamBubbleThink()
1683 {
1684         self.nextthink = time;
1685         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1686         {
1687                 if(self.owner) // but why can that ever be world?
1688                         self.owner.teambubbleentity = world;
1689                 remove(self);
1690                 return;
1691         }
1692 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1693         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1694                 self.model = "";
1695         else
1696                 self.model = self.mdl;
1697
1698 };
1699
1700 float TeamBubble_customizeentityforclient()
1701 {
1702         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1703 }
1704
1705 void UpdateTeamBubble()
1706 {
1707         if (!self.modelindex || !teams_matter)
1708                 return;
1709         // spawn a teambubble entity if needed
1710         if (!self.teambubbleentity && teams_matter)
1711         {
1712                 self.teambubbleentity = spawn();
1713                 self.teambubbleentity.owner = self;
1714                 self.teambubbleentity.exteriormodeltoclient = self;
1715                 self.teambubbleentity.think = TeamBubbleThink;
1716                 self.teambubbleentity.nextthink = time;
1717                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1718 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1719                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1720                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1721                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1722                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1723                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1724                 self.teambubbleentity.effects = EF_LOWPRECISION;
1725         }
1726 }
1727
1728 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1729 // added to the model skins
1730 /*void UpdateColorModHack()
1731 {
1732         local float c;
1733         c = self.clientcolors & 15;
1734         // LordHavoc: only bothering to support white, green, red, yellow, blue
1735              if (!teams_matter) self.colormod = '0 0 0';
1736         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1737         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1738         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1739         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1740         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1741         else self.colormod = '1 1 1';
1742 };*/
1743
1744 void respawn(void)
1745 {
1746         CopyBody(1);
1747         self.effects |= EF_NODRAW; // prevent another CopyBody
1748         PutClientInServer();
1749 }
1750
1751 void play_countdown(float finished, string samp)
1752 {
1753         if(clienttype(self) == CLIENTTYPE_REAL)
1754                 if(floor(finished - time - frametime) != floor(finished - time))
1755                         if(finished - time < 6)
1756                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1757 }
1758
1759 /**
1760  * When sv_timeout is used this function returs strings like
1761  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1762  * Called by centerprint functions
1763  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1764  */
1765 string getTimeoutText(float addOneSecond) {
1766         if (!cvar("sv_timeout") || !timeoutStatus)
1767                 return "";
1768
1769         local string retStr;
1770         if (timeoutStatus == 1) {
1771                 if (addOneSecond == 1) {
1772                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1773                 }
1774                 else {
1775                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1776                 }
1777                 return retStr;
1778         }
1779         else if (timeoutStatus == 2) {
1780                 if (addOneSecond) {
1781                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1782                         //don't show messages like "Timeout ends in 0 seconds"...
1783                         if ((remainingTimeoutTime + 1) > 0)
1784                                 return retStr;
1785                         else
1786                                 return "";
1787                 }
1788                 else {
1789                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1790                         //don't show messages like "Timeout ends in 0 seconds"...
1791                         if (remainingTimeoutTime > 0)
1792                                 return retStr;
1793                         else
1794                                 return "";
1795                 }
1796         }
1797         else return "";
1798 }
1799
1800 void player_powerups (void)
1801 {
1802         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1803         {
1804                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1805                 self.modelflags |= MF_ROCKET;
1806         }
1807         else
1808         {
1809                 SoundEntity_StopSound(self, CHAN_PLAYER);
1810                 self.modelflags &~= MF_ROCKET;
1811         }
1812
1813         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1814
1815         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1816                 return;
1817         
1818         Fire_ApplyDamage(self);
1819         Fire_ApplyEffect(self);
1820
1821         if (g_minstagib)
1822         {
1823                 self.effects |= EF_FULLBRIGHT;
1824
1825                 if (self.items & IT_STRENGTH)
1826                 {
1827                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1828                         if (time > self.strength_finished)
1829                         {
1830                                 self.alpha = default_player_alpha;
1831                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1832                                 self.items &~= IT_STRENGTH;
1833                                 sprint(self, "^3Invisibility has worn off\n");
1834                         }
1835                 }
1836                 else
1837                 {
1838                         if (time < self.strength_finished)
1839                         {
1840                                 self.alpha = g_minstagib_invis_alpha;
1841                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1842                                 self.items |= IT_STRENGTH;
1843                                 sprint(self, "^3You are invisible\n");
1844                         }
1845                 }
1846
1847                 if (self.items & IT_INVINCIBLE)
1848                 {
1849                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1850                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1851                         {
1852                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1853                                 sprint(self, "^3Speed has worn off\n");
1854                         }
1855                 }
1856                 else
1857                 {
1858                         if (time < self.invincible_finished)
1859                         {
1860                                 self.items = self.items | IT_INVINCIBLE;
1861                                 sprint(self, "^3You are on speed\n");
1862                         }
1863                 }
1864                 return;
1865         }
1866
1867         if (self.items & IT_STRENGTH)
1868         {
1869                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1870                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1871                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1872                 {
1873                         self.items = self.items - (self.items & IT_STRENGTH);
1874                         sprint(self, "^3Strength has worn off\n");
1875                 }
1876         }
1877         else
1878         {
1879                 if (time < self.strength_finished)
1880                 {
1881                         self.items = self.items | IT_STRENGTH;
1882                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1883                 }
1884         }
1885         if (self.items & IT_INVINCIBLE)
1886         {
1887                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1888                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1889                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1890                 {
1891                         self.items = self.items - (self.items & IT_INVINCIBLE);
1892                         sprint(self, "^3Shield has worn off\n");
1893                 }
1894         }
1895         else
1896         {
1897                 if (time < self.invincible_finished)
1898                 {
1899                         self.items = self.items | IT_INVINCIBLE;
1900                         sprint(self, "^3Shield surrounds you\n");
1901                 }
1902         }
1903
1904         if(cvar("g_nodepthtestplayers"))
1905                 self.effects = self.effects | EF_NODEPTHTEST;
1906
1907         if(cvar("g_fullbrightplayers"))
1908                 self.effects = self.effects | EF_FULLBRIGHT;
1909
1910         // midair gamemode: damage only while in the air
1911         // if in midair mode, being on ground grants temporary invulnerability
1912         // (this is so that multishot weapon don't clear the ground flag on the
1913         // first damage in the frame, leaving the player vulnerable to the
1914         // remaining hits in the same frame)
1915         if (self.flags & FL_ONGROUND)
1916         if (g_midair)
1917                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1918
1919         if (time >= game_starttime)
1920         if (time < self.spawnshieldtime)
1921                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1922 }
1923
1924 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1925 {
1926         if(current > stable)
1927                 return current;
1928         else if(current > stable - 0.25) // when close enough, "snap"
1929                 return stable;
1930         else
1931                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1932 }
1933
1934 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1935 {
1936         if(current < stable)
1937                 return current;
1938         else if(current < stable + 0.25) // when close enough, "snap"
1939                 return stable;
1940         else
1941                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1942 }
1943
1944 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1945 {
1946         if(current > rotstable)
1947         {
1948                 if(rotframetime > 0)
1949                 {
1950                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1951                         current = max(rotstable, current - rotlinear * rotframetime);
1952                 }
1953         }
1954         else if(current < regenstable)
1955         {
1956                 if(regenframetime > 0)
1957                 {
1958                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1959                         current = min(regenstable, current + regenlinear * regenframetime);
1960                 }
1961         }
1962
1963         if(current > limit)
1964                 current = limit;
1965
1966         return current;
1967 }
1968
1969 void player_regen (void)
1970 {
1971         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1972         maxh = cvar("g_balance_health_rotstable");
1973         maxa = cvar("g_balance_armor_rotstable");
1974         maxf = cvar("g_balance_fuel_rotstable");
1975         minh = cvar("g_balance_health_regenstable");
1976         mina = cvar("g_balance_armor_regenstable");
1977         minf = cvar("g_balance_fuel_regenstable");
1978         limith = cvar("g_balance_health_limit");
1979         limita = cvar("g_balance_armor_limit");
1980         limitf = cvar("g_balance_fuel_limit");
1981
1982         max_mod = regen_mod = rot_mod = limit_mod = 1;
1983
1984         if (self.runes & RUNE_REGEN)
1985         {
1986                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1987                 {
1988                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1989                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1990                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1991                 }
1992                 else
1993                 {
1994                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1995                         max_mod = cvar("g_balance_rune_regen_hpmod");
1996                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1997                 }
1998         }
1999         else if (self.runes & CURSE_VENOM)
2000         {
2001                 max_mod = cvar("g_balance_curse_venom_hpmod");
2002                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2003                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2004                 else
2005                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2006                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2007                 //if (!self.runes & RUNE_REGEN)
2008                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2009         }
2010         maxh = maxh * max_mod;
2011         //maxa = maxa * max_mod;
2012         //maxf = maxf * max_mod;
2013         minh = minh * max_mod;
2014         //mina = mina * max_mod;
2015         //minf = minf * max_mod;
2016         limith = limith * limit_mod;
2017         limita = limita * limit_mod;
2018         //limitf = limitf * limit_mod;
2019
2020         if(g_lms && g_ca)
2021                 rot_mod = 0;
2022
2023         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2024         {
2025                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2026                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2027
2028                 // if player rotted to death...  die!
2029                 if(self.health < 1)
2030                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2031         }
2032
2033         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2034                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2035 }
2036
2037 float zoomstate_set;
2038 void SetZoomState(float z)
2039 {
2040         if(z != self.zoomstate)
2041         {
2042                 self.zoomstate = z;
2043                 ClientData_Touch(self);
2044         }
2045         zoomstate_set = 1;
2046 }
2047
2048 void GetPressedKeys(void) {
2049         if (self.movement_x > 0) // get if movement keys are pressed
2050         {       // forward key pressed
2051                 self.pressedkeys |= KEY_FORWARD;
2052                 self.pressedkeys &~= KEY_BACKWARD;
2053         }
2054         else if (self.movement_x < 0)
2055         {       // backward key pressed
2056                 self.pressedkeys |= KEY_BACKWARD;
2057                 self.pressedkeys &~= KEY_FORWARD;
2058         }
2059         else
2060         {       // no x input
2061                 self.pressedkeys &~= KEY_FORWARD;
2062                 self.pressedkeys &~= KEY_BACKWARD;
2063         }
2064
2065         if (self.movement_y > 0)
2066         {       // right key pressed
2067                 self.pressedkeys |= KEY_RIGHT;
2068                 self.pressedkeys &~= KEY_LEFT;
2069         }
2070         else if (self.movement_y < 0)
2071         {       // left key pressed
2072                 self.pressedkeys |= KEY_LEFT;
2073                 self.pressedkeys &~= KEY_RIGHT;
2074         }
2075         else
2076         {       // no y input
2077                 self.pressedkeys &~= KEY_RIGHT;
2078                 self.pressedkeys &~= KEY_LEFT;
2079         }
2080
2081         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2082                 self.pressedkeys |= KEY_JUMP;
2083         else
2084                 self.pressedkeys &~= KEY_JUMP;
2085         if (self.BUTTON_CROUCH)
2086                 self.pressedkeys |= KEY_CROUCH;
2087         else
2088                 self.pressedkeys &~= KEY_CROUCH;
2089 }
2090
2091 void update_stats (float number, float hit, float fired) {
2092 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2093 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2094
2095         if(number) {
2096                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2097                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2098         } else {
2099                 self.stat_hit = hit * sv_accuracy_data_share;
2100                 self.stat_fired = fired * sv_accuracy_data_share;
2101         }
2102 }
2103
2104 /*
2105 ======================
2106 spectate mode routines
2107 ======================
2108 */
2109
2110 .float weapon_count;
2111 void SpectateCopy(entity spectatee) {
2112         if(spectatee.weapon_count < WEP_LAST) {
2113                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2114                 spectatee.weapon_count ++;
2115         } else
2116                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2117
2118         self.kh_state = spectatee.kh_state;
2119         self.armortype = spectatee.armortype;
2120         self.armorvalue = spectatee.armorvalue;
2121         self.ammo_cells = spectatee.ammo_cells;
2122         self.ammo_shells = spectatee.ammo_shells;
2123         self.ammo_nails = spectatee.ammo_nails;
2124         self.ammo_rockets = spectatee.ammo_rockets;
2125         self.ammo_fuel = spectatee.ammo_fuel;
2126         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2127         self.health = spectatee.health;
2128         self.impulse = 0;
2129         self.items = spectatee.items;
2130         self.metertime = spectatee.metertime;
2131         self.strength_finished = spectatee.strength_finished;
2132         self.invincible_finished = spectatee.invincible_finished;
2133         self.pressedkeys = spectatee.pressedkeys;
2134         self.weapons = spectatee.weapons;
2135         self.switchweapon = spectatee.switchweapon;
2136         self.weapon = spectatee.weapon;
2137         self.punchangle = spectatee.punchangle;
2138         self.view_ofs = spectatee.view_ofs;
2139         self.v_angle = spectatee.v_angle;
2140         self.velocity = spectatee.velocity;
2141         self.dmg_take = spectatee.dmg_take;
2142         self.dmg_save = spectatee.dmg_save;
2143         self.dmg_inflictor = spectatee.dmg_inflictor;
2144         self.angles = spectatee.v_angle;
2145         self.fixangle = TRUE;
2146         setorigin(self, spectatee.origin);
2147         setsize(self, spectatee.mins, spectatee.maxs);
2148         SetZoomState(spectatee.zoomstate);
2149
2150         anticheat_spectatecopy(spectatee);
2151 }
2152
2153 float SpectateUpdate() {
2154         if(!self.enemy)
2155                 return 0;
2156
2157         if (self == self.enemy)
2158                 return 0;
2159
2160         if(self.enemy.classname != "player")
2161                 return 0;
2162
2163         SpectateCopy(self.enemy);
2164
2165         return 1;
2166 }
2167
2168 float SpectateNext() {
2169         other = find(self.enemy, classname, "player");
2170
2171         if (!other)
2172                 other = find(other, classname, "player");
2173
2174         if (other)
2175                 self.enemy = other;
2176
2177         if(self.enemy.classname == "player") {
2178                 msg_entity = self;
2179                 WriteByte(MSG_ONE, SVC_SETVIEW);
2180                 WriteEntity(MSG_ONE, self.enemy);
2181                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2182                 self.movetype = MOVETYPE_NONE;
2183
2184                 self.enemy.weapon_count = 0;
2185
2186                 if(!SpectateUpdate())
2187                         PutObserverInServer();
2188
2189                 return 1;
2190         } else {
2191                 return 0;
2192         }
2193 }
2194
2195 /*
2196 =============
2197 ShowRespawnCountdown()
2198
2199 Update a respawn countdown display.
2200 =============
2201 */
2202 void ShowRespawnCountdown()
2203 {
2204         float number;
2205         if(self.deadflag == DEAD_NO) // just respawned?
2206                 return;
2207         else
2208         {
2209                 number = ceil(self.death_time - time);
2210                 if(number <= 0)
2211                         return;
2212                 if(number <= self.respawn_countdown)
2213                 {
2214                         self.respawn_countdown = number - 1;
2215                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2216                                 AnnounceTo(self, strcat(ftos(number), ""));
2217                 }
2218         }
2219 }
2220
2221 void LeaveSpectatorMode()
2222 {
2223         if(isJoinAllowed()) {
2224                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2225                         self.classname = "player";
2226
2227                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2228                                 JoinBestTeam(self, FALSE, TRUE);
2229
2230                         if(cvar("g_campaign"))
2231                                 campaign_bots_may_start = 1;
2232
2233                         self.stat_count = WEP_LAST;
2234
2235                         PutClientInServer();
2236
2237                         if(self.classname == "player")
2238                                 bprint ("^4", self.netname, "^4 is playing now\n");
2239
2240                         if(!cvar("g_campaign"))
2241                                 centerprint(self,""); // clear MOTD
2242
2243                         return;
2244                 } else {
2245                         if (g_ca && self.caplayer) {
2246                         }       // do nothing
2247                         else
2248                                 stuffcmd(self,"menu_showteamselect\n");
2249                         return;
2250                 }
2251         }
2252         else {
2253                 //player may not join because of g_maxplayers is set
2254                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2255         }
2256 }
2257
2258 /**
2259  * Determines whether the player is allowed to join. This depends on cvar
2260  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2261  * it checks whether the number of currently playing players exceeds g_maxplayers.
2262  * @return bool TRUE if the player is allowed to join, false otherwise
2263  */
2264 float isJoinAllowed() {
2265         if (!cvar("g_maxplayers"))
2266                 return TRUE;
2267
2268         local entity e;
2269         local float currentlyPlaying;
2270         FOR_EACH_REALPLAYER(e) {
2271                 if(e.classname == "player")
2272                         currentlyPlaying += 1;
2273         }
2274         if(currentlyPlaying < cvar("g_maxplayers"))
2275                 return TRUE;
2276
2277         return FALSE;
2278 }
2279
2280 /**
2281  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2282  * g_maxplayers_spectator_blocktime seconds
2283  */
2284 void checkSpectatorBlock() {
2285         if(self.classname == "spectator" || self.classname == "observer") {
2286                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2287                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2288                         dropclient(self);
2289                 }
2290         }
2291 }
2292
2293 float vercmp_recursive(string v1, string v2)
2294 {
2295         float dot1, dot2;
2296         string s1, s2;
2297         float r;
2298
2299         dot1 = strstrofs(v1, ".", 0);
2300         dot2 = strstrofs(v2, ".", 0);
2301         if(dot1 == -1)
2302                 s1 = v1;
2303         else
2304                 s1 = substring(v1, 0, dot1);
2305         if(dot2 == -1)
2306                 s2 = v2;
2307         else
2308                 s2 = substring(v2, 0, dot2);
2309
2310         r = stof(s1) - stof(s2);
2311         if(r != 0)
2312                 return r;
2313
2314         r = strcasecmp(s1, s2);
2315         if(r != 0)
2316                 return r;
2317
2318         if(dot1 == -1)
2319                 if(dot2 == -1)
2320                         return 0;
2321                 else
2322                         return -1;
2323         else
2324                 if(dot2 == -1)
2325                         return 1;
2326                 else
2327                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2328 }
2329
2330 float vercmp(string v1, string v2)
2331 {
2332         if(strcasecmp(v1, v2) == 0) // early out check
2333                 return 0;
2334         return vercmp_recursive(v1, v2);
2335 }
2336
2337 void ObserverThink()
2338 {
2339         if (self.flags & FL_JUMPRELEASED) {
2340                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2341                         self.welcomemessage_time = 0;
2342                         self.flags &~= FL_JUMPRELEASED;
2343                         self.flags |= FL_SPAWNING;
2344                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2345                         self.welcomemessage_time = 0;
2346                         self.flags &~= FL_JUMPRELEASED;
2347                         if(SpectateNext() == 1) {
2348                                 self.classname = "spectator";
2349                         }
2350                 }
2351         } else {
2352                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2353                         self.flags |= FL_JUMPRELEASED;
2354                         if(self.flags & FL_SPAWNING)
2355                         {
2356                                 self.flags &~= FL_SPAWNING;
2357                                 LeaveSpectatorMode();
2358                                 return;
2359                         }
2360                 }
2361         }
2362         PrintWelcomeMessage(self);
2363 }
2364
2365 void SpectatorThink()
2366 {
2367         if (self.flags & FL_JUMPRELEASED) {
2368                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2369                         self.welcomemessage_time = 0;
2370                         self.flags &~= FL_JUMPRELEASED;
2371                         self.flags |= FL_SPAWNING;
2372                 } else if(self.BUTTON_ATCK) {
2373                         self.welcomemessage_time = 0;
2374                         self.flags &~= FL_JUMPRELEASED;
2375                         if(SpectateNext() == 1) {
2376                                 self.classname = "spectator";
2377                         } else {
2378                                 self.classname = "observer";
2379                                 self.stat_count = WEP_LAST;
2380                                 PutClientInServer();
2381                         }
2382                 } else if (self.BUTTON_ATCK2) {
2383                         self.welcomemessage_time = 0;
2384                         self.flags &~= FL_JUMPRELEASED;
2385                         self.classname = "observer";
2386                         self.stat_count = WEP_LAST;
2387                         PutClientInServer();
2388                 } else {
2389                         if(!SpectateUpdate())
2390                                 PutObserverInServer();
2391                 }
2392         } else {
2393                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2394                         self.flags |= FL_JUMPRELEASED;
2395                         if(self.flags & FL_SPAWNING)
2396                         {
2397                                 self.flags &~= FL_SPAWNING;
2398                                 LeaveSpectatorMode();
2399                                 return;
2400                         }
2401                 }
2402         }
2403
2404         PrintWelcomeMessage(self);
2405         self.flags |= FL_CLIENT | FL_NOTARGET;
2406 }
2407
2408 .float touchexplode_time;
2409
2410 /*
2411 =============
2412 PlayerPreThink
2413
2414 Called every frame for each client before the physics are run
2415 =============
2416 */
2417 void() ctf_setstatus;
2418 void() nexball_setstatus;
2419 .float items_added;
2420 void PlayerPreThink (void)
2421 {
2422         self.stat_game_starttime = game_starttime;
2423         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2424         self.stat_leadlimit = cvar("leadlimit");
2425
2426         if(frametime)
2427         {
2428                 // physics frames: update anticheat stuff
2429                 anticheat_prethink();
2430         }
2431
2432         if(blockSpectators && frametime)
2433                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2434                 checkSpectatorBlock();
2435
2436         zoomstate_set = 0;
2437
2438         if(self.netname_previous != self.netname)
2439         {
2440                 if(cvar("sv_eventlog"))
2441                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2442                 if(self.netname_previous)
2443                         strunzone(self.netname_previous);
2444                 self.netname_previous = strzone(self.netname);
2445         }
2446
2447         // version nagging
2448         if(self.version_nagtime)
2449                 if(self.cvar_g_nexuizversion)
2450                         if(time > self.version_nagtime)
2451                         {
2452                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2453                                 {
2454                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2455                                         {
2456                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2457                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2458                                         }
2459                                         else
2460                                         {
2461                                                 float r;
2462                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2463                                                 if(r < 0)
2464                                                 {
2465                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.alientrap.org/nexuiz/^1!\n");
2466                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.alientrap.org/nexuiz/^1!\n"));
2467                                                 }
2468                                                 else if(r > 0)
2469                                                 {
2470                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2471                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2472                                                 }
2473                                         }
2474                                 }
2475                                 self.version_nagtime = 0;
2476                         }
2477
2478         // GOD MODE info
2479         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2480         {
2481                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2482                 self.max_armorvalue = 0;
2483         }
2484
2485 #ifdef TETRIS
2486         if (TetrisPreFrame())
2487                 return;
2488 #endif
2489
2490         if(self.classname == "player") {
2491 //              if(self.netname == "Wazat")
2492 //                      bprint(self.classname, "\n");
2493
2494                 CheckRules_Player();
2495
2496                 PrintWelcomeMessage(self);
2497
2498                 if (intermission_running)
2499                 {
2500                         IntermissionThink ();   // otherwise a button could be missed between
2501                         return;                                 // the think tics
2502                 }
2503
2504                 if(self.teleport_time)
2505                 if(time > self.teleport_time)
2506                 {
2507                         self.teleport_time = 0;
2508                         self.effects = self.effects - (self.effects & EF_NODRAW);
2509                 }
2510
2511                 Nixnex_GiveCurrentWeapon();
2512
2513                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2514                         UpdateSelectedPlayer();
2515
2516                 //don't allow the player to turn around while game is paused!
2517                 if(timeoutStatus == 2) {
2518                         self.v_angle = self.lastV_angle;
2519                         self.angles = self.lastV_angle;
2520                         self.fixangle = TRUE;
2521                 }
2522
2523                 if(frametime)
2524                 {
2525                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2526                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2527                         player_powerups();
2528                 }
2529
2530                 if (self.deadflag != DEAD_NO)
2531                 {
2532                         float button_pressed, force_respawn;
2533                         if(self.personal && g_race_qualifying)
2534                         {
2535                                 if(time > self.death_time)
2536                                 {
2537                                         self.death_time = time + 1; // only retry once a second
2538                                         respawn();
2539                                         self.impulse = 141;
2540                                 }
2541                         }
2542                         else
2543                         {
2544                                 if(frametime)
2545                                         player_anim();
2546                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2547                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2548                                 if (self.deadflag == DEAD_DYING)
2549                                 {
2550                                         if(force_respawn)
2551                                                 self.deadflag = DEAD_RESPAWNING;
2552                                         else if(!button_pressed)
2553                                                 self.deadflag = DEAD_DEAD;
2554                                 }
2555                                 else if (self.deadflag == DEAD_DEAD)
2556                                 {
2557                                         if(button_pressed)
2558                                                 self.deadflag = DEAD_RESPAWNABLE;
2559                                 }
2560                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2561                                 {
2562                                         if(!button_pressed)
2563                                                 self.deadflag = DEAD_RESPAWNING;
2564                                 }
2565                                 else if (self.deadflag == DEAD_RESPAWNING)
2566                                 {
2567                                         if(time > self.death_time)
2568                                         {
2569                                                 self.death_time = time + 1; // only retry once a second
2570                                                 respawn();
2571                                         }
2572                                 }
2573                                 ShowRespawnCountdown();
2574                         }
2575                         return;
2576                 }
2577
2578                 if(g_touchexplode)
2579                 if(time > self.touchexplode_time)
2580                 if(self.classname == "player")
2581                 if(self.deadflag == DEAD_NO)
2582                 if not(IS_INDEPENDENT_PLAYER(self))
2583                 FOR_EACH_PLAYER(other) if(self != other)
2584                 {
2585                         if(time > other.touchexplode_time)
2586                         if(other.classname == "player")
2587                         if(other.deadflag == DEAD_NO)
2588                         if not(IS_INDEPENDENT_PLAYER(other))
2589                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2590                         {
2591                                 PlayerTouchExplode(self, other);
2592                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2593                         }
2594                 }
2595
2596                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2597                 {
2598                         vector dist;
2599
2600                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2601                         dist = self.prevorigin - self.origin;
2602                         dist_z = 0;
2603                         self.lms_traveled_distance += fabs(vlen(dist));
2604
2605                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2606                         {
2607                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2608                                 self.lms_traveled_distance = 0;
2609                         }
2610
2611                         if(time > self.lms_nextcheck)
2612                         {
2613                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2614                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2615                                 {
2616                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2617                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2618                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2619                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2620                                 }
2621                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2622                                 self.lms_traveled_distance = 0;
2623                         }
2624                 }
2625
2626                 self.prevorigin = self.origin;
2627
2628                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2629                 {
2630                         if (!self.crouch)
2631                         {
2632                                 self.crouch = TRUE;
2633                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2634                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2635                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2636                         }
2637                 }
2638                 else
2639                 {
2640                         if (self.crouch)
2641                         {
2642                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2643                                 if (!trace_startsolid)
2644                                 {
2645                                         self.crouch = FALSE;
2646                                         self.view_ofs = PL_VIEW_OFS;
2647                                         setsize (self, PL_MIN, PL_MAX);
2648                                 }
2649                         }
2650                 }
2651
2652                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2653                 {
2654                         if(self.bloodloss_timer < time)
2655                         {
2656                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2657                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2658                         }
2659                 }
2660
2661                 FixPlayermodel();
2662
2663                 GrapplingHookFrame();
2664
2665                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2666                 //if(frametime)
2667                 {
2668                         self.items &~= self.items_added;
2669
2670                         W_WeaponFrame();
2671
2672                         self.items_added = 0;
2673                         if(self.items & IT_JETPACK)
2674                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2675                                         self.items_added |= IT_FUEL;
2676
2677                         self.items |= self.items_added;
2678                 }
2679
2680                 player_regen();
2681                 if(frametime)
2682                         player_anim();
2683
2684                 if (g_minstagib)
2685                         minstagib_ammocheck();
2686
2687                 ctf_setstatus();
2688                 nexball_setstatus();
2689
2690                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2691
2692                 //self.angles_y=self.v_angle_y + 90;   // temp
2693         } else if(gameover) {
2694                 if (intermission_running)
2695                         IntermissionThink ();   // otherwise a button could be missed between
2696                 return;
2697         } else if(self.classname == "observer") {
2698                 ObserverThink();
2699         } else if(self.classname == "spectator") {
2700                 SpectatorThink();
2701         }
2702
2703         if(!zoomstate_set)
2704                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2705
2706         float oldspectatee_status;
2707         oldspectatee_status = self.spectatee_status;
2708         if(self.classname == "spectator")
2709                 self.spectatee_status = num_for_edict(self.enemy);
2710         else if(self.classname == "observer")
2711                 self.spectatee_status = num_for_edict(self);
2712         else
2713                 self.spectatee_status = 0;
2714         if(self.spectatee_status != oldspectatee_status)
2715         {
2716                 ClientData_Touch(self);
2717                 if(g_race || g_cts)
2718                         race_InitSpectator();
2719         }
2720
2721         if(self.teamkill_soundtime)
2722         if(time > self.teamkill_soundtime)
2723         {
2724                 self.teamkill_soundtime = 0;
2725
2726                 entity oldpusher, oldself;
2727
2728                 oldself = self; self = self.teamkill_soundsource;
2729                 oldpusher = self.pusher; self.pusher = oldself;
2730
2731                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2732
2733                 self.pusher = oldpusher;
2734                 self = oldself;
2735         }
2736
2737         if(self.taunt_soundtime)
2738         if(time > self.taunt_soundtime)
2739         {
2740                 self.taunt_soundtime = 0;
2741                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2742         }
2743
2744         target_voicescript_next(self);
2745 }
2746
2747 float isInvisibleString(string s)
2748 {
2749         float i, n, c;
2750         s = strdecolorize(s);
2751         for((i = 0), (n = strlen(s)); i < n; ++i)
2752         {
2753                 c = str2chr(s, i);
2754                 switch(c)
2755                 {
2756                         case 0:
2757                         case 32:
2758                         case 160:
2759                                 break;
2760                         default:
2761                                 return FALSE;
2762                 }
2763         }
2764         return TRUE;
2765 }
2766
2767 /*
2768 =============
2769 PlayerPostThink
2770
2771 Called every frame for each client after the physics are run
2772 =============
2773 */
2774 .float idlekick_lasttimeleft;
2775 void PlayerPostThink (void)
2776 {
2777         // Savage: Check for nameless players
2778         if (isInvisibleString(self.netname)) {
2779                 self.netname = "Player";
2780                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2781         }
2782
2783         // send the clients accuracy stats to the client
2784         if(self.stat_count > 0)
2785         if(frametime)
2786         {
2787                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2788                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2789                 self.stat_count -= 1;
2790         }
2791
2792 #ifdef UID
2793         if(self.uid_kicktime)
2794         if(time > self.uid_kicktime)
2795         {
2796                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2797                 dropclient(self);
2798                 return;
2799         }
2800 #endif
2801
2802         if(sv_maxidle && frametime)
2803         {
2804                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2805                 float timeleft;
2806                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2807                 if(timeleft <= 0)
2808                 {
2809                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2810                         AnnounceTo(self, "terminated");
2811                         dropclient(self);
2812                         return;
2813                 }
2814                 else if(timeleft <= 10)
2815                 {
2816                         if(timeleft != self.idlekick_lasttimeleft)
2817                         {
2818                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2819                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2820                         }
2821                 }
2822                 else
2823                 {
2824                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2825                 }
2826                 self.idlekick_lasttimeleft = timeleft;
2827         }
2828
2829 #ifdef TETRIS
2830         if(self.impulse == 100)
2831                 ImpulseCommands();
2832         if (TetrisPostFrame())
2833                 return;
2834 #endif
2835
2836         CheatFrame();
2837
2838         if(self.classname == "player") {
2839                 CheckRules_Player();
2840                 UpdateChatBubble();
2841                 UpdateTeamBubble();
2842                 if (self.impulse)
2843                         ImpulseCommands();
2844                 if (intermission_running)
2845                         return;         // intermission or finale
2846
2847                 GetPressedKeys();
2848         } else if (self.classname == "observer") {
2849                 //do nothing
2850         } else if (self.classname == "spectator") {
2851                 //do nothing
2852         }
2853
2854         /*
2855         float i;
2856         for(i = 0; i < 1000; ++i)
2857         {
2858                 vector end;
2859                 end = self.origin + '0 0 1024' + 512 * randomvec();
2860                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2861                 if(trace_fraction < 1)
2862                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2863                 {
2864                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2865                         break;
2866                 }
2867         }
2868         */
2869
2870         Arena_Warmup();
2871
2872         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2873
2874         if(self.waypointsprite_attachedforcarrier)
2875                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2876         
2877         playerdemo_write();
2878
2879         /*
2880         if(g_race)
2881                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2882         */
2883 }