data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         if(teams_matter)
 468                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 469                         else
 470                                 self.skin = stof(self.playerskin);
 471                 }
 472
 473                 self.crouch = FALSE;
 474                 self.view_ofs = PL_VIEW_OFS;
 475                 setsize (self, PL_MIN, PL_MAX);
 476                 self.spawnorigin = spot.origin;
 477                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 478                 // don't reset back to last position, even if new position is stuck in solid
 479                 self.oldorigin = self.origin;
 480
 481                 if(cvar("g_lms"))
 482                 {
 483                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 484                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 485                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 486                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 487                         self.health = cvar("g_lms_start_health");
 488                         self.armorvalue = cvar("g_lms_start_armor");
 489                 }
 490                 else if (cvar("g_use_ammunition")) {
 491                         self.ammo_shells = cvar("g_start_ammo_shells");
 492                         self.ammo_nails = cvar("g_start_ammo_nails");
 493                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 494                         self.ammo_cells = cvar("g_start_ammo_cells");
 495                 } else {
 496                         self.ammo_shells = 999;
 497                         self.ammo_nails = 999;
 498                         self.ammo_rockets = 999;
 499                         self.ammo_cells = 999;
 500                 }
 501
 502                 self.items = 0;
 503                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 504                 {
 505                         self.items = self.items | IT_LASER;
 506                         self.switchweapon = WEP_LASER;
 507                 }
 508                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 509                 {
 510                         self.items = self.items | IT_SHOTGUN;
 511                         self.switchweapon = WEP_SHOTGUN;
 512                 }
 513                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 514                 {
 515                         self.items = self.items | IT_UZI;
 516                         self.switchweapon = WEP_UZI;
 517                 }
 518                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 519                 {
 520                         self.items = self.items | IT_GRENADE_LAUNCHER;
 521                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 522                 }
 523                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 524                 {
 525                         self.items = self.items | IT_ELECTRO;
 526                         self.switchweapon = WEP_ELECTRO;
 527                 }
 528                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 529                 {
 530                         self.items = self.items | IT_CRYLINK;
 531                         self.switchweapon = WEP_CRYLINK;
 532                 }
 533                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 534                 {
 535                         self.items = self.items | IT_NEX;
 536                         self.switchweapon = WEP_NEX;
 537                 }
 538                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 539                 {
 540                         self.items = self.items | IT_HAGAR;
 541                         self.switchweapon = WEP_HAGAR;
 542                 }
 543                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 544                 {
 545                         self.items = self.items | IT_ROCKET_LAUNCHER;
 546                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 547                 }
 548
 549                 if(cvar("g_instagib"))
 550                 {
 551                         self.items = IT_NEX;
 552                         self.switchweapon = WEP_NEX;
 553                         self.ammo_cells = 999;
 554                 }
 555
 556                 if(cvar("g_rocketarena"))
 557                 {
 558                         self.items = IT_ROCKET_LAUNCHER;
 559                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 560                         self.ammo_rockets = 999;
 561                 }
 562
 563                 if(cvar("g_nixnex"))
 564                 {
 565                         self.items = 0;
 566                         // will be done later
 567                 }
 568
 569                 if(cvar("g_minstagib"))
 570                 {
 571                         self.health = 100;
 572                         self.armorvalue = 0;
 573                         self.items = IT_NEX;
 574                         self.switchweapon = WEP_NEX;
 575                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 576                         self.jump_interval = time;
 577                 }
 578
 579                 if(cvar("g_arena"))
 580                 {
 581                         Spawnqueue_Remove(self);
 582                         Spawnqueue_Mark(self);
 583                 }
 584
 585                 self.event_damage = PlayerDamage;
 586
 587                 self.bot_attack = TRUE;
 588
 589                 self.statdraintime = time + 5;
 590                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 591
 592                 if(self.killcount == -666) {
 593                         self.killcount = 0;
 594                         if(!cvar("g_arena"))
 595                         if(!cvar("g_lms"))
 596                                 self.frags = 0;
 597                 }
 598
 599                 self.cnt = WEP_LASER;
 600                 self.nixnex_lastchange_id = -1;
 601
 602                 CL_SpawnWeaponentity();
 603                 self.alpha = default_player_alpha;
 604                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 605
 606                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 607                 self.lms_traveled_distance = 0;
 608
 609                 if(cvar("spawn_debug"))
 610                 {
 611                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 612                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 613                 }
 614
 615                 //stuffcmd(self, "chase_active 0");
 616                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 617         } else if(self.classname == "observer") {
 618                 PutObserverInServer ();
 619         }
 620 }
 621
 622 /*
 623 =============
 624 SetNewParms
 625 =============
 626 */
 627 void SetNewParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 SetChangeParms
 635 =============
 636 */
 637 void SetChangeParms (void)
 638 {
 639
 640 }
 641
 642 /*
 643 =============
 644 ClientKill
 645
 646 Called when a client types 'kill' in the console
 647 =============
 648 */
 649 void ClientKill (void)
 650 {
 651         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 652 }
 653
 654 /*
 655 =============
 656 ClientConnect
 657
 658 Called when a client connects to the server
 659 =============
 660 */
 661 string ColoredTeamName(float t);
 662 //void dom_player_join_team(entity pl);
 663 void ClientConnect (void)
 664 {
 665         //local float fh;
 666         local string s;
 667
 668         self.classname = "player_joining";
 669         self.flags = self.flags | FL_CLIENT;
 670         self.version_nagtime = time + 10 + random() * 10;
 671
 672         if(player_count<0) player_count = 0;
 673
 674         bot_clientconnect();
 675
 676         //if(cvar("g_domination"))
 677         //      dom_player_join_team(self);
 678
 679         //JoinBestTeam(self, FALSE);
 680
 681         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 682                 self.classname = "observer";
 683         } else {
 684                 self.classname = "player";
 685                 campaign_bots_may_start = 1;
 686         }
 687
 688         self.playerid = (playerid_last = playerid_last + 1);
 689         if(cvar("sv_eventlog"))
 690         {
 691                 if(clienttype(self) == CLIENTTYPE_REAL)
 692                         s = "player";
 693                 else
 694                         s = "bot";
 695                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 696                 s = strcat(":team:", ftos(self.playerid), ":");
 697                 s = strcat(s, ftos(self.team));
 698                 GameLogEcho(s, FALSE);
 699         }
 700
 701         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 702
 703         bprint ("^4",self.netname);
 704         bprint ("^4 connected");
 705
 706         if(cvar("g_domination") || cvar("g_ctf"))
 707         {
 708                 bprint(" and joined the ");
 709                 bprint(ColoredTeamName(self.team));
 710         }
 711
 712         bprint("\n");
 713
 714         self.welcomemessage_time = time + cvar("welcome_message_time");
 715         self.welcomemessage_time2 = 0;
 716
 717         /*
 718         // the client might not have his maps/%s.cfg file yet!
 719         // so send the one from the server...
 720         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 721         if(fh >= 0)
 722         {
 723                 while((s = fgets(fh)))
 724                         stuffcmd(self, strcat(s, "\n"));
 725                 fclose(fh);
 726         }
 727         // and then execute the client's so he can still override CD tracks
 728
 729         not needed any more: current map download system disconnects and reconnects
 730         after the download, and then the file will be there
 731         */
 732         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 733
 734         // TODO: is this being used for anything else than cd tracks?
 735         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 736
 737         // send prediction settings to the client
 738         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 739         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 741         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 742         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 743         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 744         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 745         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 746         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 747         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 748         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 749         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 750         // Wazat's grappling hook
 751         SetGrappleHookBindings();
 752
 753         // get autoswitch state from player
 754         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 755         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 756
 757         // get version info from player
 758         stuffcmd(self, "cmd clientversion $gameversion\n");
 759
 760         // get other cvars from player
 761         GetCvars(0);
 762
 763         // set cvar for team scoreboard
 764         if (teams_matter)
 765         {
 766                 local float t;
 767                 t = cvar("teamplay");
 768                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 769                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 770         }
 771         else
 772                 stuffcmd(self, strcat("set teamplay 0\n"));
 773
 774         if(cvar("g_lms"))
 775         {
 776                 self.frags = cvar("fraglimit");
 777                 // no fraglimit was set, so player gets 999 lives
 778                 if(self.frags < 1)
 779                         self.frags = 999;
 780
 781                 self.frags = LMS_NewPlayerLives();
 782                 if(!self.frags)
 783                 {
 784                         self.frags = -666;
 785                 }
 786         }
 787         else if(cvar("g_arena"))
 788         {
 789                 self.classname = "observer";
 790                 Spawnqueue_Insert(self);
 791         }
 792
 793         bot_relinkplayerlist();
 794
 795         self.jointime = time;
 796 }
 797
 798 /*
 799 =============
 800 ClientDisconnect
 801
 802 Called when a client disconnects from the server
 803 =============
 804 */
 805 void(entity e) DropFlag;
 806 .entity chatbubbleentity;
 807 .entity teambubbleentity;
 808 void ClientDisconnect (void)
 809 {
 810         float save;
 811         if(cvar("sv_eventlog"))
 812                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 813         bprint ("^4",self.netname);
 814         bprint ("^4 disconnected\n");
 815
 816         if (self.chatbubbleentity)
 817         {
 818                 remove (self.chatbubbleentity);
 819                 self.chatbubbleentity = world;
 820         }
 821
 822         if (self.teambubbleentity)
 823         {
 824                 remove (self.teambubbleentity);
 825                 self.teambubbleentity = world;
 826         }
 827
 828         DropAllRunes(self);
 829
 830         if(self.flagcarried)
 831                 DropFlag(self.flagcarried);
 832
 833         DistributeFragsAmongTeam(self, self.team, 1);
 834
 835         save = self.flags;
 836         self.flags = self.flags - (self.flags & FL_CLIENT);
 837         bot_relinkplayerlist();
 838         self.flags = save;
 839
 840         // remove laserdot
 841         if(self.weaponentity)
 842                 if(self.weaponentity.lasertarget)
 843                         remove(self.weaponentity.lasertarget);
 844
 845         if(cvar("g_arena"))
 846         {
 847                 Spawnqueue_Unmark(self);
 848                 Spawnqueue_Remove(self);
 849         }
 850
 851         // free cvars
 852         GetCvars(-1);
 853 }
 854
 855 .float buttonchat;
 856 void() ChatBubbleThink =
 857 {
 858         self.nextthink = time;
 859         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 860         {
 861                 self.owner.chatbubbleentity = world;
 862                 remove(self);
 863                 return;
 864         }
 865         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 866         if (self.owner.buttonchat && !self.owner.deadflag)
 867                 self.model = self.mdl;
 868         else
 869                 self.model = "";
 870 };
 871
 872 void() UpdateChatBubble =
 873 {
 874         if (!self.modelindex)
 875                 return;
 876         // spawn a chatbubble entity if needed
 877         if (!self.chatbubbleentity)
 878         {
 879                 self.chatbubbleentity = spawn();
 880                 self.chatbubbleentity.owner = self;
 881                 self.chatbubbleentity.exteriormodeltoclient = self;
 882                 self.chatbubbleentity.think = ChatBubbleThink;
 883                 self.chatbubbleentity.nextthink = time;
 884                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 885                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 886                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 887                 self.chatbubbleentity.model = "";
 888         }
 889 }
 890
 891
 892 void() TeamBubbleThink =
 893 {
 894         self.nextthink = time;
 895         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 896         {
 897                 self.owner.teambubbleentity = world;
 898                 remove(self);
 899                 return;
 900         }
 901 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 902         if (self.owner.buttonchat || self.owner.deadflag)
 903                 self.model = "";
 904         else
 905                 self.model = self.mdl;
 906
 907 };
 908
 909 float() TeamBubble_customizeentityforclient
 910 {
 911         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 912 }
 913
 914 void() UpdateTeamBubble =
 915 {
 916         if (!self.modelindex || !cvar("teamplay"))
 917                 return;
 918         // spawn a teambubble entity if needed
 919         if (!self.teambubbleentity && cvar("teamplay"))
 920         {
 921                 self.teambubbleentity = spawn();
 922                 self.teambubbleentity.owner = self;
 923                 self.teambubbleentity.exteriormodeltoclient = self;
 924                 self.teambubbleentity.think = TeamBubbleThink;
 925                 self.teambubbleentity.nextthink = time;
 926                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 927 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 928                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 929                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 930                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 931                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 932                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 933         }
 934 }
 935
 936 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 937 // added to the model skins
 938 /*void() UpdateColorModHack =
 939 {
 940         local float c;
 941         c = self.clientcolors & 15;
 942         // LordHavoc: only bothering to support white, green, red, yellow, blue
 943              if (teamplay == 0) self.colormod = '0 0 0';
 944         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 945         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 946         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 947         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 948         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 949         else self.colormod = '1 1 1';
 950 };*/
 951
 952 /*
 953 =============
 954 PlayerJump
 955
 956 When you press the jump key
 957 =============
 958 */
 959 void PlayerJump (void)
 960 {
 961         float mjumpheight;
 962
 963         mjumpheight = cvar("g_balance_jumpheight");
 964         if (self.waterlevel >= 2)
 965         {
 966                 if (self.watertype == CONTENT_WATER)
 967                         self.velocity_z = 200;
 968                 else if (self.watertype == CONTENT_SLIME)
 969                         self.velocity_z = 80;
 970                 else
 971                         self.velocity_z = 50;
 972
 973                 return;
 974         }
 975
 976
 977         if (!(self.flags & FL_ONGROUND))
 978                 return;
 979
 980         if (!(self.flags & FL_JUMPRELEASED))
 981                 return;
 982
 983         if(cvar("g_runematch"))
 984         {
 985                 if(self.runes & RUNE_SPEED)
 986                 {
 987                         if(self.runes & CURSE_SLOW)
 988                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 989                         else
 990                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 991                 }
 992                 else if(self.runes & CURSE_SLOW)
 993                 {
 994                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 995                 }
 996         }
 997
 998         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 999         {
1000                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1001         }
1002
1003         self.velocity_z = self.velocity_z + mjumpheight;
1004         self.oldvelocity_z = self.velocity_z;
1005
1006         self.flags = self.flags - FL_ONGROUND;
1007         self.flags = self.flags - FL_JUMPRELEASED;
1008 }
1009
1010 void() CheckWaterJump =
1011 {
1012         local vector start, end;
1013
1014 // check for a jump-out-of-water
1015         makevectors (self.angles);
1016         start = self.origin;
1017         start_z = start_z + 8;
1018         v_forward_z = 0;
1019         normalize(v_forward);
1020         end = start + v_forward*24;
1021         traceline (start, end, TRUE, self);
1022         if (trace_fraction < 1)
1023         {       // solid at waist
1024                 start_z = start_z + self.maxs_z - 8;
1025                 end = start + v_forward*24;
1026                 self.movedir = trace_plane_normal * -50;
1027                 traceline (start, end, TRUE, self);
1028                 if (trace_fraction == 1)
1029                 {       // open at eye level
1030                         self.flags = self.flags | FL_WATERJUMP;
1031                         self.velocity_z = 225;
1032                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1033                         self.teleport_time = time + 2;  // safety net
1034                         return;
1035                 }
1036         }
1037 };
1038
1039
1040 void respawn(void)
1041 {
1042         CopyBody(1);
1043         PutClientInServer();
1044 }
1045
1046 void player_powerups (void)
1047 {
1048         if (cvar("g_minstagib"))
1049         {
1050                 self.effects = EF_FULLBRIGHT;
1051                 if (self.items & IT_STRENGTH)
1052                 {
1053                         if (time > self.strength_finished)
1054                         {
1055                                 self.alpha = default_player_alpha;
1056                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1057                                 self.items = self.items - (self.items & IT_STRENGTH);
1058                                 sprint(self, "^3Invisibility has worn off\n");
1059                         }
1060                 }
1061                 else
1062                 {
1063                         if (time < self.strength_finished)
1064                         {
1065                                 self.alpha = cvar("g_minstagib_invis_alpha");
1066                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1067                                 self.items = self.items | IT_STRENGTH;
1068                                 sprint(self, "^3You are invisible\n");
1069                         }
1070                 }
1071
1072                 if (self.items & IT_INVINCIBLE)
1073                 {
1074                         if (time > self.invincible_finished)
1075                         {
1076                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1077                                 sprint(self, "^3Speed has worn off\n");
1078                         }
1079                 }
1080                 else
1081                 {
1082                         if (time < self.invincible_finished)
1083                         {
1084                                 self.items = self.items | IT_INVINCIBLE;
1085                                 sprint(self, "^3You are on speed\n");
1086                         }
1087                 }
1088                 return;
1089         }
1090
1091         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1092         if (self.items & IT_STRENGTH)
1093         {
1094                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1095                 if (time > self.strength_finished)
1096                 {
1097                         self.items = self.items - (self.items & IT_STRENGTH);
1098                         sprint(self, "^3Strength has worn off\n");
1099                 }
1100         }
1101         else
1102         {
1103                 if (time < self.strength_finished)
1104                 {
1105                         self.items = self.items | IT_STRENGTH;
1106                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1107                 }
1108         }
1109         if (self.items & IT_INVINCIBLE)
1110         {
1111                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1112                 if (time > self.invincible_finished)
1113                 {
1114                         self.items = self.items - (self.items & IT_INVINCIBLE);
1115                         sprint(self, "^3Shield has worn off\n");
1116                 }
1117         }
1118         else
1119         {
1120                 if (time < self.invincible_finished)
1121                 {
1122                         self.items = self.items | IT_INVINCIBLE;
1123                         sprint(self, "^3Shield surrounds you\n");
1124                 }
1125         }
1126
1127         if (cvar("g_fullbrightplayers"))
1128                 self.effects = self.effects | EF_FULLBRIGHT;
1129
1130         // midair gamemode: damage only while in the air
1131         // if in midair mode, being on ground grants temporary invulnerability
1132         // (this is so that multishot weapon don't clear the ground flag on the
1133         // first damage in the frame, leaving the player vulnerable to the
1134         // remaining hits in the same frame)
1135         if (self.flags & FL_ONGROUND)
1136         if (cvar("g_midair"))
1137                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1138
1139         if (time < self.spawnshieldtime)
1140                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1141 }
1142
1143 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1144 {
1145         if(current > stable)
1146                 return current;
1147         else if(current > stable - 0.25) // when close enough, "snap"
1148                 return stable;
1149         else
1150                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1151 }
1152
1153 void player_regen (void)
1154 {
1155         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1156         maxh = cvar("g_balance_health_stable");
1157         maxa = cvar("g_balance_armor_stable");
1158         limith = cvar("g_balance_health_limit");
1159         limita = cvar("g_balance_armor_limit");
1160
1161         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1162                 return;
1163
1164         if(cvar("g_runematch"))
1165         {
1166                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1167                 if (self.runes & RUNE_REGEN)
1168                 {
1169                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1170                         {
1171                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1172                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1173                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1174                         }
1175                         else
1176                         {
1177                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1178                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1179                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1180                         }
1181                 }
1182                 else if (self.runes & CURSE_VENOM)
1183                 {
1184                         max_mod = cvar("g_balance_curse_venom_hpmod");
1185                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1186                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1187                         else
1188                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1189                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1190                         //if (!self.runes & RUNE_REGEN)
1191                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1192                 }
1193                 maxh = maxh * max_mod;
1194                 //maxa = maxa * max_mod;
1195
1196                 if (time > self.pauserotarmor_finished)
1197                 {
1198                         if (self.armorvalue > maxa)
1199                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1200                 }
1201                 if (time > self.pauserothealth_finished)
1202                 {
1203                         if (self.health > maxh)
1204                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1205                 }
1206                 if (time > self.pauseregen_finished)
1207                 {
1208                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1209                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1210                 }
1211         }
1212         else
1213         {
1214                 if (time > self.pauserothealth_finished)
1215                 if (self.health > maxh)
1216                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1217                 if (time > self.pauserotarmor_finished)
1218                 if (self.armorvalue > maxa)
1219                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1220                 if (time > self.pauseregen_finished)
1221                 {
1222                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1223                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1224                 }
1225         }
1226
1227         if (self.health > limith)
1228                 self.health = limith;
1229         if(self.health < 1)
1230                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1231         if (self.armorvalue > limita)
1232                 self.armorvalue = limita;
1233 }
1234
1235 /*
1236 ======================
1237 spectate mode routines
1238 ======================
1239 */
1240 void SpectateCopy(entity spectatee) {
1241         self.armortype = spectatee.armortype;
1242         self.armorvalue = spectatee.armorvalue;
1243         self.currentammo = spectatee.currentammo;
1244         self.effects = spectatee.effects;
1245         self.health = spectatee.health;
1246         self.impulse = 0;
1247         self.items = spectatee.items;
1248         self.punchangle = spectatee.punchangle;
1249         self.view_ofs = spectatee.view_ofs;
1250         self.v_angle = spectatee.v_angle;
1251         self.viewzoom = spectatee.viewzoom;
1252         setorigin(self, spectatee.origin);
1253         setsize(self, spectatee.mins, spectatee.maxs);
1254 }
1255
1256 void SpectateUpdate() {
1257         if(!self.enemy)
1258                         PutObserverInServer();
1259
1260         if (self != self.enemy) {
1261                 if(self.enemy.flags & FL_NOTARGET)
1262                         PutObserverInServer();
1263                 SpectateCopy(self.enemy);
1264                 self.dmg_take = self.enemy.dmg_take;
1265                 self.dmg_save = self.enemy.dmg_save;
1266                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1267                 self.fixangle = TRUE;
1268                 self.angles = self.enemy.v_angle;
1269                 //msg_entity = self;
1270                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1271                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1272                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1273                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1274         }
1275 }
1276
1277 float SpectateNext() {
1278         other = find(self.enemy, classname, "player");
1279         if (!other) {
1280                 other = find(other, classname, "player");
1281         }
1282         if (other) {
1283                 self.enemy = other;
1284         }
1285         if(self.enemy.classname == "player") {
1286                 msg_entity = self;
1287                 WriteByte(MSG_ONE, SVC_SETVIEW);
1288                 WriteEntity(MSG_ONE, self.enemy);
1289                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1290                 SpectateUpdate();
1291                 return 1;
1292         } else {
1293                 return 0;
1294         }
1295 }
1296
1297 /*
1298 =============
1299 PlayerPreThink
1300
1301 Called every frame for each client before the physics are run
1302 =============
1303 */
1304 void() ctf_setstatus;
1305 void PlayerPreThink (void)
1306 {
1307         // version nagging
1308         if(self.version_nagtime)
1309                 if(self.cvar_g_nexuizversion)
1310                         if(time > self.version_nagtime)
1311                         {
1312                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1313                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1314                                         {
1315                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1316                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1317                                         }
1318                                 self.version_nagtime = 0;
1319                         }
1320
1321         if(self.classname == "player") {
1322                 local vector m1, m2;
1323
1324 //              if(self.netname == "Wazat")
1325 //                      bprint(strcat(self.classname, "\n"));
1326
1327                 CheckRules_Player();
1328
1329                 Nixnex_GiveCurrentWeapon();
1330
1331                 if(self.button7)
1332                         PrintWelcomeMessage(self);
1333
1334                 if(cvar("g_lms") || !cvar("sv_spectate"))
1335                 if((time - self.jointime) <= cvar("welcome_message_time"))
1336                         PrintWelcomeMessage(self);
1337
1338                 if (intermission_running)
1339                 {
1340                         IntermissionThink ();   // otherwise a button could be missed between
1341                         return;                                 // the think tics
1342                 }
1343
1344                 if (self.deadflag != DEAD_NO)
1345                 {
1346                         player_anim();
1347                         if (self.deadflag == DEAD_DYING)
1348                         {
1349                                 if (time > self.dead_time)
1350                                         self.deadflag = DEAD_DEAD;
1351                         }
1352                         else if (self.deadflag == DEAD_DEAD)
1353                         {
1354                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1355                                         self.deadflag = DEAD_RESPAWNABLE;
1356                                 else if (!self.button0 && !self.button2 && !self.button3)
1357                                         self.deadflag = DEAD_RESPAWNABLE;
1358                         }
1359                         else if (self.deadflag == DEAD_RESPAWNABLE)
1360                         {
1361                                 if (self.button0  ||
1362                                     self.button2  ||
1363                                     self.button3  ||
1364                                     self.button4  ||
1365                                     self.button5  ||
1366                                     self.button6  ||
1367                                     self.button7  ||
1368                                     self.button8  ||
1369                                     self.buttonuse ||
1370                                     cvar("g_lms") ||
1371                                     cvar("g_forced_respawn"))
1372                                         respawn();
1373                         }
1374                         return;
1375                 }
1376
1377                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1378                 {
1379                         vector dist;
1380
1381                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1382                         dist = self.oldorigin - self.origin;
1383                         dist_z = 0;
1384                         self.lms_traveled_distance += fabs(vlen(dist));
1385
1386                         if(cvar("g_campaign"))
1387                         if(!campaign_bots_may_start)
1388                         {
1389                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1390                                 self.lms_traveled_distance = 0;
1391                         }
1392
1393                         if(time > self.lms_nextcheck)
1394                         {
1395                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1396                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1397                                 {
1398                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1399                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1400                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1401                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1402                                 }
1403                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1404                                 self.lms_traveled_distance = 0;
1405                         }
1406                 }
1407
1408                 if (self.button5 && !self.hook.state)
1409                 {
1410                         if (!self.crouch)
1411                         {
1412                                 self.crouch = TRUE;
1413                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1414                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1415                         }
1416                 }
1417                 else
1418                 {
1419                         if (self.crouch)
1420                         {
1421                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1422                                 if (!trace_startsolid)
1423                                 {
1424                                         self.crouch = FALSE;
1425                                         self.view_ofs = PL_VIEW_OFS;
1426                                         setsize (self, PL_MIN, PL_MAX);
1427                                 }
1428                         }
1429                 }
1430
1431                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1432                         local string defaultmodel;
1433                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1434
1435                         if (defaultmodel != self.model)
1436                         {
1437                                 m1 = self.mins;
1438                                 m2 = self.maxs;
1439                                 setmodel_lod (self, defaultmodel);
1440                                 setsize (self, m1, m2);
1441                         }
1442
1443                         if (self.skin != cvar("sv_defaultplayerskin"))
1444                                 self.skin = cvar("sv_defaultplayerskin");
1445                 } else {
1446                         if (self.playermodel != self.model)
1447                         {
1448                                 self.playermodel = CheckPlayerModel(self.playermodel);
1449                                 m1 = self.mins;
1450                                 m2 = self.maxs;
1451                                 setmodel_lod (self, self.playermodel);
1452                                 setsize (self, m1, m2);
1453                         }
1454
1455                         if(teams_matter)
1456                         {
1457                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1458                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1459                         }
1460                         else
1461                         {
1462                                 if (self.skin != stof(self.playerskin))
1463                                         self.skin = stof(self.playerskin);
1464                         }
1465                 }
1466                 // Savage: Check for nameless players
1467                 if (strlen(self.netname) < 1) {
1468                         self.netname = "Player";
1469                         stuffcmd(self, "name Player\n");
1470                 }
1471
1472                 GrapplingHookFrame();
1473
1474                 W_WeaponFrame();
1475
1476                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1477                 {
1478                         if (cvar("g_minstagib") && self.button3)
1479                         {
1480                                 if (self.jump_interval <= (time + 0.1))
1481                                 {
1482                                         self.jump_interval = time + 1;
1483                                         W_Laser_Attack();
1484                                 }
1485                         }
1486                         else if (self.viewzoom > 0.4)
1487                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1488                 }
1489                 else if (self.viewzoom < 1.0)
1490                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1491
1492
1493                 if (self.button2)
1494                         PlayerJump ();
1495                 else
1496                         self.flags = self.flags | FL_JUMPRELEASED;
1497
1498                 player_powerups();
1499                 player_regen();
1500                 player_anim();
1501
1502                 if (cvar("g_minstagib"))
1503                         minstagib_ammocheck();
1504
1505                 ctf_setstatus();
1506
1507                 //self.angles_y=self.v_angle_y + 90;   // temp
1508
1509                 if (self.waterlevel == 2)
1510                         CheckWaterJump ();
1511
1512                 //if (TetrisPreFrame()) return;
1513         } else if(gameover) {
1514                 if (intermission_running)
1515                         IntermissionThink ();   // otherwise a button could be missed between
1516                 return;
1517         } else if(self.classname == "observer") {
1518
1519                 if (self.flags & FL_JUMPRELEASED) {
1520                         if (self.button2 && self.version == cvar("gameversion")) {
1521                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1522                                         self.flags = self.flags & !FL_JUMPRELEASED;
1523                                         self.classname = "player";
1524                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1525                                                 JoinBestTeam(self, 0);
1526                                         if(cvar("g_campaign"))
1527                                                 campaign_bots_may_start = 1;
1528                                         PutClientInServer();
1529                                         if(self.flags & !FL_NOTARGET)
1530                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1531                                         centermsg_reset();
1532                                         return;
1533                                 } else {
1534                                         self.flags = self.flags & !FL_JUMPRELEASED;
1535                                         stuffcmd(self,"menu_showteamselect\n");
1536                                         return;
1537                                 }
1538                         } else if(self.button0 && self.version == cvar("gameversion")) {
1539                                 self.flags = self.flags & !FL_JUMPRELEASED;
1540                                 if(SpectateNext() == 1) {
1541                                         self.classname = "spectator";
1542                                 }
1543                         }
1544                 } else {
1545                         if (!(self.button0 || self.button2)) {
1546                                 self.flags = self.flags | FL_JUMPRELEASED;
1547                         }
1548                 }
1549                 PrintWelcomeMessage(self);
1550         } else if(self.classname == "spectator") {
1551                 if (self.flags & FL_JUMPRELEASED) {
1552                         if (self.button2 && self.version == cvar("gameversion")) {
1553                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1554                                         self.flags = self.flags & !FL_JUMPRELEASED;
1555                                         self.classname = "player";
1556                                         if(!cvar("g_lms"))
1557                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1558
1559                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1560                                                 JoinBestTeam(self, 0);
1561                                         if(cvar("g_campaign"))
1562                                                 campaign_bots_may_start = 1;
1563                                         PutClientInServer();
1564                                         centermsg_reset();
1565                                         return;
1566                                 } else {
1567                                         self.flags = self.flags & !FL_JUMPRELEASED;
1568                                         stuffcmd(self,"menu_showteamselect\n");
1569                                         return;
1570                                 }
1571                         } else if(self.button0) {
1572                                 self.flags = self.flags & !FL_JUMPRELEASED;
1573                                 if(SpectateNext() == 1) {
1574                                         self.classname = "spectator";
1575                                 } else {
1576                                         self.classname = "observer";
1577                                         PutClientInServer();
1578                                 }
1579                         } else if (self.button3) {
1580                                 self.flags = self.flags & !FL_JUMPRELEASED;
1581                                 self.classname = "observer";
1582                                 PutClientInServer();
1583                         } else {
1584                                 SpectateUpdate();
1585                         }
1586                 } else {
1587                         if (!(self.button0 || self.button3)) {
1588                                 self.flags = self.flags | FL_JUMPRELEASED;
1589                         }
1590                 }
1591                 PrintWelcomeMessage(self);
1592                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1593         }
1594 }
1595
1596
1597 /*
1598 =============
1599 PlayerPostThink
1600
1601 Called every frame for each client after the physics are run
1602 =============
1603 */
1604 void PlayerPostThink (void)
1605 {
1606         if(self.classname == "player") {
1607                 CheckRules_Player();
1608                 UpdateChatBubble();
1609                 UpdateTeamBubble();
1610                 if (self.deadflag == DEAD_NO)
1611                 if (self.impulse)
1612                         ImpulseCommands ();
1613                 if (intermission_running)
1614                         return;         // intermission or finale
1615
1616                 //PrintWelcomeMessage(self);
1617                 //if (TetrisPostFrame()) return;
1618         } else if (self.classname == "observer") {
1619                 //do nothing
1620         } else if (self.classname == "spectator") {
1621                 //do nothing
1622         }
1623         Arena_Warmup();
1624 }