qcsrc/gamec/w_grenadelauncher.c

   1 void() glauncher_ready_01;
   2 void() glauncher_fire1_01;
   3 void() glauncher_deselect_01;
   4 void() glauncher_select_01;
   5
   6 float() glauncher_check =
   7 {
   8         if (self.ammo_rockets >= 2)
   9                 return TRUE;
  10         return FALSE;
  11 };
  12
  13 void(float req) w_glauncher =
  14 {
  15         if (req == WR_IDLE)
  16                 glauncher_ready_01();
  17         else if (req == WR_FIRE1)
  18                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire1_01, cvar("g_balance_grenadelauncher_refire"));
  19         else if (req == WR_FIRE2)
  20                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire1_01, cvar("g_balance_grenadelauncher_refire2"));
  21         else if (req == WR_RAISE)
  22                 glauncher_select_01();
  23         else if (req == WR_UPDATECOUNTS)
  24                 self.currentammo = self.ammo_rockets;
  25         else if (req == WR_DROP)
  26                 glauncher_deselect_01();
  27         else if (req == WR_SETUP)
  28                 weapon_setup(WEP_GRENADE_LAUNCHER, "w_gl.zym", IT_ROCKETS);
  29         else if (req == WR_CHECKAMMO)
  30                 weapon_hasammo = glauncher_check();
  31 };
  32
  33 void W_Grenade_Explode (void)
  34 {
  35         vector  org2;
  36         org2 = findbetterlocation (self.origin);
  37         te_explosion (org2);
  38         effect (org2, "models/sprites/grenadeexplosion.spr32", 0, 20, 30);
  39         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
  40
  41         self.event_damage = SUB_Null;
  42         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_damage"), cvar("g_balance_grenadelauncher_edgedamage"), cvar("g_balance_grenadelauncher_radius"), world, cvar("g_balance_grenadelauncher_force"), IT_GRENADE_LAUNCHER);
  43
  44         remove (self);
  45 }
  46
  47 void W_Grenade_Touch (void)
  48 {
  49         if (other.takedamage == DAMAGE_AIM)
  50                 W_Grenade_Explode ();
  51         else
  52                 sound (self, CHAN_IMPACT, "weapons/grenade_bounce.wav", 1, ATTN_NORM);
  53 }
  54
  55 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  56 {
  57         self.health = self.health - damage;
  58         if (self.health <= 0)
  59                 W_Grenade_Explode();
  60 }
  61
  62 void W_Grenade_Attack (void)
  63 {
  64         local entity gren;
  65         local vector org;
  66
  67         sound (self, CHAN_WEAPON, "weapons/grenade_fire.wav", 1, ATTN_NORM);
  68         self.punchangle_x = -4;
  69         if (cvar("g_use_ammunition"))
  70                 self.ammo_rockets = self.ammo_rockets - 2;
  71         org = self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -12;
  72
  73         gren = spawn ();
  74         gren.owner = self;
  75         gren.classname = "grenade";
  76         gren.movetype = MOVETYPE_BOUNCE;
  77         gren.solid = SOLID_BBOX;
  78         setmodel(gren, "models/grenademodel.md3");
  79         setsize(gren, '-6 -6 -3', '6 6 3');
  80         setorigin(gren, org);
  81
  82         if (self.button3)
  83         {
  84                 gren.nextthink = time + 2.5;
  85                 gren.think = W_Grenade_Explode;
  86                 gren.touch = W_Grenade_Touch;
  87                 gren.takedamage = DAMAGE_YES;
  88                 gren.health = 10;
  89                 gren.damageforcescale = 4;
  90                 gren.event_damage = W_Grenade_Damage;
  91                 gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed2") + v_up * cvar("g_balance_grenadelauncher_speed2_up");
  92                 gren.avelocity = '100 150 100';
  93         }
  94         else
  95         {
  96                 gren.nextthink = time + 30;
  97                 gren.think = W_Grenade_Explode;
  98                 gren.touch = W_Grenade_Explode;
  99                 gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed") + v_up * cvar("g_balance_grenadelauncher_speed_up");
 100                 gren.avelocity_x = random () * -500 - 500;
 101         }
 102
 103         gren.angles = vectoangles (gren.velocity);
 104 }
 105
 106 // weapon frames
 107
 108 void()  glauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, glauncher_ready_01); self.weaponentity.state = WS_READY;};
 109 void()  glauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 110 void()  glauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 111 void()  glauncher_fire1_01 =
 112 {
 113         weapon_doattack(glauncher_check, glauncher_check, W_Grenade_Attack);
 114         weapon_thinkf(WFRAME_FIRE1, 0.3, glauncher_ready_01);
 115 };