qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 string ValidateMap(string vote);
   3 void(entity e) DropFlag;
   4 string MapVote_Suggest(string m);
   5
   6 .float floodcontrol_chat;
   7 .float floodcontrol_team;
   8 void Say(entity source, float teamsay, string msgin)
   9 {
  10         string msgstr, colorstr, cmsgstr, namestr;
  11         float flood;
  12         entity head;
  13
  14         if(!teamsay)
  15                 if(substring(msgin, 0, 1) == " ")
  16                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  17
  18         msgin = formatmessage(msgin);
  19
  20         if(msgin == "")
  21                 return;
  22
  23         colorstr = Team_ColorCode(source.team);
  24
  25         if(!teams_matter)
  26                 teamsay = FALSE;
  27
  28         if(intermission_running)
  29                 teamsay = FALSE;
  30
  31         if(source.classname != "player") // observers can't
  32                 teamsay = FALSE;
  33
  34         /*
  35          * using bprint solves this... me stupid
  36         // how can we prevent the message from appearing in a listen server?
  37         // for now, just give "say" back and only handle say_team
  38         if(!teamsay)
  39         {
  40                 clientcommand(self, strcat("say ", msgin));
  41                 return;
  42         }
  43         */
  44
  45         if(cvar("g_chat_teamcolors"))
  46                 namestr = playername(source);
  47         else
  48                 namestr = source.netname;
  49         if(teamsay)
  50         {
  51                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  52                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  53         }
  54         else
  55                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  56
  57         // FLOOD CONTROL
  58         flood = 0;
  59         {
  60                 float flood_spl;
  61                 float flood_burst;
  62                 float flood_lmax;
  63                 var .float flood_field;
  64                 float lines;
  65                 if(teamsay)
  66                 {
  67                         flood_spl = cvar("g_chat_flood_spl_team");
  68                         flood_burst = cvar("g_chat_flood_burst_team");
  69                         flood_lmax = cvar("g_chat_flood_lmax_team");
  70                         flood_field = floodcontrol_team;
  71                 }
  72                 else
  73                 {
  74                         flood_spl = cvar("g_chat_flood_spl");
  75                         flood_burst = cvar("g_chat_flood_burst");
  76                         flood_lmax = cvar("g_chat_flood_lmax");
  77                         flood_field = floodcontrol_chat;
  78                 }
  79                 flood_burst = max(0, flood_burst - 1);
  80                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  81                 lines = ceil(strlennocol(msgstr) / 75);
  82                 if(flood_lmax && lines > flood_lmax)
  83                         flood = 2;
  84                 else if(time >= self.flood_field)
  85                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  86                 else
  87                         flood = 1;
  88         }
  89
  90         if(flood)
  91         {
  92                 if(cvar("g_chat_flood_notify_flooder"))
  93                 {
  94                         if(flood == 1)
  95                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  96                         else if(flood == 2)
  97                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  98                 }
  99                 else
 100                         sprint(self, msgstr);
 101                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
 102         }
 103         else if(teamsay)
 104         {
 105                 FOR_EACH_REALPLAYER(head)
 106                 {
 107                         if(head.team == source.team)
 108                         {
 109                                 sprint(head, msgstr);
 110                                 centerprint(head, cmsgstr);
 111                         }
 112                 }
 113         }
 114         else
 115         {
 116                 bprint(msgstr);
 117                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
 118         }
 119
 120         strunzone(msgstr);
 121 }
 122
 123 string GetKickVoteVictim_newcommand;
 124 entity GetKickVoteVictim(string vote, string cmd)
 125 {
 126         float tokens;
 127         float i, n;
 128         string ns;
 129         entity e;
 130
 131         tokens = tokenize(vote);
 132         ns = "";
 133
 134         if(tokens == 2)
 135                 if(substring(argv(1), 0, 1) == "#")
 136                         ns = substring(argv(1), 1, 999);
 137
 138         if(tokens == 3)
 139                 if(argv(1) == "#")
 140                         ns = argv(2);
 141
 142         if(ns != "")
 143         {
 144                 n = stof(ns);
 145                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
 146                 {
 147                         for((e = world), (i = 0); i < n; ++i, (e = nextent(e)))
 148                                 ;
 149                         if(clienttype(e) == CLIENTTYPE_REAL)
 150                         {
 151                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
 152                                 return e;
 153                         }
 154                 }
 155         }
 156
 157         sprint(self, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
 158         return world;
 159 }
 160
 161 void SV_ParseClientCommand(string s) {
 162         local string cmd;
 163         local entity e;
 164
 165         tokenize(s);
 166
 167         if(argv(0) == "vote") {
 168                 if(argv(1) == "help") {
 169                         local string vmasterdis;
 170                         if(!cvar("sv_vote_master")) {
 171                                 vmasterdis = " ^1(disabled)";
 172                         }
 173                         local string vcalldis;
 174                         if(!cvar("sv_vote_call")) {
 175                                 vcalldis = " ^1(disabled)";
 176                         }
 177                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
 178                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
 179                         sprint(self, "^7\"^2help^7\" shows this info.\n");
 180                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
 181                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
 182                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
 183                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
 184                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
 185                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
 186                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
 187                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
 188                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
 189                         sprint(self, "^7You can call a vote for or execute these commands:\n");
 190                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
 191                 } else if(argv(1) == "status") {
 192                         if(votecalled) {
 193                                 sprint(self, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", votecaller.netname, "^7.\n"));
 194                         } else {
 195                                 sprint(self, "^1No vote called.\n");
 196                         }
 197                 } else if(argv(1) == "call") {
 198                         if(cvar("sv_vote_call")) {
 199                                 if(votecalled) {
 200                                         sprint(self, "^1There is already a vote called.\n");
 201                                 } else {
 202                                         local string vote;
 203                                         vote = VoteParse();
 204                                         if(vote == "") {
 205                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
 206                                         } else if(time < self.vote_next) {
 207                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
 208                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 209                                                 // remap chmap to gotomap (forces intermission)
 210                                                 if(substring(vote, 0, 6) == "chmap ")
 211                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 212                                                 if(substring(vote, 0, 8) == "gotomap ")
 213                                                 {
 214                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8))))
 215                                                                 return;
 216                                                         vote = strcat("gotomap ", vote);
 217                                                 }
 218
 219                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 220                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
 221                                                 {
 222                                                         if(!(e = GetKickVoteVictim(vote, "vcall")))
 223                                                                 return;
 224                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", e.netname, "^1)"));
 225                                                         vote = GetKickVoteVictim_newcommand;
 226                                                 }
 227                                                 else
 228                                                 {
 229                                                         votecalledvote_display = strzone(strcat("^1", vote));
 230                                                 }
 231                                                 votecalledvote = strzone(vote);
 232                                                 votecalled = TRUE;
 233                                                 votecalledmaster = FALSE;
 234                                                 votecaller = self; // remember who called the vote
 235                                                 votefinished = time + cvar("sv_vote_timeout");
 236                                                 votecaller.vote_vote = 1; // of course you vote yes
 237                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
 238                                                 bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote for ", votecalledvote_display, "\n");
 239                                                 VoteCount(); // needed if you are the only one
 240                                         } else {
 241                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 242                                         }
 243                                 }
 244                         } else {
 245                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 246                         }
 247                 } else if(argv(1) == "stop") {
 248                         if(!votecalled) {
 249                                 sprint(self, "^1No vote called.\n");
 250                         } else if(self == votecaller) { // the votecaller can stop a vote
 251                                 VoteStop(self);
 252                         } else if(self.vote_master) { // masters can, too
 253                                 VoteStop(self);
 254                         } else {
 255                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 256                         }
 257                 } else if(argv(1) == "master") {
 258                         if(cvar("sv_vote_master")) {
 259                                 if(votecalled) {
 260                                         sprint(self, "^1There is already a vote called.\n");
 261                                 } else {
 262                                         votecalled = TRUE;
 263                                         votecalledmaster = TRUE;
 264                                         votecalledvote = strzone("XXX");
 265                                         votecalledvote_display = strzone("^3master");
 266                                         votecaller = self; // remember who called the vote
 267                                         votefinished = time + cvar("sv_vote_timeout");
 268                                         votecaller.vote_vote = 1; // of course you vote yes
 269                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 270                                         bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote to become ^3master^2.\n");
 271                                         VoteCount(); // needed if you are the only one
 272                                 }
 273                         } else {
 274                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 275                         }
 276                 } else if(argv(1) == "do") {
 277                         if(argv(2) == "login") {
 278                                 local string masterpwd;
 279                                 masterpwd = cvar_string("sv_vote_master_password");
 280                                 if(masterpwd != "") {
 281                                         self.vote_master = (masterpwd == argv(3));
 282                                         if(self.vote_master) {
 283                                                 ServerConsoleEcho(strcat("Accepted master login from ", self.netname), TRUE);
 284                                                 bprint("\{1}^2* ^3", self.netname, "^2 logged in as ^3master^2\n");
 285                                         }
 286                                         else
 287                                                 ServerConsoleEcho(strcat("REJECTED master login from ", self.netname), TRUE);
 288                                 }
 289                                 else
 290                                         sprint(self, "^1You are NOT a master.\n");
 291                         } else if(self.vote_master) {
 292                                 local string dovote, dovote_display;
 293                                 dovote = VoteParse();
 294                                 if(dovote == "") {
 295                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 296                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 297                                         if(!ValidateMap(dovote))
 298                                                 return;
 299                                         // remap chmap to gotomap (forces intermission)
 300                                         if(strlen(dovote) >= 6)
 301                                                 if(substring(dovote, 0, 6) == "chmap ")
 302                                                         dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
 303                                         dovote_display = dovote;
 304                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
 305                                         {
 306                                                 if(!(e = GetKickVoteVictim(dovote, "vdo")))
 307                                                         return;
 308                                                 dovote_display = strzone(strcat("^1", dovote, " (^7", e.netname, "^1)"));
 309                                                 dovote = GetKickVoteVictim_newcommand;
 310                                         }
 311                                         bprint("\{1}^2* ^3", self.netname, "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
 312                                         localcmd(strcat(dovote, "\n"));
 313                                 } else {
 314                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 315                                 }
 316                         } else {
 317                                 sprint(self, "^1You are NOT a master.\n");
 318                         }
 319                 } else if(argv(1) == "yes") {
 320                         if(!votecalled) {
 321                                 sprint(self, "^1No vote called.\n");
 322                         } else if(self.vote_vote == 0
 323                                   || cvar("sv_vote_change")) {
 324                                 sprint(self, "^1You accepted the vote.\n");
 325                                 self.vote_vote = 1;
 326                                 if(!cvar("sv_vote_singlecount")) {
 327                                         VoteCount();
 328                                 }
 329                         } else {
 330                                 sprint(self, "^1You have already voted.\n");
 331                         }
 332                 } else if(argv(1) == "no") {
 333                         if(!votecalled) {
 334                                 sprint(self, "^1No vote called.\n");
 335                         } else if(self.vote_vote == 0
 336                                   || cvar("sv_vote_change")) {
 337                                 sprint(self, "^1You rejected the vote.\n");
 338                                 self.vote_vote = -1;
 339                                 if(!cvar("sv_vote_singlecount")) {
 340                                         VoteCount();
 341                                 }
 342                         } else {
 343                                 sprint(self, "^1You have already voted.\n");
 344                         }
 345                 } else {
 346                         // ignore this?
 347                         sprint(self, "^1Unknown vote command.\n");
 348                 }
 349         } else if(argv(0) == "autoswitch") {
 350                 // be backwards compatible with older clients (enabled)
 351                 self.autoswitch = ("0" != argv(1));
 352                 local string autoswitchmsg;
 353                 if (self.autoswitch) {
 354                         autoswitchmsg = "on";
 355                 } else {
 356                         autoswitchmsg = "off";
 357                 }
 358                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 359         } else if(argv(0) == "clientversion") {
 360                 if (argv(1) == "$gameversion") {
 361                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 362                         // either that or someone wants to be funny
 363                         self.version = 1;
 364                 } else {
 365                         self.version = stof(argv(1));
 366                 }
 367                 if(self.version != cvar("gameversion"))
 368                 {
 369                         self.classname = "observer";
 370                         self.frags = -2;
 371                         PutClientInServer();
 372                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
 373                         //JoinBestTeam(self, 0);
 374                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 375                         self.classname = "observer";
 376                         stuffcmd(self,"menu_showteamselect\n");
 377                 }
 378         } else if(argv(0) == "reportcvar") { // old system
 379                 GetCvars(1);
 380         } else if(argv(0) == "sentcvar") { // new system
 381                 GetCvars(1);
 382         } else if(argv(0) == "spectate") {
 383                 if(g_lms || g_arena)
 384                         return; // don't allow spectating in lms, unless player runs out of lives
 385                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 386                         if(self.flagcarried)
 387                                 DropFlag(self.flagcarried);
 388                         kh_Key_DropAll(self, TRUE);
 389                         WaypointSprite_PlayerDead();
 390                         DistributeFragsAmongTeam(self, self.team, 1.0);
 391                         self.classname = "observer";
 392                         PutClientInServer();
 393                 }
 394         } else if(argv(0) == "join") {
 395                 if(!g_arena)
 396                 if (self.classname != "player")
 397                 {
 398                         self.classname = "player";
 399                         self.frags = 0;
 400                         bprint ("^4", self.netname, "^4 is playing now\n");
 401                         PutClientInServer();
 402                 }
 403         } else if( argv(0) == "selectteam" ) {
 404                 if( !cvar("teamplay") ) {
 405                         sprint( self, "selecteam can only be used in teamgames\n");
 406                 } else if(cvar("g_campaign")) {
 407                         //JoinBestTeam(self, 0);
 408                 } else if( argv(1) == "none" ) {
 409                         SV_ChangeTeam( 0 );
 410                 } else if( argv(1) == "red" ) {
 411                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 412                 } else if( argv(1) == "blue" ) {
 413                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 414                 } else if( argv(1) == "yellow" ) {
 415                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 416                 } else if( argv(1) == "pink" ) {
 417                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 418                 } else if( argv(1) == "auto" ) {
 419                         self.team = -1;
 420                         JoinBestTeam( self, 0 );
 421                 } else {
 422                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 423                 }
 424         } else if(argv(0) == "ready") {
 425                 if(cvar("sv_ready_restart"))
 426                 {
 427                         self.ready = TRUE;
 428                         bprint(self.netname, "^2 is ready\n");
 429                         ReadyCount();
 430                 }
 431         } else if(argv(0) == "maplist") {
 432                 local float i, n;
 433                 local string col;
 434                 n = tokenize(cvar_string("g_maplist"));
 435                 sprint(self, "^7Maps in list: ");
 436                 for(i = 0; i < n; ++i)
 437                 {
 438                         if(math_mod(i, 2))
 439                                 col = "^2";
 440                         else
 441                                 col = "^3";
 442                         sprint(self, strcat(col, argv(i), " "));
 443                 }
 444                 sprint(self, "\n");
 445         } else if(argv(0) == "teamstatus") {
 446                 PrintScoreboard(self);
 447         } else if(argv(0) == "say") {
 448                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 449                 //clientcommand(self, formatmessage(s));
 450         } else if(argv(0) == "say_team") {
 451                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 452                 //clientcommand(self, formatmessage(s));
 453         } else if(argv(0) == "info") {
 454                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 455                 if(cmd == "")
 456                         sprint(self, "ERROR: unsupported info command\n");
 457                 else
 458                         wordwrap_sprint(cmd, 1111);
 459         } else if(argv(0) == "suggestmap") {
 460                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 461         } else {
 462                 cmd = argv(0);
 463                 /* checks not needed any more since DP has separated clientcommands and regular commands
 464                 if(cmd != "status")
 465                 if(cmd != "name")
 466                 //if(cmd != "say") // handled above
 467                 //if(cmd != "say_team") // handled above
 468                 if(cmd != "tell")
 469                 if(cmd != "color")
 470                 if(cmd != "kill")
 471                 if(cmd != "pause")
 472                 if(cmd != "kick")
 473                 if(cmd != "ping")
 474                 if(cmd != "pings")
 475                 if(cmd != "ban")
 476                 if(cmd != "pmodel")
 477                 if(cmd != "rate")
 478                 if(cmd != "playermodel")
 479                 if(cmd != "playerskin")
 480                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 481                 {
 482                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 483                         return;
 484                 }
 485                 */
 486                 clientcommand(self,s);
 487         }
 488 }
 489
 490 string ValidateMap(string m)
 491 {
 492 #ifdef MAPINFO
 493         m = MapInfo_FixName(m);
 494         if(!m)
 495         {
 496                 sprint(self, "This map is not available on this server.\n");
 497                 return string_null;
 498         }
 499 #endif
 500         if(!cvar("sv_vote_change_gametype"))
 501                 if(!IsSameGametype(m))
 502                 {
 503                         sprint(self, "This server does not allow changing the game type by map votes.\n");
 504                         return string_null;
 505                 }
 506         if(!cvar("sv_vote_override_mostrecent"))
 507                 if(Map_IsRecent(m))
 508                 {
 509                         sprint(self, "This server does not allow for recent maps to be played again. Please be patient for some rounds.\n");
 510                         return string_null;
 511                 }
 512 #ifdef MAPINFO
 513         if(!MapInfo_CheckMap(m))
 514         {
 515                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode.\n"));
 516                 return string_null;
 517         }
 518 #else
 519         if(!TryFile(strcat("maps/", m, ".mapcfg")))
 520         {
 521                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not exist on this server.\n"));
 522                 return string_null;
 523         }
 524 #endif
 525
 526         return m;
 527 }
 528
 529
 530 void VoteThink() {
 531         if(votefinished > 0 // a vote was called
 532             && time > votefinished) // time is up
 533         {
 534                 VoteCount();
 535         }
 536 }
 537
 538 string VoteParse() {
 539         local float index;
 540         index = 3;
 541         local string vote;
 542         vote = argv(2);
 543         while(argv(index) != "") {
 544                 vote = strcat(vote, " ", argv(index));
 545                 index++;
 546         }
 547
 548         // necessary for some of the string operations
 549         vote = strzone(vote);
 550
 551         // now we remove some things that could be misused
 552         index = 0;
 553         local float found;
 554         found = FALSE;
 555         local float votelength;
 556         votelength = strlen(vote);
 557         while(!found && index < votelength)
 558         {
 559                 local string badchar;
 560                 badchar = substring(vote, index, 1);
 561                 if(badchar == ";"
 562                    || badchar == "\r"
 563                    || badchar == "\n")
 564                 {
 565                         found = TRUE;
 566                 } else {
 567                         index++;
 568                 }
 569         }
 570         return substring(vote, 0, index);
 571 }
 572
 573 float VoteAllowed(string votecommand) {
 574         tokenize(cvar_string("sv_vote_commands"));
 575         local float index;
 576         index = 0;
 577         while(argv(index) != "") {
 578                 local string allowed;
 579                 allowed = argv(index);
 580                 if(votecommand == allowed) {
 581                         return TRUE;
 582                 }
 583                 index++;
 584         }
 585         return FALSE;
 586 }
 587
 588 void VoteReset() {
 589         local entity player;
 590
 591         FOR_EACH_CLIENT(player)
 592         {
 593                 player.vote_vote = 0;
 594                 centerprint_expire(player, CENTERPRIO_VOTE);
 595         }
 596
 597         if(votecalled)
 598         {
 599                 strunzone(votecalledvote);
 600                 strunzone(votecalledvote_display);
 601         }
 602
 603         votecalled = FALSE;
 604         votecalledmaster = FALSE;
 605         votefinished = 0;
 606 }
 607
 608 void VoteAccept() {
 609         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 610         if(votecalledmaster)
 611         {
 612                 votecaller.vote_master = 1;
 613         } else {
 614                 localcmd(strcat(votecalledvote, "\n"));
 615         }
 616         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 617         VoteReset();
 618 }
 619
 620 void VoteReject() {
 621         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 622         VoteReset();
 623 }
 624
 625 void VoteTimeout() {
 626         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 627         VoteReset();
 628 }
 629
 630 void VoteStop(entity stopper) {
 631         bprint("\{1}^2* ^3", stopper.netname, "^2 stopped ^3", votecaller.netname, "^2's vote\n");
 632         if(stopper == votecaller) {
 633                 // no wait for next vote so you can correct your vote
 634                 votecaller.vote_next = 0;
 635         }
 636         VoteReset();
 637 }
 638
 639 void VoteNag() {
 640         if(votecalled)
 641                 if(self.vote_vote == 0)
 642                         centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", votecaller.netname, "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
 643 }
 644
 645 void VoteCount() {
 646         local float playercount;
 647         playercount = 0;
 648         local float yescount;
 649         yescount = 0;
 650         local float nocount;
 651         nocount = 0;
 652         local entity player;
 653
 654         FOR_EACH_REALCLIENT(player)
 655         {
 656                 if(player.vote_vote < 0) {
 657                         nocount++;
 658                 } else if(player.vote_vote > 0) {
 659                         yescount++;
 660                 }
 661                 playercount++;
 662         }
 663
 664         if((playercount == 1) && votecalledmaster) {
 665                 // if only one player is on the server becoming vote
 666                 // master is not allowed.  This could be used for
 667                 // trolling or worse. 'self' is the user who has
 668                 // called the vote because this function is called
 669                 // by SV_ParseClientCommand. Maybe all voting should
 670                 // be disabled for a single player?
 671                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 672                 votecaller.vote_next = 0;
 673                 VoteReset();
 674         } else if((playercount / 2) < yescount) { // vote accepted
 675                 VoteAccept();
 676         } else if((playercount / 2) < nocount) { // vote rejected
 677                 VoteReject();
 678         } else if(time > votefinished) { // vote timedout
 679                 if(cvar("sv_vote_simple_majority"))
 680                         if(yescount > nocount)
 681                                 VoteAccept();
 682                         else if(nocount > yescount)
 683                                 VoteReject();
 684                         else
 685                                 VoteTimeout();
 686                 else
 687                         VoteTimeout();
 688         } // else still running
 689 }
 690
 691
 692 void ReadyCount()
 693 {
 694         local entity e;
 695         local float r, p;
 696
 697         FOR_EACH_REALPLAYER(e)
 698         {
 699                 p += 1;
 700                 if(e.ready)
 701                         r += 1;
 702         }
 703
 704         if(p && r == p)
 705         {
 706                 bprint("^1Server is restarting...\n");
 707                 localcmd("restart\n");
 708         }
 709 }