data/qcsrc/server/w_hagar.qc

   1 void W_Hagar_Explode (void)
   2 {
   3         vector  org2;
   4         float b;
   5         org2 = findbetterlocation (self.origin, 12);
   6         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
   7         b = crandom();
   8         if (b<-0.7)
   9                 sound (self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
  10         else if (b<0.4)
  11                 sound (self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
  12         else if (b<1)
  13                 sound (self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
  14
  15         self.event_damage = SUB_Null;
  16         RadiusDamage (self, self.realowner, cvar("g_balance_hagar_primary_damage"), cvar("g_balance_hagar_primary_edgedamage"), cvar("g_balance_hagar_primary_radius"), world, cvar("g_balance_hagar_primary_force"), WEP_HAGAR);
  17
  18         remove (self);
  19 }
  20
  21 void W_Hagar_Explode2 (void)
  22 {
  23         vector  org2;
  24         float b;
  25         org2 = findbetterlocation (self.origin, 12);
  26         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
  27         b = crandom();
  28         if (b<-0.7)
  29                 sound (self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
  30         else if (b<0.4)
  31                 sound (self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
  32         else if (b<1)
  33                 sound (self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
  34
  35         self.event_damage = SUB_Null;
  36         RadiusDamage (self, self.realowner, cvar("g_balance_hagar_secondary_damage"), cvar("g_balance_hagar_secondary_edgedamage"), cvar("g_balance_hagar_secondary_radius"), world, cvar("g_balance_hagar_secondary_force"), WEP_HAGAR);
  37
  38         remove (self);
  39 }
  40
  41 void W_Hagar_Touch (void)
  42 {
  43         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44         {
  45                 remove(self);
  46                 return;
  47         }
  48         if (other == self.owner)
  49                 return;
  50
  51         self.think ();
  52 }
  53
  54 void W_Hagar_Touch2 (void)
  55 {
  56         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  57         {
  58                 remove(self);
  59                 return;
  60         }
  61
  62         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  63                 self.think();
  64         } else {
  65                 self.cnt++;
  66                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  67                 self.angles = vectoangles (self.velocity);
  68                 self.owner = world;
  69         }
  70 }
  71
  72 void W_Hagar_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  73 {
  74         self.health = self.health - damage;
  75         if (self.health <= 0)
  76                 self.think ();
  77 }
  78
  79 void W_Hagar_Attack (void)
  80 {
  81         local entity missile;
  82
  83         if (cvar("g_use_ammunition"))
  84                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_hagar_primary_ammo");
  85         W_SetupShot (self, '25 5 -8', FALSE, 2, "weapons/hagar_fire.wav");
  86         //W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/hagar_fire.wav"); // TODO: move model a little to the right
  87
  88         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  89
  90         missile = spawn ();
  91         missile.owner = missile.realowner = self;
  92         missile.classname = "missile";
  93         missile.bot_dodge = TRUE;
  94         missile.bot_dodgerating = cvar("g_balance_hagar_primary_damage");
  95         missile.touch = W_Hagar_Touch;
  96         missile.think = W_Hagar_Explode;
  97         missile.nextthink = time + cvar("g_balance_hagar_primary_lifetime");
  98         missile.solid = SOLID_BBOX;
  99         missile.scale = 0.4; // BUG: the model is too big
 100         setorigin (missile, w_shotorg);
 101         setmodel (missile, "models/hagarmissile.mdl"); // precision set below
 102         setsize (missile, '0 0 0', '0 0 0');
 103         //missile.takedamage = DAMAGE_YES;
 104         //missile.damageforcescale = 4;
 105         //missile.health = 10;
 106         //missile.event_damage = W_Hagar_Damage;
 107         missile.effects = EF_LOWPRECISION;
 108         missile.modelflags = MF_GRENADE;
 109
 110         missile.movetype = MOVETYPE_FLY;
 111         missile.velocity = (w_shotdir + randomvec() * cvar("g_balance_hagar_primary_spread")) * cvar("g_balance_hagar_primary_speed");
 112         W_SetupProjectileVelocity(missile);
 113
 114         missile.angles = vectoangles (missile.velocity);
 115         missile.flags = FL_PROJECTILE;
 116 }
 117
 118 void W_Hagar_Attack2 (void)
 119 {
 120         local entity missile;
 121
 122         if (cvar("g_use_ammunition"))
 123                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_hagar_secondary_ammo");
 124         W_SetupShot (self, '25 5 -8', FALSE, 2, "weapons/hagar_fire.wav");
 125         //W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/hagar_fire.wav"); // TODO: move model a little to the right
 126
 127         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 128
 129         missile = spawn ();
 130         missile.owner = missile.realowner = self;
 131         missile.classname = "missile";
 132         missile.bot_dodge = TRUE;
 133         missile.bot_dodgerating = cvar("g_balance_hagar_secondary_damage");
 134         missile.touch = W_Hagar_Touch2;
 135         missile.cnt = 0;
 136         missile.think = W_Hagar_Explode;
 137         missile.nextthink = time + cvar("g_balance_hagar_secondary_lifetime");
 138         missile.solid = SOLID_BBOX;
 139         missile.scale = 0.4; // BUG: the model is too big
 140         setorigin (missile, w_shotorg);
 141         setmodel (missile, "models/hagarmissile.mdl"); // precision set below
 142         setsize (missile, '0 0 0', '0 0 0');
 143         //missile.takedamage = DAMAGE_YES;
 144         //missile.damageforcescale = 4;
 145         //missile.health = 10;
 146         //missile.event_damage = W_Hagar_Damage;
 147         missile.effects = EF_LOWPRECISION;
 148         missile.modelflags = MF_GRENADE;
 149
 150         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 151         missile.velocity = (w_shotdir + randomvec() * cvar("g_balance_hagar_secondary_spread")) * cvar("g_balance_hagar_secondary_speed");
 152         W_SetupProjectileVelocity(missile);
 153         missile.avelocity = '100 10 10';
 154
 155         missile.angles = vectoangles (missile.velocity);
 156         missile.flags = FL_PROJECTILE;
 157 }
 158
 159 void spawnfunc_weapon_hagar (void)
 160 {
 161         weapon_defaultspawnfunc(WEP_HAGAR, 5000);
 162 }
 163
 164 float w_hagar(float req)
 165 {
 166         if (req == WR_AIM)
 167                 if (random()>0.15)
 168                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_hagar_primary_speed"), 0, cvar("g_balance_hagar_primary_lifetime"), FALSE);
 169                 else
 170                 {
 171                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 172                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_hagar_primary_speed"), 0, cvar("g_balance_hagar_primary_lifetime"), FALSE);
 173                 }
 174         else if (req == WR_THINK)
 175         {
 176                 if (self.BUTTON_ATCK)
 177                 if (weapon_prepareattack(0, cvar("g_balance_hagar_primary_refire")))
 178                 {
 179                         W_Hagar_Attack();
 180                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hagar_primary_refire"), w_ready);
 181                 }
 182                 if (self.BUTTON_ATCK2)
 183                 if (weapon_prepareattack(1, cvar("g_balance_hagar_secondary_refire")))
 184                 {
 185                         W_Hagar_Attack2();
 186                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hagar_secondary_refire"), w_ready);
 187                 }
 188         }
 189         else if (req == WR_PRECACHE)
 190         {
 191                 precache_model ("models/hagarmissile.mdl");
 192                 precache_model ("models/weapons/g_hagar.md3");
 193                 precache_model ("models/weapons/v_hagar.md3");
 194                 precache_model ("models/weapons/w_hagar.zym");
 195                 precache_sound ("weapons/hagar_fire.wav");
 196                 precache_sound ("weapons/hagexp1.wav");
 197                 precache_sound ("weapons/hagexp2.wav");
 198                 precache_sound ("weapons/hagexp3.wav");
 199         }
 200         else if (req == WR_SETUP)
 201                 weapon_setup(WEP_HAGAR);
 202         else if (req == WR_CHECKAMMO1)
 203                 return self.ammo_rockets >= cvar("g_balance_hagar_primary_ammo");
 204         else if (req == WR_CHECKAMMO2)
 205                 return self.ammo_rockets >= cvar("g_balance_hagar_secondary_ammo");
 206         // else if (req == WR_SUICIDEMESSAGE) // TODO
 207         else if (req == WR_KILLMESSAGE)
 208                 w_deathtypestring = "was pummeled by";
 209         else if (req == WR_SPAWNFUNC)
 210                 spawnfunc_weapon_hagar();
 211         return TRUE;
 212 };