data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         if(g_arena)
 448         {
 449                 if(self.version_mismatch)
 450                 {
 451                         Spawnqueue_Unmark(self);
 452                         Spawnqueue_Remove(self);
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Insert(self);
 457                 }
 458         }
 459         else if(g_lms)
 460         {
 461                 // Only if the player cannot play at all
 462                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 463                         self.frags = -666;
 464                 else
 465                         self.frags = -667;
 466         }
 467         else
 468                 self.frags = -666;
 469 }
 470
 471 float RestrictSkin(float s)
 472 {
 473         if(!teams_matter)
 474                 return s;
 475         if(s == 6)
 476                 return 6;
 477         return mod(s, 3);
 478 }
 479
 480 void FixPlayermodel()
 481 {
 482         local string defaultmodel;
 483         local float defaultskin;
 484         local vector m1, m2;
 485
 486         defaultmodel = "";
 487
 488         if(cvar("sv_defaultcharacter") == 1) {
 489                 defaultskin = 0;
 490
 491                 if(teams_matter)
 492                 {
 493                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 494                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 495                 }
 496
 497                 if(defaultmodel == "")
 498                 {
 499                         defaultmodel = cvar_string("sv_defaultplayermodel");
 500                         defaultskin = cvar("sv_defaultplayerskin");
 501                 }
 502         }
 503
 504         if(defaultmodel != "")
 505         {
 506                 if (defaultmodel != self.model)
 507                 {
 508                         m1 = self.mins;
 509                         m2 = self.maxs;
 510                         setmodel_lod (self, defaultmodel);
 511                         setsize (self, m1, m2);
 512                 }
 513
 514                 self.skin = defaultskin;
 515         } else {
 516                 if (self.playermodel != self.model)
 517                 {
 518                         self.playermodel = CheckPlayerModel(self.playermodel);
 519                         m1 = self.mins;
 520                         m2 = self.maxs;
 521                         setmodel_lod (self, self.playermodel);
 522                         setsize (self, m1, m2);
 523                 }
 524
 525                 self.skin = RestrictSkin(stof(self.playerskin));
 526         }
 527
 528         if(!teams_matter)
 529                 if(strlen(cvar_string("sv_defaultplayercolors")))
 530                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 531                                 setcolor(self, cvar("sv_defaultplayercolors"));
 532 }
 533
 534 /*
 535 =============
 536 PutClientInServer
 537
 538 Called when a client spawns in the server
 539 =============
 540 */
 541 //void() ctf_playerchanged;
 542 void PutClientInServer (void)
 543 {
 544         if(clienttype(self) == CLIENTTYPE_BOT)
 545         {
 546                 self.classname = "player";
 547         }
 548         else if(clienttype(self) == CLIENTTYPE_REAL)
 549         {
 550                 msg_entity = self;
 551                 WriteByte(MSG_ONE, SVC_SETVIEW);
 552                 WriteEntity(MSG_ONE, self);
 553         }
 554
 555         // player is dead and becomes observer
 556         // FIXME fix LMS scoring for new system
 557         if(g_lms)
 558         {
 559                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 560                         self.classname = "observer";
 561         }
 562
 563         if(g_arena)
 564         if(!self.spawned)
 565                 self.classname = "observer";
 566
 567         if(self.classname == "player") {
 568                 entity  spot;
 569
 570                 spot = SelectSpawnPoint (FALSE);
 571                 if(!spot)
 572                 {
 573                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 574                         return; // spawn failed
 575                 }
 576
 577                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 578
 579                 self.classname = "player";
 580                 self.iscreature = TRUE;
 581                 self.movetype = MOVETYPE_WALK;
 582                 self.solid = SOLID_SLIDEBOX;
 583                 self.flags = FL_CLIENT;
 584                 self.takedamage = DAMAGE_AIM;
 585                 if(g_minstagib)
 586                         self.effects = EF_FULLBRIGHT;
 587                 else
 588                         self.effects = 0;
 589                 self.air_finished = time + 12;
 590                 self.dmg = 2;
 591
 592                 self.ammo_shells = start_ammo_shells;
 593                 self.ammo_nails = start_ammo_nails;
 594                 self.ammo_rockets = start_ammo_rockets;
 595                 self.ammo_cells = start_ammo_cells;
 596                 self.health = start_health;
 597                 self.armorvalue = start_armorvalue;
 598                 self.items = start_items;
 599                 self.switchweapon = start_switchweapon;
 600                 self.cnt = start_switchweapon;
 601                 self.weapon = 0;
 602                 self.jump_interval = time;
 603
 604                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 605                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 606                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 607                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 608                 //extend the pause of rotting if client was reset at the beginning of the countdown
 609                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 610                         self.spawnshieldtime += RESTART_COUNTDOWN;
 611                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 612                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 613                         self.pauseregen_finished += RESTART_COUNTDOWN;
 614                 }
 615                 self.damageforcescale = 2;
 616                 self.death_time = 0;
 617                 self.dead_frame = 0;
 618                 self.alpha = 0;
 619                 self.scale = 0;
 620                 self.fade_time = 0;
 621                 self.pain_frame = 0;
 622                 self.pain_finished = 0;
 623                 self.strength_finished = 0;
 624                 self.invincible_finished = 0;
 625                 self.pushltime = 0;
 626                 //self.speed_finished = 0;
 627                 //self.slowmo_finished = 0;
 628                 // players have no think function
 629                 self.think = SUB_Null;
 630                 self.nextthink = 0;
 631                 self.hook_time = 0;
 632
 633                 self.runes = 0;
 634
 635                 self.deadflag = DEAD_NO;
 636
 637                 self.angles = spot.angles;
 638
 639                 self.angles_z = 0; // never spawn tilted even if the spot says to
 640                 self.fixangle = TRUE; // turn this way immediately
 641                 self.velocity = '0 0 0';
 642                 self.avelocity = '0 0 0';
 643                 self.punchangle = '0 0 0';
 644                 self.punchvector = '0 0 0';
 645                 self.oldvelocity = self.velocity;
 646
 647                 self.viewzoom = 0.6;
 648                 self.has_zoomed = 0;
 649
 650                 self.customizeentityforclient = Client_customizeentityforclient;
 651
 652                 self.model = "";
 653                 FixPlayermodel();
 654
 655                 self.crouch = FALSE;
 656                 self.view_ofs = PL_VIEW_OFS;
 657                 setsize (self, PL_MIN, PL_MAX);
 658                 self.spawnorigin = spot.origin;
 659                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 660                 // don't reset back to last position, even if new position is stuck in solid
 661                 self.oldorigin = self.origin;
 662
 663                 if(g_arena)
 664                 {
 665                         Spawnqueue_Remove(self);
 666                         Spawnqueue_Mark(self);
 667                 }
 668
 669                 self.event_damage = PlayerDamage;
 670
 671                 self.bot_attack = TRUE;
 672
 673                 self.statdraintime = time + 5;
 674                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 675
 676                 if(self.killcount == -666) {
 677                         PlayerScore_Clear(self);
 678                         self.killcount = 0;
 679                         self.frags = 0;
 680                 }
 681
 682                 self.cnt = WEP_LASER;
 683                 self.nixnex_lastchange_id = -1;
 684
 685                 CL_SpawnWeaponentity();
 686                 self.alpha = default_player_alpha;
 687                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 688                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 689
 690                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 691                 self.lms_traveled_distance = 0;
 692                 self.speedrunning = FALSE;
 693
 694                 race_PreparePlayer();
 695
 696                 if(cvar("spawn_debug"))
 697                 {
 698                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 699                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 700                 }
 701
 702                 //stuffcmd(self, "chase_active 0");
 703                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 704
 705                 if (cvar("g_spawnsound"))
 706                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 707
 708                 if(g_assault) {
 709                         if(self.team == assault_attacker_team)
 710                                 centerprint(self, "You are attacking!\n");
 711                         else
 712                                 centerprint(self, "You are defending!\n");
 713                 }
 714
 715         } else if(self.classname == "observer") {
 716                 PutObserverInServer ();
 717         }
 718
 719         //if(g_ctf)
 720         //      ctf_playerchanged();
 721 }
 722
 723 /*
 724 =============
 725 SendCSQCInfo
 726
 727 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 728 =============
 729 */
 730 void SendCSQCInfo(void)
 731 {
 732         if(clienttype(self) != CLIENTTYPE_REAL)
 733                 return;
 734         msg_entity = self;
 735         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 736         WriteByte(MSG_ONE, TE_CSQC_INIT);
 737         WriteShort(MSG_ONE, CSQC_REVISION);
 738         WriteByte(MSG_ONE, maxclients);
 739 }
 740
 741 /*
 742 =============
 743 SetNewParms
 744 =============
 745 */
 746 void SetNewParms (void)
 747 {
 748         // initialize parms for a new player
 749         parm1 = -(86400 * 366);
 750 }
 751
 752 /*
 753 =============
 754 SetChangeParms
 755 =============
 756 */
 757 void SetChangeParms (void)
 758 {
 759         // save parms for level change
 760         parm1 = self.parm_idlesince - time;
 761 }
 762
 763 /*
 764 =============
 765 DecodeLevelParms
 766 =============
 767 */
 768 void DecodeLevelParms (void)
 769 {
 770         // load parms
 771         self.parm_idlesince = parm1;
 772         if(self.parm_idlesince == -(86400 * 366))
 773                 self.parm_idlesince = time;
 774 }
 775
 776 /*
 777 =============
 778 ClientKill
 779
 780 Called when a client types 'kill' in the console
 781 =============
 782 */
 783
 784 void ClientKill_Now_TeamChange()
 785 {
 786         if(self.killindicator_teamchange == -1)
 787         {
 788                 self.team = -1;
 789                 JoinBestTeam( self, FALSE, FALSE );
 790         }
 791         else
 792         {
 793                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 794         }
 795 }
 796
 797 void ClientKill_Now()
 798 {
 799         if(self.killindicator_teamchange)
 800                 ClientKill_Now_TeamChange();
 801
 802         // in any case:
 803         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 804
 805         if(self.killindicator)
 806         {
 807                 dprint("Cleaned up after a leaked kill indicator.\n");
 808                 remove(self.killindicator);
 809                 self.killindicator = world;
 810         }
 811 }
 812 void KillIndicator_Think()
 813 {
 814         if (!self.owner.modelindex)
 815         {
 816                 self.owner.killindicator = world;
 817                 remove(self);
 818                 return;
 819         }
 820
 821         if(self.cnt <= 0)
 822         {
 823                 self = self.owner;
 824                 ClientKill_Now(); // no oldself needed
 825                 return;
 826         }
 827         else
 828         {
 829                 if(self.cnt <= 10)
 830                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 831                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 832                 {
 833                         if(self.cnt <= 10)
 834                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 835                         if(self.owner.killindicator_teamchange)
 836                         {
 837                                 if(self.owner.killindicator_teamchange == -1)
 838                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 839                                 else
 840                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 841                         }
 842                         else
 843                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 844                 }
 845                 self.nextthink = time + 1;
 846                 self.cnt -= 1;
 847         }
 848 }
 849
 850 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 851 {
 852         float killtime;
 853         entity e;
 854         killtime = cvar("g_balance_kill_delay");
 855
 856         self.killindicator_teamchange = targetteam;
 857
 858         if(!self.killindicator)
 859         {
 860                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 861                 {
 862                         ClientKill_Now();
 863                 }
 864                 else
 865                 {
 866                         self.killindicator = spawn();
 867                         self.killindicator.owner = self;
 868                         self.killindicator.scale = 0.5;
 869                         setattachment(self.killindicator, self, "");
 870                         setorigin(self.killindicator, '0 0 52');
 871                         self.killindicator.think = KillIndicator_Think;
 872                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 873                         self.killindicator.cnt = ceil(killtime);
 874                         self.killindicator.count = bound(0, ceil(killtime), 10);
 875                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 876
 877                         for(e = world; (e = find(e, classname, "body")) != world; )
 878                         {
 879                                 if(e.enemy != self)
 880                                         continue;
 881                                 e.killindicator = spawn();
 882                                 e.killindicator.owner = e;
 883                                 e.killindicator.scale = 0.5;
 884                                 setattachment(e.killindicator, e, "");
 885                                 setorigin(e.killindicator, '0 0 52');
 886                                 e.killindicator.think = KillIndicator_Think;
 887                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 888                                 e.killindicator.cnt = ceil(killtime);
 889                         }
 890                         self.lip = 0;
 891                 }
 892         }
 893         if(self.killindicator)
 894         {
 895                 if(targetteam)
 896                         self.killindicator.colormod = TeamColor(targetteam);
 897                 else
 898                         self.killindicator.colormod = '0 0 0';
 899         }
 900 }
 901
 902 void ClientKill (void)
 903 {
 904         ClientKill_TeamChange(0);
 905 }
 906
 907 void DoTeamChange(float destteam)
 908 {
 909         float t, c0;
 910         if(!cvar("teamplay"))
 911         {
 912                 if(destteam >= 0)
 913                         SetPlayerColors(self, destteam);
 914                 return;
 915         }
 916         if(self.classname == "player")
 917         if(destteam == -1)
 918         {
 919                 CheckAllowedTeams(self);
 920                 t = FindSmallestTeam(self, TRUE);
 921                 switch(self.team)
 922                 {
 923                         case COLOR_TEAM1: c0 = c1; break;
 924                         case COLOR_TEAM2: c0 = c2; break;
 925                         case COLOR_TEAM3: c0 = c3; break;
 926                         case COLOR_TEAM4: c0 = c4; break;
 927                         default:          c0 = 999;
 928                 }
 929                 switch(t)
 930                 {
 931                         case 1:
 932                                 if(c0 > c1)
 933                                         destteam = COLOR_TEAM1;
 934                                 break;
 935                         case 2:
 936                                 if(c0 > c2)
 937                                         destteam = COLOR_TEAM2;
 938                                 break;
 939                         case 3:
 940                                 if(c0 > c3)
 941                                         destteam = COLOR_TEAM3;
 942                                 break;
 943                         case 4:
 944                                 if(c0 > c4)
 945                                         destteam = COLOR_TEAM4;
 946                                 break;
 947                 }
 948                 if(destteam == -1)
 949                         return;
 950         }
 951         if(destteam == self.team && !self.killindicator)
 952                 return;
 953         ClientKill_TeamChange(destteam);
 954 }
 955
 956 void FixClientCvars(entity e)
 957 {
 958         // send prediction settings to the client
 959         stuffcmd(e, "\nin_bindmap 0 0\n");
 960         /*
 961          * we no longer need to stuff this. Remove this comment block if you feel
 962          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 963         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 964         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 970         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 975         stuffcmd(e, "cl_movement_edgefriction 1\n");
 976          */
 977 }
 978
 979 /*
 980 =============
 981 ClientConnect
 982
 983 Called when a client connects to the server
 984 =============
 985 */
 986 //void ctf_clientconnect();
 987 string ColoredTeamName(float t);
 988 void DecodeLevelParms (void);
 989 //void dom_player_join_team(entity pl);
 990 void ClientConnect (void)
 991 {
 992         local string s;
 993         float wep;
 994
 995         if(self.flags & FL_CLIENT)
 996         {
 997                 print("Warning: ClientConnect, but already connected!\n");
 998                 return;
 999         }
1000
1001         if(Ban_IsClientBanned(self))
1002         {
1003                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1004                 dropclient(self);
1005                 bprint(s);
1006                 return;
1007         }
1008
1009         DecodeLevelParms();
1010
1011         self.classname = "player_joining";
1012
1013         self.flags = self.flags | FL_CLIENT;
1014         self.version_nagtime = time + 10 + random() * 10;
1015
1016         if(player_count<0)
1017         {
1018                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1019                 player_count = 0;
1020         }
1021
1022         PlayerScore_Attach(self);
1023
1024         bot_clientconnect();
1025
1026         //if(g_domination)
1027         //      dom_player_join_team(self);
1028
1029         //JoinBestTeam(self, FALSE, FALSE);
1030
1031         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1032                 self.classname = "observer";
1033         } else {
1034                 self.classname = "player";
1035                 campaign_bots_may_start = 1;
1036         }
1037
1038         self.playerid = (playerid_last = playerid_last + 1);
1039         if(cvar("sv_eventlog"))
1040         {
1041                 if(clienttype(self) == CLIENTTYPE_REAL)
1042                         s = "player";
1043                 else
1044                         s = "bot";
1045                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1046                 s = strcat(":team:", ftos(self.playerid), ":");
1047                 s = strcat(s, ftos(self.team));
1048                 GameLogEcho(s, FALSE);
1049         }
1050         self.netname_previous = strzone(self.netname);
1051
1052         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1053
1054         bprint ("^4",self.netname);
1055         bprint ("^4 connected");
1056
1057         if(g_domination || g_ctf)
1058         {
1059                 bprint(" and joined the ");
1060                 bprint(ColoredTeamName(self.team));
1061         }
1062
1063         bprint("\n");
1064
1065         self.welcomemessage_time = 0;
1066
1067         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1068         // TODO: is this being used for anything else than cd tracks?
1069         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1070         //
1071         stuffcmd(self, "cl_particles_reloadeffects\n");
1072
1073         FixClientCvars(self);
1074
1075         // spawnfunc_waypoint sprites
1076         WaypointSprite_InitClient(self);
1077
1078         // Wazat's grappling hook
1079         SetGrappleHookBindings();
1080
1081         // get autoswitch state from player when he toggles it
1082         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1083
1084         // get version info from player
1085         stuffcmd(self, "cmd clientversion $gameversion\n");
1086
1087         // send all weapon info strings
1088         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1089         wep = WEP_FIRST;
1090         while (wep <= WEP_LAST)
1091         {
1092                 weapon_action(wep, WR_REGISTER);
1093                 wep = wep + 1;
1094         }
1095
1096         // get other cvars from player
1097         GetCvars(0);
1098
1099         // set cvar for team scoreboard
1100         if (teams_matter)
1101         {
1102                 local float t;
1103                 t = cvar("teamplay");
1104                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1105                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1106         }
1107         else
1108                 stuffcmd(self, "set teamplay 0\n");
1109
1110         // notify about available teams
1111         if(teamplay)
1112         {
1113                 CheckAllowedTeams(self);
1114                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1115                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1116         }
1117         else
1118                 stuffcmd(self, "set _teams_available 0\n");
1119
1120         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1121
1122         if(g_arena)
1123         {
1124                 self.classname = "observer";
1125                 Spawnqueue_Insert(self);
1126         }
1127         /*else if(g_ctf)
1128         {
1129                 ctf_clientconnect();
1130         }*/
1131
1132         if(entcs_start)
1133                 attach_entcs();
1134
1135         bot_relinkplayerlist();
1136
1137         self.spectatortime = time;
1138         if(blockSpectators)
1139         {
1140                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1141         }
1142
1143         self.jointime = time;
1144         self.allowedTimeouts = cvar("sv_timeout_number");
1145
1146         if(clienttype(self) == CLIENTTYPE_REAL)
1147         {
1148                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1149                 SendCSQCInfo();
1150                 msg_entity = self;
1151                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1152                 {
1153                         MapVote_SendData(MSG_ONE);
1154                         MapVote_UpdateData(MSG_ONE);
1155                 }
1156                 ScoreInfo_Write(MSG_ONE);
1157         }
1158
1159         if(g_lms)
1160         {
1161                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1162                 {
1163                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1164                         self.frags = -666; // FIXME do we still need this?
1165                 }
1166         }
1167 }
1168
1169 /*
1170 =============
1171 ClientDisconnect
1172
1173 Called when a client disconnects from the server
1174 =============
1175 */
1176 void(entity e) DropFlag;
1177 .entity chatbubbleentity;
1178 .entity teambubbleentity;
1179 //void() ctf_clientdisconnect;
1180 void ClientDisconnect (void)
1181 {
1182         float save;
1183
1184         if not(self.flags & FL_CLIENT)
1185         {
1186                 print("Warning: ClientDisconnect without ClientConnect\n");
1187                 return;
1188         }
1189
1190         bot_clientdisconnect();
1191
1192         if(entcs_start)
1193                 detach_entcs();
1194
1195         if(cvar("sv_eventlog"))
1196                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1197         bprint ("^4",self.netname);
1198         bprint ("^4 disconnected\n");
1199
1200         if (self.chatbubbleentity)
1201         {
1202                 remove (self.chatbubbleentity);
1203                 self.chatbubbleentity = world;
1204         }
1205
1206         if (self.teambubbleentity)
1207         {
1208                 remove (self.teambubbleentity);
1209                 self.teambubbleentity = world;
1210         }
1211
1212         if (self.killindicator)
1213         {
1214                 remove (self.killindicator);
1215                 self.killindicator = world;
1216         }
1217
1218         WaypointSprite_PlayerGone();
1219
1220         DropAllRunes(self);
1221         kh_Key_DropAll(self, TRUE);
1222
1223         if(self.flagcarried)
1224                 DropFlag(self.flagcarried);
1225
1226         save = self.flags;
1227         self.flags = self.flags - (self.flags & FL_CLIENT);
1228         bot_relinkplayerlist();
1229         self.flags = save;
1230
1231         // remove laserdot
1232         if(self.weaponentity)
1233                 if(self.weaponentity.lasertarget)
1234                         remove(self.weaponentity.lasertarget);
1235
1236         if(g_arena)
1237         {
1238                 Spawnqueue_Unmark(self);
1239                 Spawnqueue_Remove(self);
1240         }
1241         /*if(g_ctf)
1242         {
1243                 ctf_clientdisconnect();
1244         }
1245         */
1246
1247         PlayerScore_Detach(self);
1248
1249         if(self.netname_previous)
1250                 strunzone(self.netname_previous);
1251
1252         ClearPlayerSounds();
1253
1254         // free cvars
1255         GetCvars(-1);
1256         self.playerid = 0;
1257 }
1258
1259 .float BUTTON_CHAT;
1260 void ChatBubbleThink()
1261 {
1262         self.nextthink = time;
1263         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1264         {
1265                 self.owner.chatbubbleentity = world;
1266                 remove(self);
1267                 return;
1268         }
1269         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1270         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1271                 self.model = self.mdl;
1272         else
1273                 self.model = "";
1274 };
1275
1276 void UpdateChatBubble()
1277 {
1278         if (!self.modelindex)
1279                 return;
1280         // spawn a chatbubble entity if needed
1281         if (!self.chatbubbleentity)
1282         {
1283                 self.chatbubbleentity = spawn();
1284                 self.chatbubbleentity.owner = self;
1285                 self.chatbubbleentity.exteriormodeltoclient = self;
1286                 self.chatbubbleentity.think = ChatBubbleThink;
1287                 self.chatbubbleentity.nextthink = time;
1288                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1289                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1290                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1291                 self.chatbubbleentity.model = "";
1292                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1293         }
1294 }
1295
1296
1297 void TeamBubbleThink()
1298 {
1299         self.nextthink = time;
1300         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1301         {
1302                 self.owner.teambubbleentity = world;
1303                 remove(self);
1304                 return;
1305         }
1306 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1307         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1308                 self.model = "";
1309         else
1310                 self.model = self.mdl;
1311
1312 };
1313
1314 float TeamBubble_customizeentityforclient()
1315 {
1316         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1317 }
1318
1319 void UpdateTeamBubble()
1320 {
1321         if (!self.modelindex || !cvar("teamplay"))
1322                 return;
1323         // spawn a teambubble entity if needed
1324         if (!self.teambubbleentity && cvar("teamplay"))
1325         {
1326                 self.teambubbleentity = spawn();
1327                 self.teambubbleentity.owner = self;
1328                 self.teambubbleentity.exteriormodeltoclient = self;
1329                 self.teambubbleentity.think = TeamBubbleThink;
1330                 self.teambubbleentity.nextthink = time;
1331                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1332 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1333                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1334                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1335                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1336                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1337                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1338                 self.teambubbleentity.effects = EF_LOWPRECISION;
1339         }
1340 }
1341
1342 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1343 // added to the model skins
1344 /*void UpdateColorModHack()
1345 {
1346         local float c;
1347         c = self.clientcolors & 15;
1348         // LordHavoc: only bothering to support white, green, red, yellow, blue
1349              if (teamplay == 0) self.colormod = '0 0 0';
1350         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1351         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1352         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1353         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1354         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1355         else self.colormod = '1 1 1';
1356 };*/
1357
1358 void respawn(void)
1359 {
1360         CopyBody(1);
1361         self.effects |= EF_NODRAW; // prevent another CopyBody
1362         PutClientInServer();
1363 }
1364
1365 /**
1366  * When sv_timeout is used this function returs strings like
1367  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1368  * Called by centerprint functions
1369  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1370  */
1371 string getTimeoutText(float addOneSecond) {
1372         if (!cvar("sv_timeout") || !timeoutStatus)
1373                 return "";
1374
1375         local string retStr;
1376         if (timeoutStatus == 1) {
1377                 if (addOneSecond == 1) {
1378                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1379                 }
1380                 else {
1381                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1382                 }
1383                 return retStr;
1384         }
1385         else if (timeoutStatus == 2) {
1386                 if (addOneSecond) {
1387                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1388                         //don't show messages like "Timeout ends in 0 seconds"...
1389                         if ((remainingTimeoutTime + 1) > 0)
1390                                 return retStr;
1391                         else
1392                                 return "";
1393                 }
1394                 else {
1395                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1396                         //don't show messages like "Timeout ends in 0 seconds"...
1397                         if (remainingTimeoutTime > 0)
1398                                 return retStr;
1399                         else
1400                                 return "";
1401                 }
1402         }
1403         else return "";
1404 }
1405
1406 void player_powerups (void)
1407 {
1408         if (g_minstagib)
1409         {
1410                 if (self.items & IT_STRENGTH)
1411                 {
1412                         if (time > self.strength_finished)
1413                         {
1414                                 if (g_minstagib_invis_alpha > 0)
1415                                 {
1416                                         self.alpha = default_player_alpha;
1417                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1418                                         self.effects = self.effects | EF_FULLBRIGHT;
1419                                 }
1420                                 else
1421                                 {
1422                                         self.effects -= self.effects & EF_NODRAW;
1423                                 }
1424                                 self.items = self.items - (self.items & IT_STRENGTH);
1425                                 sprint(self, "^3Invisibility has worn off\n");
1426                         }
1427                 }
1428                 else
1429                 {
1430                         if (time < self.strength_finished)
1431                         {
1432                                 if (g_minstagib_invis_alpha > 0)
1433                                 {
1434                                         self.alpha = g_minstagib_invis_alpha;
1435                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1436                                         self.effects -= self.effects & EF_FULLBRIGHT;
1437                                 }
1438                                 else
1439                                 {
1440                                         self.effects = self.effects | EF_NODRAW;
1441                                 }
1442                                 self.items = self.items | IT_STRENGTH;
1443                                 sprint(self, "^3You are invisible\n");
1444                         }
1445                 }
1446
1447                 if (self.items & IT_INVINCIBLE)
1448                 {
1449                         if (time > self.invincible_finished)
1450                         {
1451                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1452                                 sprint(self, "^3Speed has worn off\n");
1453                         }
1454                 }
1455                 else
1456                 {
1457                         if (time < self.invincible_finished)
1458                         {
1459                                 self.items = self.items | IT_INVINCIBLE;
1460                                 sprint(self, "^3You are on speed\n");
1461                         }
1462                 }
1463                 return;
1464         }
1465
1466         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1467         if (self.items & IT_STRENGTH)
1468         {
1469                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1470                 if (time > self.strength_finished)
1471                 {
1472                         self.items = self.items - (self.items & IT_STRENGTH);
1473                         sprint(self, "^3Strength has worn off\n");
1474                 }
1475         }
1476         else
1477         {
1478                 if (time < self.strength_finished)
1479                 {
1480                         self.items = self.items | IT_STRENGTH;
1481                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1482                 }
1483         }
1484         if (self.items & IT_INVINCIBLE)
1485         {
1486                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1487                 if (time > self.invincible_finished)
1488                 {
1489                         self.items = self.items - (self.items & IT_INVINCIBLE);
1490                         sprint(self, "^3Shield has worn off\n");
1491                 }
1492         }
1493         else
1494         {
1495                 if (time < self.invincible_finished)
1496                 {
1497                         self.items = self.items | IT_INVINCIBLE;
1498                         sprint(self, "^3Shield surrounds you\n");
1499                 }
1500         }
1501
1502         if (cvar("g_fullbrightplayers"))
1503                 self.effects = self.effects | EF_FULLBRIGHT;
1504
1505         // midair gamemode: damage only while in the air
1506         // if in midair mode, being on ground grants temporary invulnerability
1507         // (this is so that multishot weapon don't clear the ground flag on the
1508         // first damage in the frame, leaving the player vulnerable to the
1509         // remaining hits in the same frame)
1510         if (self.flags & FL_ONGROUND)
1511         if (g_midair)
1512                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1513
1514         if (time < self.spawnshieldtime)
1515                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * frametime);
1526 }
1527
1528 void player_regen (void)
1529 {
1530         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1531         maxh = cvar("g_balance_health_stable");
1532         maxa = cvar("g_balance_armor_stable");
1533         limith = cvar("g_balance_health_limit");
1534         limita = cvar("g_balance_armor_limit");
1535
1536         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1537                 return;
1538
1539         max_mod = regen_mod = rot_mod = limit_mod = 1;
1540
1541         if (self.runes & RUNE_REGEN)
1542         {
1543                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1544                 {
1545                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1546                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1547                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1548                 }
1549                 else
1550                 {
1551                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1552                         max_mod = cvar("g_balance_rune_regen_hpmod");
1553                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1554                 }
1555         }
1556         else if (self.runes & CURSE_VENOM)
1557         {
1558                 max_mod = cvar("g_balance_curse_venom_hpmod");
1559                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1560                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1561                 else
1562                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1563                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1564                 //if (!self.runes & RUNE_REGEN)
1565                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1566         }
1567         maxh = maxh * max_mod;
1568         //maxa = maxa * max_mod;
1569         limith = limith * limit_mod;
1570         limita = limita * limit_mod;
1571
1572         if (self.armorvalue > maxa)
1573         {
1574                 if (time > self.pauserotarmor_finished)
1575                 {
1576                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1577                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1578                 }
1579         }
1580         else if (self.armorvalue < maxa)
1581         {
1582                 if (time > self.pauseregen_finished)
1583                 {
1584                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1585                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1586                 }
1587         }
1588         if (self.health > maxh)
1589         {
1590                 if (time > self.pauserothealth_finished)
1591                 {
1592                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1593                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1594                 }
1595         }
1596         else if (self.health < maxh)
1597         {
1598                 if (time > self.pauseregen_finished)
1599                 {
1600                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1601                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1602                 }
1603         }
1604
1605         if (self.health > limith)
1606                 self.health = limith;
1607         if (self.armorvalue > limita)
1608                 self.armorvalue = limita;
1609
1610         // if player rotted to death...  die!
1611         if(self.health < 1)
1612                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1613 }
1614
1615 /*
1616 ======================
1617 spectate mode routines
1618 ======================
1619 */
1620 void SpectateCopy(entity spectatee) {
1621         self.armortype = spectatee.armortype;
1622         self.armorvalue = spectatee.armorvalue;
1623         self.currentammo = spectatee.currentammo;
1624         self.effects = spectatee.effects;
1625         self.health = spectatee.health;
1626         self.impulse = 0;
1627         self.items = spectatee.items;
1628         self.punchangle = spectatee.punchangle;
1629         self.view_ofs = spectatee.view_ofs;
1630         self.v_angle = spectatee.v_angle;
1631         self.viewzoom = spectatee.viewzoom;
1632         self.velocity = spectatee.velocity;
1633         self.dmg_take = spectatee.dmg_take;
1634         self.dmg_save = spectatee.dmg_save;
1635         self.dmg_inflictor = spectatee.dmg_inflictor;
1636         self.angles = spectatee.v_angle;
1637         self.fixangle = TRUE;
1638         setorigin(self, spectatee.origin);
1639         setsize(self, spectatee.mins, spectatee.maxs);
1640 }
1641
1642 float SpectateUpdate() {
1643         if(!self.enemy)
1644                 return 0;
1645
1646         if (self == self.enemy)
1647                 return 0;
1648
1649         if(self.enemy.flags & FL_NOTARGET)
1650                 return 0;
1651
1652         SpectateCopy(self.enemy);
1653
1654         return 1;
1655 }
1656
1657 float SpectateNext() {
1658         other = find(self.enemy, classname, "player");
1659         if (!other) {
1660                 other = find(other, classname, "player");
1661         }
1662         if (other) {
1663                 self.enemy = other;
1664         }
1665         if(self.enemy.classname == "player") {
1666                 msg_entity = self;
1667                 WriteByte(MSG_ONE, SVC_SETVIEW);
1668                 WriteEntity(MSG_ONE, self.enemy);
1669                 self.wantswelcomemessage = 1;
1670                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1671                 if(!SpectateUpdate())
1672                         PutObserverInServer();
1673                 return 1;
1674         } else {
1675                 return 0;
1676         }
1677 }
1678
1679 /*
1680 =============
1681 ShowRespawnCountdown()
1682
1683 Update a respawn countdown display.
1684 =============
1685 */
1686 void ShowRespawnCountdown()
1687 {
1688         float number;
1689         if(self.deadflag == DEAD_NO) // just respawned?
1690                 return;
1691         else
1692         {
1693                 number = ceil(self.death_time - time);
1694                 if(number <= 0)
1695                         return;
1696                 if(number <= self.respawn_countdown)
1697                 {
1698                         self.respawn_countdown = number - 1;
1699                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1700                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1701                 }
1702         }
1703 }
1704
1705 void LeaveSpectatorMode()
1706 {
1707         if(isJoinAllowed()) {
1708                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1709                         self.classname = "player";
1710                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1711                                 JoinBestTeam(self, FALSE, TRUE);
1712                         if(cvar("g_campaign"))
1713                                 campaign_bots_may_start = 1;
1714                         PutClientInServer();
1715                         if(!(self.flags & FL_NOTARGET))
1716                                 bprint ("^4", self.netname, "^4 is playing now\n");
1717                         centerprint(self,"");
1718                         return;
1719                 } else {
1720                         stuffcmd(self,"menu_showteamselect\n");
1721                         return;
1722                 }
1723         }
1724         else {
1725                 //player may not join because of g_maxplayers is set
1726                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1727         }
1728 }
1729
1730 /**
1731  * Determines whether the player is allowed to join. This depends on cvar
1732  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1733  * it checks whether the number of currently playing players exceeds g_maxplayers.
1734  * @return bool TRUE if the player is allowed to join, false otherwise
1735  */
1736 float isJoinAllowed() {
1737         if (!cvar("g_maxplayers"))
1738                 return TRUE;
1739
1740         local entity e;
1741         local float currentlyPlaying;
1742         FOR_EACH_REALPLAYER(e) {
1743                 if(e.classname == "player")
1744                         currentlyPlaying += 1;
1745         }
1746         if(currentlyPlaying < cvar("g_maxplayers"))
1747                 return TRUE;
1748
1749         return FALSE;
1750 }
1751
1752 /**
1753  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1754  * g_maxplayers_spectator_blocktime seconds
1755  */
1756 void checkSpectatorBlock() {
1757         if(self.classname == "spectator" || self.classname == "observer") {
1758                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1759                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1760                         dropclient(self);
1761                 }
1762         }
1763 }
1764
1765 float vercmp_recursive(string v1, string v2)
1766 {
1767         float dot1, dot2;
1768         string s1, s2;
1769         float r;
1770
1771         dot1 = strstrofs(v1, ".", 0);
1772         dot2 = strstrofs(v2, ".", 0);
1773         if(dot1 == -1)
1774                 s1 = v1;
1775         else
1776                 s1 = substring(v1, 0, dot1);
1777         if(dot2 == -1)
1778                 s2 = v2;
1779         else
1780                 s2 = substring(v2, 0, dot2);
1781
1782         r = stof(s1) - stof(s2);
1783         if(r != 0)
1784                 return r;
1785
1786         r = strcasecmp(s1, s2);
1787         if(r != 0)
1788                 return r;
1789
1790         if(dot1 == -1)
1791                 if(dot2 == -1)
1792                         return 0;
1793                 else
1794                         return -1;
1795         else
1796                 if(dot2 == -1)
1797                         return 1;
1798                 else
1799                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1800 }
1801
1802 float vercmp(string v1, string v2)
1803 {
1804         if(strcasecmp(v1, v2) == 0) // early out check
1805                 return 0;
1806         return vercmp_recursive(v1, v2);
1807 }
1808
1809 void ObserverThink()
1810 {
1811         if (self.flags & FL_JUMPRELEASED) {
1812                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1813                         self.welcomemessage_time = 0;
1814                         self.flags = self.flags - FL_JUMPRELEASED;
1815                         LeaveSpectatorMode();
1816                         return;
1817                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1818                         self.welcomemessage_time = 0;
1819                         self.flags = self.flags - FL_JUMPRELEASED;
1820                         if(SpectateNext() == 1) {
1821                                 self.classname = "spectator";
1822                         }
1823                 }
1824         } else {
1825                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1826                         self.flags = self.flags | FL_JUMPRELEASED;
1827                 }
1828         }
1829         if(self.BUTTON_ZOOM)
1830                 self.wantswelcomemessage = 0;
1831         if(self.wantswelcomemessage)
1832                 PrintWelcomeMessage(self);
1833 }
1834
1835 void SpectatorThink()
1836 {
1837         if (self.flags & FL_JUMPRELEASED) {
1838                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1839                         self.welcomemessage_time = 0;
1840                         self.flags = self.flags - FL_JUMPRELEASED;
1841                         LeaveSpectatorMode();
1842                         return;
1843                 } else if(self.BUTTON_ATCK) {
1844                         self.welcomemessage_time = 0;
1845                         self.flags = self.flags - FL_JUMPRELEASED;
1846                         if(SpectateNext() == 1) {
1847                                 self.classname = "spectator";
1848                         } else {
1849                                 self.classname = "observer";
1850                                 PutClientInServer();
1851                         }
1852                 } else if (self.BUTTON_ATCK2) {
1853                         self.welcomemessage_time = 0;
1854                         self.flags = self.flags - FL_JUMPRELEASED;
1855                         self.classname = "observer";
1856                         PutClientInServer();
1857                 } else {
1858                         if(!SpectateUpdate())
1859                                 PutObserverInServer();
1860                 }
1861         } else {
1862                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1863                         self.flags = self.flags | FL_JUMPRELEASED;
1864                 }
1865         }
1866         if(self.BUTTON_ZOOM)
1867                 self.wantswelcomemessage = 0;
1868         if(self.wantswelcomemessage)
1869                 PrintWelcomeMessage(self);
1870         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1871 }
1872
1873 /*
1874 =============
1875 PlayerPreThink
1876
1877 Called every frame for each client before the physics are run
1878 =============
1879 */
1880 void() ctf_setstatus;
1881 .float vote_nagtime;
1882 void PlayerPreThink (void)
1883 {
1884         if(blockSpectators)
1885                 checkSpectatorBlock();
1886
1887         if(self.netname_previous != self.netname)
1888         {
1889                 if(cvar("sv_eventlog"))
1890                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1891                 if(self.netname_previous)
1892                         strunzone(self.netname_previous);
1893                 self.netname_previous = strzone(self.netname);
1894         }
1895
1896         // version nagging
1897         if(self.version_nagtime)
1898                 if(self.cvar_g_nexuizversion)
1899                         if(time > self.version_nagtime)
1900                         {
1901                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1902                                 {
1903                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1904                                         {
1905                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1906                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1907                                         }
1908                                         else
1909                                         {
1910                                                 float r;
1911                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1912                                                 if(r < 0)
1913                                                 {
1914                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1915                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1916                                                 }
1917                                                 else if(r > 0)
1918                                                 {
1919                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1920                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1921                                                 }
1922                                         }
1923                                 }
1924                                 self.version_nagtime = 0;
1925                         }
1926
1927         // vote nagging
1928         if(self.cvar_scr_centertime)
1929                 if(time > self.vote_nagtime)
1930                 {
1931                         VoteNag();
1932                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1933                 }
1934
1935         // GOD MODE info
1936         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1937         {
1938                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1939                 self.max_armorvalue = 0;
1940         }
1941
1942         if(frametime)
1943                 antilag_record(self);
1944
1945         if(self.classname == "player") {
1946 //              if(self.netname == "Wazat")
1947 //                      bprint(self.classname, "\n");
1948
1949                 CheckRules_Player();
1950
1951                 if(self.BUTTON_INFO)
1952                         PrintWelcomeMessage(self);
1953
1954                 if(g_lms || !cvar("sv_spectate"))
1955                 if((time - self.jointime) <= cvar("welcome_message_time"))
1956                         PrintWelcomeMessage(self);
1957
1958                 if (intermission_running)
1959                 {
1960                         IntermissionThink ();   // otherwise a button could be missed between
1961                         return;                                 // the think tics
1962                 }
1963
1964                 if(self.teleport_time)
1965                 if(time > self.teleport_time)
1966                 {
1967                         self.teleport_time = 0;
1968                         self.effects = self.effects - (self.effects & EF_NODRAW);
1969                         if(self.weaponentity)
1970                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1971                 }
1972
1973                 Nixnex_GiveCurrentWeapon();
1974
1975                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1976                         UpdateSelectedPlayer();
1977
1978                 //don't allow the player to turn around while game is paused!
1979                 if(timeoutStatus == 2) {
1980                         self.v_angle = self.lastV_angle;
1981                         self.angles = self.lastV_angle;
1982                         self.fixangle = TRUE;
1983                 }
1984
1985                 if (self.deadflag != DEAD_NO)
1986                 {
1987                         float button_pressed, force_respawn;
1988                         player_anim();
1989                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1990                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1991                         if (self.deadflag == DEAD_DYING)
1992                         {
1993                                 if(force_respawn)
1994                                         self.deadflag = DEAD_RESPAWNING;
1995                                 else if(!button_pressed)
1996                                         self.deadflag = DEAD_DEAD;
1997                         }
1998                         else if (self.deadflag == DEAD_DEAD)
1999                         {
2000                                 if(button_pressed)
2001                                         self.deadflag = DEAD_RESPAWNABLE;
2002                         }
2003                         else if (self.deadflag == DEAD_RESPAWNABLE)
2004                         {
2005                                 if(!button_pressed)
2006                                         self.deadflag = DEAD_RESPAWNING;
2007                         }
2008                         else if (self.deadflag == DEAD_RESPAWNING)
2009                         {
2010                                 if(time > self.death_time)
2011                                 {
2012                                         self.death_time = time + 1; // only retry once a second
2013                                         respawn();
2014                                 }
2015                         }
2016                         ShowRespawnCountdown();
2017                         return;
2018                 }
2019
2020                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2021                 {
2022                         vector dist;
2023
2024                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2025                         dist = self.oldorigin - self.origin;
2026                         dist_z = 0;
2027                         self.lms_traveled_distance += fabs(vlen(dist));
2028
2029                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2030                         {
2031                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2032                                 self.lms_traveled_distance = 0;
2033                         }
2034
2035                         if(time > self.lms_nextcheck)
2036                         {
2037                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2038                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2039                                 {
2040                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2041                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2042                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2043                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2044                                 }
2045                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2046                                 self.lms_traveled_distance = 0;
2047                         }
2048                 }
2049
2050                 if (self.BUTTON_CROUCH && !self.hook.state)
2051                 {
2052                         if (!self.crouch)
2053                         {
2054                                 self.crouch = TRUE;
2055                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2056                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2057                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2058                         }
2059                 }
2060                 else
2061                 {
2062                         if (self.crouch)
2063                         {
2064                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2065                                 if (!trace_startsolid)
2066                                 {
2067                                         self.crouch = FALSE;
2068                                         self.view_ofs = PL_VIEW_OFS;
2069                                         setsize (self, PL_MIN, PL_MAX);
2070                                 }
2071                         }
2072                 }
2073
2074                 FixPlayermodel();
2075
2076                 GrapplingHookFrame();
2077
2078                 W_WeaponFrame();
2079
2080                 {
2081                         float zoomfactor, zoomspeed, zoomdir;
2082                         zoomfactor = self.cvar_cl_zoomfactor;
2083                         if(zoomfactor < 1 || zoomfactor > 16)
2084                                 zoomfactor = 2.5;
2085                         zoomspeed = self.cvar_cl_zoomspeed;
2086                         if(zoomspeed >= 0) // < 0 is instant zoom
2087                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2088                                         zoomspeed = 3.5;
2089
2090                         zoomdir = self.BUTTON_ZOOM;
2091                         if(self.BUTTON_ATCK2)
2092                                 if(self.weapon == WEP_NEX)
2093                                         if(!g_minstagib)
2094                                                 zoomdir = 1;
2095
2096                         if(zoomdir)
2097                                 self.has_zoomed = 1;
2098
2099                         if(self.has_zoomed)
2100                         {
2101                                 if(zoomspeed <= 0) // instant zoom
2102                                 {
2103                                         if(zoomdir)
2104                                                 self.viewzoom = 1 / zoomfactor;
2105                                         else
2106                                                 self.viewzoom = 1;
2107                                 }
2108                                 else
2109                                 {
2110                                         // geometric zoom would be:
2111                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2112                                         // however, testing showed that arithmetic/harmonic zoom works better
2113                                         if(zoomdir)
2114                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2115                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2116                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2117                                         else
2118                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2119                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2120                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2121                                 }
2122                         }
2123                         else
2124                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2125                 }
2126
2127                 player_powerups();
2128                 player_regen();
2129                 player_anim();
2130
2131                 if (g_minstagib)
2132                         minstagib_ammocheck();
2133
2134                 ctf_setstatus();
2135                 kh_setstatus();
2136
2137                 //self.angles_y=self.v_angle_y + 90;   // temp
2138
2139                 //if (TetrisPreFrame()) return;
2140         } else if(gameover) {
2141                 if (intermission_running)
2142                         IntermissionThink ();   // otherwise a button could be missed between
2143                 return;
2144         } else if(self.classname == "observer") {
2145                 ObserverThink();
2146         } else if(self.classname == "spectator") {
2147                 SpectatorThink();
2148         }
2149 }
2150
2151
2152 /*
2153 =============
2154 PlayerPostThink
2155
2156 Called every frame for each client after the physics are run
2157 =============
2158 */
2159 .float idlekick_lasttimeleft;
2160 void PlayerPostThink (void)
2161 {
2162         // Savage: Check for nameless players
2163         if (strlen(self.netname) < 1) {
2164                 self.netname = "Player";
2165                 stuffcmd(self, "seta _cl_name Player\n");
2166         }
2167
2168         if(sv_maxidle)
2169         {
2170                 float timeleft;
2171                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2172                 if(timeleft <= 0)
2173                 {
2174                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2175                         announce(self, "announcer/robotic/terminated.ogg");
2176                         dropclient(self);
2177                         return;
2178                 }
2179                 else if(timeleft <= 10)
2180                 {
2181                         if(timeleft != self.idlekick_lasttimeleft)
2182                         {
2183                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2184                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2185                         }
2186                 }
2187                 else
2188                 {
2189                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2190                 }
2191                 self.idlekick_lasttimeleft = timeleft;
2192         }
2193
2194         if(self.classname == "player") {
2195                 CheckRules_Player();
2196                 UpdateChatBubble();
2197                 UpdateTeamBubble();
2198                 if (self.impulse)
2199                         ImpulseCommands();
2200                 if (intermission_running)
2201                         return;         // intermission or finale
2202
2203                 //PrintWelcomeMessage(self);
2204                 //if (TetrisPostFrame()) return;
2205
2206                 // restart countdown
2207                 if (restart_countdown) {
2208                         if(time < restart_countdown) {
2209                                 if (!cvar("sv_ready_restart_after_countdown"))
2210                                 {
2211                                         self.movetype = MOVETYPE_NONE;
2212                                         self.velocity = '0 0 0';
2213                                         self.avelocity = '0 0 0';
2214                                         self.movement = '0 0 0';
2215                                 }
2216                         }
2217                         else
2218                         {
2219                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2220                                 if (!cvar("sv_ready_restart_after_countdown"))
2221                                 {
2222                                         if(self.movetype == MOVETYPE_NONE)
2223                                         {
2224                                                 self.movetype = MOVETYPE_WALK;
2225                                         }
2226                                 }
2227                         }
2228                 }
2229
2230         } else if (self.classname == "observer") {
2231                 //do nothing
2232         } else if (self.classname == "spectator") {
2233                 //do nothing
2234         }
2235
2236         /*
2237         float i;
2238         for(i = 0; i < 1000; ++i)
2239         {
2240                 vector end;
2241                 end = self.origin + '0 0 1024' + 512 * randomvec();
2242                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2243                 if(trace_fraction < 1)
2244                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2245                 {
2246                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2247                         break;
2248                 }
2249         }
2250         */
2251
2252         Arena_Warmup();
2253 }