centerprints now are managed independently per line
[divverent/nexuiz.git] / data / qcsrc / server / t_items.qc
1 //void Item_ClearRespawnEffect (void) {
2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
3 //}
4
5 void Item_Respawn (void)
6 {
7         self.model = self.mdl;          // restore original model
8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
10         setorigin (self, self.origin);
11
12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
14         //// Savage: Add simple Respawn effect and make sure it gets removed
15         //self.effects = self.effects | EF_STARDUST;
16         //self.think = Item_ClearRespawnEffect;
17         //self.nextthink = time + 0.1;
18 }
19
20 void Item_Touch (void)
21 {
22         local entity oldself;
23         local float _switchweapon;
24
25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
27         {
28                 remove(self);
29                 return;
30         }
31         if (other.classname != "player")
32                 return;
33         if (other.deadflag)
34                 return;
35         if (self.solid != SOLID_TRIGGER)
36                 return;
37         if (self.health && other.health >= other.max_health)
38                 return;
39         if (self.owner == other)
40                 return;
41         // Savage: Remove the respawn effect if still present
42         self.effects = self.effects - (self.effects & EF_STARDUST);
43
44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
45
46         // in case the player has autoswitch enabled do the following:
47         // if the player is using their best weapon before items are given, they
48         // probably want to switch to an even better weapon after items are given
49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
50
51         if (cvar("g_minstagib"))
52         {
53                 if (self.ammo_cells)
54                 {
55                         // play some cool sounds ;)
56                         centermsg_freefor(other, CENTERMSG_MINSTAGIB);
57                         centermsg_freefor(other, CENTERMSG_MINSTAGIB2);
58                         if(other.health <= 5)
59                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
60                         else if(other.health < 50)
61                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
62                         // sound not available
63                         // else if(self.items == IT_CELLS)
64                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
65
66                         if (self.items & IT_NEX)
67                                 W_GiveWeapon (other, IT_NEX, "Nex");
68                         if (self.ammo_cells)
69                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
70                         other.health = 100;
71                 }
72
73                 // extralife powerup
74                 if (self.max_health)
75                 {
76                         // sound not available
77                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
78                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
79                         other.armorvalue = other.extralives;
80                         sprint(other, "^3You picked up some extra lives\n");
81                 }
82
83                 // invis powerup
84                 if (self.strength_finished)
85                 {
86                         // sound not available
87                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
88                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
89                 }
90
91                 // speed powerup
92                 if (self.invincible_finished)
93                 {
94                         // sound not available
95                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
96                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
97                 }
98         }
99         else
100         {
101                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
102                         return;
103
104                 if (self.ammo_shells)
105                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
106                 if (self.ammo_nails)
107                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
108                 if (self.ammo_rockets)
109                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
110                 if (self.ammo_cells)
111                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
112
113                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
114                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
115                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
116                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
117                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
118                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
119                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
120                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
121
122                 if (self.strength_finished)
123                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
124                 if (self.invincible_finished)
125                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
126                 //if (self.speed_finished)
127                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
128                 //if (self.slowmo_finished)
129                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
130
131                 if (self.max_health)
132                 {
133                         other.health = other.health + self.max_health;
134                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
135                 }
136                 if (self.health && other.health < other.max_health)
137                         other.health = min(other.health + self.health, other.max_health);
138                 if (self.armorvalue)
139                 {
140                         other.armorvalue = other.armorvalue + self.armorvalue;
141                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
142                 }
143         }
144
145         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
146
147         oldself = self;
148         self = other;
149
150         if (_switchweapon)
151                 self.switchweapon = w_getbestweapon(self);
152         if (self.switchweapon != self.weapon)
153                 self.cnt = self.weapon;
154
155         self = oldself;
156
157         if (self.classname == "droppedweapon")
158                 remove (self);
159         else if(self.flags & FL_WEAPON && cvar("deathmatch") == 2)
160                 return;
161         else
162         {
163                 self.solid = SOLID_NOT;
164                 self.model = string_null;
165                 self.nextthink = time + self.respawntime;
166                 self.think = Item_Respawn;
167                 setorigin (self, self.origin);
168         }
169 }
170
171 // Savage: used for item garbage-collection
172 // TODO: perhaps nice special effect?
173 void RemoveItem(void) = {
174         remove(self);
175 }
176
177 // pickup evaluation functions
178 // these functions decide how desirable an item is to the bots
179
180 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
181
182 float(entity player, entity item) weapon_pickupevalfunc =
183 {
184         // if we already have the weapon, rate it 1/5th normal value
185         if ((player.items & item.items) == item.items)
186                 return item.bot_pickupbasevalue * 0.2;
187         return item.bot_pickupbasevalue;
188 };
189
190 float(entity player, entity item) commodity_pickupevalfunc =
191 {
192         float c;
193         c = 0;
194         // TODO: figure out if the player even has the weapon this ammo is for?
195         // may not affect strategy much though...
196         // find out how much ammo the player has, in terms of this ammo pickup
197         // (how many of these ammo pickups it would take to total the player's
198         // current ammo)
199         if (item.ammo_shells)
200                 c = c + player.ammo_shells / item.ammo_shells;
201         if (item.ammo_nails)
202                 c = c + player.ammo_nails / item.ammo_nails;
203         if (item.ammo_rockets)
204                 c = c + player.ammo_rockets / item.ammo_rockets;
205         if (item.ammo_cells)
206                 c = c + player.ammo_cells / item.ammo_cells;
207         if (item.armorvalue)
208                 c = c + player.armorvalue / item.armorvalue;
209         if (item.health)
210                 c = c + player.health / item.health / 10;
211         // the more ammo the player has, the less desirable this pickup becomes
212         c = 1 / (1 + c);
213
214         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
215         if (item.flags & FL_WEAPON)
216         if (self.items & item.items)
217         if (item.classname != "droppedweapon")
218                 c = 0;
219
220         return item.bot_pickupbasevalue * c;
221 };
222
223
224 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
225 {
226         vector org;
227         org = self.origin;
228
229         if (self.classname != "droppedweapon" && !self.noalign)
230         {
231                 vector z_offset;
232
233                 z_offset = '0 0 1';
234
235                 if (itemid == IT_SHELLS)
236                         z_offset = '0 0 4';
237                 else if (itemid == IT_ROCKETS)
238                         z_offset = '0 0 4';
239                 else if (itemid == IT_NAILS)
240                         z_offset = '0 0 0';
241                 else if (itemid == IT_25HP)
242                         z_offset = '0 0 5';
243                 else if (itemid == IT_ARMOR)
244                         z_offset = '0 0 3';
245
246                 org = find_floor(org) + z_offset;
247                 setorigin(self, org);
248         }
249
250         if (self.classname != "droppedweapon")
251                 waypoint_spawnforitem(self);
252
253         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
254                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
255         {
256                 remove (self);
257                 return;
258         }
259
260         if (cvar("g_minstagib"))
261         {
262                 // don't remove dropped items and powerups
263                 if (self.classname != "droppedweapon" &&
264                     self.classname != "minstagib")
265                 {
266                         remove (self);
267                         return;
268                 }
269         }
270
271         if(cvar("g_lms") && (self.classname != "droppedweapon"))
272         {
273                 remove(self);
274                 return;
275         }
276
277         if(cvar("g_instagib") || cvar("g_rocketarena"))
278         {
279                 remove(self);
280                 return;
281         }
282
283         if (self.classname == "droppedweapon")
284         {
285                 // don't drop if in a NODROP zone (such as lava)
286                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
287                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
288                 {
289                         remove(self);
290                         return;
291                 }
292         }
293
294         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
295                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
296                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
297         {
298                 self.target = "###item###"; // for finding the nearest item using find()
299         }
300         self.bot_pickup = TRUE;
301         self.bot_pickupevalfunc = pickupevalfunc;
302         self.bot_pickupbasevalue = pickupbasevalue;
303         self.mdl = itemmodel;
304         //self.noise = pickupsound;
305         self.item_pickupsound = pickupsound;
306         // let mappers override respawntime
307         if (!self.respawntime)
308                 self.respawntime = defaultrespawntime;
309         self.netname = itemname;
310         self.items = itemid;
311         self.flags = FL_ITEM | itemflags;
312         setmodel (self, self.mdl);
313         if (itemflags & FL_WEAPON)
314         {
315                 setorigin (self, self.origin + '0 0 23');
316                 setsize (self, '-12 -12 -12', '12 12 12');
317
318                 // neutral team color for pickup weapons
319                 self.colormap = 160 * 1024 + 160;
320         }
321         else
322         {
323                 setorigin (self, self.origin + '0 0 25');
324         //      setsize (self, '-8 -8 -5', '8 8 8');
325         }
326         self.movetype = MOVETYPE_TOSS;
327         self.solid = SOLID_TRIGGER;
328         self.touch = Item_Touch;
329
330         // Savage: remove thrown items after a certain period of time ("garbage collection")
331         if (self.classname == "droppedweapon")
332         {
333                 self.think = RemoveItem;
334                 self.nextthink = time + 60;
335         }
336         else
337         {
338                 self.movetype = MOVETYPE_NONE;
339                 setorigin(self, org);
340         }
341
342         if (cvar("g_fullbrightitems"))
343                 self.effects = self.effects | EF_FULLBRIGHT;
344 }
345
346 /* replace items in minstagib
347  * IT_STRENGTH   = invisibility
348  * IT_NAILS      = extra lives
349  * IT_INVINCIBLE = speed
350  */
351 void minstagib_items (float itemid)
352 {
353         // we don't want to replace dropped weapons ;)
354         if (self.classname == "droppedweapon")
355         {
356                 self.ammo_cells = 25;
357                 StartItem ("models/weapons/g_nex.md3",
358                         "weapons/weaponpickup.ogg", 15,
359                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
360                 return;
361         }
362
363         local float rnd;
364         self.classname = "minstagib";
365
366         // replace rocket launchers and nex guns with ammo cells
367         if (itemid == IT_CELLS)
368         {
369                 self.ammo_cells = 1;
370                 StartItem ("models/items/a_cells.md3",
371                         "misc/itempickup.ogg", 45,
372                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
373                 return;
374         }
375
376         // randomize
377         rnd = random() * 3;
378         if (rnd <= 1)
379                 itemid = IT_STRENGTH;
380         else if (rnd <= 2)
381                 itemid = IT_NAILS;
382         else
383                 itemid = IT_INVINCIBLE;
384
385         // replace with invis
386         if (itemid == IT_STRENGTH)
387         {
388                 self.effects = EF_ADDITIVE;
389                 self.strength_finished = 30;
390                 StartItem ("models/items/g_strength.md3",
391                         "misc/powerup.ogg", 120,
392                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
393         }
394         // replace with extra lives
395         if (itemid == IT_NAILS)
396         {
397                 self.max_health = 1;
398                 StartItem ("models/items/g_h100.md3",
399                         "misc/megahealth.ogg", 120,
400                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
401
402         }
403         // replace with ammo
404         if (itemid == IT_INVINCIBLE)
405         {
406                 self.effects = EF_ADDITIVE;
407                 self.invincible_finished = 30;
408                 StartItem ("models/items/g_invincible.md3",
409                         "misc/powerup_shield.ogg", 120,
410                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
411         }
412
413 }
414
415 void weapon_uzi (void) {
416         self.ammo_nails = 120;
417         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
418 }
419
420 void weapon_shotgun (void) {
421         self.ammo_shells = 15;
422         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
423 }
424
425 void weapon_grenadelauncher (void) {
426         self.ammo_rockets = 15;
427         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
428 }
429
430 void weapon_electro (void) {
431         self.ammo_cells = 25;
432         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
433 }
434
435 void weapon_crylink (void) {
436         self.ammo_cells = 25;
437         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
438 }
439
440 void weapon_nex (void) {
441         if (cvar("g_minstagib")) {
442                 minstagib_items(IT_CELLS);
443         } else {
444                 self.ammo_cells = 25;
445                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
446         }
447 }
448
449 void weapon_hagar (void) {
450         self.ammo_rockets = 15;
451         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
452 }
453
454 void weapon_rocketlauncher (void) {
455         if (cvar("g_minstagib")) {
456                 minstagib_items(IT_CELLS);
457         } else {
458                 self.ammo_rockets = 15;
459                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
460         }
461 }
462
463 void item_rockets (void) {
464         self.ammo_rockets = 15;
465         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
466 }
467
468 void item_bullets (void) {
469         self.ammo_nails = 120;
470         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
471 }
472
473 void item_cells (void) {
474         self.ammo_cells = 25;
475         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
476 }
477
478 void item_shells (void) {
479         self.ammo_shells = 15;
480         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
481 }
482
483 void item_armor1 (void) {
484         self.armorvalue = 5;
485         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
486 }
487
488 void item_armor25 (void) {
489         self.armorvalue = 100;
490         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
491 }
492
493 void item_health1 (void) {
494         self.max_health = 5;
495         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
496 }
497
498 void item_health25 (void) {
499         self.max_health = 25;
500         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
501 }
502
503 void item_health100 (void) {
504         if(!cvar("g_powerup_superhealth"))
505                 return;
506
507         if(cvar("g_arena") && !cvar("g_arena_powerups"))
508                 return;
509
510         if(cvar("g_minstagib")) {
511                 minstagib_items(IT_NAILS);
512         } else {
513                 self.max_health = 100;
514                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
515         }
516 }
517
518 void item_strength (void) {
519         if(!cvar("g_powerup_strength"))
520                 return;
521
522         if(cvar("g_arena") && !cvar("g_arena_powerups"))
523                 return;
524
525         if(cvar("g_minstagib")) {
526                 minstagib_items(IT_STRENGTH);
527         } else {
528                 self.strength_finished = 30;
529                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
530         }
531 }
532
533 void item_invincible (void) {
534         if(!cvar("g_powerup_shield"))
535                 return;
536
537         if(cvar("g_arena") && !cvar("g_arena_powerups"))
538                 return;
539
540         if(cvar("g_minstagib")) {
541                 minstagib_items(IT_INVINCIBLE);
542         } else {
543                 self.invincible_finished = 30;
544                 self.effects = EF_ADDITIVE;
545                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
546         }
547 }
548 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
549 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
550
551 // compatibility:
552 void item_quad (void) {self.classname = "item_strength";item_strength();}
553
554 void misc_models (void)
555 {
556         precache_model (self.model);
557         setmodel (self, self.model);
558         setsize (self, self.mins, self.maxs);
559 }
560
561