data/qcsrc/server/w_hook.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_radius;
   4 .float dmg_force;
   5 .float dmg_power;
   6 .float dmg_duration;
   7 .float dmg_last;
   8 .float hook_refire;
   9 .float hook_time_hooked;
  10 .float hook_time_ammodecrease;
  11
  12 void W_Hook_ExplodeThink (void)
  13 {
  14         float dt, dmg_remaining_next, f;
  15
  16         dt = time - self.teleport_time;
  17         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  18
  19         f = self.dmg_last - dmg_remaining_next;
  20         self.dmg_last = dmg_remaining_next;
  21
  22         RadiusDamage (self, self.owner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.owner, self.dmg_force * f, self.projectiledeathtype, world);
  23         self.projectiledeathtype |= HITTYPE_BOUNCE;
  24         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, self.dmg_force * f, self.projectiledeathtype, world);
  25
  26         if(dt < self.dmg_duration)
  27                 self.nextthink = time + 0.05; // soon
  28         else
  29                 remove(self);
  30 }
  31
  32 void W_Hook_Explode2 (void)
  33 {
  34         self.event_damage = SUB_Null;
  35         self.touch = SUB_Null;
  36
  37         self.think = W_Hook_ExplodeThink;
  38         self.nextthink = time;
  39         self.dmg = cvar("g_balance_hook_secondary_damage");
  40         self.dmg_edge = cvar("g_balance_hook_secondary_edgedamage");
  41         self.dmg_radius = cvar("g_balance_hook_secondary_radius");
  42         self.dmg_force = cvar("g_balance_hook_secondary_force");
  43         self.dmg_power = cvar("g_balance_hook_secondary_power");
  44         self.dmg_duration = cvar("g_balance_hook_secondary_duration");
  45         self.teleport_time = time;
  46         self.dmg_last = 1;
  47         self.movetype = MOVETYPE_NONE;
  48 }
  49
  50 void W_Hook_Touch2 (void)
  51 {
  52         PROJECTILE_TOUCH;
  53         self.use();
  54 }
  55
  56 void W_Hook_Attack2()
  57 {
  58         local entity gren;
  59
  60         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  61                 self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_secondary_ammo");
  62         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/hookbomb_fire.wav");
  63
  64         gren = spawn ();
  65         gren.owner = self;
  66         gren.classname = "hookbomb";
  67         gren.bot_dodge = TRUE;
  68         gren.bot_dodgerating = cvar("g_balance_hook_secondary_damage");
  69         gren.movetype = MOVETYPE_TOSS;
  70         gren.solid = SOLID_BBOX;
  71         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
  72         setmodel(gren, "null"); // precision set above // FIXME replace
  73         setsize(gren, '0 0 0', '0 0 0');
  74         setorigin(gren, w_shotorg);
  75
  76         gren.nextthink = time + cvar("g_balance_hook_secondary_lifetime");
  77         gren.think = adaptor_think2use;
  78         gren.use = W_Hook_Explode2;
  79         gren.touch = W_Hook_Touch2;
  80
  81         gren.velocity = '0 0 1' * cvar("g_balance_hook_secondary_speed");
  82         if(cvar("g_projectiles_newton_style"))
  83                 gren.velocity = gren.velocity + self.velocity;
  84
  85         gren.gravity = cvar("g_balance_hook_secondary_gravity");
  86         //W_SetupProjectileVelocity(gren); // just falling down!
  87
  88         gren.angles = '0 0 0';
  89         gren.flags = FL_PROJECTILE;
  90
  91         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB);
  92 }
  93
  94 void spawnfunc_weapon_hook (void)
  95 {
  96         if(g_grappling_hook) // offhand hook
  97         {
  98                 startitem_failed = TRUE;
  99                 remove(self);
 100                 return;
 101         }
 102         weapon_defaultspawnfunc(WEP_HOOK);
 103 }
 104
 105 float w_hook(float req)
 106 {
 107         float hooked_time_max, hooked_ammodecrease_delay;
 108
 109         if (req == WR_AIM)
 110         {
 111                 // ... sorry ...
 112         }
 113         else if (req == WR_THINK)
 114         {
 115                 if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 116                 {
 117                         if(!self.hook)
 118                         if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 119                         if (time > self.hook_refire)
 120                         if (weapon_prepareattack(0, -1))
 121                         {
 122                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 123                                         self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_primary_ammo");
 124                                 self.hook_state |= HOOK_FIRING;
 125                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_primary_animtime"), w_ready);
 126                         }
 127                 }
 128
 129                 if (self.BUTTON_ATCK2)
 130                 {
 131                         if (weapon_prepareattack(1, cvar("g_balance_hook_secondary_refire")))
 132                         {
 133                                 W_Hook_Attack2();
 134                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_secondary_animtime"), w_ready);
 135                         }
 136                 }
 137
 138                 if(self.hook)
 139                 {
 140                         // if hooked, no bombs, and increase the timer
 141                         self.hook_refire = max(self.hook_refire, time + cvar("g_balance_hook_primary_refire"));
 142                 }
 143
 144                 if(self.hook && self.hook.state == 1)
 145                 {
 146                         hooked_time_max = cvar("g_balance_hook_primary_hooked_time_max");
 147                         if (hooked_time_max > 0)
 148                         {
 149                                 if ( time > self.hook_time_hooked + hooked_time_max )
 150                                         self.hook_state |= HOOK_REMOVING;
 151                         }
 152
 153                         hooked_ammodecrease_delay = cvar("g_balance_hook_primary_hooked_ammodecrease_delay");
 154                         if (hooked_ammodecrease_delay > 0)
 155                         {
 156                                 if ( time > self.hook_time_ammodecrease )
 157                                 {
 158                                         if ( self.ammo_cells >= 1 )
 159                                         {
 160                                                 self.ammo_cells -= 1;
 161                                                 self.hook_time_ammodecrease = time + hooked_ammodecrease_delay;
 162                                         }
 163                                         else
 164                                         {
 165                                                 self.hook_state |= HOOK_REMOVING;
 166                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 167                                         }
 168                                 }
 169                         }
 170                 }
 171                 else
 172                 {
 173                         self.hook_time_hooked = time;
 174                         self.hook_time_ammodecrease = time + cvar("g_balance_hook_primary_hooked_time_free");
 175                 }
 176
 177                 if (self.BUTTON_CROUCH)
 178                 {
 179                         self.hook_state &~= HOOK_PULLING;
 180                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 181                                 self.hook_state &~= HOOK_RELEASING;
 182                         else
 183                                 self.hook_state |= HOOK_RELEASING;
 184                 }
 185                 else
 186                 {
 187                         self.hook_state |= HOOK_PULLING;
 188                         self.hook_state &~= HOOK_RELEASING;
 189
 190                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 191                         {
 192                                 // already fired
 193                                 if(self.hook)
 194                                         self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 195                         }
 196                         else
 197                         {
 198                                 self.hook_state |= HOOK_REMOVING;
 199                                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 200                         }
 201                 }
 202         }
 203         else if (req == WR_PRECACHE)
 204         {
 205                 precache_model ("models/weapons/g_hookgun.md3");
 206                 precache_model ("models/weapons/v_hookgun.md3");
 207                 precache_model ("models/weapons/w_hookgun.zym");
 208                 precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 209                 precache_sound ("weapons/hook_fire.wav");
 210                 precache_sound ("weapons/hookbomb_fire.wav");
 211         }
 212         else if (req == WR_SETUP)
 213         {
 214                 weapon_setup(WEP_HOOK);
 215                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 216         }
 217         else if (req == WR_CHECKAMMO1)
 218         {
 219                 return self.ammo_cells >= cvar("g_balance_hook_primary_ammo");
 220         }
 221         else if (req == WR_CHECKAMMO2)
 222         {
 223                 return self.ammo_cells >= cvar("g_balance_hook_secondary_ammo");
 224         }
 225         else if (req == WR_SUICIDEMESSAGE)
 226                 w_deathtypestring = "did the impossible";
 227         else if (req == WR_KILLMESSAGE)
 228                 w_deathtypestring = "has run into #'s gravity bomb";
 229         return TRUE;
 230 };