data/qcsrc/server/w_grenadelauncher.qc

   1 void W_Grenade_Explode (void)
   2 {
   3         if(other.takedamage == DAMAGE_AIM)
   4                 if(other.classname == "player")
   5                         if(IsDifferentTeam(self.owner, other))
   6                                 if(IsFlying(other))
   7                                         announce(self.owner, "announcer/male/airshot.wav");
   8
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Grenade_Explode2 (void)
  16 {
  17         if(other.takedamage == DAMAGE_AIM)
  18                 if(other.classname == "player")
  19                         if(IsDifferentTeam(self.owner, other))
  20                                 if(IsFlying(other))
  21                                         announce(self.owner, "announcer/male/airshot.wav");
  22
  23         self.event_damage = SUB_Null;
  24         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  25
  26         remove (self);
  27 }
  28
  29 void W_Grenade_Touch1 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32         W_Grenade_Explode ();
  33 }
  34
  35 void W_Grenade_Touch2 (void)
  36 {
  37         PROJECTILE_TOUCH;
  38         if (other.takedamage == DAMAGE_AIM)
  39         {
  40                 self.use ();
  41         }
  42         else
  43         {
  44                 float r;
  45                 r = random() * 6;
  46                 if(r < 1)
  47                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  48                 else if(r < 2)
  49                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  50                 else if(r < 3)
  51                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  52                 else if(r < 4)
  53                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  54                 else if(r < 5)
  55                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  56                 else
  57                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  58                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  59         }
  60
  61         if(trace_ent && trace_ent.solid > SOLID_TRIGGER) // CSQC doesn't know about these entities well enough
  62                 UpdateCSQCProjectile(self);
  63 }
  64
  65 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  66 {
  67         self.health = self.health - damage;
  68         if (self.health <= 0)
  69         {
  70                 W_PrepareExplosionByDamage(attacker, self.think);
  71         }
  72 }
  73
  74 void W_Grenade_Attack (void)
  75 {
  76         local entity gren;
  77
  78         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  79                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  80         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/grenade_fire.wav");
  81         //W_SetupShot (self, '25 8 -8', FALSE, 4, "weapons/grenade_fire.wav"); // TODO: move model to the right a little
  82
  83         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  84
  85         gren = spawn ();
  86         gren.owner = self;
  87         gren.classname = "grenade";
  88         gren.bot_dodge = TRUE;
  89         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  90         gren.movetype = MOVETYPE_BOUNCE;
  91         gren.solid = SOLID_BBOX;
  92         gren.effects = EF_LOWPRECISION;
  93         gren.modelflags = MF_TRACER2;
  94         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
  95         setmodel(gren, "models/grenademodel.md3"); // precision set above
  96         setsize(gren, '0 0 0', '0 0 0');
  97         setorigin(gren, w_shotorg);
  98
  99         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 100         gren.think = adaptor_think2use;
 101         gren.use = W_Grenade_Explode;
 102         gren.touch = W_Grenade_Touch1;
 103         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 104         W_SetupProjectileVelocity(gren);
 105
 106         gren.angles = vectoangles (gren.velocity);
 107         gren.flags = FL_PROJECTILE;
 108
 109         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE);
 110 }
 111
 112 void W_Grenade_Attack2 (void)
 113 {
 114         local entity gren;
 115
 116         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 117                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 118         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/grenade_fire.wav");
 119         //W_SetupShot (self, '25 8 -8', FALSE, 4, "weapons/grenade_fire.wav"); // TODO: move model to the right a little
 120
 121         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 122
 123         gren = spawn ();
 124         gren.owner = self;
 125         gren.classname = "grenade";
 126         gren.bot_dodge = TRUE;
 127         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 128         gren.movetype = MOVETYPE_BOUNCE;
 129         gren.solid = SOLID_BBOX;
 130         gren.effects = EF_LOWPRECISION;
 131         gren.modelflags = MF_TRACER2;
 132         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 133         setmodel(gren, "models/grenademodel.md3"); // precision set above
 134         setsize(gren, '0 0 -3', '0 0 -3');
 135         setorigin(gren, w_shotorg);
 136
 137         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 138         gren.think = adaptor_think2use;
 139         gren.use = W_Grenade_Explode2;
 140         gren.touch = W_Grenade_Touch2;
 141         gren.takedamage = DAMAGE_YES;
 142         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 143         gren.damageforcescale = 4;
 144         gren.event_damage = W_Grenade_Damage;
 145         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 146         W_SetupProjectileVelocity(gren);
 147
 148         gren.angles = vectoangles (gren.velocity);
 149         gren.flags = FL_PROJECTILE;
 150
 151         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING);
 152 }
 153
 154 void spawnfunc_weapon_grenadelauncher (void)
 155 {
 156         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 157 }
 158
 159 .float bot_secondary_grenademooth;
 160 float w_glauncher(float req)
 161 {
 162         if (req == WR_AIM)
 163         {
 164                 self.BUTTON_ATCK = FALSE;
 165                 self.BUTTON_ATCK2 = FALSE;
 166                 if (self.bot_secondary_grenademooth == 0)
 167                 {
 168                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 169                         {
 170                                 self.BUTTON_ATCK = TRUE;
 171                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 172                         }
 173                 }
 174                 else
 175                 {
 176                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 177                         {
 178                                 self.BUTTON_ATCK2 = TRUE;
 179                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 180                         }
 181                 }
 182         }
 183         else if (req == WR_THINK)
 184         {
 185                 if (self.BUTTON_ATCK)
 186                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 187                 {
 188                         W_Grenade_Attack();
 189                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 190                 }
 191                 if (self.BUTTON_ATCK2)
 192                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 193                 {
 194                         W_Grenade_Attack2();
 195                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 196                 }
 197         }
 198         else if (req == WR_PRECACHE)
 199         {
 200                 precache_model ("models/grenademodel.md3");
 201                 precache_model ("models/weapons/g_gl.md3");
 202                 precache_model ("models/weapons/v_gl.md3");
 203                 precache_model ("models/weapons/w_gl.zym");
 204                 precache_sound ("weapons/grenade_bounce1.wav");
 205                 precache_sound ("weapons/grenade_bounce2.wav");
 206                 precache_sound ("weapons/grenade_bounce3.wav");
 207                 precache_sound ("weapons/grenade_bounce4.wav");
 208                 precache_sound ("weapons/grenade_bounce5.wav");
 209                 precache_sound ("weapons/grenade_bounce6.wav");
 210                 precache_sound ("weapons/grenade_fire.wav");
 211                 precache_sound ("weapons/grenade_impact.wav");
 212         }
 213         else if (req == WR_SETUP)
 214                 weapon_setup(WEP_GRENADE_LAUNCHER);
 215         else if (req == WR_CHECKAMMO1)
 216                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 217         else if (req == WR_CHECKAMMO2)
 218                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 219         else if (req == WR_SUICIDEMESSAGE)
 220         {
 221                 if(w_deathtype & HITTYPE_SECONDARY)
 222                         w_deathtypestring = "tried out his own grenade";
 223                 else
 224                         w_deathtypestring = "detonated";
 225         }
 226         else if (req == WR_KILLMESSAGE)
 227         {
 228                 if(w_deathtype & HITTYPE_SPLASH)
 229                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 230                                 w_deathtypestring = "didn't see #'s grenade";
 231                         else // unchecked: SECONDARY
 232                                 w_deathtypestring = "almost dodged #'s grenade";
 233                 else // unchecked: SECONDARY, BOUNCE
 234                         w_deathtypestring = "ate #'s grenade";
 235         }
 236         return TRUE;
 237 };