data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         //te_explosion (org2);
  11         // LordHavoc: TE_TEI_BIGEXPLOSION
  12         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  13         WriteByte (MSG_BROADCAST, 78);
  14         WriteCoord (MSG_BROADCAST, org2_x);
  15         WriteCoord (MSG_BROADCAST, org2_y);
  16         WriteCoord (MSG_BROADCAST, org2_z);
  17
  18         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  19         self.event_damage = SUB_Null;
  20         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  21
  22         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  23         {
  24                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  25                 {
  26                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  27                         self.owner.attack_finished = time;
  28                         self.owner.switchweapon = w_getbestweapon(self.owner);
  29                 }
  30                 if(cvar("g_laserguided_missile"))
  31                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
  32         }
  33         remove (self);
  34 }
  35
  36 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  37 {
  38         entity head, selected;
  39         vector dir;
  40         float dist, maxdist,// bestdist,
  41                 dot,// bestdot,
  42                 points, bestpoints;
  43         //bestdist = 9999;
  44         //bestdot = -2;
  45         bestpoints = 0;
  46         maxdist = 800;
  47         selected = world;
  48
  49         makevectors(e.angles);
  50
  51         head = find(world, classname, "laser_target");
  52         while(head)
  53         {
  54                 points = 0;
  55                 dir = normalize(head.origin - self.origin);
  56                 dot = dir * v_forward;
  57                 dist = vlen(head.origin - self.origin);
  58                 if(dist > maxdist)
  59                         dist = maxdist;
  60
  61                 // gain points for being in front
  62                 points = points + ((dot+1)*0.5) * 500
  63                         * (1 + crandom()*dot_variance);
  64                 // gain points for being close away
  65                 points = points + (1 - dist/maxdist) * 1000
  66                         * (1 + crandom()*dot_variance);
  67
  68                 traceline(e.origin, head.origin, TRUE, self);
  69                 if(trace_fraction < 1)
  70                 {
  71                         points = 0;
  72                 }
  73
  74                 if(points > bestpoints)//random() > 0.5)//
  75                 {
  76                         bestpoints = points;
  77                         selected = head;
  78                 }
  79
  80                 head = find(head, classname, "laser_target");
  81         }
  82
  83         //bprint(selected.owner.netname);
  84         //bprint("\n");
  85         return selected;
  86 }
  87
  88 void W_Rocket_Think (void)
  89 {
  90         entity e;
  91         vector desireddir, olddir, newdir;
  92         float turnrate;
  93         self.nextthink = time;
  94         if (time > self.cnt)
  95         {
  96                 W_Rocket_Explode ();
  97                 return;
  98         }
  99         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 100         {
 101                 if(cvar("g_laserguided_missile"))
 102                 {
 103                         if(!self.owner.button0)
 104                                 self.ltime = -1; // indicate that the player has let go of the button
 105
 106
 107                         if(self.owner.deadflag == DEAD_NO)
 108                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 109                         {
 110                                   W_Rocket_Explode ();
 111                                   return;
 112                         }
 113
 114                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 115                         {
 116                                 if(self.owner.laser_on)
 117                                 {
 118                                         if(self.attack_finished < time)
 119                                         {
 120                                                 self.attack_finished = time + 0.2 + random()*0.3;
 121                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 122                                         }
 123
 124                                         if(!self.enemy)
 125                                                 self.enemy = self.owner.weaponentity.lasertarget;
 126                                 }
 127                                 else self.enemy = world;
 128                         }
 129                         else // don't allow stealing: always target my owner's laser (if it exists)
 130                                 self.enemy = self.owner.weaponentity.lasertarget;
 131
 132                         if(self.enemy != world)
 133                         {
 134                                 //bprint(strcat("Targeting ", self.enemy.owner.netname, "'s laser\n"));
 135                                 if(!self.speed)
 136                                         self.speed = vlen(self.velocity);
 137                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 138                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 139                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 140                                 olddir = normalize(self.velocity);                              // get my current direction
 141                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 142                                 self.velocity = newdir * self.speed;                    // make me fly in the new direction at my flight speed
 143                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 144
 145                                 self.owner.attack_finished = time + 0.2;
 146                         }
 147                 }
 148                 else
 149                 {
 150                         if(self.owner.deadflag == DEAD_NO)
 151                         if (self.owner.button3)
 152                                   W_Rocket_Explode ();
 153                 }
 154         }
 155 }
 156
 157 void W_Rocket_Touch (void)
 158 {
 159         if(self.owner && self.owner.lastrocket == self)
 160                 self.owner.lastrocket = world;
 161         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 162         {
 163                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 164                 remove(self);
 165                 return;
 166         }
 167         W_Rocket_Explode ();
 168 }
 169
 170 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health = self.health - damage;
 173         if (self.health <= 0)
 174         {
 175                 self.owner = attacker;
 176                 W_Rocket_Explode();
 177         }
 178 }
 179
 180 void W_Rocket_Attack (void)
 181 {
 182         local entity missile;
 183         local entity flash;
 184
 185         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 186                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 187
 188         W_SetupShot (self, '15 3 -8', FALSE, 5, "weapons/rocket_fire.ogg");
 189         te_smallflash(w_shotorg);
 190
 191         missile = spawn ();
 192         missile.owner = self;
 193         self.lastrocket = missile;
 194         missile.classname = "missile";
 195         missile.bot_dodge = TRUE;
 196         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 197
 198         missile.takedamage = DAMAGE_YES;
 199         missile.damageforcescale = 4;
 200         missile.health = 30;
 201         missile.event_damage = W_Rocket_Damage;
 202
 203         missile.movetype = MOVETYPE_FLY;
 204         missile.solid = SOLID_BBOX;
 205         setmodel (missile, "models/rocket.md3");
 206         setsize (missile, '0 0 0', '0 0 0');
 207
 208         setorigin (missile, w_shotorg);
 209         if(cvar("g_laserguided_missile") && self.laser_on)
 210                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speed");
 211         else
 212                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speed");
 213         W_SetupProjectileVelocity(missile);
 214         missile.angles = vectoangles (missile.velocity);
 215
 216         missile.touch = W_Rocket_Touch;
 217         missile.think = W_Rocket_Think;
 218         missile.nextthink = time;
 219         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 220         missile.effects = EF_NOSHADOW;
 221         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 222         missile.flags = FL_PROJECTILE;
 223
 224         flash = spawn ();
 225         setorigin (flash, w_shotorg);
 226         setmodel (flash, "models/flash.md3");
 227         flash.angles = vectoangles (w_shotdir);
 228         SUB_SetFade (flash, time, 0.4);
 229         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 230 }
 231
 232 float(float req) w_rlauncher =
 233 {
 234         if (req == WR_AIM)
 235         {
 236                 // aim and decide to fire if appropriate
 237                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 238                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 239                 {
 240                         // decide whether to detonate rockets
 241                         local entity missile, targetlist, targ;
 242                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 243                         local float selfdamage, teamdamage, enemydamage;
 244                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 245                         coredamage = cvar("g_balance_rocketlauncher_damage");
 246                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 247                         recipricoledgeradius = 1 / edgeradius;
 248                         selfdamage = 0;
 249                         teamdamage = 0;
 250                         enemydamage = 0;
 251                         targetlist = findchainfloat(bot_attack, TRUE);
 252                         missile = find(world, classname, "missile");
 253                         while (missile)
 254                         {
 255                                 if (missile.owner != self)
 256                                 {
 257                                         missile = find(missile, classname, "missile");
 258                                         continue;
 259                                 }
 260                                 targ = targetlist;
 261                                 while (targ)
 262                                 {
 263                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 264                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 265                                         // count potential damage according to type of target
 266                                         if (targ == self)
 267                                                 selfdamage = selfdamage + d;
 268                                         else if (targ.team == self.team && teamplay)
 269                                                 teamdamage = teamdamage + d;
 270                                         else if (bot_shouldattack(targ))
 271                                                 enemydamage = enemydamage + d;
 272                                         targ = targ.chain;
 273                                 }
 274                                 missile = find(missile, classname, "missile");
 275                         }
 276                         local float desirabledamage;
 277                         desirabledamage = enemydamage;
 278                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 279                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 280                         if (self.team && teamplay == 2)
 281                                 desirabledamage = desirabledamage - teamdamage;
 282
 283                         missile = find(world, classname, "missile");
 284                         while (missile)
 285                         {
 286                                 if (missile.owner != self)
 287                                 {
 288                                         missile = find(missile, classname, "missile");
 289                                         continue;
 290                                 }
 291                                 makevectors(missile.v_angle);
 292                                 targ = targetlist;
 293                                 if (skill > 9) // normal players only do this for the target they are tracking
 294                                 {
 295                                         targ = targetlist;
 296                                         while (targ)
 297                                         {
 298                                                 if (
 299                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 300                                                         && desirabledamage > 0.1*coredamage
 301                                                 )self.button3 = TRUE;
 302                                                 targ = targ.chain;
 303                                         }
 304                                 }else{
 305                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 306                                         //As the distance gets larger, a correct detonation gets near imposible
 307                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 308                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 309                                                 if(self.enemy.classname == "player")
 310                                                         if(desirabledamage >= 0.1*coredamage)
 311                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 312                                                                         self.button3 = TRUE;
 313                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 314                                 }
 315
 316                                 missile = find(missile, classname, "missile");
 317                         }
 318                         // if we would be doing at X percent of the core damage, detonate it
 319                         // but don't fire a new shot at the same time!
 320                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 321                                 self.button3 = TRUE;
 322                         if ((skill > 6.5) && (selfdamage > self.health))
 323                                 self.button3 = FALSE;
 324                         //if(self.button3 == TRUE)
 325                         //      dprint(ftos(desirabledamage),"\n");
 326                         if (self.button3 == TRUE) self.button0 = FALSE;
 327                 }
 328         }
 329         else if (req == WR_THINK)
 330         {
 331                 if (self.button0)
 332                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 333                 {
 334                         W_Rocket_Attack();
 335                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 336                 }
 337                 if (self.button3)
 338                 if(time > self.rl_sound)
 339                 {
 340                         self.rl_sound = time + 1;
 341                         sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
 342                 }
 343                 if (self.button3)
 344                 if(cvar("g_laserguided_missile"))
 345                 if(self.exteriorweaponentity.attack_finished < time)
 346                 {
 347                         self.exteriorweaponentity.attack_finished = time + 0.4;
 348                         self.laser_on = !self.laser_on;
 349                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
 350                 }
 351         }
 352         else if (req == WR_SETUP)
 353                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 354         else if (req == WR_CHECKAMMO1)
 355         {
 356                 // don't switch while guiding a missile
 357                 if ((self.attack_finished <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 358                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 359                         return FALSE;
 360         }
 361         else if (req == WR_CHECKAMMO2)
 362                 return FALSE;
 363         return TRUE;
 364 };