data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         if(other.takedamage == DAMAGE_AIM)
  18                 if(other.classname == "player")
  19                         if(IsDifferentTeam(self.owner, other))
  20                                 if(IsFlying(other))
  21                                         announce(self.owner, "announcer/male/airshot.wav");
  22
  23         self.event_damage = SUB_Null;
  24         self.takedamage = DAMAGE_NO;
  25         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  26
  27         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  28         {
  29                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  30                 {
  31                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  32                         ATTACK_FINISHED(self.owner) = time;
  33                         self.owner.switchweapon = w_getbestweapon(self.owner);
  34                 }
  35                 if(g_laserguided_missile)
  36                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  37         }
  38         remove (self);
  39 }
  40
  41 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  42 {
  43         entity head, selected;
  44         vector dir;
  45         float dist, maxdist,// bestdist,
  46                 dot,// bestdot,
  47                 points, bestpoints;
  48         //bestdist = 9999;
  49         //bestdot = -2;
  50         bestpoints = 0;
  51         maxdist = 800;
  52         selected = world;
  53
  54         makevectors(e.angles);
  55
  56         head = find(world, classname, "laser_target");
  57         while(head)
  58         {
  59                 points = 0;
  60                 dir = normalize(head.origin - self.origin);
  61                 dot = dir * v_forward;
  62                 dist = vlen(head.origin - self.origin);
  63                 if(dist > maxdist)
  64                         dist = maxdist;
  65
  66                 // gain points for being in front
  67                 points = points + ((dot+1)*0.5) * 500
  68                         * (1 + crandom()*dot_variance);
  69                 // gain points for being close away
  70                 points = points + (1 - dist/maxdist) * 1000
  71                         * (1 + crandom()*dot_variance);
  72
  73                 traceline(e.origin, head.origin, TRUE, self);
  74                 if(trace_fraction < 1)
  75                 {
  76                         points = 0;
  77                 }
  78
  79                 if(points > bestpoints)//random() > 0.5)//
  80                 {
  81                         bestpoints = points;
  82                         selected = head;
  83                 }
  84
  85                 head = find(head, classname, "laser_target");
  86         }
  87
  88         //bprint(selected.owner.netname);
  89         //bprint("\n");
  90         return selected;
  91 }
  92
  93 void W_Rocket_RemoteExplode()
  94 {
  95         if(self.owner.deadflag == DEAD_NO)
  96         if(self.owner.lastrocket)
  97         {
  98                 if((self.spawnshieldtime >= 0)
  99                         ? (time >= self.spawnshieldtime) // timer
 100                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 101                 )
 102                 {
 103                         other = world;
 104                         self.projectiledeathtype |= HITTYPE_BOUNCE;
 105                         W_Rocket_Explode ();
 106                 }
 107                 else
 108                 {
 109                 }
 110         }
 111 }
 112
 113 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 114 {
 115         if(thisdir * goaldir > maxturn_cos)
 116                 return goaldir;
 117         float f, m2;
 118         vector v;
 119         // solve:
 120         //   g = normalize(thisdir + goaldir * X)
 121         //   thisdir * g = maxturn
 122         //
 123         //   gg = thisdir + goaldir * X
 124         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 125         //
 126         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 127         f = thisdir * goaldir;
 128         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 129         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 130         m2 = maxturn_cos * maxturn_cos;
 131         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 132         return normalize(thisdir + goaldir * v_y); // the larger solution!
 133 }
 134
 135 void W_Rocket_Think (void)
 136 {
 137         entity e;
 138         vector desireddir, olddir, newdir, desiredorigin, goal;
 139         float turnrate, velspeed, f;
 140         self.nextthink = time;
 141         if (time > self.cnt)
 142         {
 143                 other = world;
 144                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 145                 W_Rocket_Explode ();
 146                 return;
 147         }
 148
 149         if(g_laserguided_missile)
 150         {
 151                 // accelerate
 152                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 153                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 154                 if (velspeed > 0)
 155                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 156         }
 157         else
 158         {
 159                 // accelerate
 160                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 161                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 162                 if (velspeed > 0)
 163                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 164         }
 165
 166         // laser guided, or remote detonation
 167         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 168         {
 169                 if(g_laserguided_missile)
 170                 {
 171                         if(self.rl_detonate_later)
 172                                 W_Rocket_RemoteExplode();
 173
 174                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 175                         {
 176                                 if(self.owner.laser_on)
 177                                 {
 178                                         if(self.attack_finished_single < time)
 179                                         {
 180                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 181                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 182                                         }
 183
 184                                         if(!self.enemy)
 185                                                 self.enemy = self.owner.weaponentity.lasertarget;
 186                                 }
 187                                 else self.enemy = world;
 188                         }
 189                         else // don't allow stealing: always target my owner's laser (if it exists)
 190                                 self.enemy = self.owner.weaponentity.lasertarget;
 191
 192                         if(self.enemy != world)
 193                         {
 194                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 195                                 velspeed = vlen(self.velocity);
 196                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 197                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 198                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 199                                 olddir = normalize(self.velocity);                                      // get my current direction
 200                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 201                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 202                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 203
 204                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 205                         }
 206                 }
 207                 else
 208                 {
 209                         if(self == self.owner.lastrocket)
 210                         if(!self.owner.rl_release)
 211                         if(cvar("g_balance_rocketlauncher_guiderate"))
 212                         if(time > self.pushltime)
 213                         if(self.owner.deadflag == DEAD_NO)
 214                         {
 215                                 f = min(1, (time - self.pushltime) / cvar("g_balance_rocketlauncher_guideratedelay"));
 216                                 velspeed = vlen(self.velocity);
 217
 218                                 makevectors(self.owner.v_angle);
 219                                 desireddir = v_forward;
 220                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 221                                 olddir = normalize(self.velocity);
 222
 223                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 224                                 // but we are limiting the rate at which we can turn!
 225                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 226                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * PI / 180));
 227
 228                                 self.velocity = newdir * velspeed;
 229                                 self.angles = vectoangles(self.velocity);
 230                         }
 231
 232                         if(self.rl_detonate_later)
 233                                 W_Rocket_RemoteExplode();
 234                 }
 235         }
 236
 237         if(self.csqcprojectile_clientanimate == 0)
 238                 UpdateCSQCProjectile(self);
 239 }
 240
 241 void W_Rocket_Touch (void)
 242 {
 243         W_Rocket_Unregister();
 244
 245         PROJECTILE_TOUCH;
 246         W_Rocket_Explode ();
 247 }
 248
 249 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 250 {
 251         if (self.health <= 0)
 252                 return;
 253         self.health = self.health - damage;
 254         self.angles = vectoangles(self.velocity);
 255         if (self.health <= 0)
 256                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 257 }
 258
 259 void W_Rocket_Attack (void)
 260 {
 261         local entity missile;
 262         local entity flash;
 263
 264         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 265                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 266
 267         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 268         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 269
 270         missile = spawn ();
 271         missile.owner = self;
 272         self.lastrocket = missile;
 273         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 274                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 275         else
 276                 missile.spawnshieldtime = -1;
 277         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 278         missile.classname = "rocket";
 279         missile.bot_dodge = TRUE;
 280         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 281
 282         missile.takedamage = DAMAGE_YES;
 283         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 284         missile.health = cvar("g_balance_rocketlauncher_health");
 285         missile.event_damage = W_Rocket_Damage;
 286
 287         missile.movetype = MOVETYPE_FLY;
 288         PROJECTILE_MAKETRIGGER(missile);
 289         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 290         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 291
 292         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 293         if(g_laserguided_missile && self.laser_on)
 294                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart") * g_weaponspeedfactor;
 295         else
 296                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart") * g_weaponspeedfactor;
 297         W_SetupProjectileVelocity(missile);
 298         missile.angles = vectoangles (missile.velocity);
 299
 300         missile.touch = W_Rocket_Touch;
 301         missile.think = W_Rocket_Think;
 302         missile.nextthink = time;
 303         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 304         missile.flags = FL_PROJECTILE;
 305
 306         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 307
 308         // muzzle flash for 1st person view
 309         flash = spawn ();
 310         setmodel (flash, "models/flash.md3"); // precision set below
 311         SUB_SetFade (flash, time, 0.1);
 312         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 313         W_AttachToShotorg(flash, '5 0 0');
 314
 315         // common properties
 316 }
 317
 318 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 319
 320 float w_rlauncher(float req)
 321 {
 322         entity rock;
 323         float rockfound;
 324         if (req == WR_AIM)
 325         {
 326                 // aim and decide to fire if appropriate
 327                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 328                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 329                 {
 330                         // decide whether to detonate rockets
 331                         local entity missile, targetlist, targ;
 332                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 333                         local float selfdamage, teamdamage, enemydamage;
 334                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 335                         coredamage = cvar("g_balance_rocketlauncher_damage");
 336                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 337                         recipricoledgeradius = 1 / edgeradius;
 338                         selfdamage = 0;
 339                         teamdamage = 0;
 340                         enemydamage = 0;
 341                         targetlist = findchainfloat(bot_attack, TRUE);
 342                         missile = find(world, classname, "rocket");
 343                         while (missile)
 344                         {
 345                                 if (missile.owner != self)
 346                                 {
 347                                         missile = find(missile, classname, "rocket");
 348                                         continue;
 349                                 }
 350                                 targ = targetlist;
 351                                 while (targ)
 352                                 {
 353                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 354                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 355                                         // count potential damage according to type of target
 356                                         if (targ == self)
 357                                                 selfdamage = selfdamage + d;
 358                                         else if (targ.team == self.team && teams_matter)
 359                                                 teamdamage = teamdamage + d;
 360                                         else if (bot_shouldattack(targ))
 361                                                 enemydamage = enemydamage + d;
 362                                         targ = targ.chain;
 363                                 }
 364                                 missile = find(missile, classname, "rocket");
 365                         }
 366                         local float desirabledamage;
 367                         desirabledamage = enemydamage;
 368                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 369                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 370                         if (self.team && teamplay != 1)
 371                                 desirabledamage = desirabledamage - teamdamage;
 372
 373                         missile = find(world, classname, "rocket");
 374                         while (missile)
 375                         {
 376                                 if (missile.owner != self)
 377                                 {
 378                                         missile = find(missile, classname, "rocket");
 379                                         continue;
 380                                 }
 381                                 makevectors(missile.v_angle);
 382                                 targ = targetlist;
 383                                 if (skill > 9) // normal players only do this for the target they are tracking
 384                                 {
 385                                         targ = targetlist;
 386                                         while (targ)
 387                                         {
 388                                                 if (
 389                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 390                                                         && desirabledamage > 0.1*coredamage
 391                                                 )self.BUTTON_ATCK2 = TRUE;
 392                                                 targ = targ.chain;
 393                                         }
 394                                 }else{
 395                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 396                                         //As the distance gets larger, a correct detonation gets near imposible
 397                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 398                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 399                                                 if(self.enemy.classname == "player")
 400                                                         if(desirabledamage >= 0.1*coredamage)
 401                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 402                                                                         self.BUTTON_ATCK2 = TRUE;
 403                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 404                                 }
 405
 406                                 missile = find(missile, classname, "rocket");
 407                         }
 408                         // if we would be doing at X percent of the core damage, detonate it
 409                         // but don't fire a new shot at the same time!
 410                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 411                                 self.BUTTON_ATCK2 = TRUE;
 412                         if ((skill > 6.5) && (selfdamage > self.health))
 413                                 self.BUTTON_ATCK2 = FALSE;
 414                         //if(self.BUTTON_ATCK2 == TRUE)
 415                         //      dprint(ftos(desirabledamage),"\n");
 416                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 417                 }
 418         }
 419         else if (req == WR_THINK)
 420         {
 421                 if(g_laserguided_missile)
 422                 {
 423                         if (self.BUTTON_ATCK && self.rl_release)
 424                         {
 425                                 rockfound = 0;
 426                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 427                                 {
 428                                         if(!rock.rl_detonate_later)
 429                                         {
 430                                                 rock.rl_detonate_later = TRUE;
 431                                                 rockfound = 1;
 432                                         }
 433                                 }
 434                                 if(rockfound)
 435                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 436                                 else
 437                                 {
 438                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 439                                         {
 440                                                 W_Rocket_Attack();
 441                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 442                                         }
 443                                 }
 444                                 self.rl_release = 0;
 445                         }
 446                         if (!self.BUTTON_ATCK)
 447                                 self.rl_release = 1;
 448                         if (self.BUTTON_ATCK2)
 449                         if(self.exteriorweaponentity.attack_finished_single < time)
 450                         {
 451                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 452                                 self.laser_on = !self.laser_on;
 453                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 454                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 455                         }
 456                 }
 457                 else
 458                 {
 459                         if (self.BUTTON_ATCK)
 460                         {
 461                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 462                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 463                                 {
 464                                         W_Rocket_Attack();
 465                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 466                                         self.rl_release = 0;
 467                                 }
 468                         }
 469                         else
 470                                 self.rl_release = 1;
 471
 472                         if (self.BUTTON_ATCK2)
 473                         {
 474                                 rockfound = 0;
 475                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 476                                 {
 477                                         if(!rock.rl_detonate_later)
 478                                         {
 479                                                 rock.rl_detonate_later = TRUE;
 480                                                 rockfound = 1;
 481                                         }
 482                                 }
 483                                 if(rockfound)
 484                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 485                         }
 486                 }
 487         }
 488         else if (req == WR_PRECACHE)
 489         {
 490                 precache_model ("models/flash.md3");
 491                 precache_model ("models/weapons/g_rl.md3");
 492                 precache_model ("models/weapons/v_rl.md3");
 493                 precache_model ("models/weapons/h_rl.dpm");
 494                 precache_sound ("weapons/rocket_det.wav");
 495                 precache_sound ("weapons/rocket_fire.wav");
 496                 if (g_laserguided_missile)
 497                 {
 498                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 499                         precache_sound ("weapons/rocket_mode.wav");
 500                 }
 501         }
 502         else if (req == WR_SETUP)
 503         {
 504                 weapon_setup(WEP_ROCKET_LAUNCHER);
 505                 self.rl_release = 1;
 506         }
 507         else if (req == WR_CHECKAMMO1)
 508         {
 509                 // don't switch while guiding a missile
 510                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 511                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 512                         return FALSE;
 513         }
 514         else if (req == WR_CHECKAMMO2)
 515                 return FALSE;
 516         else if (req == WR_SUICIDEMESSAGE)
 517                 w_deathtypestring = "exploded";
 518         else if (req == WR_KILLMESSAGE)
 519         {
 520                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 521                         w_deathtypestring = "got too close to #'s rocket";
 522                 else if(w_deathtype & HITTYPE_SPLASH)
 523                         w_deathtypestring = "almost dodged #'s rocket";
 524                 else
 525                         w_deathtypestring = "ate #'s rocket";
 526         }
 527         return TRUE;
 528 };