server/rcon2irc/rcon2irc.pl

   1 #!/usr/bin/perl
   2
   3 our $VERSION = '0.4.2 svn $Revision$';
   4
   5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
   6 #
   7 # Permission is hereby granted, free of charge, to any person
   8 # obtaining a copy of this software and associated documentation
   9 # files (the "Software"), to deal in the Software without
  10 # restriction, including without limitation the rights to use,
  11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
  12 # copies of the Software, and to permit persons to whom the
  13 # Software is furnished to do so, subject to the following
  14 # conditions:
  15 #
  16 # The above copyright notice and this permission notice shall be
  17 # included in all copies or substantial portions of the Software.
  18 #
  19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  26 # OTHER DEALINGS IN THE SOFTWARE.
  27
  28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
  29
  30 # convert mIRC color codes to DP color codes
  31 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
  32 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
  33 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
  34 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
  35 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
  36 sub color_irc2dp($)
  37 {
  38         my ($message) = @_;
  39         $message =~ s/\^/^^/g;
  40         my $color = 7;
  41         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
  42                 # $1 is FG, $2 is BG, but let's ignore BG
  43                 my $oldcolor = $color;
  44                 if($3)
  45                 {
  46                         $color = 7;
  47                 }
  48                 else
  49                 {
  50                         $color = $color_irc2dp_table[$1];
  51                         $color = $oldcolor if not defined $color;
  52                 }
  53                 ($color == $oldcolor) ? '' : '^' . $color;
  54         }esg;
  55         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
  56         return $message;
  57 }
  58
  59 our @text_qfont_table = ( # ripped from DP console.c qfont_table
  60     "\0", '#',  '#',  '#',  '#',  '.',  '#',  '#',
  61     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
  62     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  63     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  64     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  65     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  66     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  67     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  68     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  69     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  70     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  71     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  72     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  73     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  74     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  75     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
  76     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
  77     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
  78     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  79     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  80     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  81     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  82     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  83     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  84     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  85     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  86     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  87     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  88     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  89     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  90     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  91     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
  92 );
  93 sub text_dp2ascii($)
  94 {
  95         my ($message) = @_;
  96         $message = join '', map { $text_qfont_table[ord $_] } split //, $message;
  97 }
  98
  99 sub color_dp_transform(&$)
 100 {
 101         my ($block, $message) = @_;
 102
 103         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
 104                 defined $1 ? $block->(char => '^', $7) :
 105                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
 106                 defined $5 ? $block->(color => $5, $7) :
 107                 defined $6 ? $block->(char => $6, $7) :
 108                         die "Invalid match";
 109         }esg;
 110
 111         return $message;
 112 }
 113
 114 sub color_dp2none($)
 115 {
 116         my ($message) = @_;
 117
 118         return color_dp_transform
 119         {
 120                 my ($type, $data, $next) = @_;
 121                 $type eq 'char'
 122                         ? $text_qfont_table[ord $data]
 123                         : "";
 124         }
 125         $message;
 126 }
 127
 128 sub color_rgb2basic($)
 129 {
 130         my ($data) = @_;
 131         my ($R, $G, $B) = @$data;
 132         my $min = [sort { $a <=> $b } ($R, $G, $B)]->[0];
 133         my $max = [sort { $a <=> $b } ($R, $G, $B)]->[-1];
 134
 135         my $v = $max / 15;
 136         my $s = ($max == $min) ? 0 : 1 - $min/$max;
 137
 138         if($s < 0.2)
 139         {
 140                 return 0 if $v < 0.5;
 141                 return 7;
 142         }
 143
 144         my $h;
 145         if($max == $min)
 146         {
 147                 $h = 0;
 148         }
 149         elsif($max == $R)
 150         {
 151                 $h = (60 * ($G - $B) / ($max - $min)) % 360;
 152         }
 153         elsif($max == $G)
 154         {
 155                 $h = (60 * ($B - $R) / ($max - $min)) + 120;
 156         }
 157         elsif($max == $B)
 158         {
 159                 $h = (60 * ($R - $G) / ($max - $min)) + 240;
 160         }
 161
 162         return 1 if $h < 36;
 163         return 3 if $h < 80;
 164         return 2 if $h < 150;
 165         return 5 if $h < 200;
 166         return 4 if $h < 270;
 167         return 6 if $h < 330;
 168         return 1;
 169 }
 170
 171 sub color_dp_rgb2basic($)
 172 {
 173         my ($message) = @_;
 174         return color_dp_transform
 175         {
 176                 my ($type, $data, $next) = @_;
 177                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
 178                 $type eq 'color' ? "^$data" :
 179                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
 180                         die "Invalid type";
 181         }
 182         $message;
 183 }
 184
 185 sub color_dp2irc($)
 186 {
 187         my ($message) = @_;
 188         my $color = -1;
 189         return color_dp_transform
 190         {
 191                 my ($type, $data, $next) = @_;
 192
 193                 if($type eq 'rgb')
 194                 {
 195                         $type = 'color';
 196                         $data = color_rgb2basic $data;
 197                 }
 198
 199                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 200                 $type eq 'color' ? do {
 201                         my $oldcolor = $color;
 202                         $color = $color_dp2irc_table[$data];
 203
 204                         $color == $oldcolor               ? '' :
 205                         $color < 0                        ? "\017" :
 206                         (index '0123456789,', $next) >= 0 ? "\003$color\002\002" :
 207                                                             "\003$color";
 208                 } :
 209                         die "Invalid type";
 210         }
 211         $message;
 212 }
 213
 214 sub color_dp2ansi($)
 215 {
 216         my ($message) = @_;
 217         my $color = -1;
 218         return color_dp_transform
 219         {
 220                 my ($type, $data, $next) = @_;
 221
 222                 if($type eq 'rgb')
 223                 {
 224                         $type = 'color';
 225                         $data = color_rgb2basic $data;
 226                 }
 227
 228                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 229                 $type eq 'color' ? do {
 230                         my $oldcolor = $color;
 231                         $color = $color_dp2ansi_table[$data];
 232
 233                         $color eq $oldcolor ? '' :
 234                                               "\033[${color}"
 235                 } :
 236                         die "Invalid type";
 237         }
 238         $message;
 239 }
 240
 241 sub color_dpfix($)
 242 {
 243         my ($message) = @_;
 244         # if the message ends with an odd number of ^, kill one
 245         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
 246         return $message;
 247 }
 248
 249
 250
 251
 252 # Interfaces:
 253 #   Connection:
 254 #     $conn->sockname() returns a connection type specific representation
 255 #       string of the local address, or undef if not applicable.
 256 #     $conn->send("string") sends something over the connection.
 257 #     $conn->recv() receives a string from the connection, or returns "" if no
 258 #       data is available.
 259 #     $conn->fds() returns all file descriptors used by the connection, so one
 260 #       can use select() on them.
 261 #   Channel:
 262 #     Usually wraps around a connection and implements a command based
 263 #     structure over it. It usually is constructed using new
 264 #     ChannelType($connection, someparameters...)
 265 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
 266 #       command string if the protocol supports it, or does nothing and leaves
 267 #       @cmds unchanged if the protocol does not support that usage (this is
 268 #       meant to save send() invocations).
 269 #     $chan->send($command, $nothrottle) sends a command over the channel. If
 270 #       $nothrottle is sent, the command must not be left out even if the channel
 271 #       is saturated (for example, because of IRC's flood control mechanism).
 272 #     $chan->quote($str) returns a string in a quoted form so it can safely be
 273 #       inserted as a substring into a command, or returns $str as is if not
 274 #       applicable. It is assumed that the result of the quote method is used
 275 #       as part of a quoted string, if the protocol supports that.
 276 #     $chan->recv() returns a list of received commands from the channel, or
 277 #       the empty list if none are available.
 278 #     $conn->fds() returns all file descriptors used by the channel's
 279 #       connections, so one can use select() on them.
 280
 281
 282
 283
 284
 285
 286
 287 # Socket connection.
 288 # Represents a connection over a socket.
 289 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
 290 package Connection::Socket;
 291 use strict;
 292 use warnings;
 293 use IO::Socket::INET;
 294 use IO::Handle;
 295
 296 # Constructor:
 297 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
 298 # If the remote address does not contain a port number, the numeric port is
 299 # used (it serves as a default port).
 300 sub new($$)
 301 {
 302         my ($class, $proto, $local, $remote, $defaultport) = @_;
 303         my $sock = IO::Socket::INET->new(
 304                 Proto => $proto,
 305                 (length($local) ? (LocalAddr => $local) : ()),
 306                 PeerAddr => $remote,
 307                 PeerPort => $defaultport
 308         ) or die "socket $proto/$local/$remote/$defaultport: $!";
 309         $sock->blocking(0);
 310         my $you = {
 311                 # Mortal fool! Release me from this wretched tomb! I must be set free
 312                 # or I will haunt you forever! I will hide your keys beneath the
 313                 # cushions of your upholstered furniture... and NEVERMORE will you be
 314                 # able to find socks that match!
 315                 sock => $sock,
 316                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
 317         };
 318         return
 319                 bless $you, 'Connection::Socket';
 320 }
 321
 322 # $sock->sockname() returns the local address of the socket.
 323 sub sockname($)
 324 {
 325         my ($self) = @_;
 326         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
 327         return "@{[inet_ntoa $addr]}:$port";
 328 }
 329
 330 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
 331 sub send($$)
 332 {
 333         my ($self, $data) = @_;
 334         return 1
 335                 if not length $data;
 336         if(not eval { $self->{sock}->send($data); })
 337         {
 338                 warn "$@";
 339                 return 0;
 340         }
 341         return 1;
 342 }
 343
 344 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
 345 sub recv($)
 346 {
 347         my ($self) = @_;
 348         my $data = "";
 349         if(defined $self->{sock}->recv($data, 32768, 0))
 350         {
 351                 return $data;
 352         }
 353         elsif($!{EAGAIN})
 354         {
 355                 return "";
 356         }
 357         else
 358         {
 359                 return undef;
 360         }
 361 }
 362
 363 # $sock->fds() returns the socket file descriptor.
 364 sub fds($)
 365 {
 366         my ($self) = @_;
 367         return fileno $self->{sock};
 368 }
 369
 370
 371
 372
 373
 374
 375
 376 # Line-based buffered connectionless FIFO channel.
 377 # Whatever is sent to it using send() is echoed back when using recv().
 378 package Channel::FIFO;
 379 use strict;
 380 use warnings;
 381
 382 # Constructor:
 383 #   my $chan = new Channel::FIFO();
 384 sub new($)
 385 {
 386         my ($class) = @_;
 387         my $you = {
 388                 buffer => []
 389         };
 390         return
 391                 bless $you, 'Channel::FIFO';
 392 }
 393
 394 sub join_commands($@)
 395 {
 396         my ($self, @data) = @_;
 397         return @data;
 398 }
 399
 400 sub send($$$)
 401 {
 402         my ($self, $line, $nothrottle) = @_;
 403         push @{$self->{buffer}}, $line;
 404 }
 405
 406 sub quote($$)
 407 {
 408         my ($self, $data) = @_;
 409         return $data;
 410 }
 411
 412 sub recv($)
 413 {
 414         my ($self) = @_;
 415         my $r = $self->{buffer};
 416         $self->{buffer} = [];
 417         return @$r;
 418 }
 419
 420 sub fds($)
 421 {
 422         my ($self) = @_;
 423         return ();
 424 }
 425
 426
 427
 428
 429
 430
 431
 432 # QW rcon protocol channel.
 433 # Wraps around a UDP based Connection and sends commands as rcon commands as
 434 # well as receives rcon replies. The quote and join_commands methods are using
 435 # DarkPlaces engine specific rcon protocol extensions.
 436 package Channel::QW;
 437 use strict;
 438 use warnings;
 439 use Digest::HMAC;
 440 use Digest::MD4;
 441
 442 # Constructor:
 443 #   my $chan = new Channel::QW($connection, "password");
 444 sub new($$$)
 445 {
 446         my ($class, $conn, $password, $secure, $timeout) = @_;
 447         my $you = {
 448                 connector => $conn,
 449                 password => $password,
 450                 recvbuf => "",
 451                 secure => $secure,
 452                 timeout => $timeout,
 453         };
 454         return
 455                 bless $you, 'Channel::QW';
 456 }
 457
 458 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
 459 sub join_commands($@)
 460 {
 461         my ($self, @data) = @_;
 462         return join "\0", @data;
 463 }
 464
 465 sub send($$$)
 466 {
 467         my ($self, $line, $nothrottle) = @_;
 468         if($self->{secure} > 1)
 469         {
 470                 $self->{connector}->send("\377\377\377\377getchallenge");
 471                 my $c = $self->recvchallenge();
 472                 return 0 if not defined $c;
 473                 my $key = Digest::HMAC::hmac("$c $line", $self->{password}, \&Digest::MD4::md4);
 474                 return $self->{connector}->send("\377\377\377\377srcon HMAC-MD4 CHALLENGE $key $c $line");
 475         }
 476         elsif($self->{secure})
 477         {
 478                 my $t = sprintf "%ld.%06d", time(), int rand 1000000;
 479                 my $key = Digest::HMAC::hmac("$t $line", $self->{password}, \&Digest::MD4::md4);
 480                 return $self->{connector}->send("\377\377\377\377srcon HMAC-MD4 TIME $key $t $line");
 481         }
 482         else
 483         {
 484                 return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
 485         }
 486 }
 487
 488 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
 489 sub quote($$)
 490 {
 491         my ($self, $data) = @_;
 492         $data =~ s/[\000-\037]//g;
 493         $data =~ s/([\\"])/\\$1/g;
 494         $data =~ s/\$/\$\$/g;
 495         return $data;
 496 }
 497
 498 sub recvchallenge($)
 499 {
 500         my ($self) = @_;
 501
 502         my $sel = IO::Select->new($self->fds());
 503         my $endtime_max = Time::HiRes::time() + $self->{timeout};
 504         my $endtime = $endtime_max;
 505
 506         while((my $dt = $endtime - Time::HiRes::time()) > 0)
 507         {
 508                 if($sel->can_read($dt))
 509                 {
 510                         for(;;)
 511                         {
 512                                 my $s = $self->{connector}->recv();
 513                                 die "read error\n"
 514                                         if not defined $s;
 515                                 length $s
 516                                         or last;
 517                                 if($s =~ /^\377\377\377\377challenge (.*)$/s)
 518                                 {
 519                                         return $1;
 520                                 }
 521                                 next
 522                                         if $s !~ /^\377\377\377\377n(.*)$/s;
 523                                 $self->{recvbuf} .= $1;
 524                         }
 525                 }
 526         }
 527         return undef;
 528 }
 529
 530 sub recv($)
 531 {
 532         my ($self) = @_;
 533         for(;;)
 534         {
 535                 my $s = $self->{connector}->recv();
 536                 die "read error\n"
 537                         if not defined $s;
 538                 length $s
 539                         or last;
 540                 next
 541                         if $s !~ /^\377\377\377\377n(.*)$/s;
 542                 $self->{recvbuf} .= $1;
 543         }
 544         my @out = ();
 545         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 546         {
 547                 push @out, $1;
 548         }
 549         return @out;
 550 }
 551
 552 sub fds($)
 553 {
 554         my ($self) = @_;
 555         return $self->{connector}->fds();
 556 }
 557
 558
 559
 560
 561
 562
 563
 564 # Line based protocol channel.
 565 # Wraps around a TCP based Connection and sends commands as text lines
 566 # (separated by CRLF). When reading responses from the Connection, any type of
 567 # line ending is accepted.
 568 # A flood control mechanism is implemented.
 569 package Channel::Line;
 570 use strict;
 571 use warnings;
 572 use Time::HiRes qw/time/;
 573
 574 # Constructor:
 575 #   my $chan = new Channel::Line($connection);
 576 sub new($$)
 577 {
 578         my ($class, $conn) = @_;
 579         my $you = {
 580                 connector => $conn,
 581                 recvbuf => "",
 582                 capacity => undef,
 583                 linepersec => undef,
 584                 maxlines => undef,
 585                 lastsend => time()
 586         };
 587         return
 588                 bless $you, 'Channel::Line';
 589 }
 590
 591 sub join_commands($@)
 592 {
 593         my ($self, @data) = @_;
 594         return @data;
 595 }
 596
 597 # Sets new flood control parameters:
 598 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
 599 #     exceed the lines per second limit);
 600 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
 601 #   If the $nothrottle flag is set while sending, the line is sent anyway even
 602 #   if flooding would take place.
 603 sub throttle($$$)
 604 {
 605         my ($self, $linepersec, $maxlines) = @_;
 606         $self->{linepersec} = $linepersec;
 607         $self->{maxlines} = $maxlines;
 608         $self->{capacity} = $maxlines;
 609 }
 610
 611 sub send($$$)
 612 {
 613         my ($self, $line, $nothrottle) = @_;
 614         my $t = time();
 615         if(defined $self->{capacity})
 616         {
 617                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
 618                 $self->{lastsend} = $t;
 619                 $self->{capacity} = $self->{maxlines}
 620                         if $self->{capacity} > $self->{maxlines};
 621                 if(!$nothrottle)
 622                 {
 623                         return -1
 624                                 if $self->{capacity} < 0;
 625                 }
 626                 $self->{capacity} -= 1;
 627         }
 628         $line =~ s/\r|\n//g;
 629         return $self->{connector}->send("$line\r\n");
 630 }
 631
 632 sub quote($$)
 633 {
 634         my ($self, $data) = @_;
 635         $data =~ s/\r\n?/\n/g;
 636         $data =~ s/\n/*/g;
 637         return $data;
 638 }
 639
 640 sub recv($)
 641 {
 642         my ($self) = @_;
 643         for(;;)
 644         {
 645                 my $s = $self->{connector}->recv();
 646                 die "read error\n"
 647                         if not defined $s;
 648                 length $s
 649                         or last;
 650                 $self->{recvbuf} .= $s;
 651         }
 652         my @out = ();
 653         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 654         {
 655                 push @out, $1;
 656         }
 657         return @out;
 658 }
 659
 660 sub fds($)
 661 {
 662         my ($self) = @_;
 663         return $self->{connector}->fds();
 664 }
 665
 666
 667
 668
 669
 670
 671 # main program... a gateway between IRC and DarkPlaces servers
 672 package main;
 673
 674 use strict;
 675 use warnings;
 676 use IO::Select;
 677 use Digest::SHA;
 678 use Digest::HMAC;
 679 use Time::HiRes qw/time/;
 680
 681 our @handlers = (); # list of [channel, expression, sub to handle result]
 682 our @tasks = (); # list of [time, sub]
 683 our %channels = ();
 684 our %store = (
 685         irc_nick => "",
 686         playernick_byid_0 => "(console)",
 687 );
 688 our %config = (
 689         irc_server => undef,
 690         irc_nick => undef,
 691         irc_nick_alternates => "",
 692         irc_user => undef,
 693         irc_channel => undef,
 694         irc_ping_delay => 120,
 695         irc_trigger => "",
 696
 697         irc_nickserv_password => "",
 698         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
 699         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
 700         irc_nickserv_ghost_attempts => 3,
 701
 702         irc_quakenet_authname => "",
 703         irc_quakenet_password => "",
 704         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
 705         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
 706         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
 707
 708         irc_announce_slotsfree => 1,
 709         irc_announce_mapchange => 'always',
 710
 711         dp_server => undef,
 712         dp_secure => 1,
 713         dp_secure_challengetimeout => 1,
 714         dp_listen => "",
 715         dp_password => undef,
 716         dp_status_delay => 30,
 717         dp_server_from_wan => "",
 718         irc_local => "",
 719
 720         irc_admin_password => "",
 721         irc_admin_timeout => 3600,
 722         irc_admin_quote_re => "",
 723
 724         irc_reconnect_delay => 300,
 725
 726         plugins => "",
 727 );
 728
 729
 730
 731 # Nexuiz specific parsing of some server messages
 732
 733 sub nex_slotsstring()
 734 {
 735         my $slotsstr = "";
 736         if(defined $store{slots_max})
 737         {
 738                 my $slots = $store{slots_max} - $store{slots_active};
 739                 my $slots_s = ($slots == 1) ? '' : 's';
 740                 $slotsstr = " ($slots free slot$slots_s)";
 741                 my $s = $config{dp_server_from_wan} || $config{dp_server};
 742                 $slotsstr .= "; join now: \002nexuiz +connect $s"
 743                         if $slots >= 1 and not $store{lms_blocked};
 744         }
 745         return $slotsstr;
 746 }
 747
 748
 749
 750 # Do we have a config file? If yes, read and parse it (syntax: key = value
 751 # pairs, separated by newlines), if not, complain.
 752 die "Usage: $0 configfile\n"
 753         unless @ARGV == 1;
 754
 755 open my $fh, "<", $ARGV[0]
 756         or die "open $ARGV[0]: $!";
 757 while(<$fh>)
 758 {
 759         chomp;
 760         /^#/ and next;
 761         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
 762         warn "Undefined config item: $1"
 763                 unless exists $config{$1};
 764         $config{$1} = defined $2 ? $2 : "";
 765 }
 766 close $fh;
 767 my @missing = grep { !defined $config{$_} } keys %config;
 768 die "The following config items are missing: @missing"
 769         if @missing;
 770
 771
 772
 773 # Create a channel for error messages and other internal status messages...
 774
 775 $channels{system} = new Channel::FIFO();
 776
 777 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
 778 # received, try to shut down cleanly, and if such a signal is received a second
 779 # time, just exit)
 780 my $quitting = 0;
 781 $SIG{INT} = sub {
 782         exit 1 if $quitting++;
 783         $channels{system}->send("quit SIGINT");
 784 };
 785 $SIG{TERM} = sub {
 786         exit 1 if $quitting++;
 787         $channels{system}->send("quit SIGTERM");
 788 };
 789
 790
 791
 792 # Create the two channels to gateway between...
 793
 794 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
 795 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password}, $config{dp_secure}, $config{dp_secure_challengetimeout});
 796 $config{dp_listen} = $dpsock->sockname();
 797 print "Listening on $config{dp_listen}\n";
 798
 799 $channels{irc}->throttle(0.5, 5);
 800
 801
 802 # Utility routine to write to a channel by name, also outputting what's been written and some status
 803 sub out($$@)
 804 {
 805         my $chanstr = shift;
 806         my $nothrottle = shift;
 807         my $chan = $channels{$chanstr};
 808         if(!$chan)
 809         {
 810                 print "UNDEFINED: $chanstr, ignoring message\n";
 811                 return;
 812         }
 813         @_ = $chan->join_commands(@_);
 814         for(@_)
 815         {
 816                 my $result = $chan->send($_, $nothrottle);
 817                 if($result > 0)
 818                 {
 819                         print "           $chanstr << $_\n";
 820                 }
 821                 elsif($result < 0)
 822                 {
 823                         print "FLOOD:     $chanstr << $_\n";
 824                 }
 825                 else
 826                 {
 827                         print "ERROR:     $chanstr << $_\n";
 828                         $channels{system}->send("error $chanstr", 0);
 829                 }
 830         }
 831 }
 832
 833
 834
 835 # Schedule a task for later execution by the main loop; usage: schedule sub {
 836 # task... }, $time; When a scheduled task is run, a reference to the task's own
 837 # sub is passed as first argument; that way, the task is able to re-schedule
 838 # itself so it gets periodically executed.
 839 sub schedule($$)
 840 {
 841         my ($sub, $time) = @_;
 842         push @tasks, [time() + $time, $sub];
 843 }
 844
 845 # On IRC error, delete some data store variables of the connection, and
 846 # reconnect to the IRC server soon (but only if someone is actually playing)
 847 sub irc_error()
 848 {
 849         # prevent multiple instances of this timer
 850         return if $store{irc_error_active};
 851         $store{irc_error_active} = 1;
 852
 853         delete $channels{irc};
 854         schedule sub {
 855                 my ($timer) = @_;
 856                 if(!defined $store{slots_active})
 857                 {
 858                         # DP is not running, then delay IRC reconnecting
 859                         #use Data::Dumper; print Dumper \$timer;
 860                         schedule $timer => 1;
 861                         return;
 862                         # this will keep irc_error_active
 863                 }
 864                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => "" => $config{irc_server} => 6667));
 865                 delete $store{$_} for grep { /^irc_/ } keys %store;
 866                 $store{irc_nick} = "";
 867                 schedule sub {
 868                         my ($timer) = @_;
 869                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
 870                         $store{status_waiting} = -1;
 871                 } => 1;
 872                 # this will clear irc_error_active
 873         } => $config{irc_reconnect_delay};
 874         return 0;
 875 }
 876
 877 sub uniq(@)
 878 {
 879         my @out = ();
 880         my %found = ();
 881         for(@_)
 882         {
 883                 next if $found{$_}++;
 884                 push @out, $_;
 885         }
 886         return @out;
 887 }
 888
 889 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
 890 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
 891 # until the channel has been joined for every message that may be "interesting" (basically,
 892 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
 893 sub irc_joinstage($)
 894 {
 895         my($is433) = @_;
 896
 897         return 0
 898                 if $store{irc_joined_channel};
 899
 900                 #use Data::Dumper; print Dumper \%store;
 901
 902         if($is433)
 903         {
 904                 if(length $store{irc_nick})
 905                 {
 906                         # we already have another nick, but couldn't change to the new one
 907                         # try ghosting and then get the nick again
 908                         if(length $config{irc_nickserv_password})
 909                         {
 910                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 911                                 {
 912                                         $store{irc_nick_requested} = $config{irc_nick};
 913                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 914                                         schedule sub {
 915                                                 out irc => 1, "NICK $config{irc_nick}";
 916                                         } => 1;
 917                                         return; # we'll get here again for the NICK success message, or for a 433 failure
 918                                 }
 919                                 # otherwise, we failed to ghost and will continue with the wrong
 920                                 # nick... also, no need to try to identify here
 921                         }
 922                         # otherwise, we can't handle this and will continue with our wrong nick
 923                 }
 924                 else
 925                 {
 926                         # we failed to get an initial nickname
 927                         # change ours a bit and try again
 928
 929                         my @alternates = uniq ($config{irc_nick}, grep { $_ ne "" } split /\s+/, $config{irc_nick_alternates});
 930                         my $nextnick = undef;
 931                         for(0..@alternates-2)
 932                         {
 933                                 if($store{irc_nick_requested} eq $alternates[$_])
 934                                 {
 935                                         $nextnick = $alternates[$_+1];
 936                                 }
 937                         }
 938                         if($store{irc_nick_requested} eq $alternates[@alternates-1]) # this will only happen once
 939                         {
 940                                 $store{irc_nick_requested} = $alternates[0];
 941                                 # but don't set nextnick, so we edit it
 942                         }
 943                         if(defined $nextnick)
 944                         {
 945                                 $store{irc_nick_requested} = $nextnick;
 946                         }
 947                         else
 948                         {
 949                                 for(;;)
 950                                 {
 951                                         if(length $store{irc_nick_requested} < 9)
 952                                         {
 953                                                 $store{irc_nick_requested} .= '_';
 954                                         }
 955                                         else
 956                                         {
 957                                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
 958                                         }
 959                                         last unless grep { $_ eq $store{irc_nick_requested} } @alternates;
 960                                 }
 961                         }
 962                         out irc => 1, "NICK $store{irc_nick_requested}";
 963                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
 964                 }
 965         }
 966
 967         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
 968         if(length $config{irc_nickserv_password})
 969         {
 970                 if($store{irc_nick} eq $config{irc_nick})
 971                 {
 972                         # identify
 973                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
 974                 }
 975                 else
 976                 {
 977                         # ghost
 978                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 979                         {
 980                                 $store{irc_nick_requested} = $config{irc_nick};
 981                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 982                                 schedule sub {
 983                                         out irc => 1, "NICK $config{irc_nick}";
 984                                 } => 1;
 985                                 return; # we'll get here again for the NICK success message, or for a 433 failure
 986                         }
 987                         # otherwise, we failed to ghost and will continue with the wrong
 988                         # nick... also, no need to try to identify here
 989                 }
 990         }
 991
 992         # we are on Quakenet. Try to authenticate.
 993         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
 994         {
 995                 if(defined $store{irc_quakenet_challenge})
 996                 {
 997                         if($store{irc_quakenet_challenge} =~ /^([0-9a-f]*)\b.*\bHMAC-SHA-256\b/)
 998                         {
 999                                 my $challenge = $1;
1000                                 my $hash1 = Digest::SHA::sha256_hex(substr $config{irc_quakenet_password}, 0, 10);
1001                                 my $key = Digest::SHA::sha256_hex("@{[lc $config{irc_quakenet_authname}]}:$hash1");
1002                                 my $digest = Digest::HMAC::hmac_hex($challenge, $key, \&Digest::SHA::sha256);
1003                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} $digest HMAC-SHA-256";
1004                         }
1005                 }
1006                 else
1007                 {
1008                         out irc => 1, $config{irc_quakenet_getchallenge};
1009                         return;
1010                         # we get here again when Q asks us
1011                 }
1012         }
1013
1014         # if we get here, we are on IRC
1015         $store{irc_joined_channel} = 1;
1016         schedule sub {
1017                 out irc => 1, "JOIN $config{irc_channel}";
1018         } => 1;
1019         return 0;
1020 }
1021
1022 my $RE_FAIL = qr/$ $/;
1023 my $RE_SUCCEED = qr//;
1024 sub cond($)
1025 {
1026         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
1027 }
1028
1029
1030 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
1031 @handlers = (
1032         # detect a server restart and set it up again
1033         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
1034                 out dp => 0,
1035                         'alias rcon2irc_eval "$*"',
1036                         'log_dest_udp',
1037                         'sv_logscores_console 0',
1038                         'sv_logscores_bots 1',
1039                         'sv_eventlog 1',
1040                         'sv_eventlog_console 1',
1041                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
1042                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
1043                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
1044                 return 0;
1045         } ],
1046
1047         # detect missing entry in log_dest_udp and fix it
1048         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
1049                 my ($dest) = @_;
1050                 my @dests = split ' ', $dest;
1051                 return 0 if grep { $_ eq $config{dp_listen} } @dests;
1052                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, $config{dp_listen}) . '"';
1053                 return 0;
1054         } ],
1055
1056         # retrieve list of banned hosts
1057         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
1058                 return 0 unless $store{status_waiting} < 0;
1059                 my ($id, $ip, $time) = @_;
1060                 $store{bans_new} = [] if $id == 0;
1061                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
1062                 return 0;
1063         } ],
1064
1065         # retrieve hostname from status replies
1066         [ dp => q{host:     (.*)} => sub {
1067                 return 0 unless $store{status_waiting} < 0;
1068                 my ($name) = @_;
1069                 $store{dp_hostname} = $name;
1070                 $store{bans} = $store{bans_new};
1071                 return 0;
1072         } ],
1073
1074         # retrieve version from status replies
1075         [ dp => q{version:  (.*)} => sub {
1076                 return 0 unless $store{status_waiting} < 0;
1077                 my ($version) = @_;
1078                 $store{dp_version} = $version;
1079                 return 0;
1080         } ],
1081
1082         # retrieve player names
1083         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
1084                 return 0 unless $store{status_waiting} < 0;
1085                 my ($active, $max) = @_;
1086                 my $full = ($active >= $max);
1087                 $store{slots_max} = $max;
1088                 $store{slots_active} = $active;
1089                 $store{status_waiting} = $active;
1090                 $store{playerslots_active_new} = [];
1091                 if($store{status_waiting} == 0)
1092                 {
1093                         $store{playerslots_active} = $store{playerslots_active_new};
1094                 }
1095                 if($full != ($store{slots_full} || 0))
1096                 {
1097                         $store{slots_full} = $full;
1098                         return 0 if $store{lms_blocked};
1099                         return 0 if !$config{irc_announce_slotsfree};
1100                         if($full)
1101                         {
1102                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1103                         }
1104                         else
1105                         {
1106                                 my $slotsstr = nex_slotsstring();
1107                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1108                         }
1109                 }
1110                 return 0;
1111         } ],
1112
1113         # retrieve player names
1114         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1115                 return 0 unless $store{status_waiting} > 0;
1116                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1117                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1118                 push @{$store{playerslots_active_new}}, $no;
1119                 if(--$store{status_waiting} == 0)
1120                 {
1121                         $store{playerslots_active} = $store{playerslots_active_new};
1122                 }
1123                 return 0;
1124         } ],
1125
1126         # IRC admin commands
1127         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1128                 return 0 unless $config{irc_admin_password} ne '';
1129
1130                 my ($hostmask, $nick, $command) = @_;
1131                 my $dpnick = color_dpfix $nick;
1132
1133                 if($command eq "login $config{irc_admin_password}")
1134                 {
1135                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1136                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1137                         return -1;
1138                 }
1139
1140                 if($command =~ /^login /)
1141                 {
1142                         out irc => 0, "PRIVMSG $nick :invalid password";
1143                         return -1;
1144                 }
1145
1146                 if(($store{logins}{$hostmask} || 0) < time())
1147                 {
1148                         out irc => 0, "PRIVMSG $nick :authentication required";
1149                         return -1;
1150                 }
1151
1152                 if($command =~ /^status(?: (.*))?$/)
1153                 {
1154                         my ($match) = $1;
1155                         my $found = 0;
1156                         my $foundany = 0;
1157                         for my $slot(@{$store{playerslots_active} || []})
1158                         {
1159                                 my $s = $store{"playerslot_$slot"};
1160                                 next unless $s;
1161                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1162                                 {
1163                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1164                                         ++$found;
1165                                 }
1166                                 ++$foundany;
1167                         }
1168                         if(!$found)
1169                         {
1170                                 if(!$foundany)
1171                                 {
1172                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1173                                 }
1174                                 else
1175                                 {
1176                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1177                                 }
1178                         }
1179                         return 0;
1180                 }
1181
1182                 if($command =~ /^kick # (\d+) (.*)$/)
1183                 {
1184                         my ($id, $reason) = ($1, $2);
1185                         my $dpreason = color_irc2dp $reason;
1186                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1187                         $dpreason =~ s/(["\\])/\\$1/g;
1188                         out dp => 0, "kick # $id $dpreason";
1189                         my $slotnik = "playerslot_$id";
1190                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip}) ($reason)";
1191                         return 0;
1192                 }
1193
1194                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1195                 {
1196                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1197                         my $dpreason = color_irc2dp $reason;
1198                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1199                         $dpreason =~ s/(["\\])/\\$1/g;
1200                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1201                         my $slotnik = "playerslot_$id";
1202                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1203                         return 0;
1204                 }
1205
1206                 if($command eq "bans")
1207                 {
1208                         my $banlist =
1209                                 join ", ",
1210                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1211                                 0..@{$store{bans} || []}-1;
1212                         $banlist = "no bans"
1213                                 if $banlist eq "";
1214                         out irc => 0, "PRIVMSG $nick :$banlist";
1215                         return 0;
1216                 }
1217
1218                 if($command =~ /^unban (\d+)$/)
1219                 {
1220                         my ($id) = ($1);
1221                         out dp => 0, "unban $id";
1222                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1223                         return 0;
1224                 }
1225
1226                 if($command =~ /^mute (\d+)$/)
1227                 {
1228                         my $id = $1;
1229                         out dp => 0, "mute $id";
1230                         my $slotnik = "playerslot_$id";
1231                         out irc => 0, "PRIVMSG $nick :muted $id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip})";
1232                         return 0;
1233                 }
1234
1235                 if($command =~ /^unmute (\d+)$/)
1236                 {
1237                         my ($id) = ($1);
1238                         out dp => 0, "unmute $id";
1239                         my $slotnik = "playerslot_$id";
1240                         out irc => 0, "PRIVMSG $nick :unmuted $id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip})";
1241                         return 0;
1242                 }
1243
1244                 if($command =~ /^quote (.*)$/)
1245                 {
1246                         my ($cmd) = ($1);
1247                         if($cmd =~ /^(??{$config{irc_admin_quote_re}})$/si)
1248                         {
1249                                 out irc => 0, $cmd;
1250                                 out irc => 0, "PRIVMSG $nick :executed your command";
1251                         }
1252                         else
1253                         {
1254                                 out irc => 0, "PRIVMSG $nick :permission denied";
1255                         }
1256                         return 0;
1257                 }
1258
1259                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid, mute id, unmute id)";
1260
1261                 return -1;
1262         } ],
1263
1264         # LMS: detect "no more lives" message
1265         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1266                 if(!$store{lms_blocked})
1267                 {
1268                         $store{lms_blocked} = 1;
1269                         if(!$store{slots_full})
1270                         {
1271                                 schedule sub {
1272                                         if($store{lms_blocked})
1273                                         {
1274                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1275                                         }
1276                                 } => 1;
1277                         }
1278                 }
1279         } ],
1280
1281         # detect IRC errors and reconnect
1282         [ irc => q{ERROR .*} => \&irc_error ],
1283         [ irc => q{:[^ ]* 404 .*} => \&irc_error ], # cannot send to channel
1284         [ system => q{error irc} => \&irc_error ],
1285
1286         # IRC nick in use
1287         [ irc => q{:[^ ]* 433 .*} => sub {
1288                 return irc_joinstage(433);
1289         } ],
1290
1291         # IRC welcome
1292         [ irc => q{:[^ ]* 001 .*} => sub {
1293                 $store{irc_seen_welcome} = 1;
1294                 $store{irc_nick} = $store{irc_nick_requested};
1295                 return irc_joinstage(0);
1296         } ],
1297
1298         # IRC my nickname changed
1299         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1300                 my ($n) = @_;
1301                 $store{irc_nick} = $n;
1302                 return irc_joinstage(0);
1303         } ],
1304
1305         # Quakenet: challenge from Q
1306         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1307                 $store{irc_quakenet_challenge} = $1;
1308                 return irc_joinstage(0);
1309         } ],
1310
1311         # shut down everything on SIGINT
1312         [ system => q{quit (.*)} => sub {
1313                 my ($cause) = @_;
1314                 out irc => 1, "QUIT :$cause";
1315                 $store{quitcookie} = int rand 1000000000;
1316                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1317         } ],
1318
1319         # remove myself from the log destinations and exit everything
1320         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1321                 my ($dest) = @_;
1322                 my @dests = grep { $_ ne $config{dp_listen} } split ' ', $dest;
1323                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1324                 exit 0;
1325                 return 0;
1326         } ],
1327
1328         # IRC PING
1329         [ irc => q{PING (.*)} => sub {
1330                 my ($data) = @_;
1331                 out irc => 1, "PONG $data";
1332                 return 1;
1333         } ],
1334
1335         # IRC PONG
1336         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1337                 my ($data) = @_;
1338                 return 0
1339                         if not defined $store{irc_pingtime};
1340                 return 0
1341                         if $data ne $store{irc_pingtime};
1342                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1343                 undef $store{irc_pingtime};
1344                 return 0;
1345         } ],
1346
1347         # detect channel join message and note hostname length to get the maximum allowed line length
1348         [ irc => q{(:(?i:(??{$store{irc_nick}}))![^ ]* )(?i:JOIN) :(?i:(??{$config{irc_channel}}))} => sub {
1349                 $store{irc_maxlen} = 510 - length($1);
1350                 $store{irc_joined_channel} = 1;
1351                 print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1352                 return 0;
1353         } ],
1354
1355         # chat: Nexuiz server -> IRC channel
1356         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1357                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1358                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1359                 return 0;
1360         } ],
1361
1362         # chat: Nexuiz server -> IRC channel, nick set
1363         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1364                 my ($id, $slot, $ip, $nick) = @_;
1365                 $store{"playernickraw_byid_$id"} = $nick;
1366                 $nick = color_dp2irc $nick;
1367                 $store{"playernick_byid_$id"} = $nick;
1368                 $store{"playerip_byid_$id"} = $ip;
1369                 $store{"playerslot_byid_$id"} = $slot;
1370                 $store{"playerid_byslot_$slot"} = $id;
1371                 return 0;
1372         } ],
1373
1374         # chat: Nexuiz server -> IRC channel, nick change/set
1375         [ dp => q{:name:(\d+):(.*)} => sub {
1376                 my ($id, $nick) = @_;
1377                 $store{"playernickraw_byid_$id"} = $nick;
1378                 $nick = color_dp2irc $nick;
1379                 my $oldnick = $store{"playernick_byid_$id"};
1380                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1381                 $store{"playernick_byid_$id"} = $nick;
1382                 return 0;
1383         } ],
1384
1385         # chat: Nexuiz server -> IRC channel, vote call
1386         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1387                 my ($id, $command) = @_;
1388                 $command = color_dp2irc $command;
1389                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1390                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1391                 return 0;
1392         } ],
1393
1394         # chat: Nexuiz server -> IRC channel, vote stop
1395         [ dp => q{:vote:vstop:(\d+)} => sub {
1396                 my ($id) = @_;
1397                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1398                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1399                 return 0;
1400         } ],
1401
1402         # chat: Nexuiz server -> IRC channel, master login
1403         [ dp => q{:vote:vlogin:(\d+)} => sub {
1404                 my ($id) = @_;
1405                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1406                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1407                 return 0;
1408         } ],
1409
1410         # chat: Nexuiz server -> IRC channel, master do
1411         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1412                 my ($id, $command) = @_;
1413                 $command = color_dp2irc $command;
1414                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1415                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1416                 return 0;
1417         } ],
1418
1419         # chat: Nexuiz server -> IRC channel, result
1420         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1421                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1422                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1423                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1424                 return 0;
1425         } ],
1426
1427         # chat: IRC channel -> Nexuiz server
1428         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1429                 my ($nick, $message) = @_;
1430                 $nick = color_dpfix $nick;
1431                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1432                 $message = color_irc2dp $message;
1433                 $message =~ s/(["\\])/\\$1/g;
1434                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1435                 return 0;
1436         } ],
1437
1438         (
1439                 length $config{irc_trigger}
1440                         ?
1441                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1442                                         my ($nick, $message) = @_;
1443                                         $nick = color_dpfix $nick;
1444                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1445                                         $message = color_irc2dp $message;
1446                                         $message =~ s/(["\\])/\\$1/g;
1447                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1448                                         return 0;
1449                                 } ]
1450                         :
1451                                 ()
1452         ),
1453
1454         # irc: CTCP VERSION reply
1455         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1456                 my ($nick) = @_;
1457                 my $ver = $store{dp_version} or return 0;
1458                 $ver .= ", rcon2irc $VERSION";
1459                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1460         } ],
1461
1462         # on game start, notify the channel
1463         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1464                 my ($map) = @_;
1465                 $store{playing} = 1;
1466                 $store{map} = $map;
1467                 $store{map_starttime} = time();
1468                 if ($config{irc_announce_mapchange} eq 'always' || ($config{irc_announce_mapchange} eq 'notempty' && $store{slots_active} > 0)) {
1469                         my $slotsstr = nex_slotsstring();
1470                         out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1471                 }
1472                 delete $store{lms_blocked};
1473                 return 0;
1474         } ],
1475
1476         # on game over, clear the current map
1477         [ dp => q{:gameover} => sub {
1478                 $store{playing} = 0;
1479                 return 0;
1480         } ],
1481
1482         # scores: Nexuiz server -> IRC channel (start)
1483         [ dp => q{:scores:(.*):(\d+)} => sub {
1484                 my ($map, $time) = @_;
1485                 $store{scores} = {};
1486                 $store{scores}{map} = $map;
1487                 $store{scores}{time} = $time;
1488                 $store{scores}{players} = [];
1489                 delete $store{lms_blocked};
1490                 return 0;
1491         } ],
1492
1493         # scores: Nexuiz server -> IRC channel, legacy format
1494         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1495                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1496                 return if not exists $store{scores};
1497                 push @{$store{scores}{players}}, [$frags, $team, $name]
1498                         unless $frags <= -666; # no spectators
1499                 return 0;
1500         } ],
1501
1502         # scores: Nexuiz server -> IRC channel (CTF), legacy format
1503         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1504                 my ($teams) = @_;
1505                 return if not exists $store{scores};
1506                 $store{scores}{teams} = {split /:/, $teams};
1507                 return 0;
1508         } ],
1509
1510         # scores: Nexuiz server -> IRC channel, new format
1511         [ dp => q{:player:see-labels:(-?\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1512                 my ($frags, $time, $team, $id, $name) = @_;
1513                 return if not exists $store{scores};
1514                 push @{$store{scores}{players}}, [$frags, $team, $name];
1515                 return 0;
1516         } ],
1517
1518         # scores: Nexuiz server -> IRC channel (CTF), new format
1519         [ dp => q{:teamscores:see-labels:(-?\d+)[-0-9,]*:(\d+)} => sub {
1520                 my ($frags, $team) = @_;
1521                 return if not exists $store{scores};
1522                 $store{scores}{teams}{$team} = $frags;
1523                 return 0;
1524         } ],
1525
1526         # scores: Nexuiz server -> IRC channel
1527         [ dp => q{:end} => sub {
1528                 return if not exists $store{scores};
1529                 my $s = $store{scores};
1530                 delete $store{scores};
1531                 my $teams_matter = defined $s->{teams};
1532
1533                 my @t = ();
1534                 my @p = ();
1535
1536                 if($teams_matter)
1537                 {
1538                         # put players into teams
1539                         my %t = ();
1540                         for(@{$s->{players}})
1541                         {
1542                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1543                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1544                                 if($s->{teams})
1545                                 {
1546                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1547                                 }
1548                                 else
1549                                 {
1550                                         $thisteam->{score} += $_->[0];
1551                                 }
1552                         }
1553
1554                         # sort by team score
1555                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1556
1557                         # sort by player score
1558                         @p = ();
1559                         for(@t)
1560                         {
1561                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1562                                 push @p, @{$_->{players}};
1563                         }
1564                 }
1565                 else
1566                 {
1567                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1568                 }
1569
1570                 # no display for empty server
1571                 return 0
1572                         if !@p;
1573
1574                 # make message fit somehow
1575                 for my $maxnamelen(reverse 3..64)
1576                 {
1577                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1578                         if($teams_matter)
1579                         {
1580                                 my $sep = ' ';
1581                                 for(@t)
1582                                 {
1583                                         $scores_string .= $sep . "\003" . $color_team2irc_table{$_->{team}}. "\002\002" . $_->{score} . "\017";
1584                                         $sep = ':';
1585                                 }
1586                         }
1587                         my $sep = '';
1588                         for(@p)
1589                         {
1590                                 my ($frags, $team, $name) = @$_;
1591                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1592                                 if($teams_matter)
1593                                 {
1594                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1595                                 }
1596                                 else
1597                                 {
1598                                         $name = " " . color_dp2irc $name;
1599                                 }
1600                                 $scores_string .= "$sep$name\017 $frags";
1601                                 $sep = ',';
1602                         }
1603                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1604                         {
1605                                 out irc => 0, $scores_string;
1606                                 return 0;
1607                         }
1608                 }
1609                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1610                 return 0;
1611         } ],
1612
1613         # complain when system load gets too high
1614         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1615                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1616                 return 0 # don't complain when just on the voting screen
1617                         if !$store{playing};
1618                 return 0 # don't complain if it was less than 0.5%
1619                         if $lost < 0.5;
1620                 return 0 # don't complain if nobody is looking
1621                         if $store{slots_active} == 0;
1622                 return 0 # don't complain in the first two minutes
1623                         if time() - $store{map_starttime} < 120;
1624                 return 0 # don't complain if it was already at least half as bad in this round
1625                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1626                 $store{timingerror_map_starttime} = $store{map_starttime};
1627                 $store{timingerror_lost} = $lost;
1628                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1629                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1630                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1631                 return 0;
1632         } ],
1633 );
1634
1635
1636
1637 # Load plugins and add them to the handler list in the front.
1638 for my $p(split ' ', $config{plugins})
1639 {
1640         my @h = eval { do $p; }
1641                 or die "Invalid plugin $p: $@";
1642         for(reverse @h)
1643         {
1644                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1645                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1646                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1647                 unshift @handlers, $_;
1648         }
1649 }
1650
1651
1652
1653 # verify that the server is up by letting it echo back a string that causes
1654 # re-initialization of the required aliases
1655 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1656
1657
1658
1659 # regularily, query the server status and if it still is connected to us using
1660 # the log_dest_udp feature. If not, we will detect the response to this rcon
1661 # command and re-initialize the server's connection to us (either by log_dest_udp
1662 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1663 schedule sub {
1664         my ($timer) = @_;
1665         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1666         $store{status_waiting} = -1;
1667         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1668 } => 1;
1669
1670
1671
1672 # Continue with connecting to IRC as soon as we get our first status reply from
1673 # the DP server (which contains the server's hostname that we'll use as
1674 # realname for IRC).
1675 schedule sub {
1676         my ($timer) = @_;
1677
1678         # log on to IRC when needed
1679         if(exists $store{dp_hostname} && !exists $store{irc_logged_in})
1680         {
1681                 $store{irc_nick_requested} = $config{irc_nick};
1682                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1683                 $store{irc_logged_in} = 1;
1684                 undef $store{irc_maxlen};
1685                 undef $store{irc_pingtime};
1686         }
1687
1688         schedule $timer => 1;;
1689 } => 1;
1690
1691
1692
1693 # Regularily ping the IRC server to detect if the connection is down. If it is,
1694 # schedule an IRC error that will cause reconnection later.
1695 schedule sub {
1696         my ($timer) = @_;
1697
1698         if($store{irc_logged_in})
1699         {
1700                 if(defined $store{irc_pingtime})
1701                 {
1702                         # IRC connection apparently broke
1703                         # so... KILL IT WITH FIRE
1704                         $channels{system}->send("error irc", 0);
1705                 }
1706                 else
1707                 {
1708                         # everything is fine, send a new ping
1709                         $store{irc_pingtime} = time();
1710                         out irc => 1, "PING $store{irc_pingtime}";
1711                 }
1712         }
1713
1714         schedule $timer => $config{irc_ping_delay};;
1715 } => 1;
1716
1717
1718
1719 # Main loop.
1720 for(;;)
1721 {
1722         # Build up an IO::Select object for all our channels.
1723         my $s = IO::Select->new();
1724         for my $chan(values %channels)
1725         {
1726                 $s->add($_) for $chan->fds();
1727         }
1728
1729         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1730         $s->can_read(2);
1731         my @errors = $s->has_exception(0);
1732
1733         # on every channel, look for incoming messages
1734         CHANNEL:
1735         for my $chanstr(keys %channels)
1736         {
1737                 my $chan = $channels{$chanstr};
1738                 my @chanfds = $chan->fds();
1739
1740                 for my $chanfd(@chanfds)
1741                 {
1742                         if(grep { $_ == $chanfd } @errors)
1743                         {
1744                                 # STOP! This channel errored!
1745                                 $channels{system}->send("error $chanstr", 0);
1746                                 next CHANNEL;
1747                         }
1748                 }
1749
1750                 eval
1751                 {
1752                         for my $line($chan->recv())
1753                         {
1754                                 # found one! Check if it matches the regular expression of one of
1755                                 # our handlers...
1756                                 my $handled = 0;
1757                                 my $private = 0;
1758                                 for my $h(@handlers)
1759                                 {
1760                                         my ($chanstr_wanted, $re, $sub) = @$h;
1761                                         next
1762                                                 if $chanstr_wanted ne $chanstr;
1763                                         use re 'eval';
1764                                         my @matches = ($line =~ /^$re$/s);
1765                                         no re 'eval';
1766                                         next
1767                                                 unless @matches;
1768                                         # and if it is a match, handle it.
1769                                         ++$handled;
1770                                         my $result = $sub->(@matches);
1771                                         $private = 1
1772                                                 if $result < 0;
1773                                         last
1774                                                 if $result;
1775                                 }
1776                                 # print the message, together with info on whether it has been handled or not
1777                                 if($private)
1778                                 {
1779                                         print "           $chanstr >> (private)\n";
1780                                 }
1781                                 elsif($handled)
1782                                 {
1783                                         print "           $chanstr >> $line\n";
1784                                 }
1785                                 else
1786                                 {
1787                                         print "unhandled: $chanstr >> $line\n";
1788                                 }
1789                         }
1790                         1;
1791                 } or do {
1792                         if($@ eq "read error\n")
1793                         {
1794                                 $channels{system}->send("error $chanstr", 0);
1795                                 next CHANNEL;
1796                         }
1797                         else
1798                         {
1799                                 # re-throw
1800                                 die $@;
1801                         }
1802                 };
1803         }
1804
1805         # handle scheduled tasks...
1806         my @t = @tasks;
1807         my $t = time();
1808         # by emptying the list of tasks...
1809         @tasks = ();
1810         for(@t)
1811         {
1812                 my ($time, $sub) = @$_;
1813                 if($t >= $time)
1814                 {
1815                         # calling them if they are schedled for the "past"...
1816                         $sub->($sub);
1817                 }
1818                 else
1819                 {
1820                         # or re-adding them to the task list if they still are scheduled for the "future"
1821                         push @tasks, [$time, $sub];
1822                 }
1823         }
1824 }