data/qcsrc/client/View.qc

   1 vector angles_held[24];\r
   2 void Net_ReadHoldAngles()\r
   3 {\r
   4         float wpn;\r
   5         vector v;\r
   6         wpn = ReadByte();\r
   7         --wpn;\r
   8         angles_held_status[wpn] = ReadByte();\r
   9         if(angles_held_status[wpn])\r
  10         {\r
  11                 v_x = ReadCoord();\r
  12                 v_y = ReadCoord();\r
  13                 v_z = 0;\r
  14                 angles_held[wpn] = v;\r
  15         }\r
  16 }\r
  17 \r
  18 entity porto;\r
  19 vector polyline[16];\r
  20 float trace_dphitcontents;\r
  21 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
  22 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
  23 void Porto_Draw()\r
  24 {\r
  25         vector p, dir, ang, q, nextdir;\r
  26         float idx, portal_number, portal1_idx;\r
  27 \r
  28         if(activeweapon != WEP_PORTO)\r
  29                 return;\r
  30 \r
  31         dir = view_forward;\r
  32 \r
  33         if(angles_held_status[WEP_PORTO-1])\r
  34         {\r
  35                 makevectors(angles_held[WEP_PORTO-1]);\r
  36                 dir = v_forward;\r
  37         }\r
  38 \r
  39         p = view_origin;\r
  40 \r
  41         polyline[0] = p;\r
  42         idx = 1;\r
  43         portal_number = 0;\r
  44         nextdir = dir;\r
  45 \r
  46         for(;;)\r
  47         {\r
  48                 dir = nextdir;\r
  49                 traceline(p, p + 65536 * dir, TRUE, world);\r
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  51                         return;\r
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  53                 p = trace_endpos;\r
  54                 polyline[idx] = p;\r
  55                 ++idx;\r
  56                 if(idx >= 16)\r
  57                         return;\r
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  59                         continue;\r
  60                 ++portal_number;\r
  61                 ang = vectoangles2(trace_plane_normal, dir);\r
  62                 ang_x = -ang_x;\r
  63                 makevectors(ang);\r
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  65                         return;\r
  66                 if(portal_number == 1)\r
  67                         portal1_idx = idx;\r
  68                 if(portal_number >= 2)\r
  69                         break;\r
  70         }\r
  71 \r
  72         while(idx >= 2)\r
  73         {\r
  74                 p = polyline[idx-2];\r
  75                 q = polyline[idx-1];\r
  76                 if(idx == 2)\r
  77                         p = p - view_up * 16;\r
  78                 if(idx-1 >= portal1_idx)\r
  79                 {\r
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  81                 }\r
  82                 else\r
  83                 {\r
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  85                 }\r
  86                 --idx;\r
  87         }\r
  88 }\r
  89 \r
  90 float DPCONTENTS_SOLID = 1; // hit a bmodel, not a bounding box\r
  91 float DPCONTENTS_BODY = 32; // hit a bounding box, not a bmodel\r
  92 void Porto_Init()\r
  93 {\r
  94         porto = spawn();\r
  95         porto.classname = "porto";\r
  96         porto.draw = Porto_Draw;\r
  97         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
  98 }\r
  99 \r
 100 float drawtime;\r
 101 \r
 102 float tan(float x)\r
 103 { \r
 104         return sin(x) / cos(x);\r
 105 }\r
 106 float atan2(float y, float x)\r
 107 {\r
 108         vector v;\r
 109         v = '1 0 0' * x + '0 1 0' * y;\r
 110         v = vectoangles(v);\r
 111         return v_y * 0.01745329251994329576;\r
 112 }\r
 113 \r
 114 vector GetCurrentFov(float fov)\r
 115 {\r
 116         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 117 \r
 118         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 119         zoomfactor = cvar("cl_zoomfactor");\r
 120         if(zoomfactor < 1 || zoomfactor > 16)\r
 121                 zoomfactor = 2.5;\r
 122         zoomspeed = cvar("cl_zoomspeed");\r
 123         if(zoomspeed >= 0)\r
 124                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 125                         zoomspeed = 3.5;\r
 126 \r
 127         zoomdir = button_zoom;\r
 128         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 129                 zoomdir += button_attack2;\r
 130         if(spectatee_status > 0 || isdemo())\r
 131         {\r
 132                 if(spectatorbutton_zoom)\r
 133                         zoomdir = 0 + !zoomdir;\r
 134                         // do not even THINK about removing this 0\r
 135                         // _I_ know what I am doing\r
 136                         // fteqcc does not\r
 137         }\r
 138 \r
 139         if(zoomdir)\r
 140                 zoomin_effect = 0;\r
 141 \r
 142         if(zoomin_effect)\r
 143         {\r
 144                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 145         }\r
 146         else\r
 147         {\r
 148                 if(zoomspeed < 0) // instant zoom\r
 149                 {\r
 150                         if(zoomdir)\r
 151                                 current_viewzoom = 1 / zoomfactor;\r
 152                         else\r
 153                                 current_viewzoom = 1;\r
 154                 }\r
 155                 else\r
 156                 {\r
 157                         if(zoomdir)\r
 158                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 159                         else\r
 160                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 161                 }\r
 162         }\r
 163 \r
 164         if(almost_equals(current_viewzoom, 1))\r
 165                 current_zoomfraction = 0;\r
 166         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
 167                 current_zoomfraction = 1;\r
 168         else\r
 169                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 170 \r
 171         if(zoomsensitivity < 1)\r
 172                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 173         else\r
 174                 setsensitivityscale(1);\r
 175 \r
 176         float frustumx, frustumy, fovx, fovy;\r
 177         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 178         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
 179         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 180         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 181 \r
 182         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 183 }\r
 184 \r
 185 void CSQC_common_hud(void);\r
 186 \r
 187 void CSQC_kh_hud(void);\r
 188 void CSQC_ctf_hud(void);\r
 189 void PostInit(void);\r
 190 float Sbar_WouldDrawScoreboard ();\r
 191 float zoomscript_caught;\r
 192 float view_set;\r
 193 float camera_mode;\r
 194 vector camera_offset, current_origin, mouse_angles, current_camera_offset, new_angles;\r
 195 void CSQC_UpdateView(float w, float h)\r
 196 {\r
 197         entity e;\r
 198         float fov;\r
 199         float f;\r
 200         vector v1, v2;\r
 201 \r
 202         dprint_load();\r
 203         WaypointSprite_Load();\r
 204 \r
 205         // Render the Scene\r
 206         if(!intermission || !view_set)\r
 207         {\r
 208                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 209                 view_angles = input_angles;\r
 210                 makevectors(view_angles);\r
 211                 view_forward = v_forward;\r
 212                 view_right = v_right;\r
 213                 view_up = v_up;\r
 214                 view_set = 1;\r
 215         }\r
 216 \r
 217         f = floor(cvar("v_flipped"));\r
 218         cvar_set("v_flipped", ftos(!f));\r
 219         v1 = cs_unproject('-100 -100 1000');\r
 220         cvar_set("v_flipped", ftos(f));\r
 221         v2 = cs_unproject('-100 -100 1000');\r
 222 \r
 223         if(v1 == v2)\r
 224         {\r
 225                 // non-supporting engine\r
 226                 vid_width = cvar("vid_width");\r
 227                 vid_height = cvar("vid_height");\r
 228         }\r
 229         else\r
 230         {\r
 231                 // supporting engine\r
 232                 vid_width = w;\r
 233                 vid_height = h;\r
 234         }\r
 235 \r
 236 #ifdef BLURTEST\r
 237         if(time > blurtest_time0 && time < blurtest_time1)\r
 238         {\r
 239                 float r, t;\r
 240 \r
 241                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);\r
 242                 r = t * blurtest_radius;\r
 243                 f = 1 / pow(t, blurtest_power) - 1;\r
 244 \r
 245                 cvar_set("r_glsl_postprocess", "1");\r
 246                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));\r
 247         }\r
 248         else\r
 249         {\r
 250                 cvar_set("r_glsl_postprocess", "0");\r
 251                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");\r
 252         }\r
 253 #endif\r
 254 \r
 255         Fog_Force();\r
 256 \r
 257         drawframetime = max(0.000001, time - drawtime);\r
 258         drawtime = time;\r
 259 \r
 260         // watch for gametype changes here...\r
 261         // in ParseStuffCMD the cmd isn't executed yet :/\r
 262         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 263         if(!postinit)\r
 264                 PostInit();\r
 265 \r
 266         fov = cvar("fov");\r
 267         if(button_zoom || fov <= 59.5)\r
 268         {\r
 269                 if(!zoomscript_caught)\r
 270                 {\r
 271                         localcmd("+button4\n");\r
 272                         zoomscript_caught = 1;\r
 273                         ignore_plus_zoom += 1;\r
 274                 }\r
 275         }\r
 276         else\r
 277         {\r
 278                 if(zoomscript_caught)\r
 279                 {\r
 280                         localcmd("-button4\n");\r
 281                         zoomscript_caught = 0;\r
 282                         ignore_minus_zoom += 1;\r
 283                 }\r
 284         }\r
 285         \r
 286         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 287         sbar_hudselector = cvar("sbar_hudselector");\r
 288         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
 289         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 290         f = cvar("teamplay");\r
 291         if(f != teamplay)\r
 292         {\r
 293                 teamplay = f;\r
 294                 Sbar_InitScores();\r
 295         }\r
 296 \r
 297         if(last_weapon != activeweapon) {\r
 298                 weapontime = time;\r
 299                 last_weapon = activeweapon;\r
 300         }\r
 301 \r
 302         // ALWAYS Clear Current Scene First\r
 303         R_ClearScene();\r
 304 \r
 305         // Assign Standard Viewflags\r
 306         // Draw the World (and sky)\r
 307         R_SetView(VF_DRAWWORLD, 1);\r
 308 \r
 309         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 310 \r
 311         // Camera for demo playback\r
 312         if (cvar("chase_active") > 1 && cvar("cl_demo_mousegrab") && isdemo())\r
 313         {\r
 314                 float speed, attenuation;\r
 315                 vector new_origin, m;\r
 316 \r
 317                 speed = ((cvar("camera_free")) ? cvar("camera_speed_free") : cvar("camera_speed_chase"));\r
 318                         \r
 319                 attenuation = cvar("camera_speed_attenuation");\r
 320                 \r
 321                 attenuation = ((attenuation<1) ? 1 : (1 / attenuation));\r
 322 \r
 323                 if( cvar("camera_reset") || !camera_mode )\r
 324                 {\r
 325                         camera_offset = '0 0 0';\r
 326                         new_angles = view_angles;\r
 327                         camera_offset_z += 20;\r
 328                         camera_offset_x -= 20 * cos(new_angles_y * DEG2RAD);\r
 329                         camera_offset_y -= 20 * sin(new_angles_y * DEG2RAD);\r
 330                         current_origin = view_origin;\r
 331                 }\r
 332 \r
 333                 // Camera angles\r
 334                 if( cvar("camera_roll") )\r
 335                         mouse_angles_z += cvar("camera_roll") * cvar("camera_speed_roll");\r
 336 \r
 337                 m = getmousepos() * 0.1;\r
 338                 if(vlen(m)>cvar("camera_mouse_treshold"))\r
 339                 {\r
 340                         mouse_angles_x += m_y * cos(mouse_angles_z * DEG2RAD) + (m_x * sin(mouse_angles_z * DEG2RAD));\r
 341                         mouse_angles_y -= m_x * cos(mouse_angles_z * DEG2RAD) + (m_y * -sin(mouse_angles_z * DEG2RAD));\r
 342                 }\r
 343                 \r
 344                 new_angles += (mouse_angles - new_angles) * attenuation;\r
 345                 \r
 346                 // Camera position\r
 347                 if( cvar("camera_direction_x") )\r
 348                 {\r
 349                         camera_offset_x += cvar("camera_direction_x") * speed * cos(new_angles_y * DEG2RAD);\r
 350                         camera_offset_y += cvar("camera_direction_x") * speed * sin(new_angles_y * DEG2RAD);\r
 351                 }\r
 352 \r
 353                 if( cvar("camera_direction_y") )\r
 354                 {\r
 355                         camera_offset_y += cvar("camera_direction_y") * speed * cos(new_angles_y * DEG2RAD) * cos(new_angles_z * DEG2RAD);\r
 356                         camera_offset_x += cvar("camera_direction_y") * speed * -sin(new_angles_y * DEG2RAD);\r
 357                         camera_offset_z += cvar("camera_direction_y") * speed * sin(new_angles_z * DEG2RAD);\r
 358                 }\r
 359 \r
 360                 if( cvar("camera_direction_z") )\r
 361                         camera_offset_z += cvar("camera_direction_z") * speed * cos(new_angles_z * DEG2RAD);\r
 362 \r
 363                 current_camera_offset += (camera_offset - current_camera_offset) * attenuation;\r
 364 \r
 365                 // Camera modes\r
 366                 if( cvar("camera_free") )\r
 367                 {\r
 368                         if ( camera_mode == CAMERA_CHASE )\r
 369                         {\r
 370                                 current_camera_offset = current_origin + current_camera_offset;\r
 371                                 camera_offset = current_origin + camera_offset;\r
 372                         }\r
 373 \r
 374                         camera_mode = CAMERA_FREE;\r
 375                         new_origin = current_camera_offset;\r
 376                 }\r
 377                 else\r
 378                 {\r
 379                         if ( camera_mode == CAMERA_FREE )\r
 380                         {\r
 381                                 current_origin = view_origin;\r
 382                                 camera_offset = camera_offset - current_origin;\r
 383                                 current_camera_offset = current_camera_offset - current_origin;\r
 384                         }\r
 385 \r
 386                         camera_mode = CAMERA_CHASE;\r
 387                         \r
 388                         if(cvar("camera_chase_smoothly"))\r
 389                                 current_origin += (view_origin - current_origin) * attenuation;\r
 390                         else\r
 391                                 current_origin = view_origin;\r
 392                                 \r
 393                         new_origin = current_origin + current_camera_offset;\r
 394                 }\r
 395 \r
 396                 R_SetView(VF_ANGLES, new_angles);\r
 397                 R_SetView(VF_ORIGIN, new_origin);\r
 398         }\r
 399         \r
 400         // Draw the Crosshair\r
 401         float scoreboard_active;\r
 402         scoreboard_active = Sbar_WouldDrawScoreboard();\r
 403         R_SetView(VF_DRAWCROSSHAIR, !scoreboard_active && !ons_showmap);\r
 404         \r
 405         // Draw the Engine Status Bar (the default Quake HUD)\r
 406         R_SetView(VF_DRAWENGINESBAR, 0);\r
 407 \r
 408         // Set the console size vars\r
 409         vid_conwidth = cvar("vid_conwidth");\r
 410         vid_conheight = cvar("vid_conheight");\r
 411         vid_pixelheight = cvar("vid_pixelheight");\r
 412 \r
 413         // fetch this one only once per frame\r
 414         sbar_showbinds = cvar("sbar_showbinds");\r
 415         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 416 \r
 417         // Update the mouse position\r
 418         /*\r
 419         mousepos_x = vid_conwidth;\r
 420         mousepos_y = vid_conheight;\r
 421         mousepos = mousepos*0.5 + getmousepos();\r
 422         */\r
 423 \r
 424         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 425 \r
 426         e = self;\r
 427         for(self = world; (self = nextent(self)); )\r
 428                 if(self.draw)\r
 429                         self.draw();\r
 430         self = e;\r
 431         R_RenderScene();\r
 432 \r
 433         // now switch to 2D drawing mode by calling a 2D drawing function\r
 434         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
 435         // next R_RenderScene call\r
 436         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
 437 \r
 438         // Draw the mouse cursor\r
 439         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 440         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 441         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 442         //self = edict_num(player_localnum);\r
 443         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 444         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 445         // as long as the ctf part isn't in, this is useless\r
 446         if(menu_visible)\r
 447                 menu_show();\r
 448         \r
 449         /*if(gametype == GAME_CTF)\r
 450         {\r
 451                 ctf_view();\r
 452         } else */\r
 453 \r
 454         // draw 2D entities\r
 455         e = self;\r
 456         for(self = world; (self = nextent(self)); )\r
 457                 if(self.draw2d)\r
 458                         self.draw2d();\r
 459         self = e;\r
 460         \r
 461         // draw radar\r
 462         if(teamplay || cvar("cl_teamradar") == 2)\r
 463         {\r
 464                 if((cvar_string("cl_teamradar") != "0" && !scoreboard_active) || ons_showmap)\r
 465                         teamradar_view();\r
 466         }\r
 467 \r
 468         // draw sbar\r
 469         if(cvar("r_letterbox") == 0)\r
 470         if(cvar("viewsize") < 120)\r
 471                 CSQC_common_hud();\r
 472 }\r
 473 \r
 474 void Sbar_Draw();\r
 475 void CSQC_common_hud(void)\r
 476 {\r
 477         // Sbar_SortFrags(); done in Sbar_Draw\r
 478         Sbar_Draw();\r
 479 }\r
 480 \r
 481 // KeyHunt HUD by victim\r
 482 void CSQC_kh_hud(void)\r
 483 {\r
 484         // HUD 0 has the weapons on the right hand side - temporarily shown when needed\r
 485         // HUD 1 has the weapons on the bottom - permanently\r
 486 \r
 487         // use the following two binds to check the icons move correctly\r
 488         // bind g "toggle sbar_flagstatus_right; echo Menu right $sbar_flagstatus_right"  // move the icons\r
 489         // bind h "toggle sbar_hudselector; echo HUD $sbar_hudselector"  // change the HUD\r
 490 \r
 491         float kh_keys, kh_keys_status, kh_teams_set;\r
 492         float kh_margin_x, kh_margin_y, kh_key_box;\r
 493         string kh_carrying, kh_outline;\r
 494         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;\r
 495         vector red, blue, yellow, pink;\r
 496 \r
 497         kh_keys = getstati(STAT_KH_KEYS);\r
 498         kh_keys_status = kh_keys / 256;\r
 499         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc\r
 500 \r
 501         kh_margin_y = 8;\r
 502         kh_margin_x = (cvar("sbar_flagstatus_right") * sbar_hudselector * (vid_conwidth - 67)) + 10;\r
 503 //      sbar_flagstatus_right 0/1; sbar_hudselector 0/1; screen width - key width + margin\r
 504 \r
 505         red_pos_x = blue_pos_x = yellow_pos_x = pink_pos_x = kh_margin_x;\r
 506 \r
 507         kh_key_box = 120;\r
 508 \r
 509         pink_pos_y = kh_margin_y + 0;  // top\r
 510         yellow_pos_y = kh_margin_y + kh_key_box;\r
 511         blue_pos_y = kh_margin_y + kh_key_box * 2;\r
 512         red_pos_y = kh_margin_y + kh_key_box * 3;  //bottom\r
 513 \r
 514         red = '1 0 0';\r
 515         blue = '0 0 1';\r
 516         yellow = '1 1 0';\r
 517         pink = '1 0 1';\r
 518 \r
 519         kh_size = '0 0 0';  // don't resize the image\r
 520 \r
 521         kh_carrying = "gfx/sb_kh_full";\r
 522         kh_outline = "gfx/sb_kh_outline";\r
 523 \r
 524 //      drawpic(vector position, string pic, vector size, vector rgb, float alpha, float flag)\r
 525 //      vector position = '0 0';  // 'x y' 0 0 (the origin) is the top left. X 0 - 799, Y 0 - 599\r
 526 \r
 527 //      vector size = '0 0';  // 'x y' changes the x & y dimensions. '0 0' gives the default pic size\r
 528 //      vector rgb = '0 0 0';  // 'r g b' range 0 - 1\r
 529 \r
 530         if (kh_keys_status & 1)  // red\r
 531                 drawpic (red_pos, kh_carrying, kh_size, red, 0.2, 0);  // show 20% alpha key\r
 532         else\r
 533                 drawpic (red_pos, kh_outline, kh_size, red, 0.4, 0);  // show key outline 40% alpha\r
 534 \r
 535         if (kh_keys & 1)\r
 536                 drawpic (red_pos, kh_carrying, kh_size, red, 1.0, 0);  // show solid key 100% alpha\r
 537 \r
 538 \r
 539         if (kh_keys_status & 2)  // blue\r
 540                 drawpic (blue_pos, kh_carrying, kh_size, blue, 0.2, 0);\r
 541         else\r
 542                 drawpic (blue_pos, kh_outline, kh_size, blue, 0.4, 0);\r
 543 \r
 544         if (kh_keys & 2)\r
 545                 drawpic (blue_pos, kh_carrying, kh_size, blue, 1.0, 0);\r
 546 \r
 547 \r
 548         if (kh_teams_set & 4)  // yellow\r
 549         {\r
 550                 if (kh_keys_status & 4)\r
 551                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 0.2, 0);\r
 552                 else\r
 553                         drawpic (yellow_pos, kh_outline, kh_size, yellow, 0.4, 0);\r
 554 \r
 555                 if (kh_keys & 4)\r
 556                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 1.0, 0);\r
 557         }\r
 558 \r
 559 \r
 560         if (kh_teams_set & 8)  // pink\r
 561         {\r
 562                 if (kh_keys_status & 8)\r
 563                         drawpic (pink_pos, kh_carrying, kh_size, pink, 0.2, 0);\r
 564                 else\r
 565                         drawpic (pink_pos, kh_outline, kh_size, pink, 0.4, 0);\r
 566 \r
 567                 if (kh_keys & 8)\r
 568                         drawpic (pink_pos, kh_carrying, kh_size, pink, 1.0, 0);\r
 569         }\r
 570 \r
 571 }\r