qcsrc/gamec/w_grenadelauncher.c

   1 void() glauncher_ready_01;
   2 void() glauncher_fire1_01;
   3 void() glauncher_deselect_01;
   4 void() glauncher_select_01;
   5
   6 float() glauncher_check =
   7 {
   8         if (self.ammo_rockets >= 2)
   9                 return TRUE;
  10         return FALSE;
  11 };
  12
  13 void(float req) w_glauncher =
  14 {
  15         if (req == WR_IDLE)
  16                 glauncher_ready_01();
  17         else if (req == WR_FIRE1 || req == WR_FIRE2)
  18                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire1_01, cvar("g_balance_grenadelauncher_refire"));
  19         else if (req == WR_RAISE)
  20                 glauncher_select_01();
  21         else if (req == WR_UPDATECOUNTS)
  22                 self.currentammo = self.ammo_rockets;
  23         else if (req == WR_DROP)
  24                 glauncher_deselect_01();
  25         else if (req == WR_SETUP)
  26                 weapon_setup(WEP_GRENADE_LAUNCHER, "w_gl.zym", IT_ROCKETS);
  27         else if (req == WR_CHECKAMMO)
  28                 weapon_hasammo = glauncher_check();
  29 };
  30
  31 void W_Grenade_Explode (void)
  32 {
  33         vector  org2;
  34         org2 = findbetterlocation (self.origin);
  35         te_explosion (org2);
  36         effect (org2, "models/sprites/grenadeexplosion.spr32", 0, 20, 30);
  37         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
  38
  39         self.event_damage = SUB_Null;
  40         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_damage"), cvar("g_balance_grenadelauncher_edgedamage"), cvar("g_balance_grenadelauncher_radius"), world, cvar("g_balance_grenadelauncher_force"), IT_GRENADE_LAUNCHER);
  41
  42         remove (self);
  43 }
  44
  45 void W_Grenade_Touch (void)
  46 {
  47         if (other.classname == "player" || other.classname == "corpse")
  48                 W_Grenade_Explode ();
  49         else
  50                 sound (self, CHAN_IMPACT, "weapons/grenade_bounce.wav", 1, ATTN_NORM);
  51 }
  52
  53 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  54 {
  55         self.health = self.health - damage;
  56         if (self.health <= 0)
  57                 W_Grenade_Explode();
  58 }
  59
  60 void W_Grenade_Attack (void)
  61 {
  62         local entity gren;
  63         local vector org;
  64
  65         sound (self, CHAN_WEAPON, "weapons/grenade_fire.wav", 1, ATTN_NORM);
  66         self.punchangle_x = -4;
  67         self.ammo_rockets = self.ammo_rockets - 2;
  68         org = self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -12;
  69
  70         gren = spawn ();
  71         gren.owner = self;
  72         gren.classname = "grenade";
  73         gren.movetype = MOVETYPE_BOUNCE;
  74         gren.solid = SOLID_BBOX;
  75         setmodel(gren, "models/grenademodel.md3");
  76         setsize(gren, '-6 -6 -3', '6 6 3');
  77         setorigin(gren, org);
  78
  79         if (self.button3)
  80         {
  81                 gren.nextthink = time + 2.5;
  82                 gren.think = W_Grenade_Explode;
  83                 gren.touch = W_Grenade_Touch;
  84                 gren.takedamage = DAMAGE_YES;
  85                 gren.health = 10;
  86                 gren.damageforcescale = 4;
  87                 gren.event_damage = W_Grenade_Damage;
  88                 gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed2") + v_up * cvar("g_balance_grenadelauncher_speed2_up");
  89                 gren.avelocity = '100 150 100';
  90         }
  91         else
  92         {
  93                 gren.nextthink = time + 30;
  94                 gren.think = W_Grenade_Explode;
  95                 gren.touch = W_Grenade_Explode;
  96                 gren.velocity = v_forward * cvar("g_balance_grenadelauncher_speed") + v_up * cvar("g_balance_grenadelauncher_speed_up");
  97                 gren.avelocity_x = random () * -500 - 500;
  98         }
  99
 100         gren.angles = vectoangles (gren.velocity);
 101 }
 102
 103 // weapon frames
 104
 105 void()  glauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, glauncher_ready_01); self.weaponentity.state = WS_READY;};
 106 void()  glauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 107 void()  glauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 108 void()  glauncher_fire1_01 =
 109 {
 110         weapon_doattack(glauncher_check, glauncher_check, W_Grenade_Attack);
 111         weapon_thinkf(WFRAME_FIRE1, 0.3, glauncher_ready_01);
 112 };