data/qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teams_matter)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         local float grav, sdist, zdist, vs, vz, jumpheight;
  34         local vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = cvar("sv_gravity");
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         // FIXME: add a .float for whether an entity should be tossed by jumppads
 131         if (!other.iscreature)
 132         if (other.classname != "corpse")
 133         if (other.classname != "body")
 134         if (other.classname != "gib")
 135         if (other.classname != "casing")
 136         if (other.classname != "droppedweapon")
 137         if (!other.projectiledeathtype || other.classname == "bullet")
 138                 return;
 139
 140         if (other.deadflag && other.iscreature)
 141                 return;
 142
 143         if(self.team)
 144                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 145                         return;
 146
 147         EXACTTRIGGER_TOUCH;
 148
 149         if(self.target)
 150                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 151
 152         other.flags &~= FL_ONGROUND;
 153         // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 154         other.oldvelocity = other.velocity = self.movedir;
 155
 156         UpdateCSQCProjectile(other);
 157
 158         if (other.classname == "player")
 159         {
 160                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 161                 {
 162                         // flash when activated
 163                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 164                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 165                         self.pushltime = time + 0.2;
 166                 }
 167                 local float ct;
 168                 ct = clienttype(other);
 169                 if( ct == CLIENTTYPE_REAL)
 170                 {
 171                         local float i;
 172                         local float found;
 173                         found = FALSE;
 174                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 175                                 if(other.(jumppadsused[i]) == self)
 176                                         found = TRUE;
 177                         if(!found)
 178                         {
 179                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 180                                 other.jumppadcount = other.jumppadcount + 1;
 181                         }
 182
 183                         if(self.message)
 184                                 centerprint(other, self.message);
 185                 }
 186                 else if(ct == CLIENTTYPE_BOT)
 187                         other.lastteleporttime = time;
 188                 else
 189                         other.jumppadcount = TRUE;
 190         }
 191
 192         if(self.enemy.target)
 193         {
 194                 entity oldself;
 195                 oldself = self;
 196                 activator = other;
 197                 self = self.enemy;
 198                 SUB_UseTargets();
 199                 self = oldself;
 200         }
 201
 202         // reset tracking of who pushed you into a hazard (for kill credit)
 203         other.pushltime = 0;
 204
 205         if (other.flags & FL_PROJECTILE)
 206                 other.angles = vectoangles (other.velocity);
 207
 208         if (self.spawnflags & PUSH_ONCE)
 209         {
 210                 self.touch = SUB_Null;
 211                 self.think = SUB_Remove;
 212                 self.nextthink = time;
 213         }
 214 };
 215
 216 .vector dest;
 217
 218 void trigger_push_findtarget()
 219 {
 220         local entity e;
 221         local vector org;
 222         local float flighttime;
 223
 224         // first calculate a typical start point for the jump
 225         org = (self.absmin + self.absmax) * 0.5;
 226         org_z = self.absmax_z - PL_MIN_z;
 227
 228         if (self.target)
 229         {
 230                 // find the target
 231                 self.enemy = find(world, targetname, self.target);
 232                 if (!self.enemy)
 233                 {
 234                         objerror("trigger_push: target not found\n");
 235                         remove(self);
 236                         return;
 237                 }
 238
 239                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 240                 flighttime = trigger_push_calculatevelocity_flighttime;
 241         }
 242         else
 243                 flighttime = 0;
 244
 245         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 246         e = spawn();
 247         setorigin(e, org);
 248         setsize(e, PL_MIN, PL_MAX);
 249         e.velocity = self.movedir;
 250         tracetoss(e, e);
 251         self.dest = trace_endpos;
 252         remove(e);
 253
 254         waypoint_spawnforteleporter(self, self.dest, flighttime);
 255 };
 256
 257 /*
 258  * ENTITY PARAMETERS:
 259  *
 260  *   target:  target of jump
 261  *   height:  the absolute value is the height of the highest point of the jump
 262  *            trajectory above the higher one of the player and the target.
 263  *            the sign indicates whether the highest point is INSIDE (positive)
 264  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 265  *            positive values for targets mounted on the floor, and use negative
 266  *            values to target a point on the ceiling.
 267  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 268  */
 269 void spawnfunc_trigger_push()
 270 {
 271         if (self.angles != '0 0 0')
 272                 SetMovedir ();
 273
 274         EXACTTRIGGER_INIT;
 275
 276         self.use = trigger_push_use;
 277         self.touch = trigger_push_touch;
 278
 279         // normal push setup
 280         if (!self.speed)
 281                 self.speed = 1000;
 282         self.movedir = self.movedir * self.speed * 10;
 283
 284         if not(self.noise)
 285                 self.noise = "misc/jumppad.wav";
 286         precache_sound (self.noise);
 287
 288         // this must be called to spawn the teleport waypoints for bots
 289         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 290 };
 291
 292 void spawnfunc_target_push() {};
 293 void spawnfunc_info_notnull() {};
 294 void spawnfunc_target_position() {};