CMakeLists.txt

   1
   2 project(freespace2)
   3
   4 cmake_minimum_required(VERSION 2.8.6)
   5 cmake_policy(VERSION 2.8.6)
   6
   7 if(POLICY CMP0043)
   8   cmake_policy(SET CMP0043 OLD)
   9 endif()
  10
  11 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake")
  12
  13 include(CreateSourceGroups)
  14
  15
  16 # ##############################################################################
  17
  18 option(FS1 "Build original FreeSpace" OFF)
  19
  20 if(EMSCRIPTEN)
  21   # only build for demo with emscripten
  22   set(DEMO 1)
  23 else()
  24   option(DEMO "Create demo build" OFF)
  25 endif()
  26
  27 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  28   message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  29   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  30   # Set the possible values of build type for cmake-gui
  31   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "RelWithDebInfo")
  32 endif()
  33
  34
  35 if(FS1)
  36   add_definitions(-DMAKE_FS1)
  37
  38   if(DEMO)
  39     add_definitions(-DDEMO -DFS1_DEMO)
  40   endif()
  41 else()
  42   if(DEMO)
  43     add_definitions(-DFS2_DEMO)
  44   endif()
  45 endif()
  46
  47 # build everything by default
  48 set(GAME_ONLY)
  49
  50 if(DEMO)
  51   set(GAME_ONLY 1)
  52 endif()
  53
  54 if(EMSCRIPTEN)
  55   set(GAME_ONLY 1)  # don't build launcher or toolset
  56   add_definitions(-s USE_SDL=2)
  57   add_definitions(-s FULL_ES2=1)
  58
  59   set(CMAKE_EXECUTABLE_SUFFIX ".html")
  60 endif()
  61
  62 if(NOT EMSCRIPTEN)
  63   add_definitions(-DLEGACY_GL)
  64 endif()
  65
  66 if(NOT WIN32)
  67   set(PLATFORM_LIBRARIES "")
  68
  69   add_definitions(-DPLAT_UNIX)
  70   add_definitions(-Wall)
  71   add_definitions(-Wshadow)
  72 # add_definitions(-Wno-format-y2k)
  73 # add_definitions(-Wno-deprecated)
  74   add_definitions(-fsigned-char)
  75
  76   set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -DNDEBUG -DRELEASE_REAL -g -O2")
  77   set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} -DNDEBUG -DRELEASE_REAL -Os")
  78   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -DNDEBUG -DRELEASE_REAL -O3")
  79   set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -g3")
  80 else()
  81   set(SDL2DIR "${CMAKE_SOURCE_DIR}/../Support/SDL2" CACHE PATH "Path to SDL2")
  82   set(OPENALDIR "${CMAKE_SOURCE_DIR}/../Support/OpenAL" CACHE PATH "Path to OpenAL")
  83   set(LWSDIR "${CMAKE_SOURCE_DIR}/../Support/libwebsockets" CACHE PATH "Path to libwebsockets")
  84   set(WXWIDGETSDIR "${CMAKE_SOURCE_DIR}/../Support/wxWidgets" CACHE PATH "Path to wxWidgets")
  85   set(ANGLEDIR "${CMAKE_SOURCE_DIR}/../Support/ANGLE" CACHE PATH "Path to ANGLE")
  86
  87   set(PLATFORM_LIBRARIES
  88     ws2_32.lib
  89     ${ANGLEDIR}/lib/libEGL.lib
  90     ${ANGLEDIR}/lib/libGLESv2.lib
  91   )
  92
  93   add_definitions(/D _CRT_SECURE_NO_WARNINGS)
  94   add_definitions(/W4)
  95   add_definitions(/wd4100) # unreferenced parameter
  96   add_definitions(/wd4127) # conditional expression is constant: do { } while (0)
  97   add_definitions(/wd4996) # deprecated functions: fopen, fileno, ...
  98 endif()
  99
 100 set(BIN_SUFFIX "")
 101
 102 if(NOT FS1)
 103         set(BIN_SUFFIX "2")
 104 endif()
 105
 106 if(DEMO)
 107         set(BIN_SUFFIX "${BIN_SUFFIX}demo")
 108 endif()
 109
 110 find_package(SDL2 "2.0.5" REQUIRED)
 111 find_package(OpenGL REQUIRED)
 112 find_package(OpenAL REQUIRED)
 113
 114 if(NOT EMSCRIPTEN)
 115   find_package(LibWebSockets REQUIRED)
 116
 117   find_package(wxWidgets COMPONENTS core base gl net)
 118   include(${wxWidgets_USE_FILE})
 119 endif()
 120
 121 # ##############################################################################
 122
 123
 124 include_directories(
 125   ${PROJECT_SOURCE_DIR}/include
 126   ${CMAKE_BINARY_DIR}/include
 127   ${SDL2_INCLUDE_DIR}
 128   ${OPENAL_INCLUDE_DIR}
 129   ${LIBWEBSOCKETS_INCLUDE_DIR}
 130   ${wxWidgets_INCLUDE_DIRS}
 131 )
 132
 133
 134 add_subdirectory(src)
 135 add_subdirectory(include)
 136
 137
 138 # ##############################################################################
 139 #
 140
 141 #
 142 # custom target for source tree version info
 143 #
 144
 145 add_custom_target(buildver
 146   COMMAND ${CMAKE_COMMAND}
 147     -DSOURCE_DIR=${CMAKE_SOURCE_DIR}
 148     -DBINARY_DIR=${CMAKE_BINARY_DIR}
 149     -P ${CMAKE_SOURCE_DIR}/cmake/GitInfo.cmake
 150   WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 151   SOURCES ${CMAKE_SOURCE_DIR}/cmake/GitInfo.cmake
 152 )
 153
 154 #
 155 # main code/game library
 156 #
 157
 158 add_library(code
 159   STATIC
 160   ${code_SOURCE}
 161   ${code_HEADERS}
 162   ${platform_SOURCE}
 163   ${platform_HEADERS}
 164 )
 165
 166 CreateSourceGroups(${code_SOURCE} ${platform_SOURCE})
 167
 168 add_dependencies(code
 169   buildver
 170 )
 171
 172 #
 173 # the game itself
 174 #
 175
 176 set(FS_BINARY "fs${BIN_SUFFIX}")
 177
 178 add_executable(${FS_BINARY}
 179   WIN32
 180   ${freespace_SOURCE}
 181   ${freespace_HEADERS}
 182 )
 183
 184 CreateSourceGroups(${freespace_SOURCE})
 185
 186 target_link_libraries(
 187   ${FS_BINARY}
 188   code
 189   ${SDL2_LIBRARY}
 190   ${OPENGL_LIBRARIES}
 191   ${OPENAL_LIBRARY}
 192   ${LIBWEBSOCKETS_LIBRARIES}
 193   ${PLATFORM_LIBRARIES}
 194 )
 195
 196 if(EMSCRIPTEN)
 197   set(em_SYNC_WHITELIST
 198     # for loading screen
 199     main
 200     game_main
 201     game_init
 202     #game_loop_caller
 203     #gameseq_process_events
 204     #game_process_event
 205     #gameseq_set_state
 206     #game_enter_state
 207     #game_start_mission
 208     #freespace_mission_load_stuff
 209     #game_busy_callback
 210     #game_loading_callback
 211     #game_loading_callback_close
 212     #level_page_in
 213     #bm_page_in_stop
 214     #gamesnd_preload_common_sounds
 215     #game_busy
 216     # fs2 title screen
 217     display_title_screen
 218   )
 219
 220   list(GET em_SYNC_WHITELIST -1 LastOne)
 221
 222   set(EMTERPRETIFY_WHITELIST "'[")
 223
 224   foreach(func ${em_SYNC_WHITELIST})
 225     if (${func} STREQUAL ${LastOne})
 226       set(EMTERPRETIFY_WHITELIST "${EMTERPRETIFY_WHITELIST}\"_${func}\"]'")
 227     else()
 228       set(EMTERPRETIFY_WHITELIST "${EMTERPRETIFY_WHITELIST}\"_${func}\",")
 229     endif()
 230   endforeach()
 231
 232   set(em_LINK_FLAGS
 233     "-s USE_SDL=2"
 234     "-s FULL_ES2=1"
 235         #"-s WASM=1"
 236     "-s TOTAL_MEMORY=184549376"
 237     "--shell-file ${CMAKE_SOURCE_DIR}/dist/fs_shell.html"
 238     "--preload-file game@/"
 239     "-s SAFE_HEAP=1"
 240     "-s DEMANGLE_SUPPORT=1"
 241     "-s ASSERTIONS=1"
 242     "--profiling-funcs"
 243     "-s EMTERPRETIFY=1"
 244     "-s EMTERPRETIFY_ASYNC=1"
 245         #"-s EMTERPRETIFY_FILE=\"${FS_BINARY}.binary\""
 246     "-s EMTERPRETIFY_WHITELIST=${EMTERPRETIFY_WHITELIST}"
 247   )
 248
 249   foreach(Flag ${em_LINK_FLAGS})
 250     set_property(TARGET ${FS_BINARY} APPEND_STRING PROPERTY LINK_FLAGS " ${Flag}")
 251   endforeach()
 252 endif(EMSCRIPTEN)
 253
 254 if(FS1)
 255   set_target_properties(${FS_BINARY} PROPERTIES PROJECT_LABEL "Freespace")
 256 else()
 257   set_target_properties(${FS_BINARY} PROPERTIES PROJECT_LABEL "Freespace2")
 258 endif()
 259
 260 #
 261 # launcher
 262 #
 263
 264 if(NOT GAME_ONLY)
 265   set(LAUNCHER_BINARY "freespace${BIN_SUFFIX}")
 266
 267   add_executable(${LAUNCHER_BINARY}
 268   WIN32
 269     ${launcher_SOURCE}
 270     ${launcher_HEADERS}
 271   )
 272
 273   add_dependencies(${LAUNCHER_BINARY}
 274     buildver
 275   )
 276
 277   CreateSourceGroups(${launcher_SOURCE})
 278
 279   target_link_libraries(
 280     ${LAUNCHER_BINARY}
 281     ${SDL2_LIBRARY}
 282     ${OPENGL_LIBRARIES}
 283     ${OPENAL_LIBRARY}
 284     ${wxWidgets_LIBRARIES}
 285     ${PLATFORM_LIBRARIES}
 286   )
 287
 288   set_target_properties(${LAUNCHER_BINARY} PROPERTIES PROJECT_LABEL "Launcher")
 289
 290   # wxWidgets appears to need c++11 for one or more headers
 291   if(NOT WIN32)
 292     set_target_properties(${LAUNCHER_BINARY} PROPERTIES COMPILE_FLAGS -std=c++11)
 293   endif()
 294 endif(NOT GAME_ONLY)
 295
 296 #
 297 # standalone server GUI
 298 #
 299
 300 if(NOT GAME_ONLY)
 301   # Not for FS1 Demo
 302   if(NOT FS1 OR NOT DEMO)
 303     if(FS1)
 304       set(STANDALONE_BINARY fsstandalone)
 305     else()
 306       set(STANDALONE_BINARY fs2standalone)
 307     endif()
 308
 309     add_executable(${STANDALONE_BINARY}
 310       WIN32
 311       ${standalone_SOURCE}
 312       ${standalone_HEADERS}
 313     )
 314
 315     CreateSourceGroups(${standalone_SOURCE})
 316
 317     target_link_libraries(
 318       ${STANDALONE_BINARY}
 319       ${SDL2_LIBRARY}
 320       ${wxWidgets_LIBRARIES}
 321       ${LIBWEBSOCKETS_LIBRARIES}
 322       ${PLATFORM_LIBRARIES}
 323     )
 324
 325     set_target_properties(${STANDALONE_BINARY} PROPERTIES PROJECT_LABEL "Standalone")
 326
 327     # wxWidgets appears to need c++11 for one or more headers
 328     if(NOT WIN32)
 329       set_target_properties(${STANDALONE_BINARY} PROPERTIES COMPILE_FLAGS -std=c++11)
 330     endif()
 331   endif(NOT FS1 OR NOT DEMO)
 332 endif(NOT GAME_ONLY)
 333
 334 #
 335 # extra rule to make sure we cleanup all exe variants
 336 #
 337
 338 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES
 339   # FS1 demo
 340   fsdemo${CMAKE_EXECUTABLE_SUFFIX}
 341   fsdemo.wast
 342   fsdemo.wasm
 343   fsdemo.js
 344   fsdemo.data
 345   freespacedemo${CMAKE_EXECUTABLE_SUFFIX}
 346   # FS1
 347   fs${CMAKE_EXECUTABLE_SUFFIX}
 348   freespace${CMAKE_EXECUTABLE_SUFFIX}
 349   # FS2 demo
 350   fs2demo${CMAKE_EXECUTABLE_SUFFIX}
 351   fs2demo.wast
 352   fs2demo.wasm
 353   fs2demo.js
 354   fs2demo.data
 355   freespace2demo${CMAKE_EXECUTABLE_SUFFIX}
 356   # FS2
 357   fs2${CMAKE_EXECUTABLE_SUFFIX}
 358   freespace2${CMAKE_EXECUTABLE_SUFFIX}
 359   # standalone GUI
 360   fsstandalone${CMAKE_EXECUTABLE_SUFFIX}
 361   fs2standalone${CMAKE_EXECUTABLE_SUFFIX}
 362 )
 363
 364 #
 365 # ##############################################################################
 366
 367 # ##############################################################################
 368 #
 369 # toolset: targets for creating/modifying game assets
 370 #
 371
 372 # don't build toolset unless it's a full build
 373 if(NOT GAME_ONLY)
 374
 375   #
 376   # AC: anim converter
 377   #
 378
 379   add_executable(ac
 380     EXCLUDE_FROM_ALL
 381     ${ac_SOURCE}
 382     ${ac_HEADERS}
 383   )
 384
 385   CreateSourceGroups(${ac_SOURCE})
 386
 387   target_link_libraries(
 388     ac
 389     code
 390     ${SDL2_LIBRARY}
 391     ${OPENGL_LIBRARIES}
 392     ${OPENAL_LIBRARY}
 393     ${LIBWEBSOCKETS_LIBRARIES}
 394     ${PLATFORM_LIBRARIES}
 395   )
 396
 397   #
 398   # CFILEARCHIVER: to create VP file archives
 399   #
 400
 401   add_executable(cfilearchiver
 402     EXCLUDE_FROM_ALL
 403     ${cfilearchiver_SOURCE}
 404   )
 405
 406   CreateSourceGroups(${cfilearchiver_SOURCE})
 407
 408   #
 409   # CRYPTSTRING: string encryption (for embedded cheat codes)
 410   #
 411
 412   add_executable(cryptstring
 413     EXCLUDE_FROM_ALL
 414     ${cryptstring_SOURCE}
 415   )
 416
 417   CreateSourceGroups(${cryptstring_SOURCE})
 418
 419   #
 420   # NEBEDIT: FS1 style nebula editor/creator
 421   #
 422
 423   add_executable(nebedit
 424     EXCLUDE_FROM_ALL
 425     WIN32
 426     ${nebedit_SOURCE}
 427   )
 428
 429   CreateSourceGroups(${nebedit_SOURCE})
 430
 431   target_link_libraries(
 432     nebedit
 433     code
 434     ${SDL2_LIBRARY}
 435     ${OPENGL_LIBRARIES}
 436     ${OPENAL_LIBRARY}
 437     ${wxWidgets_LIBRARIES}
 438     ${LIBWEBSOCKETS_LIBRARIES}
 439     ${PLATFORM_LIBRARIES}
 440   )
 441
 442   # wxWidgets appears to need c++11 for one or more headers
 443   if(NOT WIN32)
 444     set_target_properties(nebedit PROPERTIES COMPILE_FLAGS -std=c++11)
 445   endif()
 446
 447   #
 448   # POFVIEW: model viewer
 449   #
 450
 451   add_executable(pofview
 452     EXCLUDE_FROM_ALL
 453     WIN32
 454     ${pofview_SOURCE}
 455     ${pofview_HEADERS}
 456   )
 457
 458   CreateSourceGroups(${pofview_SOURCE})
 459
 460   target_link_libraries(
 461     pofview
 462     code
 463     ${SDL2_LIBRARY}
 464     ${OPENGL_LIBRARIES}
 465     ${OPENAL_LIBRARY}
 466     ${wxWidgets_LIBRARIES}
 467     ${LIBWEBSOCKETS_LIBRARIES}
 468     ${PLATFORM_LIBRARIES}
 469   )
 470
 471   # wxWidgets appears to need c++11 for one or more headers
 472   if(NOT WIN32)
 473     set_target_properties(pofview PROPERTIES COMPILE_FLAGS -std=c++11)
 474   endif()
 475
 476   #
 477   # SCRAMBLE: file-based encryption for TBLs
 478   #
 479
 480   add_executable(scramble
 481     EXCLUDE_FROM_ALL
 482     ${scramble_SOURCE}
 483     ${scramble_HEADERS}
 484   )
 485
 486   CreateSourceGroups(${scramble_SOURCE})
 487
 488   #
 489   # FONTTOOL: create font files / edit kerning data
 490   #
 491
 492   add_executable(fonttool
 493     EXCLUDE_FROM_ALL
 494     ${fonttool_SOURCE}
 495     ${fonttool_HEADERS}
 496   )
 497
 498   CreateSourceGroups(${fonttool_SOURCE})
 499
 500   # background setup, to allow running from build location without installing
 501   add_custom_command(TARGET fonttool
 502     POST_BUILD
 503     COMMAND ${CMAKE_COMMAND} -E make_directory "${CMAKE_CURRENT_BINARY_DIR}/src/fonttool"
 504     COMMAND ${CMAKE_COMMAND} -E copy "${PROJECT_SOURCE_DIR}/src/fonttool/fonttool.pcx" "${CMAKE_CURRENT_BINARY_DIR}/src/fonttool"
 505   )
 506
 507   target_link_libraries(
 508     fonttool
 509     code
 510     ${SDL2_LIBRARY}
 511     ${OPENGL_LIBRARIES}
 512     ${OPENAL_LIBRARY}
 513     ${LIBWEBSOCKETS_LIBRARIES}
 514     ${PLATFORM_LIBRARIES}
 515   )
 516
 517   #
 518   # custom target to build all tools in one pass
 519   #
 520
 521   add_custom_target(tools)
 522
 523   add_dependencies(tools
 524     ac
 525     cfilearchiver
 526     cryptstring
 527     nebedit
 528     pofview
 529     scramble
 530     fonttool
 531   )
 532
 533 endif(NOT GAME_ONLY)
 534
 535 #
 536 # ##############################################################################
 537
 538 #
 539 # optionally include any dev/user preferred build commands and/or options
 540 #
 541
 542 include(custom.cmake OPTIONAL)