data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Show (entity e, float mode)
  45 {
  46         if (mode > 0)
  47         {
  48                 // make the item look normal, and be touchable
  49                 e.model = e.mdl;
  50                 e.solid = SOLID_TRIGGER;
  51                 e.effects = e.effects - (e.effects & (EF_ADDITIVE | EF_FULLBRIGHT));
  52                 //e.colormod = '0 0 0';
  53                 e.alpha = 0;
  54
  55                 // special cases
  56                 if (e.strength_finished || e.invincible_finished)
  57                         e.effects = e.effects | EF_ADDITIVE | EF_FULLBRIGHT;
  58                 if (cvar("g_fullbrightitems"))
  59                         e.effects = e.effects | EF_FULLBRIGHT;
  60         }
  61         else if (mode < 0)
  62         {
  63                 // hide the item completely
  64                 e.model = string_null;
  65                 e.solid = SOLID_NOT;
  66                 e.effects = e.effects - (e.effects & (EF_ADDITIVE | EF_FULLBRIGHT));
  67                 //e.colormod = '0 0 0';
  68                 e.alpha = 0;
  69         }
  70         else
  71         {
  72                 // make the item translucent green and not touchable
  73                 e.model = e.mdl;
  74                 e.solid = SOLID_NOT;
  75                 e.effects = e.effects | EF_ADDITIVE | EF_FULLBRIGHT;
  76                 //e.colormod = '0.2 1 0.2';
  77                 e.alpha = 0.1;
  78         }
  79
  80         // relink entity (because solid may have changed)
  81         setorigin(e, e.origin);
  82 }
  83
  84 void Item_Respawn (void)
  85 {
  86         Item_Show(self, 1);
  87         if(!g_minstagib && self.items == IT_STRENGTH)
  88                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  89         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  90                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  91         else
  92                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  93         setorigin (self, self.origin);
  94
  95         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  96         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  97 }
  98
  99 void Item_RespawnCountdown (void)
 100 {
 101         if(self.count >= ITEM_RESPAWN_TICKS)
 102         {
 103                 if(self.waypointsprite_attached)
 104                         WaypointSprite_Kill(self.waypointsprite_attached);
 105                 Item_Respawn();
 106         }
 107         else
 108         {
 109                 self.nextthink = time + 1;
 110                 self.count += 1;
 111                 if(self.count == 1)
 112                 {
 113                         string name;
 114                         vector rgb;
 115                         name = string_null;
 116                         if(g_minstagib)
 117                         {
 118                                 switch(self.items)
 119                                 {
 120                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 121                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 122                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 123                                 }
 124                         }
 125                         else
 126                         {
 127                                 switch(self.items)
 128                                 {
 129                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 130                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 131                                 }
 132                         }
 133                         switch(self.items)
 134                         {
 135                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 136                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 137                         }
 138                         if(name)
 139                         {
 140                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 141                                 if(self.waypointsprite_attached)
 142                                 {
 143                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 144                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 145                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 146                                 }
 147                         }
 148                 }
 149                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 150                 if(self.waypointsprite_attached)
 151                 {
 152                         WaypointSprite_Ping(self.waypointsprite_attached);
 153                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 154                 }
 155         }
 156 }
 157
 158 void Item_ScheduleRespawnIn(entity e, float t)
 159 {
 160         if(e.flags & FL_POWERUP)
 161         {
 162                 e.think = Item_RespawnCountdown;
 163                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 164                 e.count = 0;
 165         }
 166         else
 167         {
 168                 e.think = Item_Respawn;
 169                 e.nextthink = time + t;
 170         }
 171 }
 172
 173 void Item_ScheduleRespawn(entity e)
 174 {
 175         Item_Show(e, 0);
 176         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 177 }
 178
 179 void Item_ScheduleInitialRespawn(entity e)
 180 {
 181         Item_Show(e, 0);
 182         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 183 }
 184
 185 float Item_GiveTo(entity item, entity player)
 186 {
 187         float _switchweapon;
 188         float pickedup;
 189         float it;
 190         float i;
 191         entity e;
 192
 193         // if nothing happens to player, just return without taking the item
 194         pickedup = FALSE;
 195         _switchweapon = FALSE;
 196
 197         if (g_minstagib)
 198         {
 199                 if (item.ammo_fuel)
 200                 if (player.ammo_fuel < g_pickup_fuel_max)
 201                 {
 202                         pickedup = TRUE;
 203                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 204                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 205                 }
 206                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 207                 {
 208                         pickedup = TRUE;
 209                         player.items |= it;
 210                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 211                 }
 212
 213                 _switchweapon = TRUE;
 214                 if (item.ammo_cells)
 215                 {
 216                         pickedup = TRUE;
 217                         // play some cool sounds ;)
 218                         centerprint(player, "\n");
 219                         if (clienttype(player) == CLIENTTYPE_REAL)
 220                         {
 221                                 if(player.health <= 5)
 222                                         play2(player, "announcer/robotic/lastsecond.wav");
 223                                 else if(player.health < 50)
 224                                         play2(player, "announcer/robotic/narrowly.wav");
 225                         }
 226                         // sound not available
 227                         // else if(item.items == IT_CELLS)
 228                         //      play2(player, "announce/robotic/ammo.wav");
 229
 230                         if (item.weapons & WEPBIT_MINSTANEX)
 231                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 232                         if (item.ammo_cells)
 233                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 234                         player.health = 100;
 235                 }
 236
 237                 // extralife powerup
 238                 if (item.max_health)
 239                 {
 240                         pickedup = TRUE;
 241                         // sound not available
 242                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 243                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 244                         sprint(player, "^3You picked up some extra lives\n");
 245                 }
 246
 247                 // invis powerup
 248                 if (item.strength_finished)
 249                 {
 250                         pickedup = TRUE;
 251                         // sound not available
 252                         // play2(player, "announce/robotic/invisible.wav");
 253                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 254                 }
 255
 256                 // speed powerup
 257                 if (item.invincible_finished)
 258                 {
 259                         pickedup = TRUE;
 260                         // sound not available
 261                         // play2(player, "announce/robotic/speed.wav");
 262                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 263                 }
 264
 265                 if (item.ammo_fuel)
 266                 if (player.ammo_fuel < g_pickup_fuel_max)
 267                 {
 268                         pickedup = TRUE;
 269                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 270                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 271                 }
 272
 273         }
 274         else
 275         {
 276                 if (g_weapon_stay == 1)
 277                 if not(item.flags & FL_NO_WEAPON_STAY)
 278                 if (item.flags & FL_WEAPON)
 279                 {
 280                         if(item.classname == "droppedweapon")
 281                         {
 282                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 283                                         goto skip;
 284                         }
 285                         else
 286                         {
 287                                 if (player.weapons & item.weapons)
 288                                         goto skip;
 289                         }
 290                 }
 291
 292                 // in case the player has autoswitch enabled do the following:
 293                 // if the player is using their best weapon before items are given, they
 294                 // probably want to switch to an even better weapon after items are given
 295                 if (player.autoswitch)
 296                 if (player.switchweapon == w_getbestweapon(player))
 297                         _switchweapon = TRUE;
 298
 299                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 300                         _switchweapon = TRUE;
 301
 302                 if (item.ammo_shells)
 303                 if (player.ammo_shells < g_pickup_shells_max)
 304                 {
 305                         pickedup = TRUE;
 306                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 307                 }
 308                 if (item.ammo_nails)
 309                 if (player.ammo_nails < g_pickup_nails_max)
 310                 {
 311                         pickedup = TRUE;
 312                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 313                 }
 314                 if (item.ammo_rockets)
 315                 if (player.ammo_rockets < g_pickup_rockets_max)
 316                 {
 317                         pickedup = TRUE;
 318                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 319                 }
 320                 if (item.ammo_cells)
 321                 if (player.ammo_cells < g_pickup_cells_max)
 322                 {
 323                         pickedup = TRUE;
 324                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 325                 }
 326                 if (item.ammo_fuel)
 327                 if (player.ammo_fuel < g_pickup_fuel_max)
 328                 {
 329                         pickedup = TRUE;
 330                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 332                 }
 333
 334                 if (item.flags & FL_WEAPON)
 335                 if ((it = item.weapons - (item.weapons & player.weapons)))
 336                 {
 337                         pickedup = TRUE;
 338                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 339                         {
 340                                 e = get_weaponinfo(i);
 341                                 if(it & e.weapons)
 342                                         W_GiveWeapon (player, e.weapon, item.netname);
 343                         }
 344                 }
 345
 346                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 347                 {
 348                         pickedup = TRUE;
 349                         player.items |= it;
 350                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 351                 }
 352
 353                 if (item.strength_finished)
 354                 {
 355                         pickedup = TRUE;
 356                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 357                 }
 358                 if (item.invincible_finished)
 359                 {
 360                         pickedup = TRUE;
 361                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 362                 }
 363                 //if (item.speed_finished)
 364                 //{
 365                 //      pickedup = TRUE;
 366                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 367                 //}
 368                 //if (item.slowmo_finished)
 369                 //{
 370                 //      pickedup = TRUE;
 371                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 372                 //}
 373
 374                 if (item.health)
 375                 if (player.health < item.max_health)
 376                 {
 377                         pickedup = TRUE;
 378                         player.health = min(player.health + item.health, item.max_health);
 379                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 380                 }
 381                 if (item.armorvalue)
 382                 if (player.armorvalue < item.max_armorvalue)
 383                 {
 384                         pickedup = TRUE;
 385                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 386                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 387                 }
 388         }
 389
 390 :skip
 391         // always eat teamed entities
 392         if(item.team)
 393                 pickedup = TRUE;
 394
 395         if (!pickedup)
 396                 return 0;
 397
 398         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 399         if (_switchweapon)
 400                 if (player.switchweapon != w_getbestweapon(player))
 401                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 402
 403         return 1;
 404 }
 405
 406 void Item_Touch (void)
 407 {
 408         entity e, head;
 409
 410         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 411         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 412         {
 413                 remove(self);
 414                 return;
 415         }
 416         if (other.classname != "player")
 417                 return;
 418         if (other.deadflag)
 419                 return;
 420         if (self.solid != SOLID_TRIGGER)
 421                 return;
 422         if (self.owner == other)
 423                 return;
 424
 425         if(!Item_GiveTo(self, other))
 426                 return;
 427
 428         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 429
 430         if (self.classname == "droppedweapon")
 431                 remove (self);
 432         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 433                 return;
 434         else
 435         {
 436                 if(self.team)
 437                 {
 438                         RandomSelection_Init();
 439                         for(head = world; (head = findfloat(head, team, self.team)); )
 440                         {
 441                                 if(head.flags & FL_ITEM)
 442                                 {
 443                                         Item_Show(head, -1);
 444                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 445                                 }
 446                         }
 447                         e = RandomSelection_chosen_ent;
 448                 }
 449                 else
 450                         e = self;
 451                 Item_ScheduleRespawn(e);
 452         }
 453 }
 454
 455 void Item_FindTeam()
 456 {
 457         entity head, e;
 458
 459         if(self.effects & EF_NODRAW)
 460         {
 461                 // marker for item team search
 462                 dprint("Initializing item team ", ftos(self.team), "\n");
 463                 RandomSelection_Init();
 464                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 465                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 466                 e = RandomSelection_chosen_ent;
 467                 e.state = 0;
 468                 Item_Show(e, 1);
 469
 470                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 471                 {
 472                         if(head != e)
 473                         {
 474                                 // make it a non-spawned item
 475                                 Item_Show(head, -1);
 476                                 head.state = 1; // state 1 = initially hidden item
 477                         }
 478                         head.effects &~= EF_NODRAW;
 479                 }
 480
 481                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 482                         Item_ScheduleInitialRespawn(e);
 483         }
 484 }
 485
 486 void Item_Reset()
 487 {
 488         Item_Show(self, !self.state);
 489         setorigin (self, self.origin);
 490         self.think = SUB_Null;
 491         self.nextthink = 0;
 492
 493         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 494                 Item_ScheduleInitialRespawn(self);
 495 }
 496
 497 // Savage: used for item garbage-collection
 498 // TODO: perhaps nice special effect?
 499 void RemoveItem(void)
 500 {
 501         remove(self);
 502 }
 503
 504 // pickup evaluation functions
 505 // these functions decide how desirable an item is to the bots
 506
 507 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 508
 509 float weapon_pickupevalfunc(entity player, entity item)
 510 {
 511         float c, i, j, position;
 512
 513         // See if I have it already
 514         if(player.weapons & item.weapons == item.weapons)
 515         {
 516                 // If I can pick it up
 517                 if(g_weapon_stay)
 518                         c = 0;
 519                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 520                 {
 521                         // Skilled bots will grab more
 522                         c = bound(0, skill / 10, 1) * 0.5;
 523                 }
 524                 else
 525                         c = 0;
 526         }
 527         else
 528                 c = 1;
 529
 530         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 531         if( bot_custom_weapon && c )
 532         {
 533                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 534                 {
 535                         // Find weapon
 536                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 537                                 continue;
 538
 539                         // Find the highest position on any range
 540                         position = -1;
 541                         for(j = 0; j < WEP_LAST ; ++j){
 542                                 if(
 543                                                 bot_weapons_far[j] == i ||
 544                                                 bot_weapons_mid[j] == i ||
 545                                                 bot_weapons_close[j] == i
 546                                   )
 547                                 {
 548                                         position = j;
 549                                         break;
 550                                 }
 551                         }
 552
 553                         // Rate it
 554                         if (position >= 0 )
 555                         {
 556                                 position = WEP_LAST - position;
 557                                 // item.bot_pickupbasevalue is overwritten here
 558                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 559                         }
 560                 }
 561         }
 562
 563         return item.bot_pickupbasevalue * c;
 564 };
 565
 566 float commodity_pickupevalfunc(entity player, entity item)
 567 {
 568         float c, i, need_shells, need_nails, need_rockets, need_cells;
 569         entity wi;
 570         c = 0;
 571
 572         // Detect needed ammo
 573         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 574         {
 575                 wi = get_weaponinfo(i);
 576
 577                 if not(wi.weapons & player.weapons)
 578                         continue;
 579
 580                 if(wi.items & IT_SHELLS)
 581                         need_shells = TRUE;
 582                 else if(wi.items & IT_NAILS)
 583                         need_nails = TRUE;
 584                 else if(wi.items & IT_ROCKETS)
 585                         need_rockets = TRUE;
 586                 else if(wi.items & IT_CELLS)
 587                         need_cells = TRUE;
 588         }
 589
 590         // TODO: figure out if the player even has the weapon this ammo is for?
 591         // may not affect strategy much though...
 592         // find out how much more ammo/armor/health the player can hold
 593         if (need_shells)
 594         if (item.ammo_shells)
 595         if (player.ammo_shells < g_pickup_shells_max)
 596                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 597         if (need_nails)
 598         if (item.ammo_nails)
 599         if (player.ammo_nails < g_pickup_nails_max)
 600                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 601         if (need_rockets)
 602         if (item.ammo_rockets)
 603         if (player.ammo_rockets < g_pickup_rockets_max)
 604                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 605         if (need_cells)
 606         if (item.ammo_cells)
 607         if (player.ammo_cells < g_pickup_cells_max)
 608                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 609         if (item.armorvalue)
 610         if (player.armorvalue < item.max_armorvalue*0.5)
 611                 c = c + max(0, 1 - player.armorvalue / (item.max_armorvalue*0.5));
 612         if (item.health)
 613         if (player.health < item.max_health*0.5)
 614                 c = c + max(0, 1 - player.health / (item.max_health*0.5));
 615
 616         return item.bot_pickupbasevalue * c;
 617 };
 618
 619
 620 .float is_item;
 621 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 622 {
 623         startitem_failed = FALSE;
 624
 625         // is it a dropped weapon?
 626         if (self.classname == "droppedweapon")
 627         {
 628                 self.reset = SUB_Remove;
 629                 // it's a dropped weapon
 630                 self.movetype = MOVETYPE_TOSS;
 631                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 632                 self.think = RemoveItem;
 633                 self.nextthink = time + 60;
 634                 // don't drop if in a NODROP zone (such as lava)
 635                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 636                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 637                 {
 638                         startitem_failed = TRUE;
 639                         remove(self);
 640                         return;
 641                 }
 642         }
 643         else
 644         {
 645                 self.reset = Item_Reset;
 646                 // it's a level item
 647                 if(self.spawnflags & 1)
 648                         self.noalign = 1;
 649                 if (self.noalign)
 650                         self.movetype = MOVETYPE_NONE;
 651                 else
 652                         self.movetype = MOVETYPE_TOSS;
 653                 // do item filtering according to game mode and other things
 654                 if (!self.noalign)
 655                 {
 656                         // first nudge it off the floor a little bit to avoid math errors
 657                         setorigin(self, self.origin + '0 0 1');
 658                         // set item size before we spawn a spawnfunc_waypoint
 659                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 660                                 setsize (self, '-16 -16 0', '16 16 48');
 661                         else
 662                                 setsize (self, '-16 -16 0', '16 16 32');
 663                         // note droptofloor returns FALSE if stuck/or would fall too far
 664                         droptofloor();
 665                         waypoint_spawnforitem(self);
 666                 }
 667
 668                 if(teams_matter)
 669                 {
 670                         if(self.notteam)
 671                         {
 672                                 print("removed non-teamplay ", self.classname, "\n");
 673                                 startitem_failed = TRUE;
 674                                 remove (self);
 675                                 return;
 676                         }
 677                 }
 678                 else
 679                 {
 680                         if(self.notfree)
 681                         {
 682                                 print("removed non-FFA ", self.classname, "\n");
 683                                 startitem_failed = TRUE;
 684                                 remove (self);
 685                                 return;
 686                         }
 687                 }
 688
 689                 if(self.notq3a)
 690                 {
 691                         // We aren't TA or something like that, so we keep the Q3A entities
 692                         print("removed non-Q3A ", self.classname, "\n");
 693                         startitem_failed = TRUE;
 694                         remove (self);
 695                         return;
 696                 }
 697
 698                 /*
 699                  * can't do it that way, as it would break maps
 700                  * TODO make a target_give like entity another way, that perhaps has
 701                  * the weapon name in a key
 702                 if(self.targetname)
 703                 {
 704                         // target_give not yet supported; maybe later
 705                         print("removed targeted ", self.classname, "\n");
 706                         startitem_failed = TRUE;
 707                         remove (self);
 708                         return;
 709                 }
 710                 */
 711
 712                 if(cvar("spawn_debug") >= 2)
 713                 {
 714                         entity otheritem;
 715                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 716                         {
 717                                 if(otheritem.is_item)
 718                                 {
 719                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 720                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 721                                         error("Mapper sucks.");
 722                                 }
 723                         }
 724                         self.is_item = TRUE;
 725                 }
 726
 727                 weaponsInMap |= weaponid;
 728
 729                 if(g_lms)
 730                 {
 731                         startitem_failed = TRUE;
 732                         remove(self);
 733                         return;
 734                 }
 735                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 736                 {
 737                         startitem_failed = TRUE;
 738                         remove(self);
 739                         return;
 740                 }
 741                 else if (g_minstagib)
 742                 {
 743                         // don't remove dropped items and powerups
 744                         if (self.classname != "minstagib")
 745                         {
 746                                 startitem_failed = TRUE;
 747                                 remove (self);
 748                                 return;
 749                         }
 750                 }
 751                 else if (g_nixnex)
 752                 {
 753                         local float rm;
 754
 755                         rm = 1;
 756                         switch (itemid)
 757                         {
 758                                 case IT_HEALTH:
 759                                 case IT_5HP:
 760                                 case IT_25HP:
 761                                 case IT_ARMOR:
 762                                 case IT_ARMOR_SHARD:
 763                                         if (cvar("g_nixnex_with_healtharmor"))
 764                                                 rm = 0;
 765                                         break;
 766                                 case IT_STRENGTH:
 767                                 case IT_INVINCIBLE:
 768                                         if (cvar("g_nixnex_with_powerups"))
 769                                                 rm = 0;
 770                                         break;
 771                         }
 772
 773                         if(rm)
 774                         {
 775                                 startitem_failed = TRUE;
 776                                 remove (self);
 777                                 return;
 778                         }
 779                 }
 780                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 781                 {
 782                         startitem_failed = TRUE;
 783                         remove (self);
 784                         return;
 785                 }
 786
 787                 precache_model (itemmodel);
 788                 precache_sound (pickupsound);
 789                 precache_sound ("misc/itemrespawn.wav");
 790                 precache_sound ("misc/itemrespawncountdown.wav");
 791
 792                 if(itemid == IT_STRENGTH)
 793                         precache_sound ("misc/strength_respawn.wav");
 794                 if(itemid == IT_INVINCIBLE)
 795                         precache_sound ("misc/shield_respawn.wav");
 796
 797                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 798                         self.target = "###item###"; // for finding the nearest item using find()
 799         }
 800
 801         self.bot_pickup = TRUE;
 802         self.bot_pickupevalfunc = pickupevalfunc;
 803         self.bot_pickupbasevalue = pickupbasevalue;
 804         self.mdl = itemmodel;
 805         self.item_pickupsound = pickupsound;
 806         // let mappers override respawntime
 807         if(!self.respawntime) // both set
 808         {
 809                 self.respawntime = defaultrespawntime;
 810                 self.respawntimejitter = defaultrespawntimejitter;
 811         }
 812         self.netname = itemname;
 813         self.items = itemid;
 814         self.weapons = weaponid;
 815         self.flags = FL_ITEM | itemflags;
 816         self.touch = Item_Touch;
 817         setmodel (self, self.mdl); // precision set below
 818         self.effects |= EF_LOWPRECISION;
 819         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 820                 setsize (self, '-16 -16 0', '16 16 48');
 821         else
 822                 setsize (self, '-16 -16 0', '16 16 32');
 823         if(itemflags & FL_WEAPON)
 824                 self.modelflags |= MF_ROTATE;
 825
 826         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 827         if (itemflags & FL_WEAPON)
 828         {
 829                 // neutral team color for pickup weapons
 830                 self.colormap = 1024; // color shirt=0 pants=0 grey
 831         }
 832
 833         Item_Show(self, 1);
 834         self.state = 0;
 835         if(self.team)
 836         {
 837                 if(!self.cnt)
 838                         self.cnt = 1; // item probability weight
 839                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 840                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 841         }
 842         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 843                 Item_ScheduleInitialRespawn(self);
 844 }
 845
 846 /* replace items in minstagib
 847  * IT_STRENGTH   = invisibility
 848  * IT_NAILS      = extra lives
 849  * IT_INVINCIBLE = speed
 850  */
 851 void minstagib_items (float itemid)
 852 {
 853         // we don't want to replace dropped weapons ;)
 854         if (self.classname == "droppedweapon")
 855         {
 856                 self.ammo_cells = 25;
 857                 StartItem ("models/weapons/g_nex.md3",
 858                         "weapons/weaponpickup.wav", 15, 0,
 859                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 860                 return;
 861         }
 862
 863         local float rnd;
 864         self.classname = "minstagib";
 865
 866         // replace rocket launchers and nex guns with ammo cells
 867         if (itemid == IT_CELLS)
 868         {
 869                 self.ammo_cells = 1;
 870                 StartItem ("models/items/a_cells.md3",
 871                         "misc/itempickup.wav", 45, 0,
 872                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 873                 return;
 874         }
 875
 876         // randomize
 877         rnd = random() * 3;
 878         if (rnd <= 1)
 879                 itemid = IT_STRENGTH;
 880         else if (rnd <= 2)
 881                 itemid = IT_NAILS;
 882         else
 883                 itemid = IT_INVINCIBLE;
 884
 885         // replace with invis
 886         if (itemid == IT_STRENGTH)
 887         {
 888                 self.strength_finished = 30;
 889                 StartItem ("models/items/g_strength.md3",
 890                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 891                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 892         }
 893         // replace with extra lives
 894         if (itemid == IT_NAILS)
 895         {
 896                 self.max_health = 1;
 897                 StartItem ("models/items/g_h100.md3",
 898                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 899                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 900
 901         }
 902         // replace with speed
 903         if (itemid == IT_INVINCIBLE)
 904         {
 905                 self.invincible_finished = 30;
 906                 StartItem ("models/items/g_invincible.md3",
 907                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 908                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 909         }
 910
 911 }
 912
 913 float minst_no_auto_cells;
 914 void minst_remove_item (void) {
 915         if(minst_no_auto_cells)
 916                 remove(self);
 917 }
 918
 919 float weaponswapping;
 920 float internalteam;
 921
 922 void weapon_defaultspawnfunc(float wpn)
 923 {
 924         entity e;
 925         float t;
 926         var .float ammofield;
 927         string s;
 928         entity oldself;
 929         float i, j;
 930
 931         // set the respawntime in advance (so replaced weapons can copy it)
 932
 933         if(!self.respawntime)
 934         {
 935                 e = get_weaponinfo(wpn);
 936                 if(e.items == IT_SUPERWEAPON)
 937                 {
 938                         self.respawntime = g_pickup_respawntime_powerup;
 939                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 940                 }
 941                 else
 942                 {
 943                         self.respawntime = g_pickup_respawntime_weapon;
 944                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 945                 }
 946         }
 947
 948         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 949         {
 950                 e = get_weaponinfo(wpn);
 951                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 952                 if(s == "0")
 953                 {
 954                         remove(self);
 955                         startitem_failed = TRUE;
 956                         return;
 957                 }
 958                 t = tokenize_console(s);
 959                 if(t >= 2)
 960                 {
 961                         self.team = --internalteam;
 962                         oldself = self;
 963                         for(i = 1; i < t; ++i)
 964                         {
 965                                 s = argv(i);
 966                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 967                                 {
 968                                         e = get_weaponinfo(j);
 969                                         if(e.netname == s)
 970                                         {
 971                                                 self = spawn();
 972                                                 copyentity(oldself, self);
 973                                                 self.classname = "replacedweapon";
 974                                                 weapon_defaultspawnfunc(j);
 975                                                 break;
 976                                         }
 977                                 }
 978                                 if(j > WEP_LAST)
 979                                 {
 980                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 981                                 }
 982                         }
 983                         self = oldself;
 984                 }
 985                 if(t >= 1)
 986                 {
 987                         s = argv(0);
 988                         wpn = 0;
 989                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 990                         {
 991                                 e = get_weaponinfo(j);
 992                                 if(e.netname == s)
 993                                 {
 994                                         wpn = j;
 995                                         break;
 996                                 }
 997                         }
 998                         if(j > WEP_LAST)
 999                         {
1000                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1001                         }
1002                 }
1003                 if(wpn == 0)
1004                 {
1005                         remove(self);
1006                         startitem_failed = TRUE;
1007                         return;
1008                 }
1009         }
1010
1011         e = get_weaponinfo(wpn);
1012
1013         if(e.items && e.items != IT_SUPERWEAPON)
1014         {
1015                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1016                 {
1017                         if(e.items & j)
1018                         {
1019                                 ammofield = Item_CounterField(j);
1020                                 if(!self.ammofield)
1021                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1022                         }
1023                 }
1024         }
1025         else
1026         {
1027                 self.flags |= FL_NO_WEAPON_STAY;
1028         }
1029
1030         // weapon stay isn't supported for teamed weapons
1031         if(self.team)
1032                 self.flags |= FL_NO_WEAPON_STAY;
1033
1034         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1035         {
1036                 self.ammo_shells = 0;
1037                 self.ammo_nails = 0;
1038                 self.ammo_cells = 0;
1039                 self.ammo_rockets = 0;
1040                 // weapon stay 2: don't use ammo on weapon pickups; instead
1041                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1042         }
1043
1044         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1045         if (self.modelindex) // don't precache if self was removed
1046                 weapon_action(e.weapon, WR_PRECACHE);
1047 }
1048
1049 void spawnfunc_weapon_shotgun (void);
1050 void spawnfunc_weapon_uzi (void) {
1051         if(q3acompat_machineshotgunswap)
1052         if(self.classname != "droppedweapon")
1053         {
1054                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1055                 return;
1056         }
1057         weapon_defaultspawnfunc(WEP_UZI);
1058 }
1059
1060 void spawnfunc_weapon_shotgun (void) {
1061         if(q3acompat_machineshotgunswap)
1062         if(self.classname != "droppedweapon")
1063         {
1064                 weapon_defaultspawnfunc(WEP_UZI);
1065                 return;
1066         }
1067         weapon_defaultspawnfunc(WEP_SHOTGUN);
1068 }
1069
1070 void spawnfunc_weapon_nex (void)
1071 {
1072         if (g_minstagib)
1073         {
1074                 minstagib_items(IT_CELLS);
1075                 self.think = minst_remove_item;
1076                 self.nextthink = time;
1077                 return;
1078         }
1079         weapon_defaultspawnfunc(WEP_NEX);
1080 }
1081
1082 void spawnfunc_weapon_minstanex (void)
1083 {
1084         if (g_minstagib)
1085         {
1086                 minstagib_items(IT_CELLS);
1087                 self.think = minst_remove_item;
1088                 self.nextthink = time;
1089                 return;
1090         }
1091         weapon_defaultspawnfunc(WEP_MINSTANEX);
1092 }
1093
1094 void spawnfunc_weapon_rocketlauncher (void)
1095 {
1096         if (g_minstagib)
1097         {
1098                 minstagib_items(IT_CELLS);
1099                 self.think = minst_remove_item;
1100                 self.nextthink = time;
1101                 return;
1102         }
1103         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1104 }
1105
1106 void spawnfunc_item_rockets (void) {
1107         if(!self.ammo_rockets)
1108                 self.ammo_rockets = g_pickup_rockets;
1109         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1110 }
1111
1112 void spawnfunc_item_shells (void);
1113 void spawnfunc_item_bullets (void) {
1114         if(!weaponswapping)
1115         if(q3acompat_machineshotgunswap)
1116         if(self.classname != "droppedweapon")
1117         {
1118                 weaponswapping = TRUE;
1119                 spawnfunc_item_shells();
1120                 weaponswapping = FALSE;
1121                 return;
1122         }
1123
1124         if(!self.ammo_nails)
1125                 self.ammo_nails = g_pickup_nails;
1126         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1127 }
1128
1129 void spawnfunc_item_cells (void) {
1130         if(!self.ammo_cells)
1131                 self.ammo_cells = g_pickup_cells;
1132         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1133 }
1134
1135 void spawnfunc_item_shells (void) {
1136         if(!weaponswapping)
1137         if(q3acompat_machineshotgunswap)
1138         if(self.classname != "droppedweapon")
1139         {
1140                 weaponswapping = TRUE;
1141                 spawnfunc_item_bullets();
1142                 weaponswapping = FALSE;
1143                 return;
1144         }
1145
1146         if(!self.ammo_shells)
1147                 self.ammo_shells = g_pickup_shells;
1148         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1149 }
1150
1151 void spawnfunc_item_armor_small (void) {
1152         if(!self.armorvalue)
1153                 self.armorvalue = g_pickup_armorsmall;
1154         if(!self.max_armorvalue)
1155                 self.max_armorvalue = g_pickup_armorsmall_max;
1156         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1157 }
1158
1159 void spawnfunc_item_armor_medium (void) {
1160         if(!self.armorvalue)
1161                 self.armorvalue = g_pickup_armormedium;
1162         if(!self.max_armorvalue)
1163                 self.max_armorvalue = g_pickup_armormedium_max;
1164         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1165 }
1166
1167 void spawnfunc_item_armor_big (void) {
1168         if(!self.armorvalue)
1169                 self.armorvalue = g_pickup_armorbig;
1170         if(!self.max_armorvalue)
1171                 self.max_armorvalue = g_pickup_armorbig_max;
1172         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1173 }
1174
1175 void spawnfunc_item_armor_large (void) {
1176         if(!self.armorvalue)
1177                 self.armorvalue = g_pickup_armorlarge;
1178         if(!self.max_armorvalue)
1179                 self.max_armorvalue = g_pickup_armorlarge_max;
1180         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1181 }
1182
1183 void spawnfunc_item_health_small (void) {
1184         if(!self.max_health)
1185                 self.max_health = g_pickup_healthsmall_max;
1186         if(!self.health)
1187                 self.health = g_pickup_healthsmall;
1188         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1189 }
1190
1191 void spawnfunc_item_health_medium (void) {
1192         if(!self.max_health)
1193                 self.max_health = g_pickup_healthmedium_max;
1194         if(!self.health)
1195                 self.health = g_pickup_healthmedium;
1196         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1197 }
1198
1199 void spawnfunc_item_health_large (void) {
1200         if(!self.max_health)
1201                 self.max_health = g_pickup_healthlarge_max;
1202         if(!self.health)
1203                 self.health = g_pickup_healthlarge;
1204         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1205 }
1206
1207 void spawnfunc_item_health_mega (void) {
1208         if(!cvar("g_powerup_superhealth"))
1209                 return;
1210
1211         if(g_arena && !cvar("g_arena_powerups"))
1212                 return;
1213
1214         if(g_minstagib) {
1215                 minstagib_items(IT_NAILS);
1216         } else {
1217                 if(!self.max_health)
1218                         self.max_health = g_pickup_healthmega_max;
1219                 if(!self.health)
1220                         self.health = g_pickup_healthmega;
1221                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1222         }
1223 }
1224
1225 // support old misnamed entities
1226 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1227 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1228 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1229 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1230 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1231
1232 void spawnfunc_item_strength (void) {
1233         if(!cvar("g_powerup_strength"))
1234                 return;
1235
1236         if(g_arena && !cvar("g_arena_powerups"))
1237                 return;
1238
1239         if(g_minstagib) {
1240                 minstagib_items(IT_STRENGTH);
1241         } else {
1242                 precache_sound("weapons/strength_fire.wav");
1243                 self.strength_finished = 30;
1244                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1245         }
1246 }
1247
1248 void spawnfunc_item_invincible (void) {
1249         if(!cvar("g_powerup_shield"))
1250                 return;
1251
1252         if(g_arena && !cvar("g_arena_powerups"))
1253                 return;
1254
1255         if(g_minstagib) {
1256                 minstagib_items(IT_INVINCIBLE);
1257         } else {
1258                 self.invincible_finished = 30;
1259                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1260         }
1261 }
1262
1263 void spawnfunc_item_minst_cells (void) {
1264         if (g_minstagib)
1265         {
1266                 minst_no_auto_cells = 1;
1267                 minstagib_items(IT_CELLS);
1268         }
1269         else
1270                 remove(self);
1271 }
1272
1273 // compatibility:
1274 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1275
1276 float target_item_func_set(float a, float b)
1277 {
1278         if(b == 0)
1279                 return a;
1280         else if(b < 0)
1281                 return 0;
1282         else
1283                 return b;
1284 }
1285
1286 float target_item_func_min(float a, float b)
1287 {
1288         if(b == 0)
1289                 return a;
1290         else if(b < 0)
1291                 return 0;
1292         else
1293                 return min(a, b);
1294 }
1295
1296 float target_item_func_max(float a, float b)
1297 {
1298         return max(a, b);
1299 }
1300
1301 float target_item_func_bitset(float a, float b)
1302 {
1303         return b;
1304 }
1305
1306 float target_item_func_and(float a, float b)
1307 {
1308         return a & b;
1309 }
1310
1311 float target_item_func_itembitset(float a, float b)
1312 {
1313         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1314 }
1315
1316 float target_item_func_itemand(float a, float b)
1317 {
1318         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1319 }
1320
1321 float target_item_func_or(float a, float b)
1322 {
1323         return a | b;
1324 }
1325
1326 float target_item_func_andnot(float a, float b)
1327 {
1328         return a - (a & b);
1329 }
1330
1331 float target_item_changed;
1332 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1333 {
1334         float n, d;
1335         n = func(activator.field, self.field);
1336
1337         if(binary)
1338         {
1339                 d = n & activator.field;
1340                 if(d != n) // bits added?
1341                         d = +1;
1342                 else if(d != activator.field) // bits removed?
1343                         d = -1;
1344                 else
1345                         d = 0;
1346         }
1347         else
1348                 d = n - activator.field;
1349
1350         if(d < 0)
1351         {
1352                 if(sound_decrease != "")
1353                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1354                 target_item_changed = 1;
1355         }
1356         else if(d > 0)
1357         {
1358                 if(sound_increase != "")
1359                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1360                 target_item_changed = 1;
1361         }
1362         activator.field = n;
1363 }
1364
1365 void target_items_use (void)
1366 {
1367         float h0, a0, f0;
1368
1369         if(activator.classname == "droppedweapon")
1370         {
1371                 EXACTTRIGGER_TOUCH;
1372                 remove(activator);
1373                 return;
1374         }
1375
1376         if(activator.classname != "player")
1377                 return;
1378         if(activator.deadflag != DEAD_NO)
1379                 return;
1380         EXACTTRIGGER_TOUCH;
1381
1382         entity e;
1383         for(e = world; (e = find(e, classname, "droppedweapon")); )
1384                 if(e.enemy == activator)
1385                         remove(e);
1386
1387         float _switchweapon;
1388         _switchweapon = FALSE;
1389         if (activator.autoswitch)
1390                 if (activator.switchweapon == w_getbestweapon(activator))
1391                         _switchweapon = TRUE;
1392
1393         a0 = activator.armorvalue;
1394         h0 = activator.health;
1395         f0 = activator.ammo_fuel;
1396         target_item_changed = 0;
1397
1398         if(self.spawnflags == 0) // SET
1399         {
1400                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1401                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1402                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1403                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1404                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1405                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1406                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1407                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1408                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1409
1410                 if((self.items & activator.items) & IT_STRENGTH)
1411                         activator.strength_finished = time + self.strength_finished;
1412                 if((self.items & activator.items) & IT_INVINCIBLE)
1413                         activator.invincible_finished = time + self.invincible_finished;
1414         }
1415         else if(self.spawnflags == 1) // AND/MIN
1416         {
1417                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1418                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1419                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1420                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1421                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1422                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1423                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1424                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1425                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1426
1427                 if((self.items & activator.items) & IT_STRENGTH)
1428                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1429                 if((self.items & activator.items) & IT_INVINCIBLE)
1430                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1431         }
1432         else if(self.spawnflags == 2) // OR/MAX
1433         {
1434                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1435                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1436                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1437                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1438                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1439                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1440                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1441                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1442                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1443
1444                 if((self.items & activator.items) & IT_STRENGTH)
1445                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1446                 if((self.items & activator.items) & IT_INVINCIBLE)
1447                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1448         }
1449         else if(self.spawnflags == 4) // ANDNOT/MIN
1450         {
1451                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1452                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1453                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1454                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1455                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1456                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1457                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1458                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1459                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1460
1461                 if((self.items & activator.items) & IT_STRENGTH)
1462                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1463                 if((self.items & activator.items) & IT_INVINCIBLE)
1464                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1465         }
1466
1467         if not(activator.items & IT_STRENGTH)
1468                 activator.strength_finished = 0;
1469         if not(activator.items & IT_INVINCIBLE)
1470                 activator.invincible_finished = 0;
1471
1472         if(activator.health > h0)
1473                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1474         else if(activator.health < h0)
1475                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1476
1477         if(activator.ammo_fuel > f0)
1478                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1479         else if(activator.ammo_fuel < f0)
1480                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1481
1482         if(activator.armorvalue > a0)
1483                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1484
1485         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1486                 _switchweapon = TRUE;
1487         if(_switchweapon)
1488                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1489
1490         if(target_item_changed)
1491                 centerprint(activator, self.message);
1492 }
1493
1494 void spawnfunc_target_items (void)
1495 {
1496         float n, i, j;
1497         entity e;
1498
1499         if(g_nixnex)
1500         {
1501                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1502                 remove(self);
1503                 return;
1504         }
1505
1506         self.use = target_items_use;
1507         if(!self.strength_finished)
1508                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1509         if(!self.invincible_finished)
1510                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1511
1512         precache_sound("misc/itempickup.wav");
1513         precache_sound("misc/itempickup.wav");
1514         precache_sound("misc/itempickup.wav");
1515         precache_sound("misc/itempickup.wav");
1516         precache_sound("misc/megahealth.wav");
1517         precache_sound("misc/armor25.wav");
1518         precache_sound("misc/powerup.wav");
1519         precache_sound("misc/poweroff.wav");
1520         precache_sound("weapons/weaponpickup.wav");
1521
1522         n = tokenize_console(self.netname);
1523         for(i = 0; i < n; ++i)
1524         {
1525                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1526                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1527                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1528                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1529                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1530                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1531                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1532                 else
1533                 {
1534                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1535                         {
1536                                 e = get_weaponinfo(j);
1537                                 if(argv(i) == e.netname)
1538                                 {
1539                                         self.weapons |= e.weapons;
1540                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1541                                                 weapon_action(e.weapon, WR_PRECACHE);
1542                                         break;
1543                                 }
1544                         }
1545                         if(j > WEP_LAST)
1546                                 print("target_items: invalid item ", argv(i), "\n");
1547                 }
1548         }
1549 }
1550
1551 void spawnfunc_item_fuel(void)
1552 {
1553         if(!self.ammo_fuel)
1554                 self.ammo_fuel = g_pickup_fuel;
1555         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1556 }
1557
1558 void spawnfunc_item_fuel_regen(void)
1559 {
1560         if(start_items & IT_FUEL_REGEN)
1561         {
1562                 spawnfunc_item_fuel();
1563                 return;
1564         }
1565         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1566 }
1567
1568 void spawnfunc_item_jetpack(void)
1569 {
1570         if(g_grappling_hook)
1571                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1572         if(!self.ammo_fuel)
1573                 self.ammo_fuel = g_pickup_fuel_jetpack;
1574         if(start_items & IT_JETPACK)
1575         {
1576                 spawnfunc_item_fuel();
1577                 return;
1578         }
1579         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1580 }
1581
1582 // we no longer have the seeker
1583 void spawnfunc_weapon_seeker()
1584 {
1585         spawnfunc_weapon_rocketlauncher();
1586 }