data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.wav", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         //te_explosion (org2);
  11         // LordHavoc: TE_TEI_BIGEXPLOSION
  12         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  13         WriteByte (MSG_BROADCAST, 78);
  14         WriteCoord (MSG_BROADCAST, org2_x);
  15         WriteCoord (MSG_BROADCAST, org2_y);
  16         WriteCoord (MSG_BROADCAST, org2_z);
  17
  18         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  19         self.event_damage = SUB_Null;
  20         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  21
  22         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  23         {
  24                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  25                 {
  26                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  27                         ATTACK_FINISHED(self.owner) = time;
  28                         self.owner.switchweapon = w_getbestweapon(self.owner);
  29                 }
  30                 if(g_laserguided_missile)
  31                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  32         }
  33         remove (self);
  34 }
  35
  36 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  37 {
  38         entity head, selected;
  39         vector dir;
  40         float dist, maxdist,// bestdist,
  41                 dot,// bestdot,
  42                 points, bestpoints;
  43         //bestdist = 9999;
  44         //bestdot = -2;
  45         bestpoints = 0;
  46         maxdist = 800;
  47         selected = world;
  48
  49         makevectors(e.angles);
  50
  51         head = find(world, classname, "laser_target");
  52         while(head)
  53         {
  54                 points = 0;
  55                 dir = normalize(head.origin - self.origin);
  56                 dot = dir * v_forward;
  57                 dist = vlen(head.origin - self.origin);
  58                 if(dist > maxdist)
  59                         dist = maxdist;
  60
  61                 // gain points for being in front
  62                 points = points + ((dot+1)*0.5) * 500
  63                         * (1 + crandom()*dot_variance);
  64                 // gain points for being close away
  65                 points = points + (1 - dist/maxdist) * 1000
  66                         * (1 + crandom()*dot_variance);
  67
  68                 traceline(e.origin, head.origin, TRUE, self);
  69                 if(trace_fraction < 1)
  70                 {
  71                         points = 0;
  72                 }
  73
  74                 if(points > bestpoints)//random() > 0.5)//
  75                 {
  76                         bestpoints = points;
  77                         selected = head;
  78                 }
  79
  80                 head = find(head, classname, "laser_target");
  81         }
  82
  83         //bprint(selected.owner.netname);
  84         //bprint("\n");
  85         return selected;
  86 }
  87
  88 void W_Rocket_Think (void)
  89 {
  90         entity e;
  91         vector desireddir, olddir, newdir;
  92         float turnrate, velspeed;
  93         self.nextthink = time;
  94         if (time > self.cnt)
  95         {
  96                 W_Rocket_Explode ();
  97                 return;
  98         }
  99
 100         if(g_laserguided_missile)
 101         {
 102                 // accelerate
 103                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 104                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 105                 if (velspeed > 0)
 106                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 107         }
 108         else
 109         {
 110                 // accelerate
 111                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 112                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 113                 if (velspeed > 0)
 114                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 115         }
 116
 117         // laser guided, or remote detonation
 118         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 119         {
 120                 if(g_laserguided_missile)
 121                 {
 122                         if(!self.owner.button0)
 123                                 self.ltime = -1; // indicate that the player has let go of the button
 124
 125
 126                         if(self.owner.deadflag == DEAD_NO)
 127                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 128                         {
 129                                   W_Rocket_Explode ();
 130                                   return;
 131                         }
 132
 133                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 134                         {
 135                                 if(self.owner.laser_on)
 136                                 {
 137                                         if(self.attack_finished_single < time)
 138                                         {
 139                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 140                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 141                                         }
 142
 143                                         if(!self.enemy)
 144                                                 self.enemy = self.owner.weaponentity.lasertarget;
 145                                 }
 146                                 else self.enemy = world;
 147                         }
 148                         else // don't allow stealing: always target my owner's laser (if it exists)
 149                                 self.enemy = self.owner.weaponentity.lasertarget;
 150
 151                         if(self.enemy != world)
 152                         {
 153                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 154                                 velspeed = vlen(self.velocity);
 155                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 156                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 157                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 158                                 olddir = normalize(self.velocity);                                      // get my current direction
 159                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 160                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 161                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 162
 163                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(self.owner.deadflag == DEAD_NO)
 169                         if (self.owner.button3)
 170                                   W_Rocket_Explode ();
 171                 }
 172         }
 173 }
 174
 175 void W_Rocket_Touch (void)
 176 {
 177         if(self.owner && self.owner.lastrocket == self)
 178                 self.owner.lastrocket = world;
 179         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 180         {
 181                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 182                 remove(self);
 183                 return;
 184         }
 185         W_Rocket_Explode ();
 186 }
 187
 188 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 189 {
 190         self.health = self.health - damage;
 191         self.angles = vectoangles(self.velocity);
 192         if (self.health <= 0)
 193         {
 194                 self.owner = attacker;
 195                 W_Rocket_Explode();
 196         }
 197 }
 198
 199 void W_Rocket_Attack (void)
 200 {
 201         local entity missile;
 202         local entity flash, flash2;
 203
 204         if (cvar("g_use_ammunition") && !g_rocketarena)
 205                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 206
 207         W_SetupShot (self, '8 3 -8', FALSE, 5, "weapons/rocket_fire.wav");
 208         //te_smallflash(w_shotorg);
 209         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg + v_forward * 12, v_forward * 1000, 1);
 210
 211         missile = spawn ();
 212         missile.owner = self;
 213         self.lastrocket = missile;
 214         missile.classname = "missile";
 215         missile.bot_dodge = TRUE;
 216         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 217
 218         missile.takedamage = DAMAGE_YES;
 219         missile.damageforcescale = 4;
 220         missile.health = 30;
 221         missile.event_damage = W_Rocket_Damage;
 222
 223         missile.movetype = MOVETYPE_FLY;
 224         missile.solid = SOLID_BBOX;
 225         setmodel (missile, "models/rocket.md3"); // precision set below
 226         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 227
 228         setorigin (missile, w_shotorg);
 229         if(g_laserguided_missile && self.laser_on)
 230                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 231         else
 232                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 233         W_SetupProjectileVelocity(missile);
 234         missile.angles = vectoangles (missile.velocity);
 235
 236         missile.touch = W_Rocket_Touch;
 237         missile.think = W_Rocket_Think;
 238         missile.nextthink = time;
 239         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 240         missile.effects = EF_LOWPRECISION;
 241         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 242         missile.flags = FL_PROJECTILE;
 243
 244         // muzzle flash for 1st person view
 245         flash = spawn ();
 246         flash.scale = 1.2;
 247         flash.angles_z = 180;
 248         flash.owner = self;
 249         flash.viewmodelforclient = self;
 250         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 251         setorigin (flash, '35 5 -12');
 252         setmodel (flash, "models/flash.md3"); // precision set below
 253         setattachment(flash, self.weaponentity, "bone01");
 254         SUB_SetFade (flash, time, 0.4);
 255
 256         // muzzle flash for 3rd person view
 257         flash2 = spawn ();
 258         flash2.scale = 0.8;
 259         flash2.angles_y = 180;
 260         flash2.angles_z = 90;
 261         setorigin (flash2, '42 0 5');
 262         setmodel (flash2, "models/flash.md3"); // precision set below
 263         setattachment(flash2, self.exteriorweaponentity, "");
 264         SUB_SetFade (flash2, time, 0.4);
 265
 266         // common properties
 267         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 268 }
 269
 270 float(float req) w_rlauncher =
 271 {
 272         if (req == WR_AIM)
 273         {
 274                 // aim and decide to fire if appropriate
 275                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 276                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 277                 {
 278                         // decide whether to detonate rockets
 279                         local entity missile, targetlist, targ;
 280                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 281                         local float selfdamage, teamdamage, enemydamage;
 282                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 283                         coredamage = cvar("g_balance_rocketlauncher_damage");
 284                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 285                         recipricoledgeradius = 1 / edgeradius;
 286                         selfdamage = 0;
 287                         teamdamage = 0;
 288                         enemydamage = 0;
 289                         targetlist = findchainfloat(bot_attack, TRUE);
 290                         missile = find(world, classname, "missile");
 291                         while (missile)
 292                         {
 293                                 if (missile.owner != self)
 294                                 {
 295                                         missile = find(missile, classname, "missile");
 296                                         continue;
 297                                 }
 298                                 targ = targetlist;
 299                                 while (targ)
 300                                 {
 301                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 302                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 303                                         // count potential damage according to type of target
 304                                         if (targ == self)
 305                                                 selfdamage = selfdamage + d;
 306                                         else if (targ.team == self.team && teamplay)
 307                                                 teamdamage = teamdamage + d;
 308                                         else if (bot_shouldattack(targ))
 309                                                 enemydamage = enemydamage + d;
 310                                         targ = targ.chain;
 311                                 }
 312                                 missile = find(missile, classname, "missile");
 313                         }
 314                         local float desirabledamage;
 315                         desirabledamage = enemydamage;
 316                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 317                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 318                         if (self.team && teamplay == 2)
 319                                 desirabledamage = desirabledamage - teamdamage;
 320
 321                         missile = find(world, classname, "missile");
 322                         while (missile)
 323                         {
 324                                 if (missile.owner != self)
 325                                 {
 326                                         missile = find(missile, classname, "missile");
 327                                         continue;
 328                                 }
 329                                 makevectors(missile.v_angle);
 330                                 targ = targetlist;
 331                                 if (skill > 9) // normal players only do this for the target they are tracking
 332                                 {
 333                                         targ = targetlist;
 334                                         while (targ)
 335                                         {
 336                                                 if (
 337                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 338                                                         && desirabledamage > 0.1*coredamage
 339                                                 )self.button3 = TRUE;
 340                                                 targ = targ.chain;
 341                                         }
 342                                 }else{
 343                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 344                                         //As the distance gets larger, a correct detonation gets near imposible
 345                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 346                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 347                                                 if(self.enemy.classname == "player")
 348                                                         if(desirabledamage >= 0.1*coredamage)
 349                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 350                                                                         self.button3 = TRUE;
 351                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 352                                 }
 353
 354                                 missile = find(missile, classname, "missile");
 355                         }
 356                         // if we would be doing at X percent of the core damage, detonate it
 357                         // but don't fire a new shot at the same time!
 358                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 359                                 self.button3 = TRUE;
 360                         if ((skill > 6.5) && (selfdamage > self.health))
 361                                 self.button3 = FALSE;
 362                         //if(self.button3 == TRUE)
 363                         //      dprint(ftos(desirabledamage),"\n");
 364                         if (self.button3 == TRUE) self.button0 = FALSE;
 365                 }
 366         }
 367         else if (req == WR_THINK)
 368         {
 369                 if (self.button0)
 370                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 371                 {
 372                         W_Rocket_Attack();
 373                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 374                 }
 375                 if (self.button3)
 376                 if(time > self.rl_sound)
 377                 {
 378                         self.rl_sound = time + 1;
 379                         sound (self, CHAN_BODY, "weapons/rocket_det.wav", 0.5, ATTN_NORM);
 380                 }
 381                 if (self.button3)
 382                 if(g_laserguided_missile)
 383                 if(self.exteriorweaponentity.attack_finished_single < time)
 384                 {
 385                         self.exteriorweaponentity.attack_finished_single = time + 0.4;
 386                         self.laser_on = !self.laser_on;
 387                         sound (self, CHAN_AUTO, "weapons/tink1.wav", 1, ATTN_NORM);
 388                 }
 389         }
 390         else if (req == WR_PRECACHE)
 391         {
 392                 precache_model ("models/flash.md3");
 393                 precache_model ("models/rocket.md3");
 394                 precache_model ("models/weapons/g_rl.md3");
 395                 precache_model ("models/weapons/v_rl.md3");
 396                 precache_model ("models/weapons/w_rl.zym");
 397                 precache_sound ("weapons/rocket_det.wav");
 398                 precache_sound ("weapons/rocket_fire.wav");
 399                 precache_sound ("weapons/rocket_fly.wav");
 400                 precache_sound ("weapons/rocket_impact.wav");
 401                 if (g_laserguided_missile)
 402                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 403         }
 404         else if (req == WR_SETUP)
 405                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 406         else if (req == WR_CHECKAMMO1)
 407         {
 408                 // don't switch while guiding a missile
 409                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 410                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 411                         return FALSE;
 412         }
 413         else if (req == WR_CHECKAMMO2)
 414                 return FALSE;
 415         else if (req == WR_REGISTER)
 416                 weapon_register(WEP_ROCKET_LAUNCHER, cvar("g_balance_rocketlauncher_ammo"));
 417         return TRUE;
 418 };