data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centermsg_freefor(other, CENTERMSG_MINSTAGIB);
  57                         centermsg_freefor(other, CENTERMSG_MINSTAGIB2);
  58                         if(other.health <= 5)
  59                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  60                         else if(other.health < 50)
  61                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  62                         // sound not available
  63                         // else if(self.items == IT_CELLS)
  64                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  65
  66                         if (self.items & IT_NEX)
  67                                 W_GiveWeapon (other, IT_NEX, "Nex");
  68                         if (self.ammo_cells)
  69                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  70                         other.health = 100;
  71                 }
  72
  73                 // extralife powerup
  74                 if (self.max_health)
  75                 {
  76                         // sound not available
  77                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  78                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  79                         sprint(other, "^3You picked up some extra lives\n");
  80                 }
  81
  82                 // invis powerup
  83                 if (self.strength_finished)
  84                 {
  85                         // sound not available
  86                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         // sound not available
  94                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  95                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  96                 }
  97         }
  98         else
  99         {
 100                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 101                 {
 102                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 103                                 return;
 104                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 105                                 return;
 106                 }
 107
 108                 if (self.ammo_shells)
 109                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 110                 if (self.ammo_nails)
 111                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 112                 if (self.ammo_rockets)
 113                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 114                 if (self.ammo_cells)
 115                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 116
 117                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 118                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 119                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 120                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 121                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 122                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 123                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 124                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 125
 126                 if (self.strength_finished)
 127                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 128                 if (self.invincible_finished)
 129                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 130                 //if (self.speed_finished)
 131                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 132                 //if (self.slowmo_finished)
 133                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 134
 135                 if (self.max_health)
 136                 {
 137                         other.health = other.health + self.max_health;
 138                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 139                 }
 140                 if (self.health && other.health < other.max_health)
 141                         other.health = min(other.health + self.health, other.max_health);
 142                 if (self.armorvalue)
 143                 {
 144                         other.armorvalue = other.armorvalue + self.armorvalue;
 145                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 146                 }
 147         }
 148
 149         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 150
 151         oldself = self;
 152         self = other;
 153
 154         if (_switchweapon)
 155                 self.switchweapon = w_getbestweapon(self);
 156         if (self.switchweapon != self.weapon)
 157                 self.cnt = self.weapon;
 158
 159         self = oldself;
 160
 161         if (self.classname == "droppedweapon")
 162                 remove (self);
 163         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 164                 return;
 165         else
 166         {
 167                 self.solid = SOLID_NOT;
 168                 self.model = string_null;
 169                 self.nextthink = time + self.respawntime;
 170                 self.think = Item_Respawn;
 171                 setorigin (self, self.origin);
 172         }
 173 }
 174
 175 // Savage: used for item garbage-collection
 176 // TODO: perhaps nice special effect?
 177 void RemoveItem(void) = {
 178         remove(self);
 179 }
 180
 181 // pickup evaluation functions
 182 // these functions decide how desirable an item is to the bots
 183
 184 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 185
 186 float(entity player, entity item) weapon_pickupevalfunc =
 187 {
 188         // if we already have the weapon, rate it 1/5th normal value
 189         if ((player.items & item.items) == item.items)
 190                 return item.bot_pickupbasevalue * 0.2;
 191         return item.bot_pickupbasevalue;
 192 };
 193
 194 float(entity player, entity item) commodity_pickupevalfunc =
 195 {
 196         float c;
 197         c = 0;
 198         // TODO: figure out if the player even has the weapon this ammo is for?
 199         // may not affect strategy much though...
 200         // find out how much ammo the player has, in terms of this ammo pickup
 201         // (how many of these ammo pickups it would take to total the player's
 202         // current ammo)
 203         if (item.ammo_shells)
 204                 c = c + player.ammo_shells / item.ammo_shells;
 205         if (item.ammo_nails)
 206                 c = c + player.ammo_nails / item.ammo_nails;
 207         if (item.ammo_rockets)
 208                 c = c + player.ammo_rockets / item.ammo_rockets;
 209         if (item.ammo_cells)
 210                 c = c + player.ammo_cells / item.ammo_cells;
 211         if (item.armorvalue)
 212                 c = c + player.armorvalue / item.armorvalue;
 213         if (item.health)
 214                 c = c + player.health / item.health / 10;
 215         // the more ammo the player has, the less desirable this pickup becomes
 216         c = 1 / (1 + c);
 217
 218         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 219         if (item.flags & FL_WEAPON)
 220         if (self.items & item.items)
 221         if (item.classname != "droppedweapon")
 222                 c = 0;
 223
 224         return item.bot_pickupbasevalue * c;
 225 };
 226
 227
 228 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 229 {
 230         vector org;
 231         org = self.origin;
 232
 233         startitem_failed = FALSE;
 234
 235         if (self.classname != "droppedweapon" && !self.noalign)
 236         {
 237                 vector z_offset;
 238
 239                 z_offset = '0 0 1';
 240
 241                 if (itemid == IT_SHELLS)
 242                         z_offset = '0 0 4';
 243                 else if (itemid == IT_ROCKETS)
 244                         z_offset = '0 0 4';
 245                 else if (itemid == IT_NAILS)
 246                         z_offset = '0 0 0';
 247                 else if (itemid == IT_25HP)
 248                         z_offset = '0 0 5';
 249                 else if (itemid == IT_ARMOR)
 250                         z_offset = '0 0 3';
 251
 252                 org = find_floor(org) + z_offset;
 253                 setorigin(self, org);
 254         }
 255
 256         if (self.classname != "droppedweapon")
 257                 waypoint_spawnforitem(self);
 258
 259         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 260                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 261         {
 262                 startitem_failed = TRUE;
 263                 remove (self);
 264                 return;
 265         }
 266
 267         if (cvar("g_minstagib"))
 268         {
 269                 // don't remove dropped items and powerups
 270                 if (self.classname != "droppedweapon" &&
 271                     self.classname != "minstagib")
 272                 {
 273                         startitem_failed = TRUE;
 274                         remove (self);
 275                         return;
 276                 }
 277         }
 278
 279         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 280         {
 281                 startitem_failed = TRUE;
 282                 remove(self);
 283                 return;
 284         }
 285
 286         if(cvar("g_instagib") || cvar("g_rocketarena"))
 287         {
 288                 startitem_failed = TRUE;
 289                 remove(self);
 290                 return;
 291         }
 292
 293         if (self.classname == "droppedweapon")
 294         {
 295                 // don't drop if in a NODROP zone (such as lava)
 296                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 297                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 298                 {
 299                         startitem_failed = TRUE;
 300                         remove(self);
 301                         return;
 302                 }
 303         }
 304
 305         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 306                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 307                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 308         {
 309                 self.target = "###item###"; // for finding the nearest item using find()
 310         }
 311         self.bot_pickup = TRUE;
 312         self.bot_pickupevalfunc = pickupevalfunc;
 313         self.bot_pickupbasevalue = pickupbasevalue;
 314         self.mdl = itemmodel;
 315         //self.noise = pickupsound;
 316         self.item_pickupsound = pickupsound;
 317         // let mappers override respawntime
 318         if (!self.respawntime)
 319                 self.respawntime = defaultrespawntime;
 320         self.netname = itemname;
 321         self.items = itemid;
 322         self.flags = FL_ITEM | itemflags;
 323         setmodel (self, self.mdl);
 324         if (itemflags & FL_WEAPON)
 325         {
 326                 setorigin (self, self.origin + '0 0 23');
 327                 setsize (self, '-12 -12 -12', '12 12 12');
 328
 329                 // neutral team color for pickup weapons
 330                 self.colormap = 160 * 1024 + 160;
 331         }
 332         else
 333         {
 334                 setorigin (self, self.origin + '0 0 25');
 335         //      setsize (self, '-8 -8 -5', '8 8 8');
 336         }
 337         self.movetype = MOVETYPE_TOSS;
 338         self.solid = SOLID_TRIGGER;
 339         self.touch = Item_Touch;
 340
 341         // Savage: remove thrown items after a certain period of time ("garbage collection")
 342         if (self.classname == "droppedweapon")
 343         {
 344                 self.think = RemoveItem;
 345                 self.nextthink = time + 60;
 346         }
 347         else
 348         {
 349                 self.movetype = MOVETYPE_NONE;
 350                 setorigin(self, org);
 351         }
 352
 353         if (cvar("g_fullbrightitems"))
 354                 self.effects = self.effects | EF_FULLBRIGHT;
 355 }
 356
 357 /* replace items in minstagib
 358  * IT_STRENGTH   = invisibility
 359  * IT_NAILS      = extra lives
 360  * IT_INVINCIBLE = speed
 361  */
 362 void minstagib_items (float itemid)
 363 {
 364         // we don't want to replace dropped weapons ;)
 365         if (self.classname == "droppedweapon")
 366         {
 367                 self.ammo_cells = 25;
 368                 StartItem ("models/weapons/g_nex.md3",
 369                         "weapons/weaponpickup.ogg", 15,
 370                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 371                 return;
 372         }
 373
 374         local float rnd;
 375         self.classname = "minstagib";
 376
 377         // replace rocket launchers and nex guns with ammo cells
 378         if (itemid == IT_CELLS)
 379         {
 380                 self.ammo_cells = 1;
 381                 StartItem ("models/items/a_cells.md3",
 382                         "misc/itempickup.ogg", 45,
 383                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 384                 return;
 385         }
 386
 387         // randomize
 388         rnd = random() * 3;
 389         if (rnd <= 1)
 390                 itemid = IT_STRENGTH;
 391         else if (rnd <= 2)
 392                 itemid = IT_NAILS;
 393         else
 394                 itemid = IT_INVINCIBLE;
 395
 396         // replace with invis
 397         if (itemid == IT_STRENGTH)
 398         {
 399                 self.effects = EF_ADDITIVE;
 400                 self.strength_finished = 30;
 401                 StartItem ("models/items/g_strength.md3",
 402                         "misc/powerup.ogg", 120,
 403                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 404         }
 405         // replace with extra lives
 406         if (itemid == IT_NAILS)
 407         {
 408                 self.max_health = 1;
 409                 StartItem ("models/items/g_h100.md3",
 410                         "misc/megahealth.ogg", 120,
 411                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 412
 413         }
 414         // replace with speed
 415         if (itemid == IT_INVINCIBLE)
 416         {
 417                 self.effects = EF_ADDITIVE;
 418                 self.invincible_finished = 30;
 419                 StartItem ("models/items/g_invincible.md3",
 420                         "misc/powerup_shield.ogg", 120,
 421                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 422         }
 423
 424 }
 425
 426 void weapon_uzi (void) {
 427         if(!self.ammo_nails)
 428                 self.ammo_nails = 120;
 429         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 430 }
 431
 432 void weapon_shotgun (void) {
 433         if(!self.ammo_shells)
 434                 self.ammo_shells = 15;
 435         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 436 }
 437
 438 void weapon_grenadelauncher (void) {
 439         if(!self.ammo_rockets)
 440                 self.ammo_rockets = 15;
 441         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 442 }
 443
 444 void weapon_electro (void) {
 445         if(!self.ammo_cells)
 446                 self.ammo_cells = 25;
 447         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 448 }
 449
 450 void weapon_crylink (void) {
 451         if(!self.ammo_cells)
 452                 self.ammo_cells = 25;
 453         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 454 }
 455
 456 void weapon_nex (void) {
 457         if (cvar("g_minstagib")) {
 458                 minstagib_items(IT_CELLS);
 459         } else {
 460                 float nextime;
 461                 if(!self.ammo_cells)
 462                         self.ammo_cells = 25;
 463                 nextime = cvar("g_balance_nex_respawntime_modifier");
 464                 if(nextime)
 465                         nextime = 15 * nextime;
 466                 else
 467                         nextime = 15;
 468                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 469         }
 470 }
 471
 472 void weapon_hagar (void) {
 473         if(!self.ammo_rockets)
 474                 self.ammo_rockets = 15;
 475         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 476 }
 477
 478 void weapon_rocketlauncher (void) {
 479         if (cvar("g_minstagib")) {
 480                 minstagib_items(IT_CELLS);
 481         } else {
 482                 if(!self.ammo_rockets)
 483                         self.ammo_rockets = 15;
 484                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 485         }
 486 }
 487
 488 void item_rockets (void) {
 489         if(!self.ammo_rockets)
 490                 self.ammo_rockets = 15;
 491         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 492 }
 493
 494 void item_bullets (void) {
 495         if(!self.ammo_nails)
 496                 self.ammo_nails = 120;
 497         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 498 }
 499
 500 void item_cells (void) {
 501         if(!self.ammo_cells)
 502                 self.ammo_cells = 25;
 503         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 504 }
 505
 506 void item_shells (void) {
 507         if(!self.ammo_shells)
 508                 self.ammo_shells = 15;
 509         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 510 }
 511
 512 void item_armor1 (void) {
 513         if(!self.armorvalue)
 514                 self.armorvalue = 5;
 515         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 516 }
 517
 518 void item_armor25 (void) {
 519         if(!self.armorvalue)
 520                 self.armorvalue = 100;
 521         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 522 }
 523
 524 void item_health1 (void) {
 525         if(!self.max_health)
 526                 self.max_health = 5;
 527         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 528 }
 529
 530 void item_health25 (void) {
 531         if(!self.max_health)
 532                 self.max_health = 25;
 533         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 534 }
 535
 536 void item_health100 (void) {
 537         if(!cvar("g_powerup_superhealth"))
 538                 return;
 539
 540         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 541                 return;
 542
 543         if(cvar("g_minstagib")) {
 544                 minstagib_items(IT_NAILS);
 545         } else {
 546                 if(!self.max_health)
 547                         self.max_health = 100;
 548                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 549         }
 550 }
 551
 552 void item_strength (void) {
 553         if(!cvar("g_powerup_strength"))
 554                 return;
 555
 556         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 557                 return;
 558
 559         if(cvar("g_minstagib")) {
 560                 minstagib_items(IT_STRENGTH);
 561         } else {
 562                 self.strength_finished = 30;
 563                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 564         }
 565 }
 566
 567 void item_invincible (void) {
 568         if(!cvar("g_powerup_shield"))
 569                 return;
 570
 571         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 572                 return;
 573
 574         if(cvar("g_minstagib")) {
 575                 minstagib_items(IT_INVINCIBLE);
 576         } else {
 577                 self.invincible_finished = 30;
 578                 self.effects = EF_ADDITIVE;
 579                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 580         }
 581 }
 582 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 583 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 584
 585 // compatibility:
 586 void item_quad (void) {self.classname = "item_strength";item_strength();}
 587
 588 void misc_models (void)
 589 {
 590         precache_model (self.model);
 591         setmodel (self, self.model);
 592         setsize (self, self.mins, self.maxs);
 593 }
 594
 595
 596
 597
 598
 599 floatfield Item_CounterField(float it)
 600 {
 601         switch(it)
 602         {
 603                 case IT_SHELLS:      return ammo_shells;
 604                 case IT_NAILS:       return ammo_nails;
 605                 case IT_ROCKETS:     return ammo_rockets;
 606                 case IT_CELLS:       return ammo_cells;
 607                 case IT_5HP:         return health;
 608                 case IT_25HP:        return health;
 609                 case IT_HEALTH:      return health;
 610                 case IT_ARMOR_SHARD: return armorvalue;
 611                 case IT_ARMOR:       return armorvalue;
 612                 // add more things here (health, armor)
 613                 default:             error("requested item has no counter field");
 614         }
 615 }
 616
 617 float Item_WeaponCode(float it)
 618 {
 619         switch(it)
 620         {
 621                 case IT_LASER:            return WEP_LASER;
 622                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 623                 case IT_UZI:              return WEP_UZI;
 624                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 625                 case IT_ELECTRO:          return WEP_ELECTRO;
 626                 case IT_CRYLINK:          return WEP_CRYLINK;
 627                 case IT_NEX:              return WEP_NEX;
 628                 case IT_HAGAR:            return WEP_HAGAR;
 629                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 630                 default:                  return 0;
 631         }
 632 }
 633
 634 spawnfunc Item_SpawnFunc(float it)
 635 {
 636         switch(it)
 637         {
 638                 case IT_SHOTGUN:          return weapon_shotgun;
 639                 case IT_UZI:              return weapon_uzi;
 640                 case IT_GRENADE_LAUNCHER: return weapon_grenadelauncher;
 641                 case IT_ELECTRO:          return weapon_electro;
 642                 case IT_CRYLINK:          return weapon_crylink;
 643                 case IT_NEX:              return weapon_nex;
 644                 case IT_HAGAR:            return weapon_hagar;
 645                 case IT_ROCKET_LAUNCHER:  return weapon_rocketlauncher;
 646                 // add all other item spawn functions here
 647                 default:                  error("requested item can't be spawned");
 648         }
 649 }