data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.wav", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  11
  12         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  13         self.event_damage = SUB_Null;
  14         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  15
  16         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  17         {
  18                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  19                 {
  20                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  21                         ATTACK_FINISHED(self.owner) = time;
  22                         self.owner.switchweapon = w_getbestweapon(self.owner);
  23                 }
  24                 if(g_laserguided_missile)
  25                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  26         }
  27         remove (self);
  28 }
  29
  30 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  31 {
  32         entity head, selected;
  33         vector dir;
  34         float dist, maxdist,// bestdist,
  35                 dot,// bestdot,
  36                 points, bestpoints;
  37         //bestdist = 9999;
  38         //bestdot = -2;
  39         bestpoints = 0;
  40         maxdist = 800;
  41         selected = world;
  42
  43         makevectors(e.angles);
  44
  45         head = find(world, classname, "laser_target");
  46         while(head)
  47         {
  48                 points = 0;
  49                 dir = normalize(head.origin - self.origin);
  50                 dot = dir * v_forward;
  51                 dist = vlen(head.origin - self.origin);
  52                 if(dist > maxdist)
  53                         dist = maxdist;
  54
  55                 // gain points for being in front
  56                 points = points + ((dot+1)*0.5) * 500
  57                         * (1 + crandom()*dot_variance);
  58                 // gain points for being close away
  59                 points = points + (1 - dist/maxdist) * 1000
  60                         * (1 + crandom()*dot_variance);
  61
  62                 traceline(e.origin, head.origin, TRUE, self);
  63                 if(trace_fraction < 1)
  64                 {
  65                         points = 0;
  66                 }
  67
  68                 if(points > bestpoints)//random() > 0.5)//
  69                 {
  70                         bestpoints = points;
  71                         selected = head;
  72                 }
  73
  74                 head = find(head, classname, "laser_target");
  75         }
  76
  77         //bprint(selected.owner.netname);
  78         //bprint("\n");
  79         return selected;
  80 }
  81
  82 void W_Rocket_Think (void)
  83 {
  84         entity e;
  85         vector desireddir, olddir, newdir;
  86         float turnrate, velspeed;
  87         self.nextthink = time;
  88         if (time > self.cnt)
  89         {
  90                 W_Rocket_Explode ();
  91                 return;
  92         }
  93
  94         if(g_laserguided_missile)
  95         {
  96                 // accelerate
  97                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
  98                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
  99                 if (velspeed > 0)
 100                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 101         }
 102         else
 103         {
 104                 // accelerate
 105                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 106                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 107                 if (velspeed > 0)
 108                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 109         }
 110
 111         // laser guided, or remote detonation
 112         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 113         {
 114                 if(g_laserguided_missile)
 115                 {
 116                         if(!self.owner.button0)
 117                                 self.ltime = -1; // indicate that the player has let go of the button
 118
 119
 120                         if(self.owner.deadflag == DEAD_NO)
 121                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 122                         if(time >= self.spawnshieldtime)
 123                         {
 124                                   W_Rocket_Explode ();
 125                                   return;
 126                         }
 127
 128                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 129                         {
 130                                 if(self.owner.laser_on)
 131                                 {
 132                                         if(self.attack_finished_single < time)
 133                                         {
 134                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 135                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 136                                         }
 137
 138                                         if(!self.enemy)
 139                                                 self.enemy = self.owner.weaponentity.lasertarget;
 140                                 }
 141                                 else self.enemy = world;
 142                         }
 143                         else // don't allow stealing: always target my owner's laser (if it exists)
 144                                 self.enemy = self.owner.weaponentity.lasertarget;
 145
 146                         if(self.enemy != world)
 147                         {
 148                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 149                                 velspeed = vlen(self.velocity);
 150                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 151                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 152                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 153                                 olddir = normalize(self.velocity);                                      // get my current direction
 154                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 155                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 156                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 157
 158                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 159                         }
 160                 }
 161                 else
 162                 {
 163                         if(self.owner.deadflag == DEAD_NO)
 164                         if (self.owner.button3)
 165                         if(time >= self.spawnshieldtime)
 166                                   W_Rocket_Explode ();
 167                 }
 168         }
 169 }
 170
 171 void W_Rocket_Touch (void)
 172 {
 173         if(self.owner && self.owner.lastrocket == self)
 174                 self.owner.lastrocket = world;
 175         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 176         {
 177                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 178                 remove(self);
 179                 return;
 180         }
 181         W_Rocket_Explode ();
 182 }
 183
 184 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 185 {
 186         self.health = self.health - damage;
 187         self.angles = vectoangles(self.velocity);
 188         if (self.health <= 0)
 189         {
 190                 self.owner = attacker;
 191                 W_Rocket_Explode();
 192         }
 193 }
 194
 195 void W_Rocket_Attack (void)
 196 {
 197         local entity missile;
 198         local entity flash, flash2;
 199
 200         if (cvar("g_use_ammunition") && !g_rocketarena)
 201                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 202
 203         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 204         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 205         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 206
 207         missile = spawn ();
 208         missile.owner = self;
 209         self.lastrocket = missile;
 210         missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 211         missile.classname = "missile";
 212         missile.bot_dodge = TRUE;
 213         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 214
 215         missile.takedamage = DAMAGE_YES;
 216         missile.damageforcescale = 4;
 217         missile.health = 30;
 218         missile.event_damage = W_Rocket_Damage;
 219
 220         missile.movetype = MOVETYPE_FLY;
 221         missile.solid = SOLID_BBOX;
 222         setmodel (missile, "models/rocket.md3"); // precision set below
 223         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 224
 225         setorigin (missile, w_shotorg);
 226         if(g_laserguided_missile && self.laser_on)
 227                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 228         else
 229                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 230         W_SetupProjectileVelocity(missile);
 231         missile.angles = vectoangles (missile.velocity);
 232
 233         missile.touch = W_Rocket_Touch;
 234         missile.think = W_Rocket_Think;
 235         missile.nextthink = time;
 236         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 237         missile.effects = EF_LOWPRECISION;
 238         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 239         missile.flags = FL_PROJECTILE;
 240
 241         // muzzle flash for 1st person view
 242         flash = spawn ();
 243         flash.scale = 1.2;
 244         flash.angles_z = 180;
 245         flash.owner = self;
 246         flash.viewmodelforclient = self;
 247         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 248         setorigin (flash, '35 8 0');
 249         setmodel (flash, "models/flash.md3"); // precision set below
 250         setattachment(flash, self.weaponentity, "bone01");
 251         SUB_SetFade (flash, time, 0.4);
 252
 253         // muzzle flash for 3rd person view
 254         flash2 = spawn ();
 255         flash2.scale = 0.8;
 256         flash2.angles_y = 180;
 257         flash2.angles_z = 90;
 258         setorigin (flash2, '42 0 5');
 259         setmodel (flash2, "models/flash.md3"); // precision set below
 260         setattachment(flash2, self.exteriorweaponentity, "");
 261         SUB_SetFade (flash2, time, 0.4);
 262
 263         // common properties
 264         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 265 }
 266
 267 float(float req) w_rlauncher =
 268 {
 269         if (req == WR_AIM)
 270         {
 271                 // aim and decide to fire if appropriate
 272                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 273                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 274                 {
 275                         // decide whether to detonate rockets
 276                         local entity missile, targetlist, targ;
 277                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 278                         local float selfdamage, teamdamage, enemydamage;
 279                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 280                         coredamage = cvar("g_balance_rocketlauncher_damage");
 281                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 282                         recipricoledgeradius = 1 / edgeradius;
 283                         selfdamage = 0;
 284                         teamdamage = 0;
 285                         enemydamage = 0;
 286                         targetlist = findchainfloat(bot_attack, TRUE);
 287                         missile = find(world, classname, "missile");
 288                         while (missile)
 289                         {
 290                                 if (missile.owner != self)
 291                                 {
 292                                         missile = find(missile, classname, "missile");
 293                                         continue;
 294                                 }
 295                                 targ = targetlist;
 296                                 while (targ)
 297                                 {
 298                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 299                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 300                                         // count potential damage according to type of target
 301                                         if (targ == self)
 302                                                 selfdamage = selfdamage + d;
 303                                         else if (targ.team == self.team && teamplay)
 304                                                 teamdamage = teamdamage + d;
 305                                         else if (bot_shouldattack(targ))
 306                                                 enemydamage = enemydamage + d;
 307                                         targ = targ.chain;
 308                                 }
 309                                 missile = find(missile, classname, "missile");
 310                         }
 311                         local float desirabledamage;
 312                         desirabledamage = enemydamage;
 313                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 314                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 315                         if (self.team && teamplay == 2)
 316                                 desirabledamage = desirabledamage - teamdamage;
 317
 318                         missile = find(world, classname, "missile");
 319                         while (missile)
 320                         {
 321                                 if (missile.owner != self)
 322                                 {
 323                                         missile = find(missile, classname, "missile");
 324                                         continue;
 325                                 }
 326                                 makevectors(missile.v_angle);
 327                                 targ = targetlist;
 328                                 if (skill > 9) // normal players only do this for the target they are tracking
 329                                 {
 330                                         targ = targetlist;
 331                                         while (targ)
 332                                         {
 333                                                 if (
 334                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 335                                                         && desirabledamage > 0.1*coredamage
 336                                                 )self.button3 = TRUE;
 337                                                 targ = targ.chain;
 338                                         }
 339                                 }else{
 340                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 341                                         //As the distance gets larger, a correct detonation gets near imposible
 342                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 343                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 344                                                 if(self.enemy.classname == "player")
 345                                                         if(desirabledamage >= 0.1*coredamage)
 346                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 347                                                                         self.button3 = TRUE;
 348                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 349                                 }
 350
 351                                 missile = find(missile, classname, "missile");
 352                         }
 353                         // if we would be doing at X percent of the core damage, detonate it
 354                         // but don't fire a new shot at the same time!
 355                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 356                                 self.button3 = TRUE;
 357                         if ((skill > 6.5) && (selfdamage > self.health))
 358                                 self.button3 = FALSE;
 359                         //if(self.button3 == TRUE)
 360                         //      dprint(ftos(desirabledamage),"\n");
 361                         if (self.button3 == TRUE) self.button0 = FALSE;
 362                 }
 363         }
 364         else if (req == WR_THINK)
 365         {
 366                 if (self.button0)
 367                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 368                 {
 369                         W_Rocket_Attack();
 370                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 371                 }
 372                 if (self.button3)
 373                 if(time > self.rl_sound)
 374                 {
 375                         self.rl_sound = time + 1;
 376                         sound (self, CHAN_BODY, "weapons/rocket_det.wav", 0.5, ATTN_NORM);
 377                 }
 378                 if (self.button3)
 379                 if(g_laserguided_missile)
 380                 if(self.exteriorweaponentity.attack_finished_single < time)
 381                 {
 382                         self.exteriorweaponentity.attack_finished_single = time + 0.4;
 383                         self.laser_on = !self.laser_on;
 384                         sound (self, CHAN_AUTO, "weapons/tink1.wav", 1, ATTN_NORM);
 385                 }
 386         }
 387         else if (req == WR_PRECACHE)
 388         {
 389                 precache_model ("models/flash.md3");
 390                 precache_model ("models/rocket.md3");
 391                 precache_model ("models/weapons/g_rl.md3");
 392                 precache_model ("models/weapons/v_rl.md3");
 393                 precache_model ("models/weapons/w_rl.zym");
 394                 precache_sound ("weapons/rocket_det.wav");
 395                 precache_sound ("weapons/rocket_fire.wav");
 396                 precache_sound ("weapons/rocket_fly.wav");
 397                 precache_sound ("weapons/rocket_impact.wav");
 398                 if (g_laserguided_missile)
 399                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 400         }
 401         else if (req == WR_SETUP)
 402                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 403         else if (req == WR_CHECKAMMO1)
 404         {
 405                 // don't switch while guiding a missile
 406                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 407                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 408                         return FALSE;
 409         }
 410         else if (req == WR_CHECKAMMO2)
 411                 return FALSE;
 412         else if (req == WR_REGISTER)
 413                 weapon_register(WEP_ROCKET_LAUNCHER, cvar("g_balance_rocketlauncher_ammo"));
 414         return TRUE;
 415 };