data/qcsrc/server/w_porto.qc

   1 .entity porto_current;
   2 .vector porto_v_angle; // holds "held" view angles
   3 .float porto_v_angle_held;
   4 .vector right_vector;
   5
   6 void W_Porto_Success (void)
   7 {
   8         if(self.owner == world)
   9         {
  10                 objerror("Cannot succeed successfully: no owner\n");
  11                 return;
  12         }
  13
  14         self.owner.porto_current = world;
  15         remove(self);
  16 }
  17
  18 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  19 void W_Porto_Fail (float failhard)
  20 {
  21         if(self.owner == world)
  22         {
  23                 objerror("Cannot fail successfully: no owner\n");
  24                 return;
  25         }
  26
  27         // no portals here!
  28         Portal_ClearWithID(self.owner, self.portal_id);
  29         self.owner.porto_current = world;
  30
  31         if(!failhard && self.owner.playerid == self.playerid && self.owner.deadflag == DEAD_NO && !(self.owner.weapons & WEPBIT_PORTO))
  32         {
  33                 setsize (self, '-16 -16 0', '16 16 32');
  34                 setorigin(self, self.origin + trace_plane_normal);
  35                 if(move_out_of_solid(self))
  36                 {
  37                         self.flags = FL_ITEM;
  38                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  39                         tracetoss(self, self);
  40                         if(vlen(trace_endpos - self.owner.origin) < 128)
  41                         {
  42                                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  43                                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  44                         }
  45                 }
  46         }
  47         remove(self);
  48 }
  49
  50 void W_Porto_Remove (entity p)
  51 {
  52         if(p.porto_current)
  53         {
  54                 entity oldself;
  55                 oldself = self;
  56                 self = p.porto_current;
  57                 W_Porto_Fail(1);
  58                 self = oldself;
  59         }
  60 }
  61
  62 void W_Porto_Think (void)
  63 {
  64         trace_plane_normal = '0 0 0';
  65         if(self.owner.playerid != self.playerid)
  66                 remove(self);
  67         else
  68                 W_Porto_Fail(0);
  69 }
  70
  71 void W_Porto_Touch (void)
  72 {
  73         vector norm;
  74
  75         // do not use PROJECTILE_TOUCH here
  76
  77         if(other.classname == "portal")
  78                 return; // handled by the portal
  79
  80         norm = trace_plane_normal;
  81         if(trace_ent.iscreature)
  82         {
  83                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
  84                 if(trace_fraction >= 1)
  85                         return;
  86                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  87                         return;
  88                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  89                         return;
  90         }
  91
  92         if(self.owner.playerid != self.playerid)
  93         {
  94                 sound(self, CHAN_PROJECTILE, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
  95                 remove(self);
  96         }
  97         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  98         {
  99                 sound(self, CHAN_PROJECTILE, "porto/bounce.wav", VOL_BASE, ATTN_NORM);
 100                 // just reflect
 101                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 102                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 103         }
 104         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 105         {
 106                 sound(self, CHAN_PROJECTILE, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 107                 W_Porto_Fail(0);
 108         }
 109         else if(self.effects & EF_RED)
 110         {
 111                 self.effects += EF_BLUE - EF_RED;
 112                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 113                 {
 114                         sound(self, CHAN_PROJECTILE, "porto/create.wav", VOL_BASE, ATTN_NORM);
 115                         trace_plane_normal = norm;
 116                         centerprint(self.owner, "^1In^7-portal created.\n");
 117                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 118                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 119                 }
 120                 else
 121                 {
 122                         sound(self, CHAN_PROJECTILE, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 123                         trace_plane_normal = norm;
 124                         W_Porto_Fail(0);
 125                 }
 126         }
 127         else
 128         {
 129                 if(self.owner.portal_in.portal_id == self.portal_id)
 130                 {
 131                         if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 132                         {
 133                                 sound(self, CHAN_PROJECTILE, "porto/create.wav", VOL_BASE, ATTN_NORM);
 134                                 trace_plane_normal = norm;
 135                                 centerprint(self.owner, "^4Out^7-portal created.\n");
 136                                 W_Porto_Success();
 137                         }
 138                         else
 139                         {
 140                                 sound(self, CHAN_PROJECTILE, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 141                                 W_Porto_Fail(0);
 142                         }
 143                 }
 144                 else
 145                 {
 146                         sound(self, CHAN_PROJECTILE, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 147                         W_Porto_Fail(0);
 148                 }
 149         }
 150
 151 }
 152
 153 void W_Porto_Attack (void)
 154 {
 155         local entity gren;
 156
 157         if not(self.items & IT_UNLIMITED_SUPERWEAPONS)
 158                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 159         W_SetupShot (self, '0 0 0', FALSE, 4, "porto/fire.wav");
 160
 161         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 162
 163         gren = spawn ();
 164         gren.owner = self;
 165         gren.playerid = self.playerid;
 166         gren.classname = "porto";
 167         gren.bot_dodge = TRUE;
 168         gren.bot_dodgerating = 200;
 169         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 170         gren.solid = SOLID_BBOX;
 171         gren.effects = EF_LOWPRECISION | EF_RED | EF_ADDITIVE;
 172         gren.scale = 4;
 173         gren.modelflags = MF_TRACER;
 174         setmodel(gren, "models/grenademodel.md3"); // precision set above
 175         setsize(gren, '0 0 0', '0 0 0');
 176         setorigin(gren, w_shotorg);
 177
 178         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 179         gren.think = W_Porto_Think;
 180         gren.touch = W_Porto_Touch;
 181         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 182         if(self.items & IT_STRENGTH)
 183                 gren.velocity = gren.velocity * cvar("g_balance_powerup_strength_force");
 184         W_SetupProjectileVelocity(gren);
 185
 186         gren.angles = vectoangles (gren.velocity);
 187         gren.flags = FL_PROJECTILE;
 188
 189         gren.portal_id = time;
 190         self.porto_current = gren;
 191         gren.playerid = self.playerid;
 192         fixedmakevectors(vectoangles(gren.velocity));
 193         gren.right_vector = v_right;
 194
 195         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 196 }
 197
 198 void spawnfunc_weapon_porto (void)
 199 {
 200         weapon_defaultspawnfunc(WEP_PORTO);
 201 }
 202
 203 float w_porto(float req)
 204 {
 205         vector v_angle_save;
 206
 207         if (req == WR_AIM)
 208         {
 209                 self.BUTTON_ATCK = FALSE;
 210                 self.BUTTON_ATCK2 = FALSE;
 211                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 212                         self.BUTTON_ATCK = TRUE;
 213         }
 214         else if (req == WR_THINK)
 215         {
 216                 if(self.porto_v_angle_held)
 217                 {
 218                         if(!self.BUTTON_ATCK2)
 219                         {
 220                                 msg_entity = self;
 221                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy1, {
 222                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 223                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 224                                         WriteByte(MSG_ONE, WEP_PORTO);
 225                                         WriteByte(MSG_ONE, 0);
 226                                 });
 227                                 self.porto_v_angle_held = 0;
 228                         }
 229                 }
 230                 else
 231                 {
 232                         if(self.BUTTON_ATCK2)
 233                         {
 234                                 self.porto_v_angle = self.v_angle;
 235                                 msg_entity = self;
 236                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy2, {
 237                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 238                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 239                                         WriteByte(MSG_ONE, WEP_PORTO);
 240                                         WriteByte(MSG_ONE, 1);
 241                                         WriteCoord(MSG_ONE, self.v_angle_x);
 242                                         WriteCoord(MSG_ONE, self.v_angle_y);
 243                                 });
 244                                 self.porto_v_angle_held = 1;
 245                         }
 246                 }
 247                 v_angle_save = self.v_angle;
 248                 if(self.porto_v_angle_held)
 249                         makevectors(self.porto_v_angle); // override the previously set angles
 250
 251                 if (self.BUTTON_ATCK)
 252                 if (!self.porto_current)
 253                 if (!self.porto_forbidden)
 254                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 255                 {
 256                         W_Porto_Attack();
 257                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 258                 }
 259         }
 260         else if (req == WR_PRECACHE)
 261         {
 262                 precache_model ("models/grenademodel.md3");
 263                 precache_model ("models/weapons/g_porto.md3");
 264                 precache_model ("models/weapons/v_porto.md3");
 265                 precache_model ("models/weapons/w_porto.zym");
 266                 precache_model ("models/portal.md3");
 267                 precache_sound ("porto/bounce.wav");
 268                 precache_sound ("porto/create.wav");
 269                 precache_sound ("porto/expire.wav");
 270                 precache_sound ("porto/explode.wav");
 271                 precache_sound ("porto/fire.wav");
 272                 precache_sound ("porto/unsupported.wav");
 273         }
 274         else if (req == WR_SETUP)
 275                 weapon_setup(WEP_PORTO);
 276         else if (req == WR_SUICIDEMESSAGE)
 277                 w_deathtypestring = "did the impossible";
 278         else if (req == WR_KILLMESSAGE)
 279                 w_deathtypestring = "felt # doing the impossible to him";
 280         return TRUE;
 281 };