data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  78                         other.armorvalue = other.extralives;
  79                         sprint(other, "^3You picked up some extra lives\n");
  80                 }
  81
  82                 // invis powerup
  83                 if (self.strength_finished)
  84                 {
  85                         // sound not available
  86                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         // sound not available
  94                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  95                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  96                 }
  97         }
  98         else
  99         {
 100                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 101                         return;
 102
 103                 if (self.ammo_shells)
 104                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 105                 if (self.ammo_nails)
 106                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 107                 if (self.ammo_rockets)
 108                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 109                 if (self.ammo_cells)
 110                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 111
 112                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 113                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 114                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 115                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 116                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 117                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 118                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 119                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 120
 121                 if (self.strength_finished)
 122                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 123                 if (self.invincible_finished)
 124                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 125                 //if (self.speed_finished)
 126                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 127                 //if (self.slowmo_finished)
 128                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 129
 130                 if (self.max_health)
 131                 {
 132                         other.health = other.health + self.max_health;
 133                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 134                 }
 135                 if (self.health && other.health < other.max_health)
 136                         other.health = min(other.health + self.health, other.max_health);
 137                 if (self.armorvalue)
 138                 {
 139                         other.armorvalue = other.armorvalue + self.armorvalue;
 140                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 141                 }
 142         }
 143
 144         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 145
 146         oldself = self;
 147         self = other;
 148
 149         if (_switchweapon)
 150                 self.switchweapon = w_getbestweapon(self);
 151         if (self.switchweapon != self.weapon)
 152                 self.cnt = self.weapon;
 153
 154         self = oldself;
 155
 156         if (self.classname == "droppedweapon")
 157                 remove (self);
 158         else if(self.flags & FL_WEAPON && cvar("deathmatch") == 2)
 159                 return;
 160         else
 161         {
 162                 self.solid = SOLID_NOT;
 163                 self.model = string_null;
 164                 self.nextthink = time + self.respawntime;
 165                 self.think = Item_Respawn;
 166                 setorigin (self, self.origin);
 167         }
 168 }
 169
 170 // Savage: used for item garbage-collection
 171 // TODO: perhaps nice special effect?
 172 void RemoveItem(void) = {
 173         remove(self);
 174 }
 175
 176 // pickup evaluation functions
 177 // these functions decide how desirable an item is to the bots
 178
 179 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 180
 181 float(entity player, entity item) weapon_pickupevalfunc =
 182 {
 183         // if we already have the weapon, rate it 1/5th normal value
 184         if ((player.items & item.items) == item.items)
 185                 return item.bot_pickupbasevalue * 0.2;
 186         return item.bot_pickupbasevalue;
 187 };
 188
 189 float(entity player, entity item) commodity_pickupevalfunc =
 190 {
 191         float c;
 192         c = 0;
 193         // TODO: figure out if the player even has the weapon this ammo is for?
 194         // may not affect strategy much though...
 195         // find out how much ammo the player has, in terms of this ammo pickup
 196         // (how many of these ammo pickups it would take to total the player's
 197         // current ammo)
 198         if (item.ammo_shells)
 199                 c = c + player.ammo_shells / item.ammo_shells;
 200         if (item.ammo_nails)
 201                 c = c + player.ammo_nails / item.ammo_nails;
 202         if (item.ammo_rockets)
 203                 c = c + player.ammo_rockets / item.ammo_rockets;
 204         if (item.ammo_cells)
 205                 c = c + player.ammo_cells / item.ammo_cells;
 206         if (item.armorvalue)
 207                 c = c + player.armorvalue / item.armorvalue;
 208         if (item.health)
 209                 c = c + player.health / item.health / 10;
 210         // the more ammo the player has, the less desirable this pickup becomes
 211         c = 1 / (1 + c);
 212
 213         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 214         if (item.flags & FL_WEAPON)
 215         if (self.items & item.items)
 216         if (item.classname != "droppedweapon")
 217                 c = 0;
 218
 219         return item.bot_pickupbasevalue * c;
 220 };
 221
 222
 223 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 224 {
 225         vector org;
 226         org = self.origin;
 227
 228         if (self.classname != "droppedweapon" && !self.noalign)
 229         {
 230                 vector z_offset;
 231
 232                 z_offset = '0 0 1';
 233
 234                 if (itemid == IT_SHELLS)
 235                         z_offset = '0 0 4';
 236                 else if (itemid == IT_ROCKETS)
 237                         z_offset = '0 0 4';
 238                 else if (itemid == IT_NAILS)
 239                         z_offset = '0 0 0';
 240                 else if (itemid == IT_25HP)
 241                         z_offset = '0 0 5';
 242                 else if (itemid == IT_ARMOR)
 243                         z_offset = '0 0 3';
 244
 245                 org = find_floor(org) + z_offset;
 246                 setorigin(self, org);
 247         }
 248
 249         if (self.classname != "droppedweapon")
 250                 waypoint_spawnforitem(self);
 251
 252         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 253                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 254         {
 255                 remove (self);
 256                 return;
 257         }
 258
 259         if (cvar("g_minstagib"))
 260         {
 261                 // don't remove dropped items and powerups
 262                 if (self.classname != "droppedweapon" &&
 263                     self.classname != "minstagib")
 264                 {
 265                         remove (self);
 266                         return;
 267                 }
 268         }
 269
 270         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 271         {
 272                 remove(self);
 273                 return;
 274         }
 275
 276         if(cvar("g_instagib") || cvar("g_rocketarena"))
 277         {
 278                 remove(self);
 279                 return;
 280         }
 281
 282         if (self.classname == "droppedweapon")
 283         {
 284                 // don't drop if in a NODROP zone (such as lava)
 285                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 286                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 287                 {
 288                         remove(self);
 289                         return;
 290                 }
 291         }
 292
 293         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 294                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 295                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 296         {
 297                 self.target = "###item###"; // for finding the nearest item using find()
 298         }
 299         self.bot_pickup = TRUE;
 300         self.bot_pickupevalfunc = pickupevalfunc;
 301         self.bot_pickupbasevalue = pickupbasevalue;
 302         self.mdl = itemmodel;
 303         //self.noise = pickupsound;
 304         self.item_pickupsound = pickupsound;
 305         // let mappers override respawntime
 306         if (!self.respawntime)
 307                 self.respawntime = defaultrespawntime;
 308         self.netname = itemname;
 309         self.items = itemid;
 310         self.flags = FL_ITEM | itemflags;
 311         setmodel (self, self.mdl);
 312         if (itemflags & FL_WEAPON)
 313         {
 314                 setorigin (self, self.origin + '0 0 23');
 315                 setsize (self, '-12 -12 -12', '12 12 12');
 316
 317                 // neutral team color for pickup weapons
 318                 self.colormap = 160 * 1024 + 160;
 319         }
 320         else
 321         {
 322                 setorigin (self, self.origin + '0 0 25');
 323         //      setsize (self, '-8 -8 -5', '8 8 8');
 324         }
 325         self.movetype = MOVETYPE_TOSS;
 326         self.solid = SOLID_TRIGGER;
 327         self.touch = Item_Touch;
 328
 329         // Savage: remove thrown items after a certain period of time ("garbage collection")
 330         if (self.classname == "droppedweapon")
 331         {
 332                 self.think = RemoveItem;
 333                 self.nextthink = time + 60;
 334         }
 335         else
 336         {
 337                 self.movetype = MOVETYPE_NONE;
 338                 setorigin(self, org);
 339         }
 340
 341         if (cvar("g_fullbrightitems"))
 342                 self.effects = self.effects | EF_FULLBRIGHT;
 343 }
 344
 345 /* replace items in minstagib
 346  * IT_STRENGTH   = invisibility
 347  * IT_NAILS      = extra lives
 348  * IT_INVINCIBLE = speed
 349  */
 350 void minstagib_items (float itemid)
 351 {
 352         // we don't want to replace dropped weapons ;)
 353         if (self.classname == "droppedweapon")
 354         {
 355                 self.ammo_cells = 25;
 356                 StartItem ("models/weapons/g_nex.md3",
 357                         "weapons/weaponpickup.ogg", 15,
 358                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 359                 return;
 360         }
 361
 362         local float rnd;
 363         self.classname = "minstagib";
 364
 365         // replace rocket launchers and nex guns with ammo cells
 366         if (itemid == IT_CELLS)
 367         {
 368                 self.ammo_cells = 1;
 369                 StartItem ("models/items/a_cells.md3",
 370                         "misc/itempickup.ogg", 45,
 371                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 372                 return;
 373         }
 374
 375         // randomize
 376         rnd = random() * 3;
 377         if (rnd <= 1)
 378                 itemid = IT_STRENGTH;
 379         else if (rnd <= 2)
 380                 itemid = IT_NAILS;
 381         else
 382                 itemid = IT_INVINCIBLE;
 383
 384         // replace with invis
 385         if (itemid == IT_STRENGTH)
 386         {
 387                 self.effects = EF_ADDITIVE;
 388                 self.strength_finished = 30;
 389                 StartItem ("models/items/g_strength.md3",
 390                         "misc/powerup.ogg", 120,
 391                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 392         }
 393         // replace with extra lives
 394         if (itemid == IT_NAILS)
 395         {
 396                 self.max_health = 1;
 397                 StartItem ("models/items/g_h100.md3",
 398                         "misc/megahealth.ogg", 120,
 399                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 400
 401         }
 402         // replace with ammo
 403         if (itemid == IT_INVINCIBLE)
 404         {
 405                 self.effects = EF_ADDITIVE;
 406                 self.invincible_finished = 30;
 407                 StartItem ("models/items/g_invincible.md3",
 408                         "misc/powerup_shield.ogg", 120,
 409                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 410         }
 411
 412 }
 413
 414 void weapon_uzi (void) {
 415         self.ammo_nails = 120;
 416         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 417 }
 418
 419 void weapon_shotgun (void) {
 420         self.ammo_shells = 15;
 421         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 422 }
 423
 424 void weapon_grenadelauncher (void) {
 425         self.ammo_rockets = 15;
 426         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 427 }
 428
 429 void weapon_electro (void) {
 430         self.ammo_cells = 25;
 431         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 432 }
 433
 434 void weapon_crylink (void) {
 435         self.ammo_cells = 25;
 436         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 437 }
 438
 439 void weapon_nex (void) {
 440         if (cvar("g_minstagib")) {
 441                 minstagib_items(IT_CELLS);
 442         } else {
 443                 self.ammo_cells = 25;
 444                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 445         }
 446 }
 447
 448 void weapon_hagar (void) {
 449         self.ammo_rockets = 15;
 450         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 451 }
 452
 453 void weapon_rocketlauncher (void) {
 454         if (cvar("g_minstagib")) {
 455                 minstagib_items(IT_CELLS);
 456         } else {
 457                 self.ammo_rockets = 15;
 458                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 459         }
 460 }
 461
 462 void item_rockets (void) {
 463         self.ammo_rockets = 15;
 464         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 465 }
 466
 467 void item_bullets (void) {
 468         self.ammo_nails = 120;
 469         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 470 }
 471
 472 void item_cells (void) {
 473         self.ammo_cells = 25;
 474         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 475 }
 476
 477 void item_shells (void) {
 478         self.ammo_shells = 15;
 479         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 480 }
 481
 482 void item_armor1 (void) {
 483         self.armorvalue = 5;
 484         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 485 }
 486
 487 void item_armor25 (void) {
 488         self.armorvalue = 100;
 489         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 490 }
 491
 492 void item_health1 (void) {
 493         self.max_health = 5;
 494         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 495 }
 496
 497 void item_health25 (void) {
 498         self.max_health = 25;
 499         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 500 }
 501
 502 void item_health100 (void) {
 503         if(!cvar("g_powerup_superhealth"))
 504                 return;
 505
 506         if(cvar("g_minstagib")) {
 507                 minstagib_items(IT_NAILS);
 508         } else {
 509                 self.max_health = 100;
 510                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 511         }
 512 }
 513
 514 void item_strength (void) {
 515         if(!cvar("g_powerup_strength"))
 516                 return;
 517
 518         if(cvar("g_minstagib")) {
 519                 minstagib_items(IT_STRENGTH);
 520         } else {
 521                 self.strength_finished = 30;
 522                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 523         }
 524 }
 525
 526 void item_invincible (void) {
 527         if(!cvar("g_powerup_shield"))
 528                 return;
 529
 530         if(cvar("g_minstagib")) {
 531                 minstagib_items(IT_INVINCIBLE);
 532         } else {
 533                 self.invincible_finished = 30;
 534                 self.effects = EF_ADDITIVE;
 535                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 536         }
 537 }
 538 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 539 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 540
 541 // compatibility:
 542 void item_quad (void) {self.classname = "item_strength";item_strength();}
 543
 544 void misc_models (void)
 545 {
 546         precache_model (self.model);
 547         setmodel (self, self.model);
 548         setsize (self, self.mins, self.maxs);
 549 }
 550
 551