data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         self.owner.porto_current = world;
  10         remove(self);
  11 }
  12
  13 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  14 void W_Porto_Fail (float failhard)
  15 {
  16         // no portals here!
  17         Portal_ClearWithID(self.owner, self.portal_id);
  18         self.owner.porto_current = world;
  19
  20         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  21         {
  22                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  23                 setsize (self, '-16 -16 0', '16 16 32');
  24                 setorigin(self, self.origin + trace_plane_normal);
  25                 if(move_out_of_solid(self))
  26                 {
  27                         self.flags = FL_ITEM;
  28                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  29                         tracetoss(self, self);
  30                         if(vlen(trace_endpos - self.owner.origin) > 128)
  31                                 self.velocity = '0 0 0';
  32                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  33                 }
  34                 else
  35                 {
  36                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  37                 }
  38         }
  39         remove(self);
  40 }
  41
  42 void W_Porto_Think (void)
  43 {
  44         trace_plane_normal = '0 0 0';
  45         if(self.owner.playerid != self.playerid)
  46                 remove(self);
  47         else
  48                 W_Porto_Fail(0);
  49 }
  50
  51 void W_Porto_Touch (void)
  52 {
  53         vector norm;
  54
  55         if(other.classname == "portal")
  56                 return; // handled by the portal
  57
  58         norm = trace_plane_normal;
  59         if(self.owner.playerid != self.playerid)
  60         {
  61                 remove(self);
  62         }
  63         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  64         {
  65                 // just reflect
  66                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  67                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  68         }
  69         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 W_Porto_Fail(0);
  72         }
  73         else if(self.effects & EF_RED)
  74         {
  75                 self.effects += EF_BLUE - EF_RED;
  76                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  77                 {
  78                         trace_plane_normal = norm;
  79                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  80                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  81                 }
  82                 else
  83                 {
  84                         trace_plane_normal = norm;
  85                         W_Porto_Fail(0);
  86                 }
  87         }
  88         else
  89         {
  90                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  91                 {
  92                         W_Porto_Success();
  93                 }
  94                 else
  95                 {
  96                         trace_plane_normal = norm;
  97                         W_Porto_Fail(0);
  98                 }
  99         }
 100
 101 }
 102
 103 void W_Porto_Attack (void)
 104 {
 105         local entity gren;
 106
 107         if not(self.items & IT_UNLIMITED_AMMO)
 108                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 109         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 110
 111         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 112
 113         gren = spawn ();
 114         gren.owner = self;
 115         gren.classname = "porto";
 116         gren.bot_dodge = TRUE;
 117         gren.bot_dodgerating = 200;
 118         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 119         gren.solid = SOLID_BBOX;
 120         gren.effects = EF_LOWPRECISION | EF_RED;
 121         gren.scale = 4;
 122         gren.modelflags = MF_GRENADE;
 123         setmodel(gren, "models/grenademodel.md3"); // precision set above
 124         setsize(gren, '0 0 0', '0 0 0');
 125         setorigin(gren, w_shotorg);
 126
 127         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 128         gren.think = W_Porto_Think;
 129         gren.touch = W_Porto_Touch;
 130         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 131         W_SetupProjectileVelocity(gren);
 132
 133         gren.angles = vectoangles (gren.velocity);
 134         gren.flags = FL_PROJECTILE;
 135
 136         gren.portal_id = time;
 137         self.porto_current = gren;
 138         gren.playerid = self.playerid;
 139         fixedmakevectors(vectoangles(gren.velocity));
 140         gren.right_vector = v_right;
 141
 142         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 143 }
 144
 145 void spawnfunc_weapon_porto (void)
 146 {
 147         weapon_defaultspawnfunc(WEP_PORTO);
 148 }
 149
 150 float w_porto(float req)
 151 {
 152         vector v_angle_save;
 153
 154         if (req == WR_AIM)
 155         {
 156                 self.BUTTON_ATCK = FALSE;
 157                 self.BUTTON_ATCK2 = FALSE;
 158                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 159                         self.BUTTON_ATCK = TRUE;
 160         }
 161         else if (req == WR_THINK)
 162         {
 163                 if(self.porto_v_angle_held)
 164                 {
 165                         if(!self.BUTTON_ATCK2)
 166                         {
 167                                 msg_entity = self;
 168                                 WRITESPECTATABLE_MSG_ONE({
 169                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 170                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 171                                         WriteByte(MSG_ONE, WEP_PORTO);
 172                                         WriteByte(MSG_ONE, 0);
 173                                 });
 174                                 self.porto_v_angle_held = 0;
 175                         }
 176                 }
 177                 else
 178                 {
 179                         if(self.BUTTON_ATCK2)
 180                         {
 181                                 self.porto_v_angle = self.v_angle;
 182                                 msg_entity = self;
 183                                 WRITESPECTATABLE_MSG_ONE({
 184                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 185                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 186                                         WriteByte(MSG_ONE, WEP_PORTO);
 187                                         WriteByte(MSG_ONE, 1);
 188                                         WriteCoord(MSG_ONE, self.v_angle_x);
 189                                         WriteCoord(MSG_ONE, self.v_angle_y);
 190                                 });
 191                                 self.porto_v_angle_held = 1;
 192                         }
 193                 }
 194                 v_angle_save = self.v_angle;
 195                 if(self.porto_v_angle_held)
 196                         makevectors(self.porto_v_angle); // override the previously set angles
 197
 198                 if (self.BUTTON_ATCK)
 199                 if (!self.porto_current)
 200                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 201                 {
 202                         W_Porto_Attack();
 203                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 204                 }
 205         }
 206         else if (req == WR_PRECACHE)
 207         {
 208                 precache_model ("models/grenademodel.md3");
 209                 precache_model ("models/weapons/g_porto.md3");
 210                 precache_model ("models/weapons/v_porto.md3");
 211                 precache_model ("models/weapons/w_porto.zym");
 212                 precache_sound ("weapons/grenade_fire.wav");
 213                 precache_model ("models/portal.md3");
 214         }
 215         else if (req == WR_SETUP)
 216                 weapon_setup(WEP_PORTO);
 217         else if (req == WR_SUICIDEMESSAGE)
 218                 w_deathtypestring = "did the impossible";
 219         else if (req == WR_KILLMESSAGE)
 220                 w_deathtypestring = "felt # doing the impossible";
 221         return TRUE;
 222 };