data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         self.owner.porto_current = world;
  10         remove(self);
  11 }
  12
  13 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  14 void W_Porto_Fail (float failhard)
  15 {
  16         // no portals here!
  17         Portal_ClearWithID(self.owner, self.portal_id);
  18         self.owner.porto_current = world;
  19
  20         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  21         {
  22                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  23                 setsize (self, '-16 -16 0', '16 16 32');
  24                 setorigin(self, self.origin + trace_plane_normal);
  25                 if(move_out_of_solid(self))
  26                 {
  27                         self.flags = FL_ITEM;
  28                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  29                         tracetoss(self, self);
  30                         if(vlen(trace_endpos - self.owner.origin) > 128)
  31                                 self.velocity = '0 0 0';
  32                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  33                 }
  34                 else
  35                 {
  36                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  37                 }
  38         }
  39         remove(self);
  40 }
  41
  42 void W_Porto_Think (void)
  43 {
  44         trace_plane_normal = '0 0 0';
  45         if(self.owner.playerid != self.playerid)
  46                 remove(self);
  47         else
  48                 W_Porto_Fail(0);
  49 }
  50
  51 void W_Porto_Touch (void)
  52 {
  53         vector norm;
  54
  55         if(other.classname == "portal")
  56                 return; // handled by the portal
  57
  58         norm = trace_plane_normal;
  59         if(self.owner.playerid != self.playerid)
  60         {
  61                 remove(self);
  62         }
  63         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  64         {
  65                 // just reflect
  66                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  67                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  68         }
  69         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 W_Porto_Fail(0);
  72         }
  73         else if(self.effects & EF_RED)
  74         {
  75                 self.effects += EF_BLUE - EF_RED;
  76                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  77                 {
  78                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
  79                         centerprint(self.owner, "^1In^7-portal created.\n");
  80                         trace_plane_normal = norm;
  81                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  82                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  83                 }
  84                 else
  85                 {
  86                         trace_plane_normal = norm;
  87                         W_Porto_Fail(0);
  88                 }
  89         }
  90         else
  91         {
  92                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  93                 {
  94                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
  95                         centerprint(self.owner, "^4Out^7-portal created.\n");
  96                         W_Porto_Success();
  97                 }
  98                 else
  99                 {
 100                         trace_plane_normal = norm;
 101                         W_Porto_Fail(0);
 102                 }
 103         }
 104
 105 }
 106
 107 void W_Porto_Attack (void)
 108 {
 109         local entity gren;
 110
 111         if not(self.items & IT_UNLIMITED_AMMO)
 112                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 113         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 114
 115         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 116
 117         gren = spawn ();
 118         gren.owner = self;
 119         gren.classname = "porto";
 120         gren.bot_dodge = TRUE;
 121         gren.bot_dodgerating = 200;
 122         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 123         gren.solid = SOLID_BBOX;
 124         gren.effects = EF_LOWPRECISION | EF_RED;
 125         gren.scale = 4;
 126         gren.modelflags = MF_GRENADE;
 127         setmodel(gren, "models/grenademodel.md3"); // precision set above
 128         setsize(gren, '0 0 0', '0 0 0');
 129         setorigin(gren, w_shotorg);
 130
 131         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 132         gren.think = W_Porto_Think;
 133         gren.touch = W_Porto_Touch;
 134         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 135         W_SetupProjectileVelocity(gren);
 136
 137         gren.angles = vectoangles (gren.velocity);
 138         gren.flags = FL_PROJECTILE;
 139
 140         gren.portal_id = time;
 141         self.porto_current = gren;
 142         gren.playerid = self.playerid;
 143         fixedmakevectors(vectoangles(gren.velocity));
 144         gren.right_vector = v_right;
 145
 146         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 147 }
 148
 149 void spawnfunc_weapon_porto (void)
 150 {
 151         weapon_defaultspawnfunc(WEP_PORTO);
 152 }
 153
 154 float w_porto(float req)
 155 {
 156         vector v_angle_save;
 157
 158         if (req == WR_AIM)
 159         {
 160                 self.BUTTON_ATCK = FALSE;
 161                 self.BUTTON_ATCK2 = FALSE;
 162                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 163                         self.BUTTON_ATCK = TRUE;
 164         }
 165         else if (req == WR_THINK)
 166         {
 167                 if(self.porto_v_angle_held)
 168                 {
 169                         if(!self.BUTTON_ATCK2)
 170                         {
 171                                 msg_entity = self;
 172                                 WRITESPECTATABLE_MSG_ONE({
 173                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 174                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 175                                         WriteByte(MSG_ONE, WEP_PORTO);
 176                                         WriteByte(MSG_ONE, 0);
 177                                 });
 178                                 self.porto_v_angle_held = 0;
 179                         }
 180                 }
 181                 else
 182                 {
 183                         if(self.BUTTON_ATCK2)
 184                         {
 185                                 self.porto_v_angle = self.v_angle;
 186                                 msg_entity = self;
 187                                 WRITESPECTATABLE_MSG_ONE({
 188                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 189                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 190                                         WriteByte(MSG_ONE, WEP_PORTO);
 191                                         WriteByte(MSG_ONE, 1);
 192                                         WriteCoord(MSG_ONE, self.v_angle_x);
 193                                         WriteCoord(MSG_ONE, self.v_angle_y);
 194                                 });
 195                                 self.porto_v_angle_held = 1;
 196                         }
 197                 }
 198                 v_angle_save = self.v_angle;
 199                 if(self.porto_v_angle_held)
 200                         makevectors(self.porto_v_angle); // override the previously set angles
 201
 202                 if (self.BUTTON_ATCK)
 203                 if (!self.porto_current)
 204                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 205                 {
 206                         W_Porto_Attack();
 207                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 208                 }
 209         }
 210         else if (req == WR_PRECACHE)
 211         {
 212                 precache_model ("models/grenademodel.md3");
 213                 precache_model ("models/weapons/g_porto.md3");
 214                 precache_model ("models/weapons/v_porto.md3");
 215                 precache_model ("models/weapons/w_porto.zym");
 216                 precache_sound ("weapons/grenade_fire.wav");
 217                 precache_model ("models/portal.md3");
 218         }
 219         else if (req == WR_SETUP)
 220                 weapon_setup(WEP_PORTO);
 221         else if (req == WR_SUICIDEMESSAGE)
 222                 w_deathtypestring = "did the impossible";
 223         else if (req == WR_KILLMESSAGE)
 224                 w_deathtypestring = "felt # doing the impossible";
 225         return TRUE;
 226 };