data/qcsrc/server/t_teleporters.qc

   1 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   2 {
   3         entity head;
   4         vector deathmin;
   5         vector deathmax;
   6         float deathradius;
   7         deathmin = player.absmin;
   8         deathmax = player.absmax;
   9         if(telefragmin != telefragmax)
  10         {
  11                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  12                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  13                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  14                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  15                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  16                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  17         }
  18         deathradius = max(vlen(deathmin), vlen(deathmax));
  19         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  20                 if(head != player)
  21                         if(head.takedamage)
  22                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  23                                 {
  24                                         if ((player.classname == "player") && (player.health >= 1))
  25                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  26                                         else if (telefragger.health < 1) // corpses gib
  27                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  28                                         else // dead bodies and monsters gib themselves instead of telefragging
  29                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  30                                 }
  31 }
  32
  33 void spawn_tdeath(vector v0, entity e, vector v)
  34 {
  35         tdeath(e, e, e, '0 0 0', '0 0 0');
  36 }
  37
  38 .entity pusher;
  39 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  40 {
  41         entity oldself;
  42         entity telefragger;
  43         vector from;
  44
  45         if(teleporter.owner)
  46                 telefragger = teleporter.owner;
  47         else
  48                 telefragger = player;
  49
  50         makevectors (to_angles);
  51
  52         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  53         {
  54                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  55                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  56                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  57                 self.pushltime = time + 0.2;
  58         }
  59
  60         // Relocate the player
  61         // assuming to allows PL_MIN to PL_MAX box and some more
  62         from = player.origin;
  63         setorigin (player, to);
  64         player.angles = to_angles;
  65         player.fixangle = TRUE;
  66         player.velocity = to_velocity;
  67
  68         UpdateCSQCProjectile(player);
  69
  70         if(player.classname == "player")
  71         {
  72                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  73                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  74
  75                 // hide myself a tic
  76                 player.effects = player.effects | EF_NODRAW;
  77                 player.teleport_time = time + cvar("sys_ticrate");
  78
  79                 // player no longer is on ground
  80                 player.flags &~= FL_ONGROUND;
  81
  82                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  83                 player.oldvelocity = player.velocity;
  84
  85                 // reset tracking of who pushed you into a hazard (for kill credit)
  86                 if(teleporter.owner)
  87                 {
  88                         player.pusher = teleporter.owner;
  89                         player.pushltime = time + cvar("g_maxpushtime");
  90                 }
  91                 else
  92                 {
  93                         player.pushltime = 0;
  94                 }
  95
  96                 // stop player name display
  97                 {
  98                         oldself = self;
  99                         self = player;
 100                         ClearSelectedPlayer();
 101                         self = oldself;
 102                 }
 103         }
 104 }
 105
 106 void Teleport_Touch (void)
 107 {
 108         entity oldself, e;
 109
 110         if (other.health < 1)
 111                 return;
 112         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 113                 return;
 114
 115         EXACTTRIGGER_TOUCH;
 116
 117         makevectors(self.enemy.mangle);
 118
 119         if(other.classname == "player")
 120                 RemoveGrapplingHook(other);
 121
 122         if(self.enemy)
 123         {
 124                 e = self.enemy;
 125         }
 126         else
 127         {
 128                 RandomSelection_Init();
 129                 for(e = world; (e = find(e, targetname, self.target)); )
 130                 {
 131                         if(e.cnt)
 132                                 RandomSelection_Add(e, 0, e.cnt, 0);
 133                         else
 134                                 RandomSelection_Add(e, 0, 1, 0);
 135                 }
 136                 e = RandomSelection_chosen_ent;
 137         }
 138
 139         if(!e)
 140         {
 141                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 142         }
 143
 144         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 145
 146         if(e.target)
 147         {
 148                 oldself = self;
 149                 activator = other;
 150                 self = e;
 151                 SUB_UseTargets();
 152                 self = oldself;
 153         }
 154 }
 155
 156 void spawnfunc_info_teleport_destination (void)
 157 {
 158         self.classname = "info_teleport_destination";
 159
 160         self.mangle = self.angles;
 161         self.angles = '0 0 0';
 162
 163         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 164         setorigin (self, self.origin);
 165
 166         IFTARGETED
 167         {
 168         }
 169         else
 170                 objerror ("^3Teleport destination without a targetname");
 171 }
 172
 173 void spawnfunc_misc_teleporter_dest (void)
 174 {
 175         spawnfunc_info_teleport_destination();
 176 }
 177
 178 void spawnfunc_target_teleporter (void)
 179 {
 180         spawnfunc_info_teleport_destination();
 181 }
 182
 183 void teleport_findtarget (void)
 184 {
 185         entity e;
 186         float n;
 187
 188         n = 0;
 189         for(e = world; (e = find(e, targetname, self.target)); )
 190         {
 191                 ++n;
 192                 if(e.movetype == MOVETYPE_NONE)
 193                         waypoint_spawnforteleporter(self, e.origin, 0);
 194                 if(e.classname != "info_teleport_destination")
 195                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 196         }
 197
 198         if(n == 0)
 199         {
 200                 // no dest!
 201                 objerror ("Teleporter with nonexistant target");
 202                 return;
 203         }
 204         else if(n == 1)
 205         {
 206                 // exactly one dest - bots love that
 207                 self.enemy = find(e, targetname, self.target);
 208                 self.dest = self.enemy.origin;
 209         }
 210         else
 211         {
 212                 // have to use random selection every single time
 213                 self.enemy = world;
 214         }
 215
 216         // now enable touch
 217         self.touch = Teleport_Touch;
 218 }
 219
 220 void spawnfunc_trigger_teleport (void)
 221 {
 222         self.angles = '0 0 0';
 223
 224         EXACTTRIGGER_INIT;
 225
 226         // this must be called to spawn the teleport waypoints for bots
 227         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 228
 229         if (!self.target)
 230         {
 231                 objerror ("Teleporter with no target");
 232                 return;
 233         }
 234 }