menu/mcustom.qc

   1 ///////////////////////////////////////////////
   2 // Custom Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains menu specific stuff that is made especially for dpmod
   6 // AK this file is used e.g. for defining some special event functions
   7 ////////////////////////////////////////////////
   8
   9 ////////////////
  10 // global stuff
  11 ///
  12
  13 void() nex_setposition =
  14 {
  15         self.pos_x = 0;
  16         self.pos_y = (self.font_size_y + 5) * self.orderpos;
  17         self.pos_z = 0;
  18
  19         self.origin = self.pos;
  20 };
  21
  22 void(entity item) nex_makeonlyvisible =
  23 {
  24         local entity node;
  25
  26         if( item.flag & FLAG_HIDDEN )
  27                 item.flag = item.flag - FLAG_HIDDEN;
  28         for( node = item._next ; node ; node = node._next )
  29                 node.flag = item.flag | FLAG_HIDDEN;
  30         for( node = item._prev ; node ; node = node._prev )
  31                 node.flag = item.flag | FLAG_HIDDEN;
  32 };
  33
  34 void(void) nex_linkrelhack =
  35 {
  36         self._child._parent = self;
  37 };
  38
  39 void(void) nex_maketextzone =
  40 {
  41         self.text = strzone(self.text);
  42 };
  43
  44 void(void) nex_slidertext =
  45 {
  46         entity ent;
  47         if(self.link == "")
  48         {
  49                 print("No link specified\n");
  50                 eprint(self);
  51                 self.init = null_function;
  52                 return;
  53         }
  54
  55         ent = menu_getitem(self.link);
  56         if(ent == null_entity)
  57         {
  58                 objerror("No link found for ", self.link,"\n");
  59         }
  60
  61         self._link = ent;
  62
  63         self.flag = self.flag | FLAG_DRAWREFRESHONLY;
  64
  65         self.refresh = _nex_slidertext_refresh;
  66 };
  67
  68 void(void) _nex_slidertext_refresh =
  69 {
  70         self.text = ftos(self._link.value);
  71         if(self.maxlen > 0)
  72                 self.text = substring(self.text,0, self.maxlen);
  73         // reset the size, so its set
  74         self.size = '0 0 0';
  75 };
  76
  77 float(float keynr, float ascii) nex_redirect_key =
  78 {
  79         if((ascii>=20 && ascii <= 126) || keynr == K_BACKSPACE || keynr == K_ENTER || keynr == K_LEFTARROW || keynr == K_RIGHTARROW || (keynr >= K_MOUSE1 && keynr <= K_MOUSE10))
  80         {
  81                 raise_key(self._child, keynr, ascii);
  82                 return true;
  83         }
  84         return false;
  85 };
  86
  87 void(void) nex_cvar_slider =
  88 {
  89         self.value = cvar(self.cvarname);
  90         self.slidermove = self.switchchange = _nex_cvar_slider;
  91         self.refresh = _nex_cvar_slider_refresh;
  92 };
  93
  94 void(void) _nex_cvar_slider_refresh =
  95 {
  96         if(self.cvartype == CVAR_INT || self.cvartype == CVAR_FLOAT || self.cvartype == CVAR_STEP)
  97                 self.value = cvar(self.cvarname);
  98 };
  99
 100 void(void) _nex_cvar_slider =
 101 {
 102         if(self.cvarname == "")
 103                 return;
 104         if(self.cvartype == CVAR_INT) // || self.cvartype == CVAR_STRING)
 105                 self.value = rint(self.value);
 106         if(self.cvartype == CVAR_STEP)
 107                 self.value = rint(self.value / self.step) * self.step;
 108         if(self.cvartype == CVAR_INT || self.cvartype == CVAR_FLOAT || self.cvartype == CVAR_STEP)
 109                 cvar_set(self.cvarname, ftos(self.value));
 110         /*if(cvartype == CVAR_STRING)
 111         {
 112                 string s;
 113                 s = getaltstring(self.value, self.cvarvalues);
 114                 cvar_set(self.cvarname, s);
 115         }
 116         */
 117 };
 118
 119 //////////////
 120 // main.menu
 121 ///
 122
 123 void(void) nex_makeselfonlyvisible =
 124 {
 125         nex_makeonlyvisible( self );
 126 };
 127
 128 // quit menu
 129
 130 void(void) nex_quit_choose =
 131 {
 132         entity e;
 133         // because of the missing support for real array, we have to do it the stupid way
 134         // (we also have to use strzone for the text, cause it the temporary strings wont work
 135         // for it)
 136         if(nex_quitrequest == 0)
 137         {
 138                 e = menu_getitem("quit_msg_0");
 139                 e.text = getaltstring(0,nex_quitmsg_0);
 140         }
 141         if(nex_quitrequest == 1)
 142         {
 143                 e = menu_getitem("quit_msg_0");
 144                 e.text = getaltstring(0,nex_quitmsg_1);
 145         }
 146         if(nex_quitrequest == 2)
 147         {
 148                 e = menu_getitem("quit_msg_0");
 149                 e.text = getaltstring(0,nex_quitmsg_2);
 150         }
 151         if(nex_quitrequest == 3)
 152         {
 153                 e = menu_getitem("quit_msg_0");
 154                 e.text = getaltstring(0,nex_quitmsg_3);
 155         }
 156         e.text = strzone(e.text);
 157
 158         if(nex_quitrequest == 0)
 159         {
 160                 e = menu_getitem("quit_msg_1");
 161                 e.text = getaltstring(1,nex_quitmsg_0);
 162         }
 163         if(nex_quitrequest == 1)
 164         {
 165                 e = menu_getitem("quit_msg_1");
 166                 e.text = getaltstring(1,nex_quitmsg_1);
 167         }
 168         if(nex_quitrequest == 2)
 169         {
 170                 e = menu_getitem("quit_msg_1");
 171                 e.text = getaltstring(1,nex_quitmsg_2);
 172         }
 173         if(nex_quitrequest == 3)
 174         {
 175                 e = menu_getitem("quit_msg_1");
 176                 e.text = getaltstring(1,nex_quitmsg_3);
 177         }
 178         e.text = strzone(e.text);
 179
 180         nex_quitrequest = nex_quitrequest + 1;
 181         if(nex_quitrequest == DPMOD_QUIT_MSG_COUNT)
 182                 nex_quitrequest = 0;
 183 };
 184
 185 void(void) nex_quit =
 186 {
 187 /*  entity ent;
 188         // choose a quit message
 189         nex_quit_choose();
 190
 191         // change the flags
 192         ent = menu_getitem("main");
 193         ent.flag = ent.flag | FLAG_CHILDDRAWONLY;
 194         ent = menu_getitem("quit");
 195         ent.flag = FLAG_NOSELECT;
 196         menu_jumptowindow(ent, false);*/
 197         entity ent;
 198
 199         // change the flags
 200         ent = menu_getitem("quitbox_ref");
 201         ent._child = menu_activewindow;
 202         ent = menu_getitem("quitbox");
 203         menu_jumptowindow(ent, true);
 204 };
 205
 206 void(void) nex_quit_yes =
 207 {
 208         cmd("quit\n");
 209 };
 210
 211 void(void) nex_quit_no =
 212 {
 213 /*  entity ent;
 214
 215         ent = menu_getitem("quit_msg_0");
 216         strunzone(ent.text);
 217
 218         ent = menu_getitem("quit_msg_1");
 219         strunzone(ent.text);
 220
 221         ent = menu_getitem("quit");
 222         ent.flag = FLAG_HIDDEN;
 223         ent = menu_getitem("main");
 224         ent.flag = ent.flag - FLAG_CHILDDRAWONLY;
 225         menu_selectup();*/
 226         menu_selectup();
 227 };
 228
 229 float(float keynr, float ascii) nex_quit_key =
 230 {
 231         if(keynr == K_LEFTARROW)
 232                 return false;
 233         if(keynr == K_RIGHTARROW)
 234                 return false;
 235         if(keynr == K_ENTER)
 236                 return false;
 237         if(keynr == K_MOUSE1)
 238                 return false;
 239         if(ascii == 'Y' || ascii == 'y')
 240                 nex_quit_yes();
 241         if(ascii == 'N' || ascii == 'n' || keynr == K_ESCAPE)
 242                 nex_quit_no();
 243         return true;
 244 };
 245
 246 // options menu
 247
 248 void(void) nex_display_options =
 249 {
 250         entity ent;
 251
 252         ent = menu_getitem( "options" );
 253
 254         nex_makeonlyvisible( ent );
 255         menu_jumptowindow( ent, false );
 256 };
 257
 258 /////////////////
 259 // video.menu
 260
 261 void(void) nex_display_video =
 262 {
 263         nex_makeonlyvisible( menu_getitem( "video" ) );
 264         menu_jumptowindow( menu_getitem( "video" ), false );
 265 };
 266
 267 void(void) nex_video_bpp_reinit =
 268 {
 269         if(cvar("vid_bitsperpixel") == 32)
 270                 self.value = 1;
 271         else
 272                 self.value = 0;
 273 };
 274
 275 void(void) nex_video_fullscreen_reinit =
 276 {
 277         self.value = cvar("vid_fullscreen");
 278 };
 279
 280 string nex_video_resolutions;
 281
 282 void(void) nex_video_resolution_switch_reinit =
 283 {
 284         float c, i;
 285         float pos86;
 286
 287         c = getaltstringcount(nex_video_resolutions);
 288         for(i = 0; i < c; i=i+1)
 289         {
 290                 string s;
 291                 vector t;
 292                 s = getaltstring(i,nex_video_resolutions);
 293                 s = strcat("'",s,"'");
 294                 t = stov(s);
 295                 if(t_x == cvar("vid_width") && t_y == cvar("vid_height"))
 296                 {
 297                         self.value = i;
 298                         return;
 299                 }
 300                 if(t == '800 600 0')
 301                         pos86 = i;
 302         }
 303
 304         self.value = pos86;
 305 };
 306
 307 void(void) nex_video_resolution_switch =
 308 {
 309         var float pos86 = 0;
 310         var float counter = 0;
 311         vector t;
 312
 313         nex_video_resolutions = "";
 314         self.text = "";
 315         self.value = -1;
 316
 317         while((t = getresolution(counter)) != '0 0 0')
 318         {
 319                 if(t == '800 600 0')
 320                         pos86 = counter;
 321                 if(t_x == cvar("vid_width") && t_y == cvar("vid_height"))
 322                 {
 323                         self.value = counter;
 324                 }
 325                 counter = counter + 1;
 326                 self.text = strcat(self.text,"'",ftos(t_x),"x");
 327                 self.text = strcat(self.text,ftos(t_y),"'");
 328                 nex_video_resolutions = strcat(nex_video_resolutions,vtos(t));
 329         }
 330
 331         if(self.value == -1)
 332                 self.value = pos86;
 333
 334         self.text = strzone(self.text);
 335         nex_video_resolutions = strzone(nex_video_resolutions);
 336
 337         self.reinit = nex_video_resolution_switch;
 338 };
 339
 340 void(void) nex_video_apply =
 341 {
 342         vector set, res;
 343         float changed;
 344         entity tmp;
 345
 346         changed = false;
 347
 348         // resolution test
 349         res_x = cvar("vid_width");
 350         res_y = cvar("vid_height");
 351         res_z = 0;
 352
 353         tmp = menu_getitem("video_resolution_switch");
 354         set = stov(getaltstring(tmp.value, nex_video_resolutions));
 355         if(set != res)
 356         {
 357                 cvar_set("vid_width",ftos(set_x));
 358                 cvar_set("vid_height",ftos(set_y));
 359                 changed = true;
 360         }
 361         // bpp test
 362         tmp = menu_getitem("video_bpp_switch");
 363         if((tmp.value+1)*16 != cvar("vid_bitsperpixel"))
 364         {
 365                 cvar_set("vid_bitsperpixel",ftos((tmp.value+1)*16));
 366                 changed = true;
 367         }
 368         // fullscreen changed
 369         tmp = menu_getitem("video_fullscreen_switch");
 370         if(tmp.value != cvar("vid_fullscreen"))
 371         {
 372                 cvar_set("vid_fullscreen",ftos(tmp.value));
 373                 changed = true;
 374         }
 375
 376         if(changed)
 377         {
 378                 cmd("vid_restart\n");
 379         }
 380 };
 381
 382 /////////////////
 383 // xplayer.menu
 384 ///
 385
 386 float maxfrags;
 387 float maxtime;
 388 float maxbots;
 389 float skilllevel;
 390 string hostname;
 391 float  maxclients;
 392 float  publicserver;
 393 float  gamemode;
 394
 395 entity maps_list;
 396 entity maps_current;
 397
 398 // text = info text
 399 // picture = picture filename
 400 // name = map name
 401 void(entity node) _nex_xp_remove =
 402 {
 403         strunzone( node.picture );
 404         strunzone( node.text );
 405         strunzone( node.name );
 406         remove( node );
 407 }
 408
 409 void(void) _nex_xp_update =
 410 {
 411         entity item;
 412
 413         item = menu_getitem( "creategame_map_name" );
 414         item.text = maps_current.name;
 415
 416         item = menu_getitem( "creategame_map_picture" );
 417         item.picture = maps_current.picture;
 418
 419         item = menu_getitem( "creategame_map_info" );
 420         item.text = maps_current.text;
 421 };
 422
 423 void(void) nex_xp_enummaps =
 424 {
 425         float count;
 426         float searchhandle;
 427         float counter;
 428
 429         // remove the old list
 430         if( maps_list ) {
 431                 entity node;
 432
 433                 node = maps_list;
 434                 while( node._next ) {
 435                         node = node._next;
 436                         _nex_xp_remove( node._prev );
 437                 }
 438                 _nex_xp_remove( node );
 439         }
 440         maps_list = maps_current = null_entity;
 441
 442         searchhandle = search_begin( "maps/*.bsp", true, true );
 443         if( searchhandle == -1 ) {
 444                 print( "menu: No maps found!\n" );
 445                 return;
 446         } else if( searchhandle == -2)
 447                 return;
 448
 449         maps_list = maps_current = spawn();
 450         count = search_getsize( searchhandle );
 451         for( counter = 0 ; counter < count ; counter = counter + 1 ) {
 452                 float file;
 453                 string fname;
 454
 455                 fname = search_getfilename( searchhandle, counter );
 456                 fname = substring( fname, 0, strlen( fname ) -  4 );
 457                 fname = strzone( fname );
 458
 459                 //try to find the information text
 460                 file = fopen( strcat( fname, ".txt" ), FILE_READ );
 461                 if( file == -1 )
 462                         maps_current.text = strzone( "--NO INFORMATION AVAILABLE--" );
 463                 else {
 464                         string temp, old;
 465                         maps_current.text = strzone( "" );
 466                         do {
 467                                 old = maps_current.text;
 468                                 temp = fgets( file );
 469                                 maps_current.text = strzone( strcat( old, temp, "\n" ) );
 470                                 strunzone( old );
 471                         } while( temp );
 472                         fclose( file );
 473                 }
 474
 475                 //try to find the picture
 476                 file = search_begin( strcat( fname, ".jpg" ), true, true );
 477                 if( file == -1 )
 478                         maps_current.picture = strzone( "gfx/m_nomap" );
 479                 else {
 480                         maps_current.picture = strzone( strcat( fname, ".jpg" ) );
 481                         search_end( file );
 482                 }
 483
 484                 maps_current.name = strzone( substring( fname, 5, strlen( fname ) - 5 ) ); // remove the 'maps/'
 485                 strunzone( fname );
 486
 487                 // create next item and link it with the list
 488                 maps_current._next = spawn();
 489                 maps_current._next._prev = maps_current;
 490                 maps_current = maps_current._next;
 491         }
 492         // remove the last item
 493         maps_current = maps_current._prev;
 494         remove( maps_current._next );
 495         maps_current._next = null_entity;
 496
 497         search_end( searchhandle );
 498
 499         maps_current = maps_list;
 500         _nex_xp_update();
 501 };
 502
 503 void(void) nex_xp_prev =
 504 {
 505         if( maps_current._prev )
 506                 maps_current = maps_current._prev;
 507         _nex_xp_update();
 508 };
 509
 510 void(void) nex_xp_next =
 511 {
 512         if( maps_current._next )
 513                 maps_current = maps_current._next;
 514         _nex_xp_update();
 515 };
 516
 517
 518 void(void) nex_display_creategame =
 519 {
 520         nex_makeonlyvisible( menu_getitem( "creategame" ) );
 521         menu_jumptowindow( menu_getitem( "creategame" ), false );
 522 };
 523
 524 void(void) nex_xp_maxfrags =
 525 {
 526         float x;
 527         x = stof(self.text);
 528         maxfrags = rint(x);
 529
 530         strunzone(self.text);
 531         self.text = ftos(x);
 532         self.text = strzone(self.text);
 533 };
 534
 535 void(void) nex_xp_maxbots =
 536 {
 537         float x;
 538         x = stof(self.text);
 539         maxbots = min( fabs(rint(x)), maxclients - 1, 16 ); // 16 is currently max in frikbot - see below
 540
 541         strunzone(self.text);
 542         self.text = ftos(x);
 543         self.text = strzone(self.text);
 544 };
 545
 546 void(void) nex_xp_maxtime =
 547 {
 548         float x;
 549         x = stof(self.text);
 550         maxtime = rint(x);
 551
 552         strunzone(self.text);
 553         self.text = ftos(maxtime);
 554         self.text = strzone(self.text);
 555 };
 556
 557 void(void) nex_xp_hostname =
 558 {
 559         hostname = self.text;
 560 };
 561
 562 void(void) nex_xp_maxclients =
 563 {
 564         local float i;
 565         i = stof(self.text);
 566         maxclients = rint(i);
 567
 568         strunzone(self.text);
 569         self.text = strzone(ftos(maxclients));
 570 };
 571
 572 void(void) nex_xp_publicserv =
 573 {
 574         publicserver = self.value;
 575 };
 576
 577 void(void) nex_xp_gamemode =
 578 {
 579         gamemode = self.value;
 580 };
 581
 582 void(void) nex_xp_skilllevel =
 583 {
 584         skilllevel = self.value;
 585 }
 586
 587 void(void) nex_xp_start =
 588 {
 589         cvar_set( "fraglimit", ftos( maxfrags ) );
 590         cvar_set( "timelimit", ftos( maxtime ) );
 591         cvar_set( "deathmatch", "1" );
 592
 593         cmd( "maxplayers " );
 594         cmd( ftos( maxclients ) );
 595         cmd( "\n" );
 596
 597         cvar_set( "sv_public", ftos( publicserver ) );
 598         cvar_set( "hostname", hostname );
 599
 600         // see bot/bot.qc: BotInit
 601         cvar_set( "saved1", "1" );
 602         cvar_set( "scratch1", ftos( pow( 2, maxbots ) - 1 ) );
 603         cvar_set( "scratch2", ftos( skilllevel * (pow(4, min(maxbots, 8)) - 1) / 3) );
 604         cvar_set( "scratch3", ftos( skilllevel * (pow(4, min(maxbots - 8, 8)) - 1) / 3) );
 605
 606         cmd( "map " );
 607         cmd( maps_current.name );
 608         cmd( "\n" );
 609         cmd( "togglemenu\n" );
 610 };
 611
 612 void(void) nex_goto_createserver =
 613 {
 614         menu_jumptowindow( menu_getitem( "multiplayer_frame"), false );
 615 }
 616
 617 void(void) nex_draw_text =
 618 {
 619         local vector drawpos;
 620         local float cpos, end;
 621
 622         cpos = 0;
 623         drawpos = self.pos;
 624         drawpos_y = drawpos_y + self.font_size_y;
 625         do {
 626                 local string l;
 627                 local float i;
 628
 629                 end = strlen( self.text );
 630                 i = cpos;
 631                 do {
 632                         l = substring( self.text, i, 1 );
 633
 634                         if( l == "\n" ) {
 635                                 end = i;
 636                                 break;
 637                         }
 638
 639                         i = i + 1;
 640                 } while( l != "" );
 641
 642                 l = substring( self.text, cpos, end - cpos );
 643                 if( l != "" )
 644                         menu_drawstring( drawpos, l, self.font_size, self.color, self.alpha, self.drawflag );
 645                 drawpos_y = drawpos_y + self.font_size_y;
 646
 647                 cpos = end + 1;
 648         } while( end != strlen( self.text ) );
 649 }
 650
 651 // server list
 652 var float slist_selected = 0;
 653 var float slist_start   = 0;
 654 float slist_estimatedsize;
 655
 656 void(void) nex_display_serverlist =
 657 {
 658         if(menu_activewindow.name == "serverlist")
 659                 return;
 660         menu_jumptowindow(menu_getitem("serverlist"),true);
 661         cmd("net_slist\n");
 662 };
 663
 664 // use a ITEM_TEXT as base item for this
 665 // we need another item to clip the slist
 666 // (another reason for a new menu qc!)
 667 void(void) slist_draw =
 668 {
 669         float c;
 670         vector pos;
 671         float listsize;
 672
 673         //print("slist drawing...", ftos(listsize), "\n");
 674
 675         pos = '0 0 0'; // the upper item sets the origin
 676         listsize = gethostcachevalue(SLIST_HOSTCACHECOUNT);
 677         if(!listsize)
 678         {
 679                 menu_drawstring(pos, "No Servers", self.font_size, self.color, self.alpha, self.drawflag);
 680                 return;
 681         }
 682
 683         for(c = 0; c < slist_estimatedsize + 1; c = c + 1)
 684         {
 685                 string line;
 686
 687                 if(listsize <= slist_start + c)
 688                         break;
 689
 690                 //print("drawing ", ftos(c),"\n");
 691
 692                 if(slist_selected - slist_start == c)
 693                 {
 694                         vector s;
 695                         s = self.size;
 696                         s_y = self.font_size_y * 2;
 697
 698                         menu_fillarea(pos, s, self.color_selected, self.alpha_selected * (sin(time * 9) + 1) / 2, self.drawflag_selected);
 699                 }
 700
 701                 line = gethostcachestring(SLIST_LINE1, slist_start + c);
 702
 703                 if( !line || line == "" )
 704                         line = "Empty";
 705                 menu_drawstring(pos, line, self.font_size, self.color, self.alpha, self.drawflag);
 706
 707                 pos_y = pos_y + self.font_size_y;
 708
 709                 line = gethostcachestring(SLIST_LINE2, slist_start + c);
 710
 711                 if( !line || line == "" )
 712                         line = "Empty";
 713                 menu_drawstring(pos, line, self.font_size, self.color, self.alpha, self.drawflag);
 714
 715                 pos_y = pos_y + self.font_size_y;
 716         }
 717 };
 718
 719 void(void) slist_init =
 720 {
 721         self.size = self._parent.size;
 722         slist_estimatedsize = self.size_y / self.font_size_y / 2;
 723 };
 724
 725 void(void) slist_refresh =
 726 {
 727         float hostcachesize;
 728
 729         hostcachesize = gethostcachevalue(SLIST_HOSTCACHECOUNT);
 730         if(slist_start >= hostcachesize)
 731                 slist_start = ceil(hostcachesize - slist_estimatedsize);
 732         if(slist_start < 0)
 733                 slist_start = 0;
 734         if(slist_selected >= hostcachesize)
 735                 slist_selected = hostcachesize;
 736 };
 737
 738 void(void) slist_join =
 739 {
 740         string cname;
 741         cname = gethostcachestring(SLIST_CNAME, slist_selected);
 742
 743         if(cname != "")
 744         {
 745                 cmd("connect ");
 746                 cmd(cname);
 747                 cmd(" ;togglemenu\n");
 748         }
 749 };
 750
 751 float(float keynr, float ascii ) slist_key =
 752 {
 753         float listsize;
 754
 755         if(keynr == K_UPARROW)
 756         {
 757                 if(slist_selected > 0)
 758                         slist_selected = slist_selected - 1;
 759                 if(slist_start > slist_selected)
 760                         slist_start = slist_selected;
 761                 return TRUE;
 762         } else if(keynr == K_DOWNARROW)
 763         {
 764                 listsize = gethostcachevalue(SLIST_HOSTCACHECOUNT);
 765                 if(slist_selected < listsize - 1)
 766                         slist_selected = slist_selected + 1;
 767                 if(slist_start + slist_estimatedsize - 0.5 < slist_selected)
 768                         slist_start = ceil(slist_selected - slist_estimatedsize + 0.5);
 769                 return TRUE;
 770         } else if(keynr == K_ENTER)
 771         {
 772                 slist_join();
 773                 return TRUE;
 774         } else if(keynr == K_SPACE)
 775         {
 776                 cmd("net_slist\n");
 777                 return TRUE;
 778         } else if(keynr == K_MOUSE1)
 779         {
 780                 float pos;
 781
 782                 listsize = gethostcachevalue(SLIST_HOSTCACHECOUNT);
 783                 pos = floor(menu_cursor_y / self.font_size_y / 2);
 784
 785                  if(pos + slist_start == slist_selected)
 786                         slist_join();
 787                 else if(pos + slist_start < listsize)
 788                         slist_selected = pos;
 789                 return TRUE;
 790         }
 791         return FALSE;
 792 };
 793
 794 void(void) slist_info1 =
 795 {
 796         float query, reply;
 797         string temp;
 798
 799         query = gethostcachevalue(SLIST_MASTERQUERYCOUNT);
 800         reply = gethostcachevalue(SLIST_MASTERREPLYCOUNT);
 801
 802         strunzone(self.text);
 803
 804         temp = strcat(ftos(reply), "/");
 805         temp = strcat(temp, ftos(query), " Master Servers");
 806
 807         self.text = strzone(temp);
 808 };
 809
 810 void(void) slist_info2 =
 811 {
 812         float query, reply;
 813         string temp;
 814
 815         query = gethostcachevalue(SLIST_SERVERQUERYCOUNT);
 816         reply = gethostcachevalue(SLIST_SERVERREPLYCOUNT);
 817
 818         strunzone(self.text);
 819
 820         temp = strcat(ftos(reply), "/");
 821         temp = strcat(temp, ftos(query), " Game Servers");
 822
 823         self.text = strzone(temp);
 824 };
 825
 826 /////////////////
 827 // options.menu
 828 ///
 829
 830 // player options
 831 var entity mlist_list = null_entity;
 832 entity mlist_current;
 833 string mlist_saved;
 834
 835 string player_name;
 836
 837 string player_model_cvar = "player_model";
 838 string player_name_cvar = "_cl_name";
 839 string player_skin_cvar = "player_skin";
 840 string player_fov_cvar = "player_fov";
 841
 842 void(void) nex_player_init =
 843 {
 844         entity ent;
 845
 846         if( mlist_saved )
 847                 strunzone( mlist_saved );
 848         mlist_saved = strzone( str_cvar( player_model_cvar ) );
 849
 850         ent = menu_getitem( "options_player_opt_playername_switch" );
 851         strunzone( ent.text );
 852         ent.text = strzone( str_cvar( player_name_cvar ) );
 853 };
 854
 855 void(void) nex_player_name =
 856 {
 857         player_name = self.text;
 858 };
 859
 860 void(void) nex_player_apply =
 861 {
 862         cvar_set( player_model_cvar, mlist_current.picture_selected );
 863         cvar_set( player_skin_cvar, mlist_current.picture_pressed );
 864
 865         cmd( strcat( "name ", player_name, "\n" ) );
 866 };
 867
 868 // name = name
 869 // picture_selected = model name
 870 // picture_pressed = skin name
 871 // picture = picture
 872 // text = desc text
 873 void(entity e) _nex_player_remove =
 874 {
 875         strunzone( e.name );
 876         strunzone( e.picture_selected );
 877         strunzone( e.picture_pressed );
 878         strunzone( e.picture );
 879         strunzone( e.text );
 880
 881         remove( e );
 882 };
 883
 884 void() _nex_player_model_update =
 885 {
 886         entity item;
 887
 888         if( !mlist_list )
 889                 return;
 890
 891         item = menu_getitem( "options_player_model_name" );
 892         item.text = mlist_current.name;
 893
 894         item = menu_getitem( "options_player_model_picture" );
 895         item.picture = mlist_current.picture;
 896
 897         item = menu_getitem( "options_player_model_info" );
 898         item.text = mlist_current.text;
 899 };
 900
 901 /*
 902 .mdef file format
 903 name
 904 picture\n
 905 skin filename\n
 906 model filename\n
 907 rest text*/
 908 void(void) nex_player_buildlist =
 909 {
 910         local float shandle;
 911         local float count;
 912         local float counter;
 913         local float loaded;
 914         local entity hit;
 915
 916         // remove the old player list
 917         if( mlist_list ) {
 918                 entity node;
 919
 920                 // save the old selected model
 921                 mlist_saved = strzone( mlist_current.name );
 922
 923                 node = mlist_list;
 924                 while( node._next ) {
 925                         node = node._next;
 926                         _nex_player_remove( node._prev );
 927                 }
 928                 _nex_player_remove( node );
 929
 930                 mlist_list = mlist_current = null_entity;
 931         }
 932
 933         shandle = search_begin( "models/player/*.txt", false, true );
 934         if( shandle < 0 )
 935                 return;
 936
 937         count = search_getsize( shandle );
 938         mlist_list = mlist_current = spawn();
 939         hit = null_entity;
 940         loaded = 0;
 941         for ( counter = 0 ; counter < count ; counter = counter + 1 ) {
 942                 local string dname;
 943                 local string dpicture;
 944                 local string dskin;
 945                 local string dmodel;
 946                 local string dtext;
 947
 948                 local float handle;
 949
 950                 handle = fopen( search_getfilename( handle, counter ), FILE_READ );
 951
 952                 if( handle < 0 )
 953                         continue;
 954
 955                 dname = strzone( fgets( handle ) );
 956                 dpicture = strzone( fgets( handle ) );
 957                 dskin = strzone( fgets( handle ) );
 958                 dmodel = strzone( fgets( handle ) );
 959                 {
 960                         local string temp, old;
 961                         dtext = strzone( "" );
 962                         do {
 963                                 old = dtext;
 964                                 temp = fgets( handle );
 965                                 dtext = strzone( strcat( old, temp, "\n" ) );
 966                                 strunzone( old );
 967                         } while( temp );
 968                 }
 969
 970                 if( !dname || !dpicture || !dskin || !dmodel || !dtext ) {
 971                         print( "Bad model definition file '", search_getfilename( shandle, counter ), "'\n" );
 972
 973                         strunzone( dname );
 974                         strunzone( dpicture );
 975                         strunzone( dskin );
 976                         strunzone( dmodel );
 977
 978                         fclose( handle );
 979                         continue;
 980                 }
 981
 982                 // is this the previous selected model?
 983                 if( dname == mlist_saved )
 984                         hit = mlist_current;
 985
 986                 mlist_current.name = dname;
 987                 mlist_current.picture = dpicture;
 988                 mlist_current.picture_pressed = dskin;
 989                 mlist_current.picture_selected = dmodel;
 990                 mlist_current.text = dtext;
 991
 992                 loaded = loaded + 1;
 993
 994                 mlist_current._next = spawn();
 995                 mlist_current._next._prev = mlist_current;
 996                 mlist_current = mlist_current._next;
 997
 998                 fclose( handle );
 999         }
1000         mlist_current._prev._next = null_entity;
1001         remove( mlist_current );
1002
1003         search_end( shandle );
1004
1005         if( loaded == 0 ) {
1006                 print( "No model description files found in models/player\n" );
1007                 mlist_list = mlist_current = null_entity;
1008         } else
1009                 print( ftos( loaded ), " model description files loaded from models/player\n" );
1010
1011         if( hit )
1012                 mlist_current = hit;
1013         else
1014                 mlist_current = mlist_list;
1015
1016         _nex_player_model_update();
1017 };
1018
1019 void(void) nex_player_model_next =
1020 {
1021         if( mlist_current._next )
1022                 mlist_current = mlist_current._next;
1023         _nex_player_model_update();
1024 };
1025
1026 void(void) nex_player_model_prev =
1027 {
1028         if( mlist_current._prev )
1029                 mlist_current = mlist_current._prev;
1030         _nex_player_model_update();
1031 };
1032
1033 void(void) nex_player =
1034 {
1035         entity ent;
1036         ent = menu_getitem("options_player");
1037         nex_makeonlyvisible( ent );
1038         menu_jumptowindow(ent, false);
1039 };
1040
1041 // old/other options
1042
1043 void(void) nex_options_alwaysrun_switchchange =
1044 {
1045         if(self.value)
1046         {
1047                 cvar_set("cl_forwardspeed","400");
1048                 cvar_set("cl_backspeed","400");
1049         }
1050         else
1051         {
1052                 cvar_set("cl_forwardspeed","200");
1053                 cvar_set("cl_backspeed","200");
1054         }
1055 };
1056
1057 void(void) nex_options_alwaysrun_refresh =
1058 {
1059         if(cvar("cl_forwardspeed") > 200)
1060                 self.value = 1;
1061         else
1062                 self.value = 0;
1063 };
1064
1065 void(void) nex_options_invmouse_switchchange =
1066 {
1067         float old;
1068         old = 0 - cvar("m_pitch");
1069         cvar_set("m_pitch",ftos(old));
1070 };
1071
1072 void(void) nex_options_invmouse_refresh =
1073 {
1074         if(cvar("m_pitch") > 0)
1075                 self.value = 0;
1076         else
1077                 self.value = 1;
1078 };
1079
1080 void(void) nex_snd =
1081 {
1082         entity ent;
1083         ent = menu_getitem("options_sound");
1084         nex_makeonlyvisible( ent );
1085         menu_jumptowindow(ent, false);
1086 }
1087
1088 void(void) nex_snd_cd_init =
1089 {
1090         if(cvar("cdaudioinitialized"))
1091         {
1092                 self.flag = FLAG_AUTOSETCLICK;
1093                 self.color = ITEM_TEXT_NORMAL_COLOR;
1094         }
1095         else
1096         {
1097                 self.flag = FLAG_NOSELECT | FLAG_DRAWONLY | FLAG_CHILDDRAWONLY;
1098                 self.color = '0.5 0.5 0.5';
1099         }
1100 };
1101
1102 void(void) nex_snd_snd_init =
1103 {
1104         if(cvar("snd_initialized"))
1105         {
1106                 self.flag = FLAG_AUTOSETCLICK;
1107                 self.color = ITEM_TEXT_NORMAL_COLOR;
1108         }
1109         else
1110         {
1111                 self.flag = FLAG_NOSELECT | FLAG_DRAWONLY | FLAG_CHILDDRAWONLY;
1112                 self.color = '0.5 0.5 0.5';
1113         }
1114 };
1115
1116 void(void) nex_cc =
1117 {
1118         entity ent;
1119         ent = menu_getitem("options_cc");
1120         nex_makeonlyvisible( ent );
1121         menu_jumptowindow(ent, false);
1122 }
1123
1124 void(void) nex_cc_reset =
1125 {
1126         cmd(
1127         "v_hwgamma 1;"
1128         "v_gamma 1;"
1129         "v_contrast 1;"
1130         "v_brightness 0;"
1131         "v_color_enable 0;"
1132         "v_color_black_r 0;"
1133         "v_color_black_g 0;"
1134         "v_color_black_b 0;"
1135         "v_color_grey_r 0;"
1136         "v_color_grey_g 0;"
1137         "v_color_grey_b 0;"
1138         "v_color_white_r 1;"
1139         "v_color_white_g 1;"
1140         "v_color_white_b 1;"
1141         "\n");
1142 };
1143
1144 void(void) nex_cc_check_hwgamma =
1145 {
1146         if(cvar("vid_hardwaregammasupported"))
1147         {
1148                 self.flag = FLAG_AUTOSETCLICK;
1149                 self.color = ITEM_TEXT_NORMAL_COLOR;
1150         }
1151         else
1152         {
1153                 self.flag = FLAG_NOSELECT;
1154                 self.color = '0.5 0.5 0.5';
1155         }
1156 };
1157
1158 void(void) nex_cc_check_gamma = // used in key -- BADBAD HACKHACK
1159 {
1160         if(cvar("v_hwgamma") && cvar("vid_hardwaregammasupported") && !cvar("v_color_enable"))
1161         {
1162                 self.flag = FLAG_AUTOSETCLICK;
1163                 self.color = ITEM_TEXT_NORMAL_COLOR;
1164         }
1165         else
1166         {
1167                 self.flag = FLAG_NOSELECT;
1168                 self.color = '0.5 0.5 0.5';
1169         }
1170 };
1171
1172 void(void) nex_cc_check_grey = // used in key -- BADBAD HACKHACK
1173 {
1174         if(cvar("v_hwgamma") && cvar("vid_hardwaregammasupported") && cvar("v_color_enable"))
1175         {
1176                 self.flag = FLAG_AUTOSETCLICK;
1177                 self.color = ITEM_TEXT_NORMAL_COLOR;
1178         }
1179         else
1180         {
1181                 self.flag = FLAG_NOSELECT;
1182                 self.color = '0.5 0.5 0.5';
1183         }
1184 };
1185
1186 void(void) nex_cc_check_ncolor_enable =
1187 {
1188         if(!cvar("v_color_enable"))
1189         {
1190                 self.flag = FLAG_AUTOSETCLICK;
1191                 self.color = ITEM_TEXT_NORMAL_COLOR;
1192         }
1193         else
1194         {
1195                 self.flag = FLAG_NOSELECT;
1196                 self.color = '0.5 0.5 0.5';
1197         }
1198 };
1199
1200 void(void) nex_cc_check_color_enable =
1201 {
1202         if(cvar("v_color_enable"))
1203         {
1204                 self.flag = FLAG_AUTOSETCLICK;
1205                 self.color = ITEM_TEXT_NORMAL_COLOR;
1206         }
1207         else
1208         {
1209                 self.flag = FLAG_NOSELECT;
1210                 self.color = '0.5 0.5 0.5';
1211         }
1212 };
1213
1214 void(void) nex_cc_color_enable =
1215 {
1216         cvar_set("v_color_enable","1");
1217 };
1218
1219 void(void) nex_cc_ncolor_enable =
1220 {
1221         cvar_set("v_color_enable","0");
1222 };
1223
1224 void(void) nex_cc_grey_refresh =
1225 {
1226         self.value = cvar(strcat(self.cvarname,"_r"));
1227         self.value = self.value + cvar(strcat(self.cvarname,"_g"));
1228         self.value = self.value + cvar(strcat(self.cvarname,"_b"));
1229         self.value = self.value / 3;
1230 };
1231
1232
1233 void(void) nex_cc_grey_move =
1234 {
1235         string tmp;
1236         tmp = ftos(self.value);
1237         cvar_set(strcat(self.cvarname,"_r"), tmp);
1238         cvar_set(strcat(self.cvarname,"_g"), tmp);
1239         cvar_set(strcat(self.cvarname,"_b"), tmp);
1240 };
1241
1242 void(void) nex_cc_grey =
1243 {
1244         self.refresh = nex_cc_grey_refresh;
1245         self.slidermove = nex_cc_grey_move;
1246 };
1247
1248 // key control stuff
1249 void(void) nex_cntrl =
1250 {
1251         entity ent;
1252         ent = menu_getitem("options_control");
1253         nex_makeonlyvisible( ent );
1254         menu_jumptowindow(ent, false);
1255 }
1256
1257 const float NUMKEYS = 2;        // visible key count (first and secondary key)
1258 string bindcommand;
1259
1260 void(float keynr, float ascii) nex_con_keyhook =
1261 {
1262         entity ent;
1263
1264         //dprint("nex_con_keyhook called !\n");
1265
1266         if(keynr != K_ESCAPE)
1267         {
1268                 string tmp;
1269                 tmp = bind_getkeylist(bindcommand);
1270                 // remove the binds if we need more space
1271                 bind_limitbinds(NUMKEYS - 1, bindcommand);
1272                 // bind the new key
1273                 bind_bindkey(bind_getstringforkey(keynr), bindcommand);
1274         }
1275
1276         ent = menu_getitem("options_control_statemsg1");
1277         ent.value = 0;
1278
1279         ent = menu_getitem("options_control_statemsg2");
1280         ent.value = 0;
1281
1282         menu_keyhook = null_function;
1283 };
1284
1285 void(void) nex_con_action_key =
1286 {
1287         entity ent;
1288
1289         bindcommand = self.link;
1290
1291         //dprint("action called");
1292
1293         menu_keyhook = nex_con_keyhook;
1294
1295         ent = menu_getitem("options_control_statemsg1");
1296         ent.value = 1;
1297
1298         ent = menu_getitem("options_control_statemsg2");
1299         ent.value = 1;
1300 };
1301
1302 float(float keynr, float ascii) nex_con_key =
1303 {
1304         if(keynr == K_DEL)
1305         {
1306                 // the user wants to unbind this action
1307                 //dprint("Removing binds for '", self.link,"'\n");
1308                 bind_limitbinds(0, self.link);
1309                 return true;
1310         }
1311
1312         return false;
1313 };
1314
1315 void(void) nex_con_update_keys =
1316 {
1317         entity ent;
1318         string keystr;
1319         float num;
1320
1321         if(!self._child)
1322                 return;
1323
1324         keystr = strzone(bind_getkeylist(self.link));
1325
1326         num = 0;
1327
1328         for(ent = self._child; ent != null_entity; ent = ent._next)
1329         {
1330                 float keynr;
1331
1332                 keynr = stof(getaltstring(num, keystr));
1333
1334                 strunzone(ent.text);
1335
1336                 if(keynr == -1 )
1337                         ent.text = strzone("-");
1338                 else
1339                         ent.text = strzone(bind_getstringforkey(keynr));
1340
1341                 num = num + 1;
1342         }
1343
1344         strunzone(keystr);
1345 };
1346
1347 var float numkey = 0;
1348 void(void) CONTROL_KEY =
1349 {
1350         entity key1, key2, desc;
1351         entity temp_desc, temp_key;
1352
1353         temp_desc = menu_getitem("control_desc_template");
1354         temp_key = menu_getitem("control_key_template");
1355
1356         desc = spawn();
1357         copyentity(temp_desc, desc);
1358
1359         key1 = spawn();
1360         copyentity(temp_key, key1);
1361
1362         key2 = spawn();
1363         copyentity(temp_key, key2);
1364
1365         desc.name = self.text;
1366         key1.name = strzone(strcat(self.text, " key1"));
1367         key2.name = strzone(strcat(self.text, " key2"));
1368
1369         desc.pos_y = key1.pos_y = key2.pos_y = temp_desc.pos_y * numkey;
1370         key2.pos_x = 2 * key2.pos_x;
1371
1372         desc.text = self.text;
1373         desc.link = self.link;
1374
1375         key1.text = strzone("-");
1376         key2.text = strzone("-");
1377
1378         desc.alignment = 0;
1379
1380         // set the parents
1381         desc.parent = "options_control";
1382         desc._parent = menu_getitem("options_control");
1383
1384         key1.parent = key2.parent = desc.name;
1385         key1._parent = key2._parent = desc;
1386
1387         //eprint(key1);
1388         //eprint(key2);
1389         //eprint(desc);
1390
1391         numkey = numkey + 1;
1392 };
1393
1394 ////////////////////////////////////////////////////
1395 // Test Stuff
1396 ///
1397 void(void) initbrightness =
1398 {
1399         self.value = cvar("scr_conbrightness");
1400 };
1401
1402 void(void) setbrightness =
1403 {
1404         cvar_set("scr_conbrightness",ftos(self.value));
1405 };
1406
1407 void(void)  nex_main_exit =
1408 {
1409         entity e;
1410         e = menu_getitem("MAIN_MENU");
1411         e.flag = FLAG_NOSELECT + FLAG_CHILDDRAWONLY;
1412         e = menu_getitem("MAIN_EXIT_MENU");
1413         e.flag = FLAG_NOSELECT;
1414         menu_jumptowindow(e, false);
1415 };
1416
1417 void(void) nex_main_exit_no =
1418 {
1419         entity e;
1420         e = menu_getitem("MAIN_EXIT_MENU");
1421         e.flag = FLAG_NOSELECT + FLAG_HIDDEN;
1422         e = menu_getitem("MAIN_MENU");
1423         e.flag = FLAG_NOSELECT;
1424         menu_selectup();
1425 };
1426
1427 void(void) nex_main_exit_yes =
1428 {
1429         cmd("quit\n");
1430 };
1431
1432 float(float keynr, float ascii) nex_main_exit_key =
1433 {
1434         if(keynr == K_ESCAPE)
1435         {
1436                 nex_main_exit_no();
1437                 return true;
1438         }
1439         return false;
1440 }
1441
1442 void(void)  dorestart =
1443 {
1444         cmd("menu_restart\n");
1445 };
1446
1447 void(void) nex_text_cur_x =
1448 {
1449         self.text = ftos(rint(cursor_x));
1450 };
1451
1452 void(void) nex_text_cur_y =
1453 {
1454         self.text = ftos(rint(cursor_y));
1455 };