data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   2         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   3 #define ITEM_RESPAWNTIME_INITIAL(i) (10 + random() * ((i).respawntime + (i).respawntimejitter - 10))
   4         // range: 10 .. respawntime + respawntimejitter
   5
   6 floatfield Item_CounterField(float it)
   7 {
   8         switch(it)
   9         {
  10                 case IT_SHELLS:      return ammo_shells;
  11                 case IT_NAILS:       return ammo_nails;
  12                 case IT_ROCKETS:     return ammo_rockets;
  13                 case IT_CELLS:       return ammo_cells;
  14                 case IT_FUEL:        return ammo_fuel;
  15                 case IT_5HP:         return health;
  16                 case IT_25HP:        return health;
  17                 case IT_HEALTH:      return health;
  18                 case IT_ARMOR_SHARD: return armorvalue;
  19                 case IT_ARMOR:       return armorvalue;
  20                 // add more things here (health, armor)
  21                 default:             error("requested item has no counter field");
  22         }
  23 }
  24
  25 string Item_CounterFieldName(float it)
  26 {
  27         switch(it)
  28         {
  29                 case IT_SHELLS:      return "shells";
  30                 case IT_NAILS:       return "nails";
  31                 case IT_ROCKETS:     return "rockets";
  32                 case IT_CELLS:       return "cells";
  33                 case IT_FUEL:        return "fuel";
  34
  35                 // add more things here (health, armor)
  36                 default:             error("requested item has no counter field name");
  37         }
  38 }
  39
  40 .float max_armorvalue;
  41
  42 void Item_Respawn (void)
  43 {
  44         self.model = self.mdl;          // restore original model
  45         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  46         sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  47         setorigin (self, self.origin);
  48
  49         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  50         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  51 }
  52
  53 void Item_RespawnCountdown (void)
  54 {
  55         if(self.count >= 5)
  56         {
  57                 if(self.waypointsprite_attached)
  58                         WaypointSprite_Kill(self.waypointsprite_attached);
  59                 Item_Respawn();
  60         }
  61         else
  62         {
  63                 self.nextthink = time + 1;
  64                 self.count += 1;
  65                 if(self.count == 1)
  66                 {
  67                         string name;
  68                         vector rgb;
  69                         name = string_null;
  70                         if(g_minstagib)
  71                         {
  72                                 switch(self.items)
  73                                 {
  74                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  75                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  76                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  77                                 }
  78                         }
  79                         else
  80                         {
  81                                 switch(self.items)
  82                                 {
  83                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  84                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  85                                 }
  86                         }
  87                         switch(self.items)
  88                         {
  89                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  90                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  91                         }
  92                         if(name)
  93                         {
  94                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, FALSE);
  95                                 if(self.waypointsprite_attached)
  96                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
  97                         }
  98                 }
  99                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 100                 if(self.waypointsprite_attached)
 101                         WaypointSprite_Ping(self.waypointsprite_attached);
 102         }
 103 }
 104
 105 void Item_ScheduleRespawnIn(entity e, float t)
 106 {
 107         if(e.flags & FL_POWERUP)
 108         {
 109                 e.think = Item_RespawnCountdown;
 110                 e.nextthink = time + max(0, t - 5);
 111                 e.count = 0;
 112         }
 113         else
 114         {
 115                 e.think = Item_Respawn;
 116                 e.nextthink = time + t;
 117         }
 118 }
 119
 120 void Item_ScheduleRespawn(entity e)
 121 {
 122         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 123 }
 124
 125 void Item_ScheduleInitialRespawn(entity e)
 126 {
 127         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 128 }
 129
 130 float Item_GiveTo(entity item, entity player)
 131 {
 132         float _switchweapon;
 133         float pickedup;
 134         float it;
 135         float i;
 136         entity e;
 137
 138         // if nothing happens to player, just return without taking the item
 139         pickedup = FALSE;
 140         _switchweapon = FALSE;
 141
 142         if (g_minstagib)
 143         {
 144                 if (item.ammo_fuel)
 145                 if (player.ammo_fuel < g_pickup_fuel_max)
 146                 {
 147                         pickedup = TRUE;
 148                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 149                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 150                 }
 151                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 152                 {
 153                         pickedup = TRUE;
 154                         player.items |= it;
 155                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 156                 }
 157
 158                 _switchweapon = TRUE;
 159                 if (item.ammo_cells)
 160                 {
 161                         pickedup = TRUE;
 162                         // play some cool sounds ;)
 163                         centerprint(player, "\n");
 164                         if(player.health <= 5)
 165                                 announce(player, "announcer/robotic/lastsecond.wav");
 166                         else if(player.health < 50)
 167                                 announce(player, "announcer/robotic/narrowly.wav");
 168                         // sound not available
 169                         // else if(item.items == IT_CELLS)
 170                         //      play2(player, "announce/robotic/ammo.wav");
 171
 172                         if (item.weapons & WEPBIT_MINSTANEX)
 173                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 174                         if (item.ammo_cells)
 175                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 176                         player.health = 100;
 177                 }
 178
 179                 // extralife powerup
 180                 if (item.max_health)
 181                 {
 182                         pickedup = TRUE;
 183                         // sound not available
 184                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 185                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 186                         sprint(player, "^3You picked up some extra lives\n");
 187                 }
 188
 189                 // invis powerup
 190                 if (item.strength_finished)
 191                 {
 192                         pickedup = TRUE;
 193                         // sound not available
 194                         // play2(player, "announce/robotic/invisible.wav");
 195                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 196                 }
 197
 198                 // speed powerup
 199                 if (item.invincible_finished)
 200                 {
 201                         pickedup = TRUE;
 202                         // sound not available
 203                         // play2(player, "announce/robotic/speed.wav");
 204                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 205                 }
 206
 207                 if (item.ammo_fuel)
 208                 if (player.ammo_fuel < g_pickup_fuel_max)
 209                 {
 210                         pickedup = TRUE;
 211                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 212                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 213                 }
 214
 215         }
 216         else
 217         {
 218                 if (g_weapon_stay == 1)
 219                 if not(item.flags & FL_NO_WEAPON_STAY)
 220                 if (item.flags & FL_WEAPON)
 221                 {
 222                         if(item.classname == "droppedweapon")
 223                         {
 224                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 225                                         goto skip;
 226                         }
 227                         else
 228                         {
 229                                 if (player.weapons & item.weapons)
 230                                         goto skip;
 231                         }
 232                 }
 233
 234                 // in case the player has autoswitch enabled do the following:
 235                 // if the player is using their best weapon before items are given, they
 236                 // probably want to switch to an even better weapon after items are given
 237                 if (player.autoswitch)
 238                 if (player.switchweapon == w_getbestweapon(player))
 239                         _switchweapon = TRUE;
 240
 241                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 242                         _switchweapon = TRUE;
 243
 244                 if (item.ammo_shells)
 245                 if (player.ammo_shells < g_pickup_shells_max)
 246                 {
 247                         pickedup = TRUE;
 248                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 249                 }
 250                 if (item.ammo_nails)
 251                 if (player.ammo_nails < g_pickup_nails_max)
 252                 {
 253                         pickedup = TRUE;
 254                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 255                 }
 256                 if (item.ammo_rockets)
 257                 if (player.ammo_rockets < g_pickup_rockets_max)
 258                 {
 259                         pickedup = TRUE;
 260                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 261                 }
 262                 if (item.ammo_cells)
 263                 if (player.ammo_cells < g_pickup_cells_max)
 264                 {
 265                         pickedup = TRUE;
 266                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 267                 }
 268                 if (item.ammo_fuel)
 269                 if (player.ammo_fuel < g_pickup_fuel_max)
 270                 {
 271                         pickedup = TRUE;
 272                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 273                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 274                 }
 275
 276                 if (item.flags & FL_WEAPON)
 277                 if ((it = item.weapons - (item.weapons & player.weapons)))
 278                 {
 279                         pickedup = TRUE;
 280                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 281                         {
 282                                 e = get_weaponinfo(i);
 283                                 if(it & e.weapons)
 284                                         W_GiveWeapon (player, e.weapon, item.netname);
 285                         }
 286                 }
 287
 288                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 289                 {
 290                         pickedup = TRUE;
 291                         player.items |= it;
 292                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 293                 }
 294
 295                 if (item.strength_finished)
 296                 {
 297                         pickedup = TRUE;
 298                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 299                 }
 300                 if (item.invincible_finished)
 301                 {
 302                         pickedup = TRUE;
 303                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 304                 }
 305                 //if (item.speed_finished)
 306                 //{
 307                 //      pickedup = TRUE;
 308                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 309                 //}
 310                 //if (item.slowmo_finished)
 311                 //{
 312                 //      pickedup = TRUE;
 313                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 314                 //}
 315
 316                 if (item.health)
 317                 if (player.health < item.max_health)
 318                 {
 319                         pickedup = TRUE;
 320                         player.health = min(player.health + item.health, item.max_health);
 321                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 322                 }
 323                 if (item.armorvalue)
 324                 if (player.armorvalue < item.max_armorvalue)
 325                 {
 326                         pickedup = TRUE;
 327                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 328                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 329                 }
 330         }
 331
 332 :skip
 333         // always eat teamed entities
 334         if(item.team)
 335                 pickedup = TRUE;
 336
 337         if (!pickedup)
 338                 return 0;
 339
 340         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 341         if (_switchweapon)
 342                 if (player.switchweapon != w_getbestweapon(player))
 343                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 344
 345         return 1;
 346 }
 347
 348 void Item_Touch (void)
 349 {
 350         entity e, head;
 351
 352         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 353         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 354         {
 355                 remove(self);
 356                 return;
 357         }
 358         if (other.classname != "player")
 359                 return;
 360         if (other.deadflag)
 361                 return;
 362         if (self.solid != SOLID_TRIGGER)
 363                 return;
 364         if (self.owner == other)
 365                 return;
 366
 367         if(!Item_GiveTo(self, other))
 368                 return;
 369
 370         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 371
 372         if (self.classname == "droppedweapon")
 373                 remove (self);
 374         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 375                 return;
 376         else
 377         {
 378                 self.solid = SOLID_NOT;
 379                 self.model = string_null;
 380                 if(self.team)
 381                 {
 382                         RandomSelection_Init();
 383                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 384                                 RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 385                         e = RandomSelection_chosen_ent;
 386                 }
 387                 else
 388                         e = self;
 389                 Item_ScheduleRespawn(e);
 390         }
 391 }
 392
 393 void Item_FindTeam()
 394 {
 395         entity head, e;
 396
 397         if(self.effects & EF_NODRAW)
 398         {
 399                 // marker for item team search
 400                 dprint("Initializing item team ", ftos(self.team), "\n");
 401                 RandomSelection_Init();
 402                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 403                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 404                 e = RandomSelection_chosen_ent;
 405                 e.state = 0;
 406
 407                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 408                 {
 409                         if(head != e)
 410                         {
 411                                 // make it a non-spawned item
 412                                 head.solid = SOLID_NOT;
 413                                 head.model = string_null;
 414                                 head.state = 1; // state 1 = initially hidden item
 415                         }
 416                         head.effects &~= EF_NODRAW;
 417                 }
 418
 419                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 420                 {
 421                         e.solid = SOLID_NOT;
 422                         e.model = string_null;
 423                         Item_ScheduleInitialRespawn(e);
 424                 }
 425         }
 426 }
 427
 428 void Item_Reset()
 429 {
 430         if(self.state == 1)
 431         {
 432                 self.model = string_null;
 433                 self.solid = SOLID_NOT;
 434         }
 435         else
 436         {
 437                 self.model = self.mdl;
 438                 self.solid = SOLID_TRIGGER;
 439         }
 440         setorigin (self, self.origin);
 441         self.think = SUB_Null;
 442         self.nextthink = 0;
 443
 444         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 445         {
 446                 self.solid = SOLID_NOT;
 447                 self.model = string_null;
 448                 Item_ScheduleInitialRespawn(self);
 449         }
 450 }
 451
 452 // Savage: used for item garbage-collection
 453 // TODO: perhaps nice special effect?
 454 void RemoveItem(void)
 455 {
 456         remove(self);
 457 }
 458
 459 // pickup evaluation functions
 460 // these functions decide how desirable an item is to the bots
 461
 462 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 463
 464 float weapon_pickupevalfunc(entity player, entity item)
 465 {
 466         // if we already have the weapon, rate it 1/5th normal value
 467         if ((player.weapons & item.weapons) == item.weapons)
 468                 return item.bot_pickupbasevalue * 0.2;
 469         return item.bot_pickupbasevalue;
 470 };
 471
 472 float commodity_pickupevalfunc(entity player, entity item)
 473 {
 474         float c;
 475         c = 0;
 476         // TODO: figure out if the player even has the weapon this ammo is for?
 477         // may not affect strategy much though...
 478         // find out how much more ammo/armor/health the player can hold
 479         if (item.ammo_shells)
 480         if (player.ammo_shells < g_pickup_shells_max)
 481                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 482         if (item.ammo_nails)
 483         if (player.ammo_nails < g_pickup_nails_max)
 484                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 485         if (item.ammo_rockets)
 486         if (player.ammo_rockets < g_pickup_rockets_max)
 487                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 488         if (item.ammo_cells)
 489         if (player.ammo_cells < g_pickup_cells_max)
 490                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 491         if (item.armorvalue)
 492         if (player.armorvalue < item.max_armorvalue)
 493                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 494         if (item.health)
 495         if (player.health < item.max_health)
 496                 c = c + max(0, 1 - player.health / item.max_health);
 497
 498         return item.bot_pickupbasevalue * c;
 499 };
 500
 501
 502 .float is_item;
 503 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 504 {
 505         startitem_failed = FALSE;
 506
 507         // is it a dropped weapon?
 508         if (self.classname == "droppedweapon")
 509         {
 510                 self.reset = SUB_Remove;
 511                 // it's a dropped weapon
 512                 self.movetype = MOVETYPE_TOSS;
 513                 self.solid = SOLID_TRIGGER;
 514                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 515                 self.think = RemoveItem;
 516                 self.nextthink = time + 60;
 517                 // don't drop if in a NODROP zone (such as lava)
 518                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 519                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 520                 {
 521                         startitem_failed = TRUE;
 522                         remove(self);
 523                         return;
 524                 }
 525         }
 526         else
 527         {
 528                 self.reset = Item_Reset;
 529                 // it's a level item
 530                 if(self.spawnflags & 1)
 531                         self.noalign = 1;
 532                 if (self.noalign)
 533                         self.movetype = MOVETYPE_NONE;
 534                 else
 535                         self.movetype = MOVETYPE_TOSS;
 536                 self.solid = SOLID_TRIGGER;
 537                 // do item filtering according to game mode and other things
 538                 if (!self.noalign)
 539                 {
 540                         // first nudge it off the floor a little bit to avoid math errors
 541                         setorigin(self, self.origin + '0 0 1');
 542                         // set item size before we spawn a spawnfunc_waypoint
 543                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 544                                 setsize (self, '-16 -16 0', '16 16 48');
 545                         else
 546                                 setsize (self, '-16 -16 0', '16 16 32');
 547                         // note droptofloor returns FALSE if stuck/or would fall too far
 548                         droptofloor();
 549                         waypoint_spawnforitem(self);
 550                 }
 551
 552                 if(teams_matter)
 553                 {
 554                         if(self.notteam)
 555                         {
 556                                 print("removed non-teamplay ", self.classname, "\n");
 557                                 startitem_failed = TRUE;
 558                                 remove (self);
 559                                 return;
 560                         }
 561                 }
 562                 else
 563                 {
 564                         if(self.notfree)
 565                         {
 566                                 print("removed non-FFA ", self.classname, "\n");
 567                                 startitem_failed = TRUE;
 568                                 remove (self);
 569                                 return;
 570                         }
 571                 }
 572
 573                 if(self.notq3a)
 574                 {
 575                         // We aren't TA or something like that, so we keep the Q3A entities
 576                         print("removed non-Q3A ", self.classname, "\n");
 577                         startitem_failed = TRUE;
 578                         remove (self);
 579                         return;
 580                 }
 581
 582                 /*
 583                  * can't do it that way, as it would break maps
 584                  * TODO make a target_give like entity another way, that perhaps has
 585                  * the weapon name in a key
 586                 if(self.targetname)
 587                 {
 588                         // target_give not yet supported; maybe later
 589                         print("removed targeted ", self.classname, "\n");
 590                         startitem_failed = TRUE;
 591                         remove (self);
 592                         return;
 593                 }
 594                 */
 595
 596                 if(cvar("spawn_debug") >= 2)
 597                 {
 598                         entity otheritem;
 599                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 600                         {
 601                                 if(otheritem.is_item)
 602                                 {
 603                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 604                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 605                                         error("Mapper sucks.");
 606                                 }
 607                         }
 608                         self.is_item = TRUE;
 609                 }
 610
 611                 weaponsInMap |= weaponid;
 612
 613                 if(g_lms)
 614                 {
 615                         startitem_failed = TRUE;
 616                         remove(self);
 617                         return;
 618                 }
 619                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 620                 {
 621                         startitem_failed = TRUE;
 622                         remove(self);
 623                         return;
 624                 }
 625                 else if (g_minstagib)
 626                 {
 627                         // don't remove dropped items and powerups
 628                         if (self.classname != "minstagib")
 629                         {
 630                                 startitem_failed = TRUE;
 631                                 remove (self);
 632                                 return;
 633                         }
 634                 }
 635                 else if ((!cvar("g_pickup_items") || g_nixnex) && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 636                 {
 637                         startitem_failed = TRUE;
 638                         remove (self);
 639                         return;
 640                 }
 641
 642                 precache_model (itemmodel);
 643                 precache_sound (pickupsound);
 644                 precache_sound ("misc/itemrespawn.wav");
 645                 precache_sound ("misc/itemrespawncountdown.wav");
 646
 647                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 648                         self.target = "###item###"; // for finding the nearest item using find()
 649         }
 650
 651         self.bot_pickup = TRUE;
 652         self.bot_pickupevalfunc = pickupevalfunc;
 653         self.bot_pickupbasevalue = pickupbasevalue;
 654         self.mdl = itemmodel;
 655         self.item_pickupsound = pickupsound;
 656         // let mappers override respawntime
 657         if(!self.respawntime) // both set
 658         {
 659                 self.respawntime = defaultrespawntime;
 660                 self.respawntimejitter = defaultrespawntimejitter;
 661         }
 662         self.netname = itemname;
 663         self.items = itemid;
 664         self.weapons = weaponid;
 665         self.flags = FL_ITEM | itemflags;
 666         self.touch = Item_Touch;
 667         setmodel (self, self.mdl); // precision set below
 668         self.effects |= EF_LOWPRECISION;
 669         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 670                 setsize (self, '-16 -16 0', '16 16 48');
 671         else
 672                 setsize (self, '-16 -16 0', '16 16 32');
 673         if(itemflags & FL_WEAPON)
 674                 self.modelflags |= MF_ROTATE;
 675
 676         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 677         if (itemflags & FL_WEAPON)
 678         {
 679                 // neutral team color for pickup weapons
 680                 self.colormap = 1024; // color shirt=0 pants=0 grey
 681         }
 682
 683         if (cvar("g_fullbrightitems"))
 684                 self.effects = self.effects | EF_FULLBRIGHT;
 685
 686         self.state = 0;
 687         if(self.team)
 688         {
 689                 if(!self.cnt)
 690                         self.cnt = 1; // item probability weight
 691                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 692                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 693         }
 694         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 695         {
 696                 self.solid = SOLID_NOT;
 697                 self.model = string_null;
 698                 Item_ScheduleInitialRespawn(self);
 699         }
 700 }
 701
 702 /* replace items in minstagib
 703  * IT_STRENGTH   = invisibility
 704  * IT_NAILS      = extra lives
 705  * IT_INVINCIBLE = speed
 706  */
 707 void minstagib_items (float itemid)
 708 {
 709         // we don't want to replace dropped weapons ;)
 710         if (self.classname == "droppedweapon")
 711         {
 712                 self.ammo_cells = 25;
 713                 StartItem ("models/weapons/g_nex.md3",
 714                         "weapons/weaponpickup.wav", 15, 0,
 715                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 716                 return;
 717         }
 718
 719         local float rnd;
 720         self.classname = "minstagib";
 721
 722         // replace rocket launchers and nex guns with ammo cells
 723         if (itemid == IT_CELLS)
 724         {
 725                 self.ammo_cells = 1;
 726                 StartItem ("models/items/a_cells.md3",
 727                         "misc/itempickup.wav", 45, 0,
 728                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 729                 return;
 730         }
 731
 732         // randomize
 733         rnd = random() * 3;
 734         if (rnd <= 1)
 735                 itemid = IT_STRENGTH;
 736         else if (rnd <= 2)
 737                 itemid = IT_NAILS;
 738         else
 739                 itemid = IT_INVINCIBLE;
 740
 741         // replace with invis
 742         if (itemid == IT_STRENGTH)
 743         {
 744                 self.effects = EF_ADDITIVE;
 745                 self.strength_finished = 30;
 746                 StartItem ("models/items/g_strength.md3",
 747                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 748                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 749         }
 750         // replace with extra lives
 751         if (itemid == IT_NAILS)
 752         {
 753                 self.max_health = 1;
 754                 StartItem ("models/items/g_h100.md3",
 755                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 756                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 757
 758         }
 759         // replace with speed
 760         if (itemid == IT_INVINCIBLE)
 761         {
 762                 self.effects = EF_ADDITIVE;
 763                 self.invincible_finished = 30;
 764                 StartItem ("models/items/g_invincible.md3",
 765                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 766                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 767         }
 768
 769 }
 770
 771 float minst_no_auto_cells;
 772 void minst_remove_item (void) {
 773         if(minst_no_auto_cells)
 774                 remove(self);
 775 }
 776
 777 float weaponswapping;
 778 float internalteam;
 779
 780 void weapon_defaultspawnfunc(float wpn)
 781 {
 782         entity e;
 783         float t;
 784         var .float ammofield;
 785         string s;
 786         entity oldself;
 787         float i, j;
 788
 789         // set the respawntime in advance (so replaced weapons can copy it)
 790
 791         if(!self.respawntime)
 792         {
 793                 e = get_weaponinfo(wpn);
 794                 if(e.items == IT_SUPERWEAPON)
 795                 {
 796                         self.respawntime = g_pickup_respawntime_powerup;
 797                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 798                 }
 799                 else
 800                 {
 801                         self.respawntime = g_pickup_respawntime_weapon;
 802                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 803                 }
 804         }
 805
 806         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 807         {
 808                 e = get_weaponinfo(wpn);
 809                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 810                 if(s == "0")
 811                 {
 812                         remove(self);
 813                         startitem_failed = TRUE;
 814                         return;
 815                 }
 816                 t = tokenize_console(s);
 817                 if(t >= 2)
 818                 {
 819                         self.team = --internalteam;
 820                         oldself = self;
 821                         for(i = 1; i < t; ++i)
 822                         {
 823                                 s = argv(i);
 824                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 825                                 {
 826                                         e = get_weaponinfo(j);
 827                                         if(e.netname == s)
 828                                         {
 829                                                 self = spawn();
 830                                                 copyentity(oldself, self);
 831                                                 self.classname = "replacedweapon";
 832                                                 weapon_defaultspawnfunc(j);
 833                                                 break;
 834                                         }
 835                                 }
 836                                 if(j > WEP_LAST)
 837                                 {
 838                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 839                                 }
 840                         }
 841                         self = oldself;
 842                 }
 843                 if(t >= 1)
 844                 {
 845                         s = argv(0);
 846                         wpn = 0;
 847                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 848                         {
 849                                 e = get_weaponinfo(j);
 850                                 if(e.netname == s)
 851                                 {
 852                                         wpn = j;
 853                                         break;
 854                                 }
 855                         }
 856                         if(j > WEP_LAST)
 857                         {
 858                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 859                         }
 860                 }
 861                 if(wpn == 0)
 862                 {
 863                         remove(self);
 864                         startitem_failed = TRUE;
 865                         return;
 866                 }
 867         }
 868
 869         e = get_weaponinfo(wpn);
 870
 871         if(e.items && e.items != IT_SUPERWEAPON)
 872         {
 873                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 874                 {
 875                         if(e.items & j)
 876                         {
 877                                 ammofield = Item_CounterField(j);
 878                                 if(!self.ammofield)
 879                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
 880                         }
 881                 }
 882         }
 883         else
 884         {
 885                 self.flags |= FL_NO_WEAPON_STAY;
 886         }
 887
 888         // weapon stay isn't supported for teamed weapons
 889         if(self.team)
 890                 self.flags |= FL_NO_WEAPON_STAY;
 891
 892         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
 893         {
 894                 self.ammo_shells = 0;
 895                 self.ammo_nails = 0;
 896                 self.ammo_cells = 0;
 897                 self.ammo_rockets = 0;
 898                 // weapon stay 2: don't use ammo on weapon pickups; instead
 899                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
 900         }
 901
 902         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
 903         if (self.modelindex) // don't precache if self was removed
 904                 weapon_action(e.weapon, WR_PRECACHE);
 905 }
 906
 907 void spawnfunc_weapon_shotgun (void);
 908 void spawnfunc_weapon_uzi (void) {
 909         if(q3acompat_machineshotgunswap)
 910         if(self.classname != "droppedweapon")
 911         {
 912                 weapon_defaultspawnfunc(WEP_SHOTGUN);
 913                 return;
 914         }
 915         weapon_defaultspawnfunc(WEP_UZI);
 916 }
 917
 918 void spawnfunc_weapon_shotgun (void) {
 919         if(q3acompat_machineshotgunswap)
 920         if(self.classname != "droppedweapon")
 921         {
 922                 weapon_defaultspawnfunc(WEP_UZI);
 923                 return;
 924         }
 925         weapon_defaultspawnfunc(WEP_SHOTGUN);
 926 }
 927
 928 void spawnfunc_weapon_nex (void)
 929 {
 930         if (g_minstagib)
 931         {
 932                 minstagib_items(IT_CELLS);
 933                 self.think = minst_remove_item;
 934                 self.nextthink = time;
 935                 return;
 936         }
 937         weapon_defaultspawnfunc(WEP_NEX);
 938 }
 939
 940 void spawnfunc_weapon_minstanex (void)
 941 {
 942         if (g_minstagib)
 943         {
 944                 minstagib_items(IT_CELLS);
 945                 self.think = minst_remove_item;
 946                 self.nextthink = time;
 947                 return;
 948         }
 949         weapon_defaultspawnfunc(WEP_MINSTANEX);
 950 }
 951
 952 void spawnfunc_weapon_rocketlauncher (void)
 953 {
 954         if (g_minstagib)
 955         {
 956                 minstagib_items(IT_CELLS);
 957                 self.think = minst_remove_item;
 958                 self.nextthink = time;
 959                 return;
 960         }
 961         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
 962 }
 963
 964 void spawnfunc_item_rockets (void) {
 965         if(!self.ammo_rockets)
 966                 self.ammo_rockets = g_pickup_rockets;
 967         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
 968 }
 969
 970 void spawnfunc_item_shells (void);
 971 void spawnfunc_item_bullets (void) {
 972         if(!weaponswapping)
 973         if(q3acompat_machineshotgunswap)
 974         if(self.classname != "droppedweapon")
 975         {
 976                 weaponswapping = TRUE;
 977                 spawnfunc_item_shells();
 978                 weaponswapping = FALSE;
 979                 return;
 980         }
 981
 982         if(!self.ammo_nails)
 983                 self.ammo_nails = g_pickup_nails;
 984         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
 985 }
 986
 987 void spawnfunc_item_cells (void) {
 988         if(!self.ammo_cells)
 989                 self.ammo_cells = g_pickup_cells;
 990         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
 991 }
 992
 993 void spawnfunc_item_shells (void) {
 994         if(!weaponswapping)
 995         if(q3acompat_machineshotgunswap)
 996         if(self.classname != "droppedweapon")
 997         {
 998                 weaponswapping = TRUE;
 999                 spawnfunc_item_bullets();
1000                 weaponswapping = FALSE;
1001                 return;
1002         }
1003
1004         if(!self.ammo_shells)
1005                 self.ammo_shells = g_pickup_shells;
1006         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1007 }
1008
1009 void spawnfunc_item_armor_small (void) {
1010         if(!self.armorvalue)
1011                 self.armorvalue = g_pickup_armorsmall;
1012         if(!self.max_armorvalue)
1013                 self.max_armorvalue = g_pickup_armorsmall_max;
1014         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1015 }
1016
1017 void spawnfunc_item_armor_medium (void) {
1018         if(!self.armorvalue)
1019                 self.armorvalue = g_pickup_armormedium;
1020         if(!self.max_armorvalue)
1021                 self.max_armorvalue = g_pickup_armormedium_max;
1022         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1023 }
1024
1025 void spawnfunc_item_armor_big (void) {
1026         if(!self.armorvalue)
1027                 self.armorvalue = g_pickup_armorbig;
1028         if(!self.max_armorvalue)
1029                 self.max_armorvalue = g_pickup_armorbig_max;
1030         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1031 }
1032
1033 void spawnfunc_item_armor_large (void) {
1034         if(!self.armorvalue)
1035                 self.armorvalue = g_pickup_armorlarge;
1036         if(!self.max_armorvalue)
1037                 self.max_armorvalue = g_pickup_armorlarge_max;
1038         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1039 }
1040
1041 void spawnfunc_item_health_small (void) {
1042         if(!self.max_health)
1043                 self.max_health = g_pickup_healthsmall_max;
1044         if(!self.health)
1045                 self.health = g_pickup_healthsmall;
1046         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1047 }
1048
1049 void spawnfunc_item_health_medium (void) {
1050         if(!self.max_health)
1051                 self.max_health = g_pickup_healthmedium_max;
1052         if(!self.health)
1053                 self.health = g_pickup_healthmedium;
1054         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1055 }
1056
1057 void spawnfunc_item_health_large (void) {
1058         if(!self.max_health)
1059                 self.max_health = g_pickup_healthlarge_max;
1060         if(!self.health)
1061                 self.health = g_pickup_healthlarge;
1062         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1063 }
1064
1065 void spawnfunc_item_health_mega (void) {
1066         if(!cvar("g_powerup_superhealth"))
1067                 return;
1068
1069         if(g_arena && !cvar("g_arena_powerups"))
1070                 return;
1071
1072         if(g_minstagib) {
1073                 minstagib_items(IT_NAILS);
1074         } else {
1075                 if(!self.max_health)
1076                         self.max_health = g_pickup_healthmega_max;
1077                 if(!self.health)
1078                         self.health = g_pickup_healthmega;
1079                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1080         }
1081 }
1082
1083 // support old misnamed entities
1084 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1085 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1086 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1087 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1088 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1089
1090 void spawnfunc_item_strength (void) {
1091         if(!cvar("g_powerup_strength"))
1092                 return;
1093
1094         if(g_arena && !cvar("g_arena_powerups"))
1095                 return;
1096
1097         if(g_minstagib) {
1098                 minstagib_items(IT_STRENGTH);
1099         } else {
1100                 precache_sound("weapons/strength_fire.wav");
1101                 self.strength_finished = 30;
1102                 self.effects = EF_ADDITIVE;
1103                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1104         }
1105 }
1106
1107 void spawnfunc_item_invincible (void) {
1108         if(!cvar("g_powerup_shield"))
1109                 return;
1110
1111         if(g_arena && !cvar("g_arena_powerups"))
1112                 return;
1113
1114         if(g_minstagib) {
1115                 minstagib_items(IT_INVINCIBLE);
1116         } else {
1117                 self.invincible_finished = 30;
1118                 self.effects = EF_ADDITIVE;
1119                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1120         }
1121 }
1122
1123 void spawnfunc_item_minst_cells (void) {
1124         if (g_minstagib)
1125         {
1126                 minst_no_auto_cells = 1;
1127                 minstagib_items(IT_CELLS);
1128         }
1129         else
1130                 remove(self);
1131 }
1132
1133 // compatibility:
1134 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1135
1136 float target_item_func_set(float a, float b)
1137 {
1138         if(b == 0)
1139                 return a;
1140         else if(b < 0)
1141                 return 0;
1142         else
1143                 return b;
1144 }
1145
1146 float target_item_func_min(float a, float b)
1147 {
1148         if(b == 0)
1149                 return a;
1150         else if(b < 0)
1151                 return 0;
1152         else
1153                 return min(a, b);
1154 }
1155
1156 float target_item_func_max(float a, float b)
1157 {
1158         return max(a, b);
1159 }
1160
1161 float target_item_func_bitset(float a, float b)
1162 {
1163         return b;
1164 }
1165
1166 float target_item_func_and(float a, float b)
1167 {
1168         return a & b;
1169 }
1170
1171 float target_item_func_itembitset(float a, float b)
1172 {
1173         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1174 }
1175
1176 float target_item_func_itemand(float a, float b)
1177 {
1178         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1179 }
1180
1181 float target_item_func_or(float a, float b)
1182 {
1183         return a | b;
1184 }
1185
1186 float target_item_func_andnot(float a, float b)
1187 {
1188         return a - (a & b);
1189 }
1190
1191 float target_item_changed;
1192 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1193 {
1194         float n, d;
1195         n = func(activator.field, self.field);
1196
1197         if(binary)
1198         {
1199                 d = n & activator.field;
1200                 if(d != n) // bits added?
1201                         d = +1;
1202                 else if(d != activator.field) // bits removed?
1203                         d = -1;
1204                 else
1205                         d = 0;
1206         }
1207         else
1208                 d = n - activator.field;
1209
1210         if(d < 0)
1211         {
1212                 if(sound_decrease != "")
1213                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1214                 target_item_changed = 1;
1215         }
1216         else if(d > 0)
1217         {
1218                 if(sound_increase != "")
1219                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1220                 target_item_changed = 1;
1221         }
1222         activator.field = n;
1223 }
1224
1225 void target_items_use (void)
1226 {
1227         float h0, a0;
1228
1229         if(activator.classname == "droppedweapon")
1230         {
1231                 EXACTTRIGGER_TOUCH;
1232                 remove(activator);
1233                 return;
1234         }
1235
1236         if(activator.classname != "player")
1237                 return;
1238         if(activator.deadflag != DEAD_NO)
1239                 return;
1240         EXACTTRIGGER_TOUCH;
1241
1242         entity e;
1243         for(e = world; (e = find(e, classname, "droppedweapon")); )
1244                 if(e.enemy == activator)
1245                         remove(e);
1246
1247         float _switchweapon;
1248         _switchweapon = FALSE;
1249         if (activator.autoswitch)
1250                 if (activator.switchweapon == w_getbestweapon(activator))
1251                         _switchweapon = TRUE;
1252
1253         a0 = activator.armorvalue;
1254         h0 = activator.health;
1255         target_item_changed = 0;
1256
1257         if(self.spawnflags == 0) // SET
1258         {
1259                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1260                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1261                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1262                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1263                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1264                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1265                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1266                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1267                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1268
1269                 if((self.items & activator.items) & IT_STRENGTH)
1270                         activator.strength_finished = time + self.strength_finished;
1271                 if((self.items & activator.items) & IT_INVINCIBLE)
1272                         activator.invincible_finished = time + self.invincible_finished;
1273         }
1274         else if(self.spawnflags == 1) // AND/MIN
1275         {
1276                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1277                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1278                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1279                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1280                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1281                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1282                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1283                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1284                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1285
1286                 if((self.items & activator.items) & IT_STRENGTH)
1287                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1288                 if((self.items & activator.items) & IT_INVINCIBLE)
1289                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1290         }
1291         else if(self.spawnflags == 2) // OR/MAX
1292         {
1293                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1294                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1295                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1296                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1297                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1298                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1299                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1300                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1301                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1302
1303                 if((self.items & activator.items) & IT_STRENGTH)
1304                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1305                 if((self.items & activator.items) & IT_INVINCIBLE)
1306                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1307         }
1308         else if(self.spawnflags == 4) // ANDNOT/MIN
1309         {
1310                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1311                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1312                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1313                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1314                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1315                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1316                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1317                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1318                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1319
1320                 if((self.items & activator.items) & IT_STRENGTH)
1321                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1322                 if((self.items & activator.items) & IT_INVINCIBLE)
1323                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1324         }
1325
1326         if not(activator.items & IT_STRENGTH)
1327                 activator.strength_finished = 0;
1328         if not(activator.items & IT_INVINCIBLE)
1329                 activator.invincible_finished = 0;
1330
1331         if(activator.health > h0)
1332                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1333         else if(activator.health < h0)
1334                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1335
1336         if(activator.armorvalue > a0)
1337                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1338
1339         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1340                 _switchweapon = TRUE;
1341         if(_switchweapon)
1342                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1343
1344         if(target_item_changed)
1345                 centerprint(activator, self.message);
1346 }
1347
1348 void spawnfunc_target_items (void)
1349 {
1350         float n, i, j;
1351         entity e;
1352         self.use = target_items_use;
1353         if(!self.strength_finished)
1354                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1355         if(!self.invincible_finished)
1356                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1357
1358         precache_sound("misc/itempickup.wav");
1359         precache_sound("misc/itempickup.wav");
1360         precache_sound("misc/itempickup.wav");
1361         precache_sound("misc/itempickup.wav");
1362         precache_sound("misc/megahealth.wav");
1363         precache_sound("misc/armor25.wav");
1364         precache_sound("misc/powerup.wav");
1365         precache_sound("misc/poweroff.wav");
1366         precache_sound("weapons/weaponpickup.wav");
1367
1368         n = tokenize_console(self.netname);
1369         for(i = 0; i < n; ++i)
1370         {
1371                 if(argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1372                 if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1373                 if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1374                 if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1375                 if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1376                 if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1377                 if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1378                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1379                 {
1380                         e = get_weaponinfo(j);
1381                         if(argv(i) == e.netname)
1382                         {
1383                                 self.weapons |= e.weapons;
1384                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1385                                         weapon_action(e.weapon, WR_PRECACHE);
1386                         }
1387                 }
1388         }
1389 }
1390
1391 void spawnfunc_item_fuel(void)
1392 {
1393         if(!self.ammo_fuel)
1394                 self.ammo_fuel = g_pickup_fuel;
1395         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1396 }
1397
1398 void spawnfunc_item_fuel_regen(void)
1399 {
1400         if(start_items & IT_FUEL_REGEN)
1401         {
1402                 spawnfunc_item_fuel();
1403                 return;
1404         }
1405         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1406 }
1407
1408 void spawnfunc_item_jetpack(void)
1409 {
1410         if(g_grappling_hook)
1411                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1412         if(!self.ammo_fuel)
1413                 self.ammo_fuel = g_pickup_fuel_jetpack;
1414         if(start_items & IT_JETPACK)
1415         {
1416                 spawnfunc_item_fuel();
1417                 return;
1418         }
1419         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1420 }