data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         if(self.owner == world)
  10         {
  11                 objerror("Cannot succeed successfully: no owner\n");
  12                 return;
  13         }
  14
  15         self.owner.porto_current = world;
  16         remove(self);
  17 }
  18
  19 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  20 void W_Porto_Fail (float failhard)
  21 {
  22         if(self.owner == world)
  23         {
  24                 objerror("Cannot fail successfully: no owner\n");
  25                 return;
  26         }
  27
  28         // no portals here!
  29         Portal_ClearWithID(self.owner, self.portal_id);
  30         self.owner.porto_current = world;
  31
  32         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  33         {
  34                 setsize (self, '-16 -16 0', '16 16 32');
  35                 setorigin(self, self.origin + trace_plane_normal);
  36                 if(move_out_of_solid(self))
  37                 {
  38                         self.flags = FL_ITEM;
  39                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  40                         tracetoss(self, self);
  41                         if(vlen(trace_endpos - self.owner.origin) < 128)
  42                         {
  43                                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  44                                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  45                         }
  46                 }
  47         }
  48         remove(self);
  49 }
  50
  51 void W_Porto_Think (void)
  52 {
  53         trace_plane_normal = '0 0 0';
  54         if(self.owner.playerid != self.playerid)
  55                 remove(self);
  56         else
  57                 W_Porto_Fail(0);
  58 }
  59
  60 void W_Porto_Touch (void)
  61 {
  62         vector norm;
  63
  64         if(other.classname == "portal")
  65                 return; // handled by the portal
  66
  67         norm = trace_plane_normal;
  68         if(self.owner.playerid != self.playerid)
  69         {
  70                 remove(self);
  71         }
  72         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  73         {
  74                 // just reflect
  75                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  76                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  77         }
  78         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  79         {
  80                 W_Porto_Fail(0);
  81         }
  82         else if(self.effects & EF_RED)
  83         {
  84                 self.effects += EF_BLUE - EF_RED;
  85                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  86                 {
  87                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
  88                         centerprint(self.owner, "^1In^7-portal created.\n");
  89                         trace_plane_normal = norm;
  90                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  91                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  92                 }
  93                 else
  94                 {
  95                         trace_plane_normal = norm;
  96                         W_Porto_Fail(0);
  97                 }
  98         }
  99         else
 100         {
 101                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 102                 {
 103                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 104                         centerprint(self.owner, "^4Out^7-portal created.\n");
 105                         W_Porto_Success();
 106                 }
 107                 else
 108                 {
 109                         trace_plane_normal = norm;
 110                         W_Porto_Fail(0);
 111                 }
 112         }
 113
 114 }
 115
 116 void W_Porto_Attack (void)
 117 {
 118         local entity gren;
 119
 120         if not(self.items & IT_UNLIMITED_AMMO)
 121                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 122         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 123
 124         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 125
 126         gren = spawn ();
 127         gren.owner = self;
 128         gren.classname = "porto";
 129         gren.bot_dodge = TRUE;
 130         gren.bot_dodgerating = 200;
 131         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 132         gren.solid = SOLID_BBOX;
 133         gren.effects = EF_LOWPRECISION | EF_RED;
 134         gren.scale = 4;
 135         gren.modelflags = MF_GRENADE;
 136         setmodel(gren, "models/grenademodel.md3"); // precision set above
 137         setsize(gren, '0 0 0', '0 0 0');
 138         setorigin(gren, w_shotorg);
 139
 140         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 141         gren.think = W_Porto_Think;
 142         gren.touch = W_Porto_Touch;
 143         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 144         if(self.items & IT_STRENGTH)
 145                 gren.velocity = gren.velocity * cvar("g_balance_powerup_strength_force");
 146         W_SetupProjectileVelocity(gren);
 147
 148         gren.angles = vectoangles (gren.velocity);
 149         gren.flags = FL_PROJECTILE;
 150
 151         gren.portal_id = time;
 152         self.porto_current = gren;
 153         gren.playerid = self.playerid;
 154         fixedmakevectors(vectoangles(gren.velocity));
 155         gren.right_vector = v_right;
 156
 157         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 158 }
 159
 160 void spawnfunc_weapon_porto (void)
 161 {
 162         weapon_defaultspawnfunc(WEP_PORTO);
 163 }
 164
 165 float w_porto(float req)
 166 {
 167         vector v_angle_save;
 168
 169         if (req == WR_AIM)
 170         {
 171                 self.BUTTON_ATCK = FALSE;
 172                 self.BUTTON_ATCK2 = FALSE;
 173                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 174                         self.BUTTON_ATCK = TRUE;
 175         }
 176         else if (req == WR_THINK)
 177         {
 178                 if(self.porto_v_angle_held)
 179                 {
 180                         if(!self.BUTTON_ATCK2)
 181                         {
 182                                 msg_entity = self;
 183                                 WRITESPECTATABLE_MSG_ONE({
 184                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 185                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 186                                         WriteByte(MSG_ONE, WEP_PORTO);
 187                                         WriteByte(MSG_ONE, 0);
 188                                 });
 189                                 self.porto_v_angle_held = 0;
 190                         }
 191                 }
 192                 else
 193                 {
 194                         if(self.BUTTON_ATCK2)
 195                         {
 196                                 self.porto_v_angle = self.v_angle;
 197                                 msg_entity = self;
 198                                 WRITESPECTATABLE_MSG_ONE({
 199                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 200                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 201                                         WriteByte(MSG_ONE, WEP_PORTO);
 202                                         WriteByte(MSG_ONE, 1);
 203                                         WriteCoord(MSG_ONE, self.v_angle_x);
 204                                         WriteCoord(MSG_ONE, self.v_angle_y);
 205                                 });
 206                                 self.porto_v_angle_held = 1;
 207                         }
 208                 }
 209                 v_angle_save = self.v_angle;
 210                 if(self.porto_v_angle_held)
 211                         makevectors(self.porto_v_angle); // override the previously set angles
 212
 213                 if (self.BUTTON_ATCK)
 214                 if (!self.porto_current)
 215                 if (!self.porto_forbidden)
 216                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 217                 {
 218                         W_Porto_Attack();
 219                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 220                 }
 221         }
 222         else if (req == WR_PRECACHE)
 223         {
 224                 precache_model ("models/grenademodel.md3");
 225                 precache_model ("models/weapons/g_porto.md3");
 226                 precache_model ("models/weapons/v_porto.md3");
 227                 precache_model ("models/weapons/w_porto.zym");
 228                 precache_sound ("weapons/grenade_fire.wav");
 229                 precache_model ("models/portal.md3");
 230         }
 231         else if (req == WR_SETUP)
 232                 weapon_setup(WEP_PORTO);
 233         else if (req == WR_SUICIDEMESSAGE)
 234                 w_deathtypestring = "did the impossible";
 235         else if (req == WR_KILLMESSAGE)
 236                 w_deathtypestring = "felt # doing the impossible";
 237         return TRUE;
 238 };