data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         self.skin = stof(self.playerskin);
 468
 469                 }
 470
 471                 self.crouch = FALSE;
 472                 self.view_ofs = PL_VIEW_OFS;
 473                 setsize (self, PL_MIN, PL_MAX);
 474                 self.spawnorigin = spot.origin;
 475                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 476                 // don't reset back to last position, even if new position is stuck in solid
 477                 self.oldorigin = self.origin;
 478
 479                 if(cvar("g_lms"))
 480                 {
 481                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 482                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 483                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 484                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 485                         self.health = cvar("g_lms_start_health");
 486                         self.armorvalue = cvar("g_lms_start_armor");
 487                 }
 488                 else if (cvar("g_use_ammunition")) {
 489                         self.ammo_shells = cvar("g_start_ammo_shells");
 490                         self.ammo_nails = cvar("g_start_ammo_nails");
 491                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 492                         self.ammo_cells = cvar("g_start_ammo_cells");
 493                 } else {
 494                         self.ammo_shells = 999;
 495                         self.ammo_nails = 999;
 496                         self.ammo_rockets = 999;
 497                         self.ammo_cells = 999;
 498                 }
 499
 500                 self.items = 0;
 501                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_LASER;
 504                         self.switchweapon = WEP_LASER;
 505                 }
 506                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_SHOTGUN;
 509                         self.switchweapon = WEP_SHOTGUN;
 510                 }
 511                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_UZI;
 514                         self.switchweapon = WEP_UZI;
 515                 }
 516                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_GRENADE_LAUNCHER;
 519                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 520                 }
 521                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_ELECTRO;
 524                         self.switchweapon = WEP_ELECTRO;
 525                 }
 526                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_CRYLINK;
 529                         self.switchweapon = WEP_CRYLINK;
 530                 }
 531                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_NEX;
 534                         self.switchweapon = WEP_NEX;
 535                 }
 536                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_HAGAR;
 539                         self.switchweapon = WEP_HAGAR;
 540                 }
 541                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 542                 {
 543                         self.items = self.items | IT_ROCKET_LAUNCHER;
 544                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 545                 }
 546
 547                 if(cvar("g_instagib"))
 548                 {
 549                         self.items = IT_NEX;
 550                         self.switchweapon = WEP_NEX;
 551                         self.ammo_cells = 999;
 552                 }
 553
 554                 if(cvar("g_rocketarena"))
 555                 {
 556                         self.items = IT_ROCKET_LAUNCHER;
 557                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 558                         self.ammo_rockets = 999;
 559                 }
 560
 561                 if(cvar("g_nixnex"))
 562                 {
 563                         self.items = 0;
 564                         // will be done later
 565                 }
 566
 567                 if(cvar("g_minstagib"))
 568                 {
 569                         self.health = 100;
 570                         self.armorvalue = 0;
 571                         self.items = IT_NEX;
 572                         self.switchweapon = WEP_NEX;
 573                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 574                         self.extralives = 0;
 575                         self.jump_interval = time;
 576                 }
 577
 578                 if(cvar("g_arena"))
 579                 {
 580                         Spawnqueue_Remove(self);
 581                         Spawnqueue_Mark(self);
 582                 }
 583
 584                 self.event_damage = PlayerDamage;
 585
 586                 self.bot_attack = TRUE;
 587
 588                 self.statdraintime = time + 5;
 589                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 590
 591                 if(self.killcount == -666) {
 592                         self.killcount = 0;
 593                         if(!cvar("g_arena"))
 594                         if(!cvar("g_lms"))
 595                                 self.frags = 0;
 596                 }
 597
 598                 self.cnt = WEP_LASER;
 599                 self.nixnex_lastchange_id = -1;
 600
 601                 CL_SpawnWeaponentity();
 602                 self.alpha = default_player_alpha;
 603                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 604
 605                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 606                 self.lms_traveled_distance = 0;
 607
 608                 if(cvar("spawn_debug"))
 609                 {
 610                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 611                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 612                 }
 613
 614                 //stuffcmd(self, "chase_active 0");
 615                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 616         } else if(self.classname == "observer") {
 617                 PutObserverInServer ();
 618         }
 619 }
 620
 621 /*
 622 =============
 623 SetNewParms
 624 =============
 625 */
 626 void SetNewParms (void)
 627 {
 628
 629 }
 630
 631 /*
 632 =============
 633 SetChangeParms
 634 =============
 635 */
 636 void SetChangeParms (void)
 637 {
 638
 639 }
 640
 641 /*
 642 =============
 643 ClientKill
 644
 645 Called when a client types 'kill' in the console
 646 =============
 647 */
 648 void ClientKill (void)
 649 {
 650         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 651 }
 652
 653 /*
 654 =============
 655 ClientConnect
 656
 657 Called when a client connects to the server
 658 =============
 659 */
 660 string ColoredTeamName(float t);
 661 //void dom_player_join_team(entity pl);
 662 void ClientConnect (void)
 663 {
 664         local float fh;
 665         local string s;
 666
 667         self.classname = "player_joining";
 668         self.flags = self.flags | FL_CLIENT;
 669
 670         if(player_count<0) player_count = 0;
 671
 672         bot_clientconnect();
 673
 674         //if(cvar("g_domination"))
 675         //      dom_player_join_team(self);
 676
 677         //JoinBestTeam(self, FALSE);
 678
 679         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 680                 self.classname = "observer";
 681         } else {
 682                 self.classname = "player";
 683                 campaign_bots_may_start = 1;
 684         }
 685
 686         self.playerid = (playerid_last = playerid_last + 1);
 687         if(cvar("sv_eventlog"))
 688         {
 689                 if(clienttype(self) == CLIENTTYPE_REAL)
 690                         s = "player";
 691                 else
 692                         s = "bot";
 693                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 694                 s = strcat(":team:", ftos(self.playerid), ":");
 695                 s = strcat(s, ftos(self.team));
 696                 GameLogEcho(s, FALSE);
 697         }
 698
 699         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 700
 701         bprint ("^4",self.netname);
 702         bprint ("^4 connected");
 703
 704         if(cvar("g_domination") || cvar("g_ctf"))
 705         {
 706                 bprint(" and joined the ");
 707                 bprint(ColoredTeamName(self.team));
 708         }
 709
 710         bprint("\n");
 711
 712         self.welcomemessage_time = time + cvar("welcome_message_time");
 713         self.welcomemessage_time2 = 0;
 714
 715         /*
 716         // the client might not have his maps/%s.cfg file yet!
 717         // so send the one from the server...
 718         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 719         if(fh >= 0)
 720         {
 721                 while((s = fgets(fh)))
 722                         stuffcmd(self, strcat(s, "\n"));
 723                 fclose(fh);
 724         }
 725         // and then execute the client's so he can still override CD tracks
 726
 727         not needed any more: current map download system disconnects and reconnects
 728         after the download, and then the file will be there
 729         */
 730         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 731
 732         // TODO: is this being used for anything else than cd tracks?
 733         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 734
 735         // send prediction settings to the client
 736         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 737         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 738         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 739         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 741         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 742         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 743         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 744         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 745         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 746         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 747         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 748         // Wazat's grappling hook
 749         SetGrappleHookBindings();
 750
 751         // get autoswitch state from player
 752         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 753         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 754
 755         // get version info from player
 756         stuffcmd(self, "cmd clientversion $gameversion\n");
 757
 758         // get other cvars from player
 759         GetCvars(0);
 760
 761         // set cvar for team scoreboard
 762         if (teams_matter)
 763         {
 764                 local float t;
 765                 t = cvar("teamplay");
 766                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 767                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 768         }
 769         else
 770                 stuffcmd(self, strcat("set teamplay 0\n"));
 771
 772         if(cvar("g_lms"))
 773         {
 774                 self.frags = cvar("fraglimit");
 775                 // no fraglimit was set, so player gets 999 lives
 776                 if(self.frags < 1)
 777                         self.frags = 999;
 778
 779                 // disallow player to join after the worst player has lost g_lms_last_join lives
 780                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 781                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 782                 {
 783                         self.frags = -666;
 784                         lms_dead_count += 1;
 785                 }
 786                 else if(cvar("fraglimit") > lms_lowest_lives)
 787                 {
 788                         self.frags = lms_lowest_lives;
 789                 }
 790         }
 791         else if(cvar("g_arena"))
 792         {
 793                 self.classname = "observer";
 794                 Spawnqueue_Insert(self);
 795         }
 796
 797         bot_relinkplayerlist();
 798
 799         self.jointime = time;
 800 }
 801
 802 /*
 803 =============
 804 ClientDisconnect
 805
 806 Called when a client disconnects from the server
 807 =============
 808 */
 809 void(entity e) DropFlag;
 810 .entity chatbubbleentity;
 811 .entity teambubbleentity;
 812 void ClientDisconnect (void)
 813 {
 814         float save;
 815         if(cvar("sv_eventlog"))
 816                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 817         bprint ("^4",self.netname);
 818         bprint ("^4 disconnected\n");
 819
 820         if (self.chatbubbleentity)
 821         {
 822                 remove (self.chatbubbleentity);
 823                 self.chatbubbleentity = world;
 824         }
 825
 826         if (self.teambubbleentity)
 827         {
 828                 remove (self.teambubbleentity);
 829                 self.teambubbleentity = world;
 830         }
 831
 832         DropAllRunes(self);
 833
 834         if(self.flagcarried)
 835                 DropFlag(self.flagcarried);
 836
 837         DistributeFragsAmongTeam(self, self.team, 1);
 838
 839         save = self.flags;
 840         self.flags = self.flags - (self.flags & FL_CLIENT);
 841         bot_relinkplayerlist();
 842         self.flags = save;
 843
 844         // remove laserdot
 845         if(self.weaponentity)
 846                 if(self.weaponentity.lasertarget)
 847                         remove(self.weaponentity.lasertarget);
 848
 849         // player was dead, decrease dead count
 850         if(cvar("g_lms") && self.frags < 1)
 851                 lms_dead_count -= 1;
 852         else if(cvar("g_arena"))
 853         {
 854                 Spawnqueue_Unmark(self);
 855                 Spawnqueue_Remove(self);
 856         }
 857 }
 858
 859 .float buttonchat;
 860 void() ChatBubbleThink =
 861 {
 862         self.nextthink = time;
 863         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 864         {
 865                 self.owner.chatbubbleentity = world;
 866                 remove(self);
 867                 return;
 868         }
 869         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 870         if (self.owner.buttonchat && !self.owner.deadflag)
 871                 self.model = self.mdl;
 872         else
 873                 self.model = "";
 874 };
 875
 876 void() UpdateChatBubble =
 877 {
 878         if (!self.modelindex)
 879                 return;
 880         // spawn a chatbubble entity if needed
 881         if (!self.chatbubbleentity)
 882         {
 883                 self.chatbubbleentity = spawn();
 884                 self.chatbubbleentity.owner = self;
 885                 self.chatbubbleentity.exteriormodeltoclient = self;
 886                 self.chatbubbleentity.think = ChatBubbleThink;
 887                 self.chatbubbleentity.nextthink = time;
 888                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 889                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 890                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 891                 self.chatbubbleentity.model = "";
 892         }
 893 }
 894
 895
 896 void() TeamBubbleThink =
 897 {
 898         self.nextthink = time;
 899         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 900         {
 901                 self.owner.teambubbleentity = world;
 902                 remove(self);
 903                 return;
 904         }
 905 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 906         if (self.owner.buttonchat || self.owner.deadflag)
 907                 self.model = "";
 908         else
 909                 self.model = self.mdl;
 910
 911 };
 912
 913 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 914
 915 void() UpdateTeamBubble =
 916 {
 917         if (!self.modelindex || !cvar("teamplay"))
 918                 return;
 919         // spawn a teambubble entity if needed
 920         if (!self.teambubbleentity && cvar("teamplay"))
 921         {
 922                 self.teambubbleentity = spawn();
 923                 self.teambubbleentity.owner = self;
 924                 self.teambubbleentity.exteriormodeltoclient = self;
 925                 self.teambubbleentity.think = TeamBubbleThink;
 926                 self.teambubbleentity.nextthink = time;
 927                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 928 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 929                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 930                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 931                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 932                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 933                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 934         }
 935 }
 936
 937 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 938 // added to the model skins
 939 /*void() UpdateColorModHack =
 940 {
 941         local float c;
 942         c = self.clientcolors & 15;
 943         // LordHavoc: only bothering to support white, green, red, yellow, blue
 944              if (teamplay == 0) self.colormod = '0 0 0';
 945         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 946         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 947         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 948         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 949         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 950         else self.colormod = '1 1 1';
 951 };*/
 952
 953 /*
 954 =============
 955 PlayerJump
 956
 957 When you press the jump key
 958 =============
 959 */
 960 void PlayerJump (void)
 961 {
 962         float mjumpheight;
 963
 964         mjumpheight = cvar("g_balance_jumpheight");
 965         if (self.waterlevel >= 2)
 966         {
 967                 if (self.watertype == CONTENT_WATER)
 968                         self.velocity_z = 200;
 969                 else if (self.watertype == CONTENT_SLIME)
 970                         self.velocity_z = 80;
 971                 else
 972                         self.velocity_z = 50;
 973
 974                 return;
 975         }
 976
 977
 978         if (!(self.flags & FL_ONGROUND))
 979                 return;
 980
 981         if (!(self.flags & FL_JUMPRELEASED))
 982                 return;
 983
 984         if(cvar("g_runematch"))
 985         {
 986                 if(self.runes & RUNE_SPEED)
 987                 {
 988                         if(self.runes & CURSE_SLOW)
 989                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 990                         else
 991                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 992                 }
 993                 else if(self.runes & CURSE_SLOW)
 994                 {
 995                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 996                 }
 997         }
 998
 999         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
1000         {
1001                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1002         }
1003
1004         self.velocity_z = self.velocity_z + mjumpheight;
1005         self.oldvelocity_z = self.velocity_z;
1006
1007         self.flags = self.flags - FL_ONGROUND;
1008         self.flags = self.flags - FL_JUMPRELEASED;
1009 }
1010
1011 void() CheckWaterJump =
1012 {
1013         local vector start, end;
1014
1015 // check for a jump-out-of-water
1016         makevectors (self.angles);
1017         start = self.origin;
1018         start_z = start_z + 8;
1019         v_forward_z = 0;
1020         normalize(v_forward);
1021         end = start + v_forward*24;
1022         traceline (start, end, TRUE, self);
1023         if (trace_fraction < 1)
1024         {       // solid at waist
1025                 start_z = start_z + self.maxs_z - 8;
1026                 end = start + v_forward*24;
1027                 self.movedir = trace_plane_normal * -50;
1028                 traceline (start, end, TRUE, self);
1029                 if (trace_fraction == 1)
1030                 {       // open at eye level
1031                         self.flags = self.flags | FL_WATERJUMP;
1032                         self.velocity_z = 225;
1033                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1034                         self.teleport_time = time + 2;  // safety net
1035                         return;
1036                 }
1037         }
1038 };
1039
1040
1041 void respawn(void)
1042 {
1043         CopyBody(1);
1044         PutClientInServer();
1045 }
1046
1047 void player_powerups (void)
1048 {
1049         if (cvar("g_minstagib"))
1050         {
1051                 self.effects = EF_FULLBRIGHT;
1052                 if (self.items & IT_STRENGTH)
1053                 {
1054                         if (time > self.strength_finished)
1055                         {
1056                                 self.alpha = default_player_alpha;
1057                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1058                                 self.items = self.items - (self.items & IT_STRENGTH);
1059                                 sprint(self, "^3Invisibility has worn off\n");
1060                         }
1061                 }
1062                 else
1063                 {
1064                         if (time < self.strength_finished)
1065                         {
1066                                 self.alpha = cvar("g_minstagib_invis_alpha");
1067                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1068                                 self.items = self.items | IT_STRENGTH;
1069                                 sprint(self, "^3You are invisible\n");
1070                         }
1071                 }
1072
1073                 if (self.items & IT_INVINCIBLE)
1074                 {
1075                         if (time > self.invincible_finished)
1076                         {
1077                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1078                                 sprint(self, "^3Speed has worn off\n");
1079                         }
1080                 }
1081                 else
1082                 {
1083                         if (time < self.invincible_finished)
1084                         {
1085                                 self.items = self.items | IT_INVINCIBLE;
1086                                 sprint(self, "^3You are on speed\n");
1087                         }
1088                 }
1089                 return;
1090         }
1091
1092         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1093         if (self.items & IT_STRENGTH)
1094         {
1095                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1096                 if (time > self.strength_finished)
1097                 {
1098                         self.items = self.items - (self.items & IT_STRENGTH);
1099                         sprint(self, "^3Strength has worn off\n");
1100                 }
1101         }
1102         else
1103         {
1104                 if (time < self.strength_finished)
1105                 {
1106                         self.items = self.items | IT_STRENGTH;
1107                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1108                 }
1109         }
1110         if (self.items & IT_INVINCIBLE)
1111         {
1112                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1113                 if (time > self.invincible_finished)
1114                 {
1115                         self.items = self.items - (self.items & IT_INVINCIBLE);
1116                         sprint(self, "^3Shield has worn off\n");
1117                 }
1118         }
1119         else
1120         {
1121                 if (time < self.invincible_finished)
1122                 {
1123                         self.items = self.items | IT_INVINCIBLE;
1124                         sprint(self, "^3Shield surrounds you\n");
1125                 }
1126         }
1127
1128         if (cvar("g_fullbrightplayers"))
1129                 self.effects = self.effects | EF_FULLBRIGHT;
1130
1131         // midair gamemode: damage only while in the air
1132         // if in midair mode, being on ground grants temporary invulnerability
1133         // (this is so that multishot weapon don't clear the ground flag on the
1134         // first damage in the frame, leaving the player vulnerable to the
1135         // remaining hits in the same frame)
1136         if (self.flags & FL_ONGROUND)
1137         if (cvar("g_midair"))
1138                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1139
1140         if (time < self.spawnshieldtime)
1141                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1142 }
1143
1144 void player_regen (void)
1145 {
1146         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1147         maxh = cvar("g_balance_health_stable");
1148         maxa = cvar("g_balance_armor_stable");
1149         limith = cvar("g_balance_health_limit");
1150         limita = cvar("g_balance_armor_limit");
1151
1152         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1153                 return;
1154
1155         if(cvar("g_runematch"))
1156         {
1157                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1158                 if (self.runes & RUNE_REGEN)
1159                 {
1160                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1161                         {
1162                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1163                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1164                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1165                         }
1166                         else
1167                         {
1168                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1169                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1170                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1171                         }
1172                 }
1173                 else if (self.runes & CURSE_VENOM)
1174                 {
1175                         max_mod = cvar("g_balance_curse_venom_hpmod");
1176                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1177                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1178                         else
1179                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1180                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1181                         //if (!self.runes & RUNE_REGEN)
1182                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1183                 }
1184                 maxh = maxh * max_mod;
1185                 //maxa = maxa * max_mod;
1186
1187                 if (time > self.pauserotarmor_finished)
1188                 {
1189                         if (self.armorvalue > maxa)
1190                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1191                 }
1192                 if (time > self.pauserothealth_finished)
1193                 {
1194                         if (self.health > maxh)
1195                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1196                 }
1197                 if (time > self.pauseregen_finished)
1198                 {
1199                         if (self.health < maxh)
1200                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1201                         if (self.armorvalue < maxa)
1202                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1203                 }
1204         }
1205         else
1206         {
1207                 if (time > self.pauserothealth_finished)
1208                 if (self.health > maxh)
1209                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1210                 if (time > self.pauserotarmor_finished)
1211                 if (self.armorvalue > maxa)
1212                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1213                 if (time > self.pauseregen_finished)
1214                 {
1215                         if (self.health < maxh)
1216                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1217                         if (self.armorvalue < maxa)
1218                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1219                 }
1220         }
1221
1222         if (self.health > limith)
1223                 self.health = limith;
1224         if(self.health < 1)
1225                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1226         if (self.armorvalue > limita)
1227                 self.armorvalue = limita;
1228 }
1229
1230 /*
1231 ======================
1232 spectate mode routines
1233 ======================
1234 */
1235 void SpectateCopy(entity spectatee) {
1236         self.armortype = spectatee.armortype;
1237         self.armorvalue = spectatee.armorvalue;
1238         self.currentammo = spectatee.currentammo;
1239         self.effects = spectatee.effects;
1240         self.health = spectatee.health;
1241         self.impulse = 0;
1242         self.items = spectatee.items;
1243         self.punchangle = spectatee.punchangle;
1244         self.view_ofs = spectatee.view_ofs;
1245         self.v_angle = spectatee.v_angle;
1246         self.viewzoom = spectatee.viewzoom;
1247         setorigin(self, spectatee.origin);
1248         setsize(self, spectatee.mins, spectatee.maxs);
1249 }
1250
1251 void SpectateUpdate() {
1252         if(!self.enemy)
1253                         PutObserverInServer();
1254
1255         if (self != self.enemy) {
1256                 if(self.enemy.flags & FL_NOTARGET)
1257                         PutObserverInServer();
1258                 SpectateCopy(self.enemy);
1259                 self.dmg_take = self.enemy.dmg_take;
1260                 self.dmg_save = self.enemy.dmg_save;
1261                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1262                 self.fixangle = TRUE;
1263                 self.angles = self.enemy.v_angle;
1264                 //msg_entity = self;
1265                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1266                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1267                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1268                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1269         }
1270 }
1271
1272 float SpectateNext() {
1273         other = find(self.enemy, classname, "player");
1274         if (!other) {
1275                 other = find(other, classname, "player");
1276         }
1277         if (other) {
1278                 self.enemy = other;
1279         }
1280         if(self.enemy.classname == "player") {
1281                 msg_entity = self;
1282                 WriteByte(MSG_ONE, SVC_SETVIEW);
1283                 WriteEntity(MSG_ONE, self.enemy);
1284                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1285                 SpectateUpdate();
1286                 return 1;
1287         } else {
1288                 return 0;
1289         }
1290 }
1291
1292 /*
1293 =============
1294 PlayerPreThink
1295
1296 Called every frame for each client before the physics are run
1297 =============
1298 */
1299 void() ctf_setstatus;
1300 void PlayerPreThink (void)
1301 {
1302         if(self.classname == "player") {
1303                 local vector m1, m2;
1304
1305 //              if(self.netname == "Wazat")
1306 //                      bprint(strcat(self.classname, "\n"));
1307
1308                 CheckRules_Player();
1309
1310                 Nixnex_GiveCurrentWeapon();
1311
1312                 if(self.button7)
1313                         PrintWelcomeMessage(self);
1314
1315                 if(cvar("g_lms") || !cvar("sv_spectate"))
1316                 if((time - self.jointime) <= cvar("welcome_message_time"))
1317                         PrintWelcomeMessage(self);
1318
1319                 if (intermission_running)
1320                 {
1321                         IntermissionThink ();   // otherwise a button could be missed between
1322                         return;                                 // the think tics
1323                 }
1324
1325                 if (self.deadflag != DEAD_NO)
1326                 {
1327                         player_anim();
1328                         if (self.deadflag == DEAD_DYING)
1329                         {
1330                                 if (time > self.dead_time)
1331                                         self.deadflag = DEAD_DEAD;
1332                         }
1333                         else if (self.deadflag == DEAD_DEAD)
1334                         {
1335                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1336                                         self.deadflag = DEAD_RESPAWNABLE;
1337                                 else if (!self.button0 && !self.button2 && !self.button3)
1338                                         self.deadflag = DEAD_RESPAWNABLE;
1339                         }
1340                         else if (self.deadflag == DEAD_RESPAWNABLE)
1341                         {
1342                                 if (self.button0  ||
1343                                     self.button2  ||
1344                                     self.button3  ||
1345                                     self.button4  ||
1346                                     self.button5  ||
1347                                     self.button6  ||
1348                                     self.button7  ||
1349                                     self.button8  ||
1350                                     self.buttonuse ||
1351                                     cvar("g_lms") ||
1352                                     cvar("g_forced_respawn"))
1353                                         respawn();
1354                         }
1355                         return;
1356                 }
1357
1358                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1359                 {
1360                         vector dist;
1361
1362                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1363                         dist = self.oldorigin - self.origin;
1364                         dist_z = 0;
1365                         self.lms_traveled_distance += fabs(vlen(dist));
1366
1367                         if(cvar("g_campaign"))
1368                         if(!campaign_bots_may_start)
1369                         {
1370                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1371                                 self.lms_traveled_distance = 0;
1372                         }
1373
1374                         if(time > self.lms_nextcheck)
1375                         {
1376                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1377                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1378                                 {
1379                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1380                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1381                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1382                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1383                                 }
1384                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1385                                 self.lms_traveled_distance = 0;
1386                         }
1387                 }
1388
1389                 if (self.button5 && !self.hook.state)
1390                 {
1391                         if (!self.crouch)
1392                         {
1393                                 self.crouch = TRUE;
1394                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1395                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1396                         }
1397                 }
1398                 else
1399                 {
1400                         if (self.crouch)
1401                         {
1402                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1403                                 if (!trace_startsolid)
1404                                 {
1405                                         self.crouch = FALSE;
1406                                         self.view_ofs = PL_VIEW_OFS;
1407                                         setsize (self, PL_MIN, PL_MAX);
1408                                 }
1409                         }
1410                 }
1411
1412                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1413                         local string defaultmodel;
1414                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1415
1416                         if (defaultmodel != self.model)
1417                         {
1418                                 m1 = self.mins;
1419                                 m2 = self.maxs;
1420                                 setmodel_lod (self, defaultmodel);
1421                                 setsize (self, m1, m2);
1422                         }
1423
1424                         if (self.skin != cvar("sv_defaultplayerskin"))
1425                                 self.skin = cvar("sv_defaultplayerskin");
1426                 } else {
1427                         if (self.playermodel != self.model)
1428                         {
1429                                 self.playermodel = CheckPlayerModel(self.playermodel);
1430                                 m1 = self.mins;
1431                                 m2 = self.maxs;
1432                                 setmodel_lod (self, self.playermodel);
1433                                 setsize (self, m1, m2);
1434                         }
1435
1436                         if (self.skin != stof(self.playerskin))
1437                                 self.skin = stof(self.playerskin);
1438                 }
1439                 // Savage: Check for nameless players
1440                 if (strlen(self.netname) < 1) {
1441                         self.netname = "Player";
1442                         stuffcmd(self, "name Player\n");
1443                 }
1444
1445                 GrapplingHookFrame();
1446
1447                 W_WeaponFrame();
1448
1449                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1450                 {
1451                         if (cvar("g_minstagib") && self.button3)
1452                         {
1453                                 if (self.jump_interval <= (time + 0.1))
1454                                 {
1455                                         self.jump_interval = time + 1;
1456                                         W_Laser_Attack();
1457                                 }
1458                         }
1459                         else if (self.viewzoom > 0.4)
1460                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1461                 }
1462                 else if (self.viewzoom < 1.0)
1463                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1464
1465
1466                 if (self.button2)
1467                         PlayerJump ();
1468                 else
1469                         self.flags = self.flags | FL_JUMPRELEASED;
1470
1471                 player_powerups();
1472                 player_regen();
1473                 player_anim();
1474
1475                 if (cvar("g_minstagib"))
1476                         minstagib_ammocheck();
1477
1478                 ctf_setstatus();
1479
1480                 //self.angles_y=self.v_angle_y + 90;   // temp
1481
1482                 if (self.waterlevel == 2)
1483                         CheckWaterJump ();
1484
1485                 //if (TetrisPreFrame()) return;
1486         } else if(gameover) {
1487                 if (intermission_running)
1488                         IntermissionThink ();   // otherwise a button could be missed between
1489                 return;
1490         } else if(self.classname == "observer") {
1491
1492                 if (self.flags & FL_JUMPRELEASED) {
1493                         if (self.button2 && self.version == cvar("gameversion")) {
1494                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1495                                         self.flags = self.flags & !FL_JUMPRELEASED;
1496                                         self.classname = "player";
1497                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1498                                                 JoinBestTeam(self, 0);
1499                                         if(cvar("g_campaign"))
1500                                                 campaign_bots_may_start = 1;
1501                                         PutClientInServer();
1502                                         if(self.flags & !FL_NOTARGET)
1503                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1504                                         centermsg_reset();
1505                                         return;
1506                                 } else {
1507                                         self.flags = self.flags & !FL_JUMPRELEASED;
1508                                         stuffcmd(self,"menu_showteamselect\n");
1509                                         return;
1510                                 }
1511                         } else if(self.button0 && self.version == cvar("gameversion")) {
1512                                 self.flags = self.flags & !FL_JUMPRELEASED;
1513                                 if(SpectateNext() == 1) {
1514                                         self.classname = "spectator";
1515                                 }
1516                         }
1517                 } else {
1518                         if (!(self.button0 || self.button2)) {
1519                                 self.flags = self.flags | FL_JUMPRELEASED;
1520                         }
1521                 }
1522                 PrintWelcomeMessage(self);
1523         } else if(self.classname == "spectator") {
1524                 if (self.flags & FL_JUMPRELEASED) {
1525                         if (self.button2 && self.version == cvar("gameversion")) {
1526                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1527                                         self.flags = self.flags & !FL_JUMPRELEASED;
1528                                         self.classname = "player";
1529                                         if(!cvar("g_lms"))
1530                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1531
1532                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1533                                                 JoinBestTeam(self, 0);
1534                                         if(cvar("g_campaign"))
1535                                                 campaign_bots_may_start = 1;
1536                                         PutClientInServer();
1537                                         centermsg_reset();
1538                                         return;
1539                                 } else {
1540                                         self.flags = self.flags & !FL_JUMPRELEASED;
1541                                         stuffcmd(self,"menu_showteamselect\n");
1542                                         return;
1543                                 }
1544                         } else if(self.button0) {
1545                                 self.flags = self.flags & !FL_JUMPRELEASED;
1546                                 if(SpectateNext() == 1) {
1547                                         self.classname = "spectator";
1548                                 } else {
1549                                         self.classname = "observer";
1550                                         PutClientInServer();
1551                                 }
1552                         } else if (self.button3) {
1553                                 self.flags = self.flags & !FL_JUMPRELEASED;
1554                                 self.classname = "observer";
1555                                 PutClientInServer();
1556                         } else {
1557                                 SpectateUpdate();
1558                         }
1559                 } else {
1560                         if (!(self.button0 || self.button3)) {
1561                                 self.flags = self.flags | FL_JUMPRELEASED;
1562                         }
1563                 }
1564                 PrintWelcomeMessage(self);
1565                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1566         }
1567 }
1568
1569
1570 /*
1571 =============
1572 PlayerPostThink
1573
1574 Called every frame for each client after the physics are run
1575 =============
1576 */
1577 void PlayerPostThink (void)
1578 {
1579         if(self.classname == "player") {
1580                 CheckRules_Player();
1581                 UpdateChatBubble();
1582                 UpdateTeamBubble();
1583                 if (self.deadflag == DEAD_NO)
1584                 if (self.impulse)
1585                         ImpulseCommands ();
1586                 if (intermission_running)
1587                         return;         // intermission or finale
1588
1589                 //PrintWelcomeMessage(self);
1590                 //if (TetrisPostFrame()) return;
1591         } else if (self.classname == "observer") {
1592                 //do nothing
1593         } else if (self.classname == "spectator") {
1594                 //do nothing
1595         }
1596         Arena_Warmup();
1597 }