data/qcsrc/server/w_grenadelauncher.qc

   1 void W_Grenade_Explode (void)
   2 {
   3         if(other.takedamage == DAMAGE_AIM)
   4                 if(other.classname == "player")
   5                         if(IsDifferentTeam(self.owner, other))
   6                                 if(IsFlying(other))
   7                                         announce(self.owner, "announcer/male/airshot.wav");
   8
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Grenade_Explode2 (void)
  16 {
  17         if(other.takedamage == DAMAGE_AIM)
  18                 if(other.classname == "player")
  19                         if(IsDifferentTeam(self.owner, other))
  20                                 if(IsFlying(other))
  21                                         announce(self.owner, "announcer/male/airshot.wav");
  22
  23         self.event_damage = SUB_Null;
  24         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  25
  26         remove (self);
  27 }
  28
  29 void W_Grenade_Touch1 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32         W_Grenade_Explode ();
  33 }
  34
  35 void W_Grenade_Touch2 (void)
  36 {
  37         PROJECTILE_TOUCH;
  38         if (other.takedamage == DAMAGE_AIM)
  39         {
  40                 self.use ();
  41         }
  42         else
  43         {
  44                 float r;
  45                 r = random() * 6;
  46                 if(r < 1)
  47                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  48                 else if(r < 2)
  49                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  50                 else if(r < 3)
  51                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  52                 else if(r < 4)
  53                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  54                 else if(r < 5)
  55                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  56                 else
  57                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  58                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  59         }
  60
  61         if(trace_ent && trace_ent.solid > SOLID_TRIGGER) // CSQC doesn't know about these entities well enough
  62                 UpdateCSQCProjectile(self);
  63 }
  64
  65 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  66 {
  67         self.health = self.health - damage;
  68         if (self.health <= 0)
  69         {
  70                 W_PrepareExplosionByDamage(attacker, self.think);
  71         }
  72 }
  73
  74 void W_Grenade_Attack (void)
  75 {
  76         local entity gren;
  77
  78         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  79                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  80         W_SetupShot (self, FALSE, 4, "weapons/grenade_fire.wav");
  81
  82         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  83
  84         gren = spawn ();
  85         gren.owner = self;
  86         gren.classname = "grenade";
  87         gren.bot_dodge = TRUE;
  88         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  89         gren.movetype = MOVETYPE_BOUNCE;
  90         gren.solid = SOLID_BBOX;
  91         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
  92         setorigin(gren, w_shotorg);
  93
  94         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
  95         gren.think = adaptor_think2use;
  96         gren.use = W_Grenade_Explode;
  97         gren.touch = W_Grenade_Touch1;
  98         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
  99         W_SetupProjectileVelocity(gren);
 100
 101         gren.angles = vectoangles (gren.velocity);
 102         gren.flags = FL_PROJECTILE;
 103
 104         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 105 }
 106
 107 void W_Grenade_Attack2 (void)
 108 {
 109         local entity gren;
 110
 111         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 112                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 113         W_SetupShot (self, FALSE, 4, "weapons/grenade_fire.wav");
 114         //W_SetupShot (self, FALSE, 4, "weapons/grenade_fire.wav"); // TODO: move model to the right a little
 115
 116         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 117
 118         gren = spawn ();
 119         gren.owner = self;
 120         gren.classname = "grenade";
 121         gren.bot_dodge = TRUE;
 122         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 123         gren.movetype = MOVETYPE_BOUNCE;
 124         gren.solid = SOLID_BBOX;
 125         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 126         setsize(gren, '0 0 -3', '0 0 -3'); // why, just, why?
 127         setorigin(gren, w_shotorg);
 128
 129         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 130         gren.think = adaptor_think2use;
 131         gren.use = W_Grenade_Explode2;
 132         gren.touch = W_Grenade_Touch2;
 133         gren.takedamage = DAMAGE_YES;
 134         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 135         gren.damageforcescale = 4;
 136         gren.event_damage = W_Grenade_Damage;
 137         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 138         W_SetupProjectileVelocity(gren);
 139
 140         gren.angles = vectoangles (gren.velocity);
 141         gren.flags = FL_PROJECTILE;
 142
 143         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 144 }
 145
 146 void spawnfunc_weapon_grenadelauncher (void)
 147 {
 148         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 149 }
 150
 151 .float bot_secondary_grenademooth;
 152 float w_glauncher(float req)
 153 {
 154         if (req == WR_AIM)
 155         {
 156                 self.BUTTON_ATCK = FALSE;
 157                 self.BUTTON_ATCK2 = FALSE;
 158                 if (self.bot_secondary_grenademooth == 0)
 159                 {
 160                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 161                         {
 162                                 self.BUTTON_ATCK = TRUE;
 163                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 169                         {
 170                                 self.BUTTON_ATCK2 = TRUE;
 171                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 172                         }
 173                 }
 174         }
 175         else if (req == WR_THINK)
 176         {
 177                 if (self.BUTTON_ATCK)
 178                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 179                 {
 180                         W_Grenade_Attack();
 181                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 182                 }
 183                 if (self.BUTTON_ATCK2)
 184                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 185                 {
 186                         W_Grenade_Attack2();
 187                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 188                 }
 189         }
 190         else if (req == WR_PRECACHE)
 191         {
 192                 precache_model ("models/weapons/g_gl.md3");
 193                 precache_model ("models/weapons/v_gl.md3");
 194                 precache_model ("models/weapons/h_gl.dpm");
 195                 precache_sound ("weapons/grenade_bounce1.wav");
 196                 precache_sound ("weapons/grenade_bounce2.wav");
 197                 precache_sound ("weapons/grenade_bounce3.wav");
 198                 precache_sound ("weapons/grenade_bounce4.wav");
 199                 precache_sound ("weapons/grenade_bounce5.wav");
 200                 precache_sound ("weapons/grenade_bounce6.wav");
 201                 precache_sound ("weapons/grenade_fire.wav");
 202         }
 203         else if (req == WR_SETUP)
 204                 weapon_setup(WEP_GRENADE_LAUNCHER);
 205         else if (req == WR_CHECKAMMO1)
 206                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 207         else if (req == WR_CHECKAMMO2)
 208                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 209         else if (req == WR_SUICIDEMESSAGE)
 210         {
 211                 if(w_deathtype & HITTYPE_SECONDARY)
 212                         w_deathtypestring = "tried out his own grenade";
 213                 else
 214                         w_deathtypestring = "detonated";
 215         }
 216         else if (req == WR_KILLMESSAGE)
 217         {
 218                 if(w_deathtype & HITTYPE_SPLASH)
 219                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 220                                 w_deathtypestring = "didn't see #'s grenade";
 221                         else // unchecked: SECONDARY
 222                                 w_deathtypestring = "almost dodged #'s grenade";
 223                 else // unchecked: SECONDARY, BOUNCE
 224                         w_deathtypestring = "ate #'s grenade";
 225         }
 226         return TRUE;
 227 };