data/qcsrc/server/t_teleporters.qc

   1 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   2 {
   3         entity head;
   4         vector deathmin;
   5         vector deathmax;
   6         float deathradius;
   7         deathmin = player.absmin;
   8         deathmax = player.absmax;
   9         if(telefragmin != telefragmax)
  10         {
  11                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  12                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  13                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  14                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  15                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  16                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  17         }
  18         deathradius = max(vlen(deathmin), vlen(deathmax));
  19         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  20                 if(head != player)
  21                         if(head.takedamage)
  22                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  23                                 {
  24                                         if ((player.classname == "player") && (player.health >= 1))
  25                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  26                                         else if (telefragger.health < 1) // corpses gib
  27                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  28                                         else // dead bodies and monsters gib themselves instead of telefragging
  29                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  30                                 }
  31 }
  32
  33 void spawn_tdeath(vector v0, entity e, vector v)
  34 {
  35         tdeath(e, e, e, '0 0 0', '0 0 0');
  36 }
  37
  38 .entity pusher;
  39 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  40 {
  41         entity head;
  42         entity oldself;
  43         entity telefragger;
  44         vector from;
  45
  46         if(teleporter.owner)
  47                 telefragger = teleporter.owner;
  48         else
  49                 telefragger = player;
  50
  51         makevectors (to_angles);
  52
  53         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  54         {
  55                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  56                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  57                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  58                 self.pushltime = time + 0.2;
  59         }
  60
  61         // Relocate the player
  62         // assuming to allows PL_MIN to PL_MAX box and some more
  63         from = player.origin;
  64         setorigin (player, to);
  65         player.angles = to_angles;
  66         player.fixangle = TRUE;
  67         player.velocity = to_velocity;
  68
  69         if(player.classname == "player")
  70         {
  71                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  72                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  73
  74                 // hide myself a tic
  75                 player.effects = player.effects | EF_NODRAW;
  76                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  77                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  78                 player.teleport_time = time + cvar("sys_ticrate");
  79
  80                 // player no longer is on ground
  81                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  82
  83                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  84                 player.oldvelocity = player.velocity;
  85
  86                 // reset tracking of who pushed you into a hazard (for kill credit)
  87                 if(teleporter.owner)
  88                 {
  89                         player.pusher = teleporter.owner;
  90                         player.pushltime = time + cvar("g_maxpushtime");
  91                 }
  92                 else
  93                 {
  94                         player.pushltime = 0;
  95                 }
  96
  97                 // stop player name display
  98                 {
  99                         oldself = self;
 100                         self = player;
 101                         ClearSelectedPlayer();
 102                         self = oldself;
 103                 }
 104         }
 105 }
 106
 107 void Teleport_Touch (void)
 108 {
 109         entity oldself;
 110
 111         if (other.health < 1)
 112                 return;
 113         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 114                 return;
 115
 116         EXACTTRIGGER_TOUCH;
 117
 118         makevectors(self.enemy.mangle);
 119
 120         if(other.classname == "player")
 121                 RemoveGrapplingHook(other);
 122
 123         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 124
 125         if(self.enemy.target)
 126         {
 127                 oldself = self;
 128                 activator = other;
 129                 self = self.enemy;
 130                 SUB_UseTargets();
 131                 self = oldself;
 132         }
 133 }
 134
 135 void spawnfunc_info_teleport_destination (void)
 136 {
 137         self.mangle = self.angles;
 138         self.angles = '0 0 0';
 139
 140         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 141         setorigin (self, self.origin);
 142
 143         IFTARGETED
 144         {
 145         }
 146         else
 147                 objerror ("Teleport destination without a targetname");
 148 }
 149
 150 void spawnfunc_misc_teleporter_dest (void)
 151 {
 152         spawnfunc_info_teleport_destination();
 153 }
 154
 155 void spawnfunc_target_teleporter (void)
 156 {
 157         spawnfunc_info_teleport_destination();
 158 }
 159
 160 void teleport_findtarget (void)
 161 {
 162         // now enable touch
 163         self.touch = Teleport_Touch;
 164
 165         self.enemy = find (world, targetname, self.target);
 166         if (!self.enemy)
 167         {
 168                 objerror ("Teleporter with nonexistant target");
 169                 return;
 170         }
 171
 172         self.dest = self.enemy.origin;
 173         waypoint_spawnforteleporter(self, self.dest, 0);
 174 }
 175
 176 void spawnfunc_trigger_teleport (void)
 177 {
 178         self.angles = '0 0 0';
 179
 180         EXACTTRIGGER_INIT;
 181
 182         // this must be called to spawn the teleport waypoints for bots
 183         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 184
 185         if (!self.target)
 186         {
 187                 objerror ("Teleporter with no target");
 188                 return;
 189         }
 190 }