cmake/FindSDL2.cmake

   1 # - Locate SDL2 library (modified from CMake's FindSDL.cmake)
   2 # This module defines
   3 #  SDL2_LIBRARY, the name of the library to link against
   4 #  SDL2_FOUND, if false, do not try to link to SDL
   5 #  SDL2_INCLUDE_DIR, where to find SDL.h
   6 #  SDL2_VERSION_STRING, human-readable string containing the version of SDL2
   7 #
   8 # This module responds to the the flag:
   9 #  SDL2_BUILDING_LIBRARY
  10 #    If this is defined, then no SDL_main will be linked in because
  11 #    only applications need main().
  12 #    Otherwise, it is assumed you are building an application and this
  13 #    module will attempt to locate and set the the proper link flags
  14 #    as part of the returned SDL2_LIBRARY variable.
  15 #
  16 # Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your configuration
  17 # and no SDL2_LIBRARY, it means CMake did not find your SDL2 library
  18 # (SDL2.dll, libsdl2.so, SDL2.framework, etc).
  19 # Set SDL2_LIBRARY_TEMP to point to your SDL2 library, and configure again.
  20 # Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this value
  21 # as appropriate. These values are used to generate the final SDL2_LIBRARY
  22 # variable, but when these values are unset, SDL2_LIBRARY does not get created.
  23 #
  24 #
  25 # $SDL2DIR is an environment variable that would
  26 # correspond to the ./configure --prefix=$SDL2DIR
  27 # used in building SDL.
  28 #
  29
  30 #=============================================================================
  31 # Copyright 2014 Justin Jacobs
  32 #
  33 # Distributed under the OSI-approved BSD License (the "License");
  34 # see accompanying file Copyright.txt for details.
  35 #
  36 # This software is distributed WITHOUT ANY WARRANTY; without even the
  37 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  38 # See the License for more information.
  39 #=============================================================================
  40
  41 find_path(SDL2_INCLUDE_DIR SDL.h
  42   HINTS
  43         ENV SDL2DIR
  44   PATH_SUFFIXES include/SDL2 include
  45 )
  46
  47 find_library(SDL2_LIBRARY_TEMP
  48   NAMES SDL2
  49   HINTS
  50         ENV SDL2DIR
  51   PATH_SUFFIXES lib
  52 )
  53
  54 if(NOT SDL2_BUILDING_LIBRARY)
  55   if(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework")
  56         # Non-OS X framework versions expect you to also dynamically link to
  57         # SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms
  58         # seem to provide SDLmain for compatibility even though they don't
  59         # necessarily need it.
  60         find_library(SDL2MAIN_LIBRARY
  61           NAMES SDL2main
  62           HINTS
  63                 ENV SDL2DIR
  64           PATH_SUFFIXES lib
  65           PATHS
  66           /sw
  67           /opt/local
  68           /opt/csw
  69           /opt
  70         )
  71   endif()
  72 endif()
  73
  74 # SDL2 may require threads on your system.
  75 # The Apple build may not need an explicit flag because one of the
  76 # frameworks may already provide it.
  77 # But for non-OSX systems, I will use the CMake Threads package.
  78 if(NOT APPLE)
  79   find_package(Threads)
  80 endif()
  81
  82 # MinGW needs an additional library, mwindows
  83 # It's total link flags should look like -lmingw32 -lSDLmain -lSDL -lmwindows
  84 # (Actually on second look, I think it only needs one of the m* libraries.)
  85 if(MINGW)
  86   set(MINGW32_LIBRARY mingw32 CACHE STRING "mwindows for MinGW")
  87 endif()
  88
  89 if(SDL2_LIBRARY_TEMP)
  90   # For SDLmain
  91   if(SDL2MAIN_LIBRARY AND NOT SDL2_BUILDING_LIBRARY)
  92         list(FIND SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" _SDL2_MAIN_INDEX)
  93         if(_SDL2_MAIN_INDEX EQUAL -1)
  94           set(SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" ${SDL2_LIBRARY_TEMP})
  95         endif()
  96         unset(_SDL2_MAIN_INDEX)
  97   endif()
  98
  99   # For OS X, SDL uses Cocoa as a backend so it must link to Cocoa.
 100   # CMake doesn't display the -framework Cocoa string in the UI even
 101   # though it actually is there if I modify a pre-used variable.
 102   # I think it has something to do with the CACHE STRING.
 103   # So I use a temporary variable until the end so I can set the
 104   # "real" variable in one-shot.
 105   if(APPLE)
 106         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} "-framework Cocoa")
 107   endif()
 108
 109   # For threads, as mentioned Apple doesn't need this.
 110   # In fact, there seems to be a problem if I used the Threads package
 111   # and try using this line, so I'm just skipping it entirely for OS X.
 112   if(NOT APPLE)
 113         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
 114   endif()
 115
 116   # For MinGW library
 117   if(MINGW)
 118         set(SDL2_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL2_LIBRARY_TEMP})
 119   endif()
 120
 121   # Set the final string here so the GUI reflects the final state.
 122   set(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 Library can be found")
 123   # Set the temp variable to INTERNAL so it is not seen in the CMake GUI
 124   set(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "")
 125 endif()
 126
 127 if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h")
 128   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+[0-9]+$")
 129   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MINOR_VERSION[ \t]+[0-9]+$")
 130   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_PATCHLEVEL[ \t]+[0-9]+$")
 131   string(REGEX REPLACE "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MAJOR "${SDL2_VERSION_MAJOR_LINE}")
 132   string(REGEX REPLACE "^#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MINOR "${SDL2_VERSION_MINOR_LINE}")
 133   string(REGEX REPLACE "^#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_PATCH "${SDL2_VERSION_PATCH_LINE}")
 134   set(SDL2_VERSION_STRING ${SDL2_VERSION_MAJOR}.${SDL2_VERSION_MINOR}.${SDL2_VERSION_PATCH})
 135   unset(SDL2_VERSION_MAJOR_LINE)
 136   unset(SDL2_VERSION_MINOR_LINE)
 137   unset(SDL2_VERSION_PATCH_LINE)
 138   unset(SDL2_VERSION_MAJOR)
 139   unset(SDL2_VERSION_MINOR)
 140   unset(SDL2_VERSION_PATCH)
 141 endif()
 142
 143 include(FindPackageHandleStandardArgs)
 144
 145 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2
 146                                                                   REQUIRED_VARS SDL2_LIBRARY SDL2_INCLUDE_DIR
 147                                                                   VERSION_VAR SDL2_VERSION_STRING)
 148