data/qcsrc/server/w_uzi.qc

   1 // leilei's fancy muzzleflash stuff
   2 void W_Uzi_Flash_Go() {
   3         if (self.frame > 10){
   4                 SUB_Remove();
   5                 return;
   6         }
   7         self.frame = self.frame + 2;
   8         self.alpha = self.alpha - 0.2;
   9         self.think = W_Uzi_Flash_Go;
  10         self.nextthink = time + 0.02;
  11 };
  12
  13 .float uzi_bulletcounter;
  14 void W_Uzi_Attack (float deathtype)
  15 {
  16         local entity flash, flash2;
  17
  18         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  19         {
  20                 if (self.uzi_bulletcounter == 1)
  21                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  22                 else
  23                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  24         }
  25         W_SetupShot (self, '23 8 -9.5', TRUE, 0, "weapons/uzi_fire.wav");
  26         if (!g_norecoil)
  27         {
  28                 self.punchangle_x = random () - 0.5;
  29                 self.punchangle_y = random () - 0.5;
  30         }
  31
  32         // this attack_finished just enforces a cooldown at the end of a burst
  33         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  34
  35         if (self.uzi_bulletcounter == 1)
  36                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  37         else
  38                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  39
  40         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  41
  42         // muzzle flash for 1st person view
  43         flash = spawn();
  44         setorigin(flash, '5 0 0');
  45         setmodel(flash, "models/uziflash.md3"); // precision set below
  46         if (gettagindex(self.weaponentity, "shot"))
  47                 setattachment(flash, self.weaponentity, "shot");
  48         else if (gettagindex(self.weaponentity, "bone02"))
  49                 setattachment(flash, self.weaponentity, "bone02");
  50         else
  51         {
  52                 setorigin(flash, shotorg + shotdir * 50);
  53                 flash.angles = vectoangles(shotdir);
  54                 //setorigin(flash, '48 0 5');
  55                 //setattachment(flash, self.weaponentity, "");
  56         }
  57         flash.owner = self;
  58         flash.viewmodelforclient = self;
  59         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  60         //SUB_SetFade(flash, time + 0.06, 0);
  61         flash.think = W_Uzi_Flash_Go;
  62         flash.nextthink = time + 0.02;
  63         flash.frame = 2;
  64
  65         // muzzle flash for 3rd person view
  66         flash2 = spawn();
  67         setorigin(flash2, '43 1 8');
  68         setmodel(flash2, "models/uziflash.md3"); // precision set below
  69         setattachment(flash2, self.exteriorweaponentity, "");
  70         //SUB_SetFade(flash2, time + 0.06, 0);
  71         flash2.think = W_Uzi_Flash_Go;
  72         flash2.nextthink = time + 0.02;
  73         flash2.frame = 2;
  74         // common properties
  75         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  76         flash.alpha = flash2.alpha = 1;
  77         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  78
  79         // casing code
  80         if (cvar("g_casings") >= 2)
  81                 SpawnCasing (w_shotorg - v_forward * 10, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  82 }
  83
  84 // weapon frames
  85 void uzi_fire1_02()
  86 {
  87         if(self.weapon != self.switchweapon) // abort immediately if switching
  88         {
  89                 w_ready();
  90                 return;
  91         }
  92         if (self.BUTTON_ATCK)
  93         {
  94                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  95                 {
  96                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  97                         w_ready();
  98                         return;
  99                 }
 100                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
 101                 W_Uzi_Attack(WEP_UZI);
 102                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 103         }
 104         else
 105                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 106 };
 107
 108 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 109
 110 float w_uzi(float req)
 111 {
 112         if (req == WR_AIM)
 113                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 114                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 115                 else
 116                 {
 117                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 118                 }
 119         else if (req == WR_THINK)
 120         {
 121                 if (self.BUTTON_ATCK)
 122                 if (weapon_prepareattack(0, 0))
 123                 {
 124                         self.uzi_bulletcounter = 1;
 125                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 126                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 127                 }
 128                 if (self.BUTTON_ATCK2)
 129                 if (weapon_prepareattack(1, 0))
 130                 {
 131                         self.uzi_bulletcounter = 1;
 132                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 133                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 134                 }
 135         }
 136         else if (req == WR_PRECACHE)
 137         {
 138                 precache_model ("models/uziflash.md3");
 139                 precache_model ("models/weapons/g_uzi.md3");
 140                 precache_model ("models/weapons/v_uzi.md3");
 141                 precache_model ("models/weapons/w_uzi.zym");
 142                 precache_sound ("weapons/uzi_fire.wav");
 143         }
 144         else if (req == WR_SETUP)
 145                 weapon_setup(WEP_UZI);
 146         else if (req == WR_CHECKAMMO1)
 147                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 148         else if (req == WR_CHECKAMMO2)
 149                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 150         else if (req == WR_SUICIDEMESSAGE)
 151                 w_deathtypestring = "did the impossible";
 152         else if (req == WR_KILLMESSAGE)
 153         {
 154                 if(w_deathtype & HITTYPE_SECONDARY)
 155                         w_deathtypestring = "was sniped by";
 156                 else
 157                         w_deathtypestring = "was riddled full of holes by";
 158         }
 159         return TRUE;
 160 };