data/qcsrc/server/w_laser.qc

   1 void(float imp) W_SwitchWeapon;
   2
   3 void W_Laser_Touch (void)
   4 {
   5         vector  dir;
   6         vector org2;
   7
   8         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
   9         {
  10                 remove(self);
  11                 return;
  12         }
  13
  14         if (other == self.owner)
  15                 return;
  16
  17         dir = normalize (self.owner.origin - self.origin);
  18         org2 = findbetterlocation (self.origin, 8);
  19
  20         te_knightspike(org2);
  21
  22
  23         self.event_damage = SUB_Null;
  24         if (self.dmg)
  25                 RadiusDamage (self, self.owner, cvar("g_balance_laser_secondary_damage"), cvar("g_balance_laser_secondary_edgedamage"), cvar("g_balance_laser_secondary_radius"), world, cvar("g_balance_laser_secondary_force"), IT_LASER);
  26         else
  27                 RadiusDamage (self, self.owner, cvar("g_balance_laser_primary_damage"), cvar("g_balance_laser_primary_edgedamage"), cvar("g_balance_laser_primary_radius"), world, cvar("g_balance_laser_primary_force"), IT_LASER);
  28         sound (self, CHAN_BODY, "weapons/laserimpact.wav", 1, ATTN_NORM);
  29
  30         remove (self);
  31 }
  32
  33 void W_Laser_Attack (float issecondary)
  34 {
  35         local entity missile;
  36
  37         W_SetupShot (self, '11 8 -8', FALSE, 3, "weapons/lasergun_fire.wav");
  38         //te_customflash(w_shotorg, 160, 0.2, '1 0 0');
  39         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg + v_forward * 8, v_forward * 1000, 1);
  40
  41         missile = spawn ();
  42         missile.owner = self;
  43         missile.classname = "laserbolt";
  44         missile.dmg = issecondary;
  45         missile.bot_dodge = TRUE;
  46         if (issecondary)
  47                 missile.bot_dodgerating = cvar("g_balance_laser_secondary_damage");
  48         else
  49                 missile.bot_dodgerating = cvar("g_balance_laser_primary_damage");
  50
  51         missile.movetype = MOVETYPE_FLY;
  52         missile.solid = SOLID_BBOX;
  53
  54         setmodel (missile, "models/laser.mdl"); // precision set below
  55         setsize (missile, '0 0 0', '0 0 0');
  56         setorigin (missile, w_shotorg);
  57
  58         if (issecondary)
  59                 missile.velocity = w_shotdir * cvar("g_balance_laser_secondary_speed");
  60         else
  61                 missile.velocity = w_shotdir * cvar("g_balance_laser_primary_speed");
  62         W_SetupProjectileVelocity(missile);
  63         missile.angles = vectoangles (missile.velocity);
  64         //missile.glow_color = 250; // 244, 250
  65         //missile.glow_size = 120;
  66         missile.touch = W_Laser_Touch;
  67         missile.think = SUB_Remove;
  68         if (issecondary)
  69                 missile.nextthink = time + cvar("g_balance_laser_secondary_lifetime");
  70         else
  71                 missile.nextthink = time + cvar("g_balance_laser_primary_lifetime");
  72
  73         missile.effects = EF_LOWPRECISION;
  74         missile.flags = FL_PROJECTILE;
  75 }
  76
  77 float(float req) w_laser =
  78 {
  79         local float r1;
  80         local float r2;
  81         if (req == WR_AIM)
  82         {
  83                 if(cvar("g_balance_laser_secondary"))
  84                 {
  85                         r1 = cvar("g_balance_laser_primary_damage");
  86                         r2 = cvar("g_balance_laser_secondary_damage");
  87                         if (random() * (r2 + r1) > r1)
  88                                 self.button3 = bot_aim(cvar("g_balance_laser_secondary_speed"), 0, cvar("g_balance_laser_secondary_lifetime"), FALSE);
  89                         else
  90                                 self.button0 = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
  91                 }
  92                 else
  93                         self.button0 = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
  94         }
  95         else if (req == WR_THINK)
  96         {
  97                 if (self.button0)
  98                 if (weapon_prepareattack(0, cvar("g_balance_laser_primary_refire")))
  99                 {
 100                         W_Laser_Attack(FALSE);
 101                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_primary_animtime"), w_ready);
 102                 }
 103                 if (self.button3)
 104                 {
 105                         if(cvar("g_balance_laser_secondary"))
 106                         {
 107                                 if (weapon_prepareattack(0, cvar("g_balance_laser_secondary_refire")))
 108                                 {
 109                                         W_Laser_Attack(TRUE);
 110                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_secondary_animtime"), w_ready);
 111                                 }
 112                         }
 113                         else
 114                         {
 115                                 if (self.button3)
 116                                 if (client_hasweapon(self, self.cnt, TRUE, FALSE))
 117                                         W_SwitchWeapon (self.cnt);
 118                         }
 119                 }
 120         }
 121         else if (req == WR_PRECACHE)
 122         {
 123                 precache_model ("models/laser.mdl");
 124                 precache_model ("models/weapons/v_laser.md3");
 125                 precache_model ("models/weapons/w_laser.zym");
 126                 precache_sound ("weapons/lasergun_fire.wav");
 127                 precache_sound ("weapons/laserimpact.wav");
 128         }
 129         else if (req == WR_SETUP)
 130                 weapon_setup(WEP_LASER, "laser", 0);
 131         else if (req == WR_CHECKAMMO1)
 132                 return TRUE;
 133         else if (req == WR_CHECKAMMO2)
 134                 return TRUE;
 135         else if (req == WR_REGISTER)
 136                 weapon_register(WEP_LASER, 0);
 137         return TRUE;
 138 };