data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void() spawnpoint_use =
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 float spawn_allbad;
  31 float spawn_allgood;
  32 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  33 {
  34         local entity spot, player, nextspot, previousspot, newfirstspot;
  35         local float pcount;
  36         spot = firstspot;
  37         newfirstspot = world;
  38         previousspot = world;
  39         spawn_allgood = TRUE;
  40         spawn_allbad = TRUE;
  41         while (spot)
  42         {
  43                 nextspot = spot.chain;
  44                 // count team mismatches as bad spots
  45
  46                 local float spotactive;
  47                 spotactive = 1;
  48
  49                 // filter out spots for assault
  50                 if(spot.target != "") {
  51                         local entity ent;
  52                         ent = find(world, targetname, spot.target);
  53                         while(ent) {
  54                                 if(ent.classname == "target_objective")
  55                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  56                                                 spotactive = 0;
  57                                 ent = find(ent, targetname, spot.target);
  58                         }
  59                 }
  60
  61                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  62                 {
  63                         pcount = 0;
  64                         player = playerlist;
  65                         while (player)
  66                         {
  67                                 if (player != self)
  68                                 if (vlen(player.origin - spot.origin) < mindist)
  69                                         pcount = pcount + 1;
  70                                 player = player.chain;
  71                         }
  72                         if (!pcount)
  73                         {
  74                                 spawn_allbad = FALSE;
  75                                 if (newfirstspot)
  76                                         previousspot.chain = spot;
  77                                 else
  78                                         newfirstspot = spot;
  79                                 previousspot = spot;
  80                                 spot.chain = world;
  81                         }
  82                         else
  83                                 spawn_allgood = FALSE;
  84                 }
  85                 spot = nextspot;
  86         }
  87         // if we couldn't find ANY good points, return world
  88         return newfirstspot;
  89 }
  90
  91 entity Spawn_RandomPoint(entity firstspot)
  92 {
  93         local entity spot;
  94         local float numspots;
  95         // count number of spots
  96         numspots = 0;
  97         spot = firstspot;
  98         while (spot)
  99         {
 100                 numspots = numspots + 1;
 101                 spot = spot.chain;
 102         }
 103         // pick a random one
 104         numspots = numspots * random();
 105         spot = firstspot;
 106         while (spot.chain && numspots >= 1)
 107         {
 108                 numspots = numspots - 1;
 109                 spot = spot.chain;
 110         }
 111         return spot;
 112 }
 113
 114 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 115 {
 116         local entity best, spot, player;
 117         local float bestrating, rating;
 118         best = world;
 119         bestrating = -1000000;
 120         spot = firstspot;
 121         while (spot)
 122         {
 123                 rating = 1000000000;
 124                 player = playerlist;
 125                 while (player)
 126                 {
 127                         if (player != self)
 128                                 rating = min(rating, vlen(player.origin - spot.origin));
 129                         player = player.chain;
 130                 }
 131                 rating = rating + random() * 16;
 132                 if (bestrating < rating)
 133                 {
 134                         best = spot;
 135                         bestrating = rating;
 136                 }
 137                 spot = spot.chain;
 138         }
 139         return best;
 140 }
 141
 142 /*
 143 =============
 144 SelectSpawnPoint
 145
 146 Finds a point to respawn
 147 =============
 148 */
 149 entity SelectSpawnPoint (float anypoint)
 150 {
 151         local float teamcheck;
 152         local entity firstspot_new;
 153         local entity spot, firstspot, playerlist;
 154
 155         spot = find (world, classname, "testplayerstart");
 156         if (spot)
 157                 return spot;
 158
 159         teamcheck = 0;
 160
 161         if(!anypoint && have_team_spawns)
 162                 teamcheck = self.team;
 163
 164         // get the list of players
 165         playerlist = findchain(classname, "player");
 166         // get the entire list of spots
 167         firstspot = findchain(classname, "info_player_deathmatch");
 168         // filter out the bad ones
 169         // (note this returns the original list if none survived)
 170         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 171         if(!firstspot_new)
 172                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 173         firstspot = firstspot_new;
 174
 175         // there is 50/50 chance of choosing a random spot or the furthest spot
 176         // (this means that roughly every other spawn will be furthest, so you
 177         // usually won't get fragged at spawn twice in a row)
 178         if (arena_roundbased)
 179         {
 180                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 181                 if(firstspot_new)
 182                         firstspot = firstspot_new;
 183                 spot = Spawn_RandomPoint(firstspot);
 184         }
 185         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 186                 spot = Spawn_RandomPoint(firstspot);
 187         else
 188                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 189
 190         if (!spot)
 191         {
 192                 if(cvar("spawn_debug"))
 193                         GotoNextMap();
 194                 else
 195                 {
 196                         if(some_spawn_has_been_used)
 197                                 return world; // team can't spawn any more, because of actions of other team
 198                         else
 199                                 error("Cannot find a spawn point - please fix the map!");
 200                 }
 201         }
 202
 203         return spot;
 204 }
 205
 206 /*
 207 =============
 208 CheckPlayerModel
 209
 210 Checks if the argument string can be a valid playermodel.
 211 Returns a valid one in doubt.
 212 =============
 213 */
 214 string FallbackPlayerModel = "models/player/marine.zym";
 215 string CheckPlayerModel(string plyermodel) {
 216         if(strlen(plyermodel) < 4)
 217                 return FallbackPlayerModel;
 218         if( substring(plyermodel,0,14) != "models/player/")
 219                 return FallbackPlayerModel;
 220         else if(cvar("sv_servermodelsonly"))
 221         {
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 223                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 224                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 225                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 226                         return FallbackPlayerModel;
 227                 if(!fexists(plyermodel))
 228                         return FallbackPlayerModel;
 229         }
 230         return plyermodel;
 231 }
 232
 233 /*
 234 =============
 235 Client_customizeentityforclient
 236
 237 LOD reduction
 238 =============
 239 */
 240 float Client_customizeentityforclient()
 241 {
 242 #ifdef ALLOW_VARIABLE_LOD
 243         // self: me
 244         // other: the player viewing me
 245         float distance;
 246         float f;
 247
 248         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 249                 return TRUE;
 250
 251         if(other.cvar_cl_playerdetailreduction <= 0)
 252         {
 253                 if(other.cvar_cl_playerdetailreduction <= -2)
 254                         self.modelindex = self.modelindex_lod2;
 255                 else if(other.cvar_cl_playerdetailreduction <= -1)
 256                         self.modelindex = self.modelindex_lod1;
 257                 else
 258                         self.modelindex = self.modelindex_lod0;
 259         }
 260         else
 261         {
 262                 distance = vlen(self.origin - other.origin);
 263                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 264                 if(f > 10000)
 265                         self.modelindex = self.modelindex_lod2;
 266                 else if(f > 5000)
 267                         self.modelindex = self.modelindex_lod1;
 268                 else
 269                         self.modelindex = self.modelindex_lod0;
 270         }
 271 #endif
 272
 273         return TRUE;
 274 }
 275
 276 void UpdatePlayerSounds();
 277 void setmodel_lod(entity e, string modelname)
 278 {
 279 #ifdef ALLOW_VARIABLE_LOD
 280         string s;
 281
 282         // FIXME: this only supports 3-letter extensions
 283         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 284         if(fexists(s))
 285         {
 286                 precache_model(s);
 287                 setmodel(e, s); // players have high precision
 288                 self.modelindex_lod1 = self.modelindex;
 289         }
 290         else
 291                 self.modelindex_lod1 = -1;
 292
 293         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 294         if(fexists(s))
 295         {
 296                 precache_model(s);
 297                 setmodel(e, s); // players have high precision
 298                 self.modelindex_lod2 = self.modelindex;
 299         }
 300         else
 301                 self.modelindex_lod2 = -1;
 302
 303         precache_model(modelname);
 304         setmodel(e, modelname); // players have high precision
 305         self.modelindex_lod0 = self.modelindex;
 306
 307         if(self.modelindex_lod1 < 0)
 308                 self.modelindex_lod1 = self.modelindex;
 309
 310         if(self.modelindex_lod2 < 0)
 311                 self.modelindex_lod2 = self.modelindex;
 312 #else
 313         precache_model(modelname);
 314         setmodel(e, modelname); // players have high precision
 315 #endif
 316         player_setupanimsformodel();
 317         UpdatePlayerSounds();
 318 }
 319
 320 /*
 321 =============
 322 PutObserverInServer
 323
 324 putting a client as observer in the server
 325 =============
 326 */
 327 void PutObserverInServer (void)
 328 {
 329         entity  spot;
 330         spot = SelectSpawnPoint (TRUE);
 331         if(!spot)
 332                 error("No spawnpoints for observers?!?\n");
 333         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 334
 335         if(clienttype(self) == CLIENTTYPE_REAL)
 336         {
 337                 msg_entity = self;
 338                 WriteByte(MSG_ONE, SVC_SETVIEW);
 339                 WriteEntity(MSG_ONE, self);
 340         }
 341
 342         DropAllRunes(self);
 343         kh_Key_DropAll(self, TRUE);
 344
 345         if(self.flagcarried)
 346                 DropFlag(self.flagcarried);
 347
 348         WaypointSprite_PlayerDead();
 349
 350         DistributeFragsAmongTeam(self, self.team, 1);
 351
 352         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 353                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 354         else if(self.killcount != -666)
 355                 bprint ("^4", self.netname, "^4 is spectating now\n");
 356
 357         self.spectatortime = time;
 358
 359         self.classname = "observer";
 360         self.health = -666;
 361         self.takedamage = DAMAGE_NO;
 362         self.solid = SOLID_NOT;
 363         self.movetype = MOVETYPE_NOCLIP;
 364         self.flags = FL_CLIENT | FL_NOTARGET;
 365         self.armorvalue = 666;
 366         self.effects = 0;
 367         self.armorvalue = cvar("g_balance_armor_start");
 368         self.pauserotarmor_finished = 0;
 369         self.pauserothealth_finished = 0;
 370         self.pauseregen_finished = 0;
 371         self.damageforcescale = 0;
 372         self.death_time = 0;
 373         self.dead_frame = 0;
 374         self.deaths = 0;
 375         self.alpha = 0;
 376         self.scale = 0;
 377         self.fade_time = 0;
 378         self.pain_frame = 0;
 379         self.pain_finished = 0;
 380         self.strength_finished = 0;
 381         self.invincible_finished = 0;
 382         self.pushltime = 0;
 383         self.think = SUB_Null;
 384         self.nextthink = 0;
 385         self.hook_time = 0;
 386         self.runes = 0;
 387         self.deadflag = DEAD_NO;
 388         self.angles = spot.angles;
 389         self.angles_z = 0;
 390         self.fixangle = TRUE;
 391         self.crouch = FALSE;
 392
 393         self.view_ofs = PL_VIEW_OFS;
 394         setorigin (self, spot.origin);
 395         setsize (self, '0 0 0', '0 0 0');
 396         self.oldorigin = self.origin;
 397         self.items = 0;
 398         self.model = "";
 399         self.modelindex = 0;
 400         self.weapon = 0;
 401         self.weaponmodel = "";
 402         self.weaponentity = world;
 403         self.killcount = -666;
 404         self.velocity = '0 0 0';
 405         self.avelocity = '0 0 0';
 406         self.punchangle = '0 0 0';
 407         self.punchvector = '0 0 0';
 408         self.oldvelocity = self.velocity;
 409         self.customizeentityforclient = Client_customizeentityforclient;
 410         self.viewzoom = 1;
 411         self.wantswelcomemessage = 1;
 412
 413         if(g_arena)
 414         {
 415                 if(self.frags != -2)
 416                 {
 417                         Spawnqueue_Insert(self);
 418                 }
 419                 else
 420                 {
 421                         Spawnqueue_Unmark(self);
 422                         Spawnqueue_Remove(self);
 423                 }
 424         }
 425         else if(!g_lms)
 426                 self.frags = -666;
 427 }
 428
 429 float RestrictSkin(float s)
 430 {
 431         if(!teams_matter)
 432                 return s;
 433         if(s == 6)
 434                 return 6;
 435         return mod(s, 3);
 436 }
 437
 438 void FixPlayermodel()
 439 {
 440         local string defaultmodel;
 441         local float defaultskin;
 442         local vector m1, m2;
 443
 444         defaultmodel = "";
 445
 446         if(cvar("sv_defaultcharacter") == 1) {
 447                 defaultskin = 0;
 448
 449                 if(teams_matter)
 450                 {
 451                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 452                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 453                 }
 454
 455                 if(defaultmodel == "")
 456                 {
 457                         defaultmodel = cvar_string("sv_defaultplayermodel");
 458                         defaultskin = cvar("sv_defaultplayerskin");
 459                 }
 460         }
 461
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != self.model)
 465                 {
 466                         m1 = self.mins;
 467                         m2 = self.maxs;
 468                         setmodel_lod (self, defaultmodel);
 469                         setsize (self, m1, m2);
 470                 }
 471
 472                 self.skin = defaultskin;
 473         } else {
 474                 if (self.playermodel != self.model)
 475                 {
 476                         self.playermodel = CheckPlayerModel(self.playermodel);
 477                         m1 = self.mins;
 478                         m2 = self.maxs;
 479                         setmodel_lod (self, self.playermodel);
 480                         setsize (self, m1, m2);
 481                 }
 482
 483                 self.skin = RestrictSkin(stof(self.playerskin));
 484         }
 485
 486         if(!teams_matter)
 487                 if(strlen(cvar_string("sv_defaultplayercolors")))
 488                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 489                                 setcolor(self, cvar("sv_defaultplayercolors"));
 490 }
 491
 492 /*
 493 =============
 494 PutClientInServer
 495
 496 Called when a client spawns in the server
 497 =============
 498 */
 499 void PutClientInServer (void)
 500 {
 501         if(clienttype(self) == CLIENTTYPE_BOT)
 502         {
 503                 self.classname = "player";
 504         }
 505         else if(clienttype(self) == CLIENTTYPE_REAL)
 506         {
 507                 msg_entity = self;
 508                 WriteByte(MSG_ONE, SVC_SETVIEW);
 509                 WriteEntity(MSG_ONE, self);
 510         }
 511
 512         // player is dead and becomes observer
 513         if(g_lms && self.frags < 1)
 514                 self.classname = "observer";
 515
 516         if(g_arena)
 517         if(!self.spawned)
 518                 self.classname = "observer";
 519
 520         if(self.classname == "player") {
 521                 entity  spot;
 522
 523                 spot = SelectSpawnPoint (FALSE);
 524                 if(!spot)
 525                 {
 526                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 527                         return; // spawn failed
 528                 }
 529
 530                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 531
 532                 self.classname = "player";
 533                 self.iscreature = TRUE;
 534                 self.movetype = MOVETYPE_WALK;
 535                 self.solid = SOLID_SLIDEBOX;
 536                 self.flags = FL_CLIENT;
 537                 self.takedamage = DAMAGE_AIM;
 538                 if(g_minstagib)
 539                         self.effects = EF_FULLBRIGHT;
 540                 else
 541                         self.effects = 0;
 542                 self.air_finished = time + 12;
 543                 self.dmg = 2;
 544
 545                 self.ammo_shells = start_ammo_shells;
 546                 self.ammo_nails = start_ammo_nails;
 547                 self.ammo_rockets = start_ammo_rockets;
 548                 self.ammo_cells = start_ammo_cells;
 549                 self.health = start_health;
 550                 self.armorvalue = start_armorvalue;
 551                 self.items = start_items;
 552                 self.switchweapon = start_switchweapon;
 553                 self.cnt = start_switchweapon;
 554                 self.weapon = 0;
 555                 self.jump_interval = time;
 556
 557                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 558                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 559                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 560                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 561                 //extend the pause of rotting if client was reset at the beginning of the countdown
 562                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 563                         self.spawnshieldtime += RESTART_COUNTDOWN;
 564                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 565                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 566                         self.pauseregen_finished += RESTART_COUNTDOWN;
 567                 }
 568                 self.damageforcescale = 2;
 569                 self.death_time = 0;
 570                 self.dead_frame = 0;
 571                 self.alpha = 0;
 572                 self.scale = 0;
 573                 self.fade_time = 0;
 574                 self.pain_frame = 0;
 575                 self.pain_finished = 0;
 576                 self.strength_finished = 0;
 577                 self.invincible_finished = 0;
 578                 self.pushltime = 0;
 579                 //self.speed_finished = 0;
 580                 //self.slowmo_finished = 0;
 581                 // players have no think function
 582                 self.think = SUB_Null;
 583                 self.nextthink = 0;
 584                 self.hook_time = 0;
 585
 586                 self.runes = 0;
 587
 588                 self.deadflag = DEAD_NO;
 589
 590                 self.angles = spot.angles;
 591
 592                 self.angles_z = 0; // never spawn tilted even if the spot says to
 593                 self.fixangle = TRUE; // turn this way immediately
 594                 self.velocity = '0 0 0';
 595                 self.avelocity = '0 0 0';
 596                 self.punchangle = '0 0 0';
 597                 self.punchvector = '0 0 0';
 598                 self.oldvelocity = self.velocity;
 599
 600                 self.viewzoom = 0.6;
 601                 self.has_zoomed = 0;
 602
 603                 self.customizeentityforclient = Client_customizeentityforclient;
 604
 605                 self.model = "";
 606                 FixPlayermodel();
 607
 608                 self.crouch = FALSE;
 609                 self.view_ofs = PL_VIEW_OFS;
 610                 setsize (self, PL_MIN, PL_MAX);
 611                 self.spawnorigin = spot.origin;
 612                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 613                 // don't reset back to last position, even if new position is stuck in solid
 614                 self.oldorigin = self.origin;
 615
 616                 if(g_arena)
 617                 {
 618                         Spawnqueue_Remove(self);
 619                         Spawnqueue_Mark(self);
 620                 }
 621
 622                 self.event_damage = PlayerDamage;
 623
 624                 self.bot_attack = TRUE;
 625
 626                 self.statdraintime = time + 5;
 627                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 628
 629                 if(self.killcount == -666) {
 630                         self.killcount = 0;
 631                         if(!g_arena)
 632                         if(!g_lms)
 633                                 self.frags = 0;
 634                 }
 635
 636                 self.cnt = WEP_LASER;
 637                 self.nixnex_lastchange_id = -1;
 638
 639                 CL_SpawnWeaponentity();
 640                 self.alpha = default_player_alpha;
 641                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 642                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 643
 644                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 645                 self.lms_traveled_distance = 0;
 646                 self.speedrunning = FALSE;
 647
 648                 if(cvar("spawn_debug"))
 649                 {
 650                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 651                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 652                 }
 653
 654                 //stuffcmd(self, "chase_active 0");
 655                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 656
 657                 if (cvar("g_spawnsound"))
 658                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 659
 660                 if(g_assault) {
 661                         if(self.team == assault_attacker_team)
 662                                 centerprint(self, "You are attacking!\n");
 663                         else
 664                                 centerprint(self, "You are defending!\n");
 665                 }
 666
 667         } else if(self.classname == "observer") {
 668                 PutObserverInServer ();
 669         }
 670 }
 671
 672 /*
 673 =============
 674 SetNewParms
 675 =============
 676 */
 677 void SetNewParms (void)
 678 {
 679
 680 }
 681
 682 /*
 683 =============
 684 SetChangeParms
 685 =============
 686 */
 687 void SetChangeParms (void)
 688 {
 689
 690 }
 691
 692 /*
 693 =============
 694 ClientKill
 695
 696 Called when a client types 'kill' in the console
 697 =============
 698 */
 699
 700 void ClientKill_Now_TeamChange()
 701 {
 702         if(self.killindicator_teamchange == -1)
 703         {
 704                 self.team = -1;
 705                 JoinBestTeam( self, FALSE, FALSE );
 706         }
 707         else
 708         {
 709                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 710         }
 711 }
 712
 713 void ClientKill_Now()
 714 {
 715         if(self.killindicator_teamchange)
 716                 ClientKill_Now_TeamChange();
 717
 718         // in any case:
 719         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 720 }
 721 void KillIndicator_Think()
 722 {
 723         if (!self.owner.modelindex)
 724         {
 725                 self.owner.killindicator = world;
 726                 remove(self);
 727                 return;
 728         }
 729
 730         if(self.cnt <= 0)
 731         {
 732                 self = self.owner;
 733                 ClientKill_Now(); // no oldself needed
 734                 return;
 735         }
 736         else
 737         {
 738                 if(self.cnt <= 10)
 739                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 740                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 741                 {
 742                         if(self.cnt <= 10)
 743                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 744                         if(self.owner.killindicator_teamchange)
 745                         {
 746                                 if(self.owner.killindicator_teamchange == -1)
 747                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 748                                 else
 749                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 750                         }
 751                         else
 752                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 753                 }
 754                 self.nextthink = time + 1;
 755                 self.cnt -= 1;
 756         }
 757 }
 758
 759 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 760 {
 761         float killtime;
 762         entity e;
 763         killtime = cvar("g_balance_kill_delay");
 764
 765         self.killindicator_teamchange = targetteam;
 766
 767         if(!self.killindicator)
 768         {
 769                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 770                 {
 771                         ClientKill_Now();
 772                 }
 773                 else
 774                 {
 775                         self.killindicator = spawn();
 776                         self.killindicator.owner = self;
 777                         self.killindicator.scale = 0.5;
 778                         setattachment(self.killindicator, self, "");
 779                         setorigin(self.killindicator, '0 0 52');
 780                         self.killindicator.think = KillIndicator_Think;
 781                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 782                         self.killindicator.cnt = ceil(killtime);
 783                         self.killindicator.count = bound(0, ceil(killtime), 10);
 784                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 785
 786                         for(e = world; (e = find(e, classname, "body")) != world; )
 787                         {
 788                                 if(e.enemy != self)
 789                                         continue;
 790                                 e.killindicator = spawn();
 791                                 e.killindicator.owner = e;
 792                                 e.killindicator.scale = 0.5;
 793                                 setattachment(e.killindicator, e, "");
 794                                 setorigin(e.killindicator, '0 0 52');
 795                                 e.killindicator.think = KillIndicator_Think;
 796                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 797                                 e.killindicator.cnt = ceil(killtime);
 798                         }
 799                         self.lip = 0;
 800                 }
 801         }
 802         if(self.killindicator)
 803         {
 804                 if(targetteam)
 805                         self.killindicator.colormod = TeamColor(targetteam);
 806                 else
 807                         self.killindicator.colormod = '0 0 0';
 808         }
 809 }
 810
 811 void ClientKill (void)
 812 {
 813         ClientKill_TeamChange(0);
 814 }
 815
 816 void DoTeamChange(float destteam)
 817 {
 818         float t, c0;
 819         if(!cvar("teamplay"))
 820         {
 821                 if(destteam >= 0)
 822                         SetPlayerColors(self, destteam);
 823                 return;
 824         }
 825         if(self.classname == "player")
 826         if(destteam == -1)
 827         {
 828                 CheckAllowedTeams(self);
 829                 t = FindSmallestTeam(self, TRUE);
 830                 switch(self.team)
 831                 {
 832                         case COLOR_TEAM1: c0 = c1; break;
 833                         case COLOR_TEAM2: c0 = c2; break;
 834                         case COLOR_TEAM3: c0 = c3; break;
 835                         case COLOR_TEAM4: c0 = c4; break;
 836                         default:          c0 = 999;
 837                 }
 838                 switch(t)
 839                 {
 840                         case 1:
 841                                 if(c0 > c1)
 842                                         destteam = COLOR_TEAM1;
 843                                 break;
 844                         case 2:
 845                                 if(c0 > c2)
 846                                         destteam = COLOR_TEAM2;
 847                                 break;
 848                         case 3:
 849                                 if(c0 > c3)
 850                                         destteam = COLOR_TEAM3;
 851                                 break;
 852                         case 4:
 853                                 if(c0 > c4)
 854                                         destteam = COLOR_TEAM4;
 855                                 break;
 856                 }
 857                 if(destteam == -1)
 858                         return;
 859         }
 860         if(destteam == self.team && !self.killindicator)
 861                 return;
 862         ClientKill_TeamChange(destteam);
 863 }
 864
 865 void FixClientCvars(entity e)
 866 {
 867         // send prediction settings to the client
 868         stuffcmd(e, "\nin_bindmap 0 0\n");
 869         /*
 870          * we no longer need to stuff this. Remove this comment block if you feel
 871          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 872         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 873         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 874         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 875         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 876         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 877         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 878         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 879         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 880         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 881         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 882         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 883         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 884         stuffcmd(e, "cl_movement_edgefriction 1\n");
 885          */
 886 }
 887
 888 /*
 889 =============
 890 ClientConnect
 891
 892 Called when a client connects to the server
 893 =============
 894 */
 895 string ColoredTeamName(float t);
 896 //void dom_player_join_team(entity pl);
 897 void ClientConnect (void)
 898 {
 899         local string s;
 900         float wep;
 901
 902         if(Ban_IsClientBanned(self))
 903         {
 904                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 905                 dropclient(self);
 906                 bprint(s);
 907                 return;
 908         }
 909
 910         self.classname = "player_joining";
 911         self.flags = self.flags | FL_CLIENT;
 912         self.version_nagtime = time + 10 + random() * 10;
 913
 914         if(player_count<0)
 915         {
 916                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 917                 player_count = 0;
 918         }
 919
 920         bot_clientconnect();
 921
 922         //if(g_domination)
 923         //      dom_player_join_team(self);
 924
 925         //JoinBestTeam(self, FALSE, FALSE);
 926
 927         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 928                 self.classname = "observer";
 929         } else {
 930                 self.classname = "player";
 931                 campaign_bots_may_start = 1;
 932         }
 933
 934         self.playerid = (playerid_last = playerid_last + 1);
 935         if(cvar("sv_eventlog"))
 936         {
 937                 if(clienttype(self) == CLIENTTYPE_REAL)
 938                         s = "player";
 939                 else
 940                         s = "bot";
 941                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 942                 s = strcat(":team:", ftos(self.playerid), ":");
 943                 s = strcat(s, ftos(self.team));
 944                 GameLogEcho(s, FALSE);
 945         }
 946         self.netname_previous = strzone(self.netname);
 947
 948         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 949
 950         bprint ("^4",self.netname);
 951         bprint ("^4 connected");
 952
 953         if(g_domination || g_ctf)
 954         {
 955                 bprint(" and joined the ");
 956                 bprint(ColoredTeamName(self.team));
 957         }
 958
 959         bprint("\n");
 960
 961         self.welcomemessage_time = 0;
 962
 963         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 964         // TODO: is this being used for anything else than cd tracks?
 965         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 966         //
 967         stuffcmd(self, "cl_particles_reloadeffects\n");
 968
 969         FixClientCvars(self);
 970
 971         // spawnfunc_waypoint sprites
 972         WaypointSprite_InitClient(self);
 973
 974         // Wazat's grappling hook
 975         SetGrappleHookBindings();
 976
 977         // get autoswitch state from player when he toggles it
 978         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
 979
 980         // get version info from player
 981         stuffcmd(self, "cmd clientversion $gameversion\n");
 982
 983         // send all weapon info strings
 984         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 985         wep = WEP_FIRST;
 986         while (wep <= WEP_LAST)
 987         {
 988                 weapon_action(wep, WR_REGISTER);
 989                 wep = wep + 1;
 990         }
 991
 992         // get other cvars from player
 993         GetCvars(0);
 994
 995         // set cvar for team scoreboard
 996         if (teams_matter)
 997         {
 998                 local float t;
 999                 t = cvar("teamplay");
1000                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1001                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1002         }
1003         else
1004                 stuffcmd(self, "set teamplay 0\n");
1005
1006         // notify about available teams
1007         if(teamplay)
1008         {
1009                 CheckAllowedTeams(self);
1010                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1011                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1012         }
1013         else
1014                 stuffcmd(self, "set _teams_available 0\n");
1015
1016         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1017
1018         if(g_lms)
1019         {
1020                 self.frags = LMS_NewPlayerLives();
1021                 if(!self.frags)
1022                         self.frags = -666;
1023         }
1024         else if(g_arena)
1025         {
1026                 self.classname = "observer";
1027                 Spawnqueue_Insert(self);
1028         }
1029
1030         bot_relinkplayerlist();
1031
1032         self.spectatortime = time;
1033         if(blockSpectators)
1034         {
1035                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1036         }
1037
1038         self.jointime = time;
1039         self.allowedTimeouts = cvar("sv_timeout_number");
1040 }
1041
1042 /*
1043 =============
1044 ClientDisconnect
1045
1046 Called when a client disconnects from the server
1047 =============
1048 */
1049 void(entity e) DropFlag;
1050 .entity chatbubbleentity;
1051 .entity teambubbleentity;
1052 void ClientDisconnect (void)
1053 {
1054         float save;
1055         if(cvar("sv_eventlog"))
1056                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1057         bprint ("^4",self.netname);
1058         bprint ("^4 disconnected\n");
1059
1060         if (self.chatbubbleentity)
1061         {
1062                 remove (self.chatbubbleentity);
1063                 self.chatbubbleentity = world;
1064         }
1065
1066         if (self.teambubbleentity)
1067         {
1068                 remove (self.teambubbleentity);
1069                 self.teambubbleentity = world;
1070         }
1071
1072         if (self.killindicator)
1073         {
1074                 remove (self.killindicator);
1075                 self.killindicator = world;
1076         }
1077
1078         WaypointSprite_PlayerGone();
1079
1080         DropAllRunes(self);
1081         kh_Key_DropAll(self, TRUE);
1082
1083         if(self.flagcarried)
1084                 DropFlag(self.flagcarried);
1085
1086         DistributeFragsAmongTeam(self, self.team, 1);
1087
1088         save = self.flags;
1089         self.flags = self.flags - (self.flags & FL_CLIENT);
1090         bot_relinkplayerlist();
1091         self.flags = save;
1092
1093         // remove laserdot
1094         if(self.weaponentity)
1095                 if(self.weaponentity.lasertarget)
1096                         remove(self.weaponentity.lasertarget);
1097
1098         if(g_arena)
1099         {
1100                 Spawnqueue_Unmark(self);
1101                 Spawnqueue_Remove(self);
1102         }
1103
1104         if(self.netname_previous)
1105                 strunzone(self.netname_previous);
1106
1107         // free cvars
1108         GetCvars(-1);
1109 }
1110
1111 .float buttonchat;
1112 void() ChatBubbleThink =
1113 {
1114         self.nextthink = time;
1115         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1116         {
1117                 self.owner.chatbubbleentity = world;
1118                 remove(self);
1119                 return;
1120         }
1121         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1122         if (self.owner.buttonchat && !self.owner.deadflag)
1123                 self.model = self.mdl;
1124         else
1125                 self.model = "";
1126 };
1127
1128 void() UpdateChatBubble =
1129 {
1130         if (!self.modelindex)
1131                 return;
1132         // spawn a chatbubble entity if needed
1133         if (!self.chatbubbleentity)
1134         {
1135                 self.chatbubbleentity = spawn();
1136                 self.chatbubbleentity.owner = self;
1137                 self.chatbubbleentity.exteriormodeltoclient = self;
1138                 self.chatbubbleentity.think = ChatBubbleThink;
1139                 self.chatbubbleentity.nextthink = time;
1140                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1141                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1142                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1143                 self.chatbubbleentity.model = "";
1144                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1145         }
1146 }
1147
1148
1149 void() TeamBubbleThink =
1150 {
1151         self.nextthink = time;
1152         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1153         {
1154                 self.owner.teambubbleentity = world;
1155                 remove(self);
1156                 return;
1157         }
1158 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1159         if (self.owner.buttonchat || self.owner.deadflag || self.owner.killindicator)
1160                 self.model = "";
1161         else
1162                 self.model = self.mdl;
1163
1164 };
1165
1166 float() TeamBubble_customizeentityforclient
1167 {
1168         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1169 }
1170
1171 void() UpdateTeamBubble =
1172 {
1173         if (!self.modelindex || !cvar("teamplay"))
1174                 return;
1175         // spawn a teambubble entity if needed
1176         if (!self.teambubbleentity && cvar("teamplay"))
1177         {
1178                 self.teambubbleentity = spawn();
1179                 self.teambubbleentity.owner = self;
1180                 self.teambubbleentity.exteriormodeltoclient = self;
1181                 self.teambubbleentity.think = TeamBubbleThink;
1182                 self.teambubbleentity.nextthink = time;
1183                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1184 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1185                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1186                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1187                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1188                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1189                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1190                 self.teambubbleentity.effects = EF_LOWPRECISION;
1191         }
1192 }
1193
1194 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1195 // added to the model skins
1196 /*void() UpdateColorModHack =
1197 {
1198         local float c;
1199         c = self.clientcolors & 15;
1200         // LordHavoc: only bothering to support white, green, red, yellow, blue
1201              if (teamplay == 0) self.colormod = '0 0 0';
1202         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1203         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1204         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1205         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1206         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1207         else self.colormod = '1 1 1';
1208 };*/
1209
1210 void respawn(void)
1211 {
1212         CopyBody(1);
1213         self.effects |= EF_NODRAW; // prevent another CopyBody
1214         PutClientInServer();
1215 }
1216
1217 /**
1218  * When sv_timeout is used this function returs strings like
1219  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1220  * Called by centerprint functions
1221  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1222  */
1223 string getTimeoutText(float addOneSecond) {
1224         if (!cvar("sv_timeout") || !timeoutStatus)
1225                 return "";
1226
1227         local string retStr;
1228         if (timeoutStatus == 1) {
1229                 if (addOneSecond == 1) {
1230                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1231                 }
1232                 else {
1233                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1234                 }
1235                 return retStr;
1236         }
1237         else if (timeoutStatus == 2) {
1238                 if (addOneSecond) {
1239                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1240                         //don't show messages like "Timeout ends in 0 seconds"...
1241                         if ((remainingTimeoutTime + 1) > 0)
1242                                 return retStr;
1243                         else
1244                                 return "";
1245                 }
1246                 else {
1247                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1248                         //don't show messages like "Timeout ends in 0 seconds"...
1249                         if (remainingTimeoutTime > 0)
1250                                 return retStr;
1251                         else
1252                                 return "";
1253                 }
1254         }
1255         else return "";
1256 }
1257
1258 void player_powerups (void)
1259 {
1260         if (g_minstagib)
1261         {
1262                 if (self.items & IT_STRENGTH)
1263                 {
1264                         if (time > self.strength_finished)
1265                         {
1266                                 if (g_minstagib_invis_alpha > 0)
1267                                 {
1268                                         self.alpha = default_player_alpha;
1269                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1270                                         self.effects = self.effects | EF_FULLBRIGHT;
1271                                 }
1272                                 else
1273                                 {
1274                                         self.effects -= self.effects & EF_NODRAW;
1275                                 }
1276                                 self.items = self.items - (self.items & IT_STRENGTH);
1277                                 sprint(self, "^3Invisibility has worn off\n");
1278                         }
1279                 }
1280                 else
1281                 {
1282                         if (time < self.strength_finished)
1283                         {
1284                                 if (g_minstagib_invis_alpha > 0)
1285                                 {
1286                                         self.alpha = g_minstagib_invis_alpha;
1287                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1288                                         self.effects -= self.effects & EF_FULLBRIGHT;
1289                                 }
1290                                 else
1291                                 {
1292                                         self.effects = self.effects | EF_NODRAW;
1293                                 }
1294                                 self.items = self.items | IT_STRENGTH;
1295                                 sprint(self, "^3You are invisible\n");
1296                         }
1297                 }
1298
1299                 if (self.items & IT_INVINCIBLE)
1300                 {
1301                         if (time > self.invincible_finished)
1302                         {
1303                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1304                                 sprint(self, "^3Speed has worn off\n");
1305                         }
1306                 }
1307                 else
1308                 {
1309                         if (time < self.invincible_finished)
1310                         {
1311                                 self.items = self.items | IT_INVINCIBLE;
1312                                 sprint(self, "^3You are on speed\n");
1313                         }
1314                 }
1315                 return;
1316         }
1317
1318         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1319         if (self.items & IT_STRENGTH)
1320         {
1321                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1322                 if (time > self.strength_finished)
1323                 {
1324                         self.items = self.items - (self.items & IT_STRENGTH);
1325                         sprint(self, "^3Strength has worn off\n");
1326                 }
1327         }
1328         else
1329         {
1330                 if (time < self.strength_finished)
1331                 {
1332                         self.items = self.items | IT_STRENGTH;
1333                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1334                 }
1335         }
1336         if (self.items & IT_INVINCIBLE)
1337         {
1338                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1339                 if (time > self.invincible_finished)
1340                 {
1341                         self.items = self.items - (self.items & IT_INVINCIBLE);
1342                         sprint(self, "^3Shield has worn off\n");
1343                 }
1344         }
1345         else
1346         {
1347                 if (time < self.invincible_finished)
1348                 {
1349                         self.items = self.items | IT_INVINCIBLE;
1350                         sprint(self, "^3Shield surrounds you\n");
1351                 }
1352         }
1353
1354         if (cvar("g_fullbrightplayers"))
1355                 self.effects = self.effects | EF_FULLBRIGHT;
1356
1357         // midair gamemode: damage only while in the air
1358         // if in midair mode, being on ground grants temporary invulnerability
1359         // (this is so that multishot weapon don't clear the ground flag on the
1360         // first damage in the frame, leaving the player vulnerable to the
1361         // remaining hits in the same frame)
1362         if (self.flags & FL_ONGROUND)
1363         if (g_midair)
1364                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1365
1366         if (time < self.spawnshieldtime)
1367                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1368 }
1369
1370 float CalcRegen(float current, float stable, float regenfactor)
1371 {
1372         if(current > stable)
1373                 return current;
1374         else if(current > stable - 0.25) // when close enough, "snap"
1375                 return stable;
1376         else
1377                 return min(stable, current + (stable - current) * regenfactor * frametime);
1378 }
1379
1380 void player_regen (void)
1381 {
1382         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1383         maxh = cvar("g_balance_health_stable");
1384         maxa = cvar("g_balance_armor_stable");
1385         limith = cvar("g_balance_health_limit");
1386         limita = cvar("g_balance_armor_limit");
1387
1388         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1389                 return;
1390
1391         max_mod = regen_mod = rot_mod = limit_mod = 1;
1392
1393         if (self.runes & RUNE_REGEN)
1394         {
1395                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1396                 {
1397                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1398                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1399                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1400                 }
1401                 else
1402                 {
1403                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1404                         max_mod = cvar("g_balance_rune_regen_hpmod");
1405                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1406                 }
1407         }
1408         else if (self.runes & CURSE_VENOM)
1409         {
1410                 max_mod = cvar("g_balance_curse_venom_hpmod");
1411                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1412                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1413                 else
1414                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1415                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1416                 //if (!self.runes & RUNE_REGEN)
1417                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1418         }
1419         maxh = maxh * max_mod;
1420         //maxa = maxa * max_mod;
1421         limith = limith * limit_mod;
1422         limita = limita * limit_mod;
1423
1424         if (self.armorvalue > maxa)
1425         {
1426                 if (time > self.pauserotarmor_finished)
1427                 {
1428                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1429                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1430                 }
1431         }
1432         else if (self.armorvalue < maxa)
1433         {
1434                 if (time > self.pauseregen_finished)
1435                 {
1436                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1437                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1438                 }
1439         }
1440         if (self.health > maxh)
1441         {
1442                 if (time > self.pauserothealth_finished)
1443                 {
1444                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1445                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1446                 }
1447         }
1448         else if (self.health < maxh)
1449         {
1450                 if (time > self.pauseregen_finished)
1451                 {
1452                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1453                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1454                 }
1455         }
1456
1457         if (self.health > limith)
1458                 self.health = limith;
1459         if (self.armorvalue > limita)
1460                 self.armorvalue = limita;
1461
1462         // if player rotted to death...  die!
1463         if(self.health < 1)
1464                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1465 }
1466
1467 /*
1468 ======================
1469 spectate mode routines
1470 ======================
1471 */
1472 void SpectateCopy(entity spectatee) {
1473         self.armortype = spectatee.armortype;
1474         self.armorvalue = spectatee.armorvalue;
1475         self.currentammo = spectatee.currentammo;
1476         self.effects = spectatee.effects;
1477         self.health = spectatee.health;
1478         self.impulse = 0;
1479         self.items = spectatee.items;
1480         self.punchangle = spectatee.punchangle;
1481         self.view_ofs = spectatee.view_ofs;
1482         self.v_angle = spectatee.v_angle;
1483         self.viewzoom = spectatee.viewzoom;
1484         self.velocity = spectatee.velocity;
1485         self.dmg_take = spectatee.dmg_take;
1486         self.dmg_save = spectatee.dmg_save;
1487         self.dmg_inflictor = spectatee.dmg_inflictor;
1488         self.angles = spectatee.v_angle;
1489         self.fixangle = TRUE;
1490         setorigin(self, spectatee.origin);
1491         setsize(self, spectatee.mins, spectatee.maxs);
1492 }
1493
1494 float SpectateUpdate() {
1495         if(!self.enemy)
1496                 return 0;
1497
1498         if (self == self.enemy)
1499                 return 0;
1500
1501         if(self.enemy.flags & FL_NOTARGET)
1502                 return 0;
1503
1504         SpectateCopy(self.enemy);
1505
1506         return 1;
1507 }
1508
1509 float SpectateNext() {
1510         other = find(self.enemy, classname, "player");
1511         if (!other) {
1512                 other = find(other, classname, "player");
1513         }
1514         if (other) {
1515                 self.enemy = other;
1516         }
1517         if(self.enemy.classname == "player") {
1518                 msg_entity = self;
1519                 WriteByte(MSG_ONE, SVC_SETVIEW);
1520                 WriteEntity(MSG_ONE, self.enemy);
1521                 self.wantswelcomemessage = 1;
1522                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1523                 if(!SpectateUpdate())
1524                         PutObserverInServer();
1525                 return 1;
1526         } else {
1527                 return 0;
1528         }
1529 }
1530
1531 /*
1532 =============
1533 ShowRespawnCountdown()
1534
1535 Update a respawn countdown display.
1536 =============
1537 */
1538 void ShowRespawnCountdown()
1539 {
1540         float number;
1541         if(self.deadflag == DEAD_NO) // just respawned?
1542                 return;
1543         else
1544         {
1545                 number = ceil(self.death_time - time);
1546                 if(number <= 0)
1547                         return;
1548                 if(number <= self.respawn_countdown)
1549                 {
1550                         self.respawn_countdown = number - 1;
1551                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1552                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1553                 }
1554         }
1555 }
1556
1557 void LeaveSpectatorMode()
1558 {
1559         if(isJoinAllowed()) {
1560                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1561                         self.classname = "player";
1562                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1563                                 JoinBestTeam(self, FALSE, TRUE);
1564                         if(cvar("g_campaign"))
1565                                 campaign_bots_may_start = 1;
1566                         PutClientInServer();
1567                         if(!(self.flags & FL_NOTARGET))
1568                                 bprint ("^4", self.netname, "^4 is playing now\n");
1569                         centerprint(self,"");
1570                         return;
1571                 } else {
1572                         stuffcmd(self,"menu_showteamselect\n");
1573                         return;
1574                 }
1575         }
1576         else {
1577                 //player may not join because of g_maxplayers is set
1578                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1579         }
1580 }
1581
1582 /**
1583  * Determines whether the player is allowed to join. This depends on cvar
1584  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1585  * it checks whether the number of currently playing players exceeds g_maxplayers.
1586  * @return bool TRUE if the player is allowed to join, false otherwise
1587  */
1588 float isJoinAllowed() {
1589         if (!cvar("g_maxplayers"))
1590                 return TRUE;
1591
1592         local entity e;
1593         local float currentlyPlaying;
1594         FOR_EACH_REALPLAYER(e) {
1595                 if(e.classname == "player")
1596                         currentlyPlaying += 1;
1597         }
1598         if(currentlyPlaying < cvar("g_maxplayers"))
1599                 return TRUE;
1600
1601         return FALSE;
1602 }
1603
1604 /**
1605  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1606  * g_maxplayers_spectator_blocktime seconds
1607  */
1608 void checkSpectatorBlock() {
1609         if(self.classname == "spectator" || self.classname == "observer") {
1610                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1611                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1612                         dropclient(self);
1613                 }
1614         }
1615 }
1616
1617 float vercmp_recursive(string v1, string v2)
1618 {
1619         float dot1, dot2;
1620         string s1, s2;
1621         float r;
1622
1623         dot1 = strstrofs(v1, ".", 0);
1624         dot2 = strstrofs(v2, ".", 0);
1625         if(dot1 == -1)
1626                 s1 = v1;
1627         else
1628                 s1 = substring(v1, 0, dot1);
1629         if(dot2 == -1)
1630                 s2 = v2;
1631         else
1632                 s2 = substring(v2, 0, dot2);
1633
1634         r = stof(s1) - stof(s2);
1635         if(r != 0)
1636                 return r;
1637
1638         r = strcasecmp(s1, s2);
1639         if(r != 0)
1640                 return r;
1641
1642         if(dot1 == -1)
1643                 if(dot2 == -1)
1644                         return 0;
1645                 else
1646                         return -1;
1647         else
1648                 if(dot2 == -1)
1649                         return 1;
1650                 else
1651                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1652 }
1653
1654 float vercmp(string v1, string v2)
1655 {
1656         if(strcasecmp(v1, v2) == 0) // early out check
1657                 return 0;
1658         return vercmp_recursive(v1, v2);
1659 }
1660
1661 void ObserverThink()
1662 {
1663         if (self.flags & FL_JUMPRELEASED) {
1664                 if (self.button2 && self.version == cvar("gameversion")) {
1665                         self.welcomemessage_time = 0;
1666                         self.flags = self.flags - FL_JUMPRELEASED;
1667                         LeaveSpectatorMode();
1668                         return;
1669                 } else if(self.button0 && self.version == cvar("gameversion")) {
1670                         self.welcomemessage_time = 0;
1671                         self.flags = self.flags - FL_JUMPRELEASED;
1672                         if(SpectateNext() == 1) {
1673                                 self.classname = "spectator";
1674                         }
1675                 }
1676         } else {
1677                 if (!(self.button0 || self.button2)) {
1678                         self.flags = self.flags | FL_JUMPRELEASED;
1679                 }
1680         }
1681         if(self.button4)
1682                 self.wantswelcomemessage = 0;
1683         if(self.wantswelcomemessage)
1684                 PrintWelcomeMessage(self);
1685 }
1686
1687 void SpectatorThink()
1688 {
1689         if (self.flags & FL_JUMPRELEASED) {
1690                 if (self.button2 && self.version == cvar("gameversion")) {
1691                         self.welcomemessage_time = 0;
1692                         self.flags = self.flags - FL_JUMPRELEASED;
1693                         LeaveSpectatorMode();
1694                         return;
1695                 } else if(self.button0) {
1696                         self.welcomemessage_time = 0;
1697                         self.flags = self.flags - FL_JUMPRELEASED;
1698                         if(SpectateNext() == 1) {
1699                                 self.classname = "spectator";
1700                         } else {
1701                                 self.classname = "observer";
1702                                 PutClientInServer();
1703                         }
1704                 } else if (self.button3) {
1705                         self.welcomemessage_time = 0;
1706                         self.flags = self.flags - FL_JUMPRELEASED;
1707                         self.classname = "observer";
1708                         PutClientInServer();
1709                 } else {
1710                         if(!SpectateUpdate())
1711                                 PutObserverInServer();
1712                 }
1713         } else {
1714                 if (!(self.button0 || self.button3)) {
1715                         self.flags = self.flags | FL_JUMPRELEASED;
1716                 }
1717         }
1718         if(self.button4)
1719                 self.wantswelcomemessage = 0;
1720         if(self.wantswelcomemessage)
1721                 PrintWelcomeMessage(self);
1722         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1723 }
1724
1725 /*
1726 =============
1727 PlayerPreThink
1728
1729 Called every frame for each client before the physics are run
1730 =============
1731 */
1732 void() ctf_setstatus;
1733 .float vote_nagtime;
1734 void PlayerPreThink (void)
1735 {
1736         if(blockSpectators)
1737                 checkSpectatorBlock();
1738
1739         if(self.netname_previous != self.netname)
1740         {
1741                 if(cvar("sv_eventlog"))
1742                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1743                 if(self.netname_previous)
1744                         strunzone(self.netname_previous);
1745                 self.netname_previous = strzone(self.netname);
1746         }
1747
1748         // version nagging
1749         if(self.version_nagtime)
1750                 if(self.cvar_g_nexuizversion)
1751                         if(time > self.version_nagtime)
1752                         {
1753                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1754                                 {
1755                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1756                                         {
1757                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1758                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1759                                         }
1760                                         else
1761                                         {
1762                                                 float r;
1763                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1764                                                 if(r < 0)
1765                                                 {
1766                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1767                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1768                                                 }
1769                                                 else if(r > 0)
1770                                                 {
1771                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1772                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1773                                                 }
1774                                         }
1775                                 }
1776                                 self.version_nagtime = 0;
1777                         }
1778
1779         // vote nagging
1780         if(self.cvar_scr_centertime)
1781                 if(time > self.vote_nagtime)
1782                 {
1783                         VoteNag();
1784                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1785                 }
1786
1787         // GOD MODE info
1788         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1789         {
1790                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1791                 self.max_armorvalue = 0;
1792         }
1793
1794         if(frametime)
1795                 antilag_record(self);
1796
1797         if(self.classname == "player") {
1798 //              if(self.netname == "Wazat")
1799 //                      bprint(self.classname, "\n");
1800
1801                 CheckRules_Player();
1802
1803                 if(self.button7)
1804                         PrintWelcomeMessage(self);
1805
1806                 if(g_lms || !cvar("sv_spectate"))
1807                 if((time - self.jointime) <= cvar("welcome_message_time"))
1808                         PrintWelcomeMessage(self);
1809
1810                 if (intermission_running)
1811                 {
1812                         IntermissionThink ();   // otherwise a button could be missed between
1813                         return;                                 // the think tics
1814                 }
1815
1816                 if(self.teleport_time)
1817                 if(time > self.teleport_time)
1818                 {
1819                         self.teleport_time = 0;
1820                         self.effects = self.effects - (self.effects & EF_NODRAW);
1821                         if(self.weaponentity)
1822                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1823                 }
1824
1825                 Nixnex_GiveCurrentWeapon();
1826
1827                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1828                         UpdateSelectedPlayer();
1829
1830                 //don't allow the player to turn around while game is paused!
1831                 if(timeoutStatus == 2) {
1832                         self.v_angle = self.lastV_angle;
1833                         self.angles = self.lastV_angle;
1834                         self.fixangle = TRUE;
1835                 }
1836
1837                 if (self.deadflag != DEAD_NO)
1838                 {
1839                         float button_pressed, force_respawn;
1840                         player_anim();
1841                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1842                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1843                         if (self.deadflag == DEAD_DYING)
1844                         {
1845                                 if(force_respawn)
1846                                         self.deadflag = DEAD_RESPAWNING;
1847                                 else if(!button_pressed)
1848                                         self.deadflag = DEAD_DEAD;
1849                         }
1850                         else if (self.deadflag == DEAD_DEAD)
1851                         {
1852                                 if(button_pressed)
1853                                         self.deadflag = DEAD_RESPAWNABLE;
1854                         }
1855                         else if (self.deadflag == DEAD_RESPAWNABLE)
1856                         {
1857                                 if(!button_pressed)
1858                                         self.deadflag = DEAD_RESPAWNING;
1859                         }
1860                         else if (self.deadflag == DEAD_RESPAWNING)
1861                         {
1862                                 if(time > self.death_time)
1863                                 {
1864                                         self.death_time = time + 1; // only retry once a second
1865                                         respawn();
1866                                 }
1867                         }
1868                         ShowRespawnCountdown();
1869                         return;
1870                 }
1871
1872                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1873                 {
1874                         vector dist;
1875
1876                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1877                         dist = self.oldorigin - self.origin;
1878                         dist_z = 0;
1879                         self.lms_traveled_distance += fabs(vlen(dist));
1880
1881                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1882                         {
1883                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1884                                 self.lms_traveled_distance = 0;
1885                         }
1886
1887                         if(time > self.lms_nextcheck)
1888                         {
1889                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1890                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1891                                 {
1892                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1893                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1894                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1895                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1896                                 }
1897                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1898                                 self.lms_traveled_distance = 0;
1899                         }
1900                 }
1901
1902                 if (self.button5 && !self.hook.state)
1903                 {
1904                         if (!self.crouch)
1905                         {
1906                                 self.crouch = TRUE;
1907                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1908                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1909                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1910                         }
1911                 }
1912                 else
1913                 {
1914                         if (self.crouch)
1915                         {
1916                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1917                                 if (!trace_startsolid)
1918                                 {
1919                                         self.crouch = FALSE;
1920                                         self.view_ofs = PL_VIEW_OFS;
1921                                         setsize (self, PL_MIN, PL_MAX);
1922                                 }
1923                         }
1924                 }
1925
1926                 FixPlayermodel();
1927
1928                 GrapplingHookFrame();
1929
1930                 W_WeaponFrame();
1931
1932                 {
1933                         float zoomfactor, zoomspeed, zoomdir;
1934                         zoomfactor = self.cvar_cl_zoomfactor;
1935                         if(zoomfactor < 1 || zoomfactor > 16)
1936                                 zoomfactor = 2.5;
1937                         zoomspeed = self.cvar_cl_zoomspeed;
1938                         if(zoomspeed >= 0) // < 0 is instant zoom
1939                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1940                                         zoomspeed = 3.5;
1941
1942                         zoomdir = self.button4;
1943                         if(self.button3)
1944                                 if(self.weapon == WEP_NEX)
1945                                         if(!g_minstagib)
1946                                                 zoomdir = 1;
1947
1948                         if(zoomdir)
1949                                 self.has_zoomed = 1;
1950
1951                         if(self.has_zoomed)
1952                         {
1953                                 if(zoomspeed <= 0) // instant zoom
1954                                 {
1955                                         if(zoomdir)
1956                                                 self.viewzoom = 1 / zoomfactor;
1957                                         else
1958                                                 self.viewzoom = 1;
1959                                 }
1960                                 else
1961                                 {
1962                                         // geometric zoom would be:
1963                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1964                                         // however, testing showed that arithmetic/harmonic zoom works better
1965                                         if(zoomdir)
1966                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1967                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1968                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1969                                         else
1970                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1971                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1972                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1973                                 }
1974                         }
1975                         else
1976                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1977                 }
1978
1979                 player_powerups();
1980                 player_regen();
1981                 player_anim();
1982
1983                 if (g_minstagib)
1984                         minstagib_ammocheck();
1985
1986                 ctf_setstatus();
1987                 kh_setstatus();
1988
1989                 //self.angles_y=self.v_angle_y + 90;   // temp
1990
1991                 //if (TetrisPreFrame()) return;
1992         } else if(gameover) {
1993                 if (intermission_running)
1994                         IntermissionThink ();   // otherwise a button could be missed between
1995                 return;
1996         } else if(self.classname == "observer") {
1997                 ObserverThink();
1998         } else if(self.classname == "spectator") {
1999                 SpectatorThink();
2000         }
2001 }
2002
2003
2004 /*
2005 =============
2006 PlayerPostThink
2007
2008 Called every frame for each client after the physics are run
2009 =============
2010 */
2011 void PlayerPostThink (void)
2012 {
2013         // Savage: Check for nameless players
2014         if (strlen(self.netname) < 1) {
2015                 self.netname = "Player";
2016                 stuffcmd(self, "seta _cl_name Player\n");
2017         }
2018
2019         if(self.classname == "player") {
2020                 CheckRules_Player();
2021                 UpdateChatBubble();
2022                 UpdateTeamBubble();
2023                 if (self.impulse)
2024                         ImpulseCommands();
2025                 if (intermission_running)
2026                         return;         // intermission or finale
2027
2028                 //PrintWelcomeMessage(self);
2029                 //if (TetrisPostFrame()) return;
2030
2031                 // restart countdown
2032                 if (restart_countdown) {
2033                         if(time < restart_countdown) {
2034                                 if (!cvar("sv_ready_restart_after_countdown"))
2035                                 {
2036                                         self.movetype = MOVETYPE_NONE;
2037                                         self.velocity = '0 0 0';
2038                                         self.avelocity = '0 0 0';
2039                                         self.movement = '0 0 0';
2040                                 }
2041                         }
2042                         else
2043                         {
2044                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2045                                 if (!cvar("sv_ready_restart_after_countdown"))
2046                                 {
2047                                         if(self.movetype == MOVETYPE_NONE)
2048                                         {
2049                                                 self.movetype = MOVETYPE_WALK;
2050                                         }
2051                                 }
2052                         }
2053                 }
2054
2055         } else if (self.classname == "observer") {
2056                 //do nothing
2057         } else if (self.classname == "spectator") {
2058                 //do nothing
2059         }
2060
2061         Arena_Warmup();
2062 }