data/qcsrc/server/sv_main.qc

   1
   2 void CreatureFrame (void)
   3 {
   4         local entity oldself;
   5         local float dm;
   6         oldself = self;
   7         self = findfloat(world, iscreature, TRUE);
   8         while (self)
   9         {
  10                 if (self.movetype != MOVETYPE_NOCLIP)
  11                 {
  12                         if (self.waterlevel)
  13                         {
  14                                 if (!(self.flags & FL_INWATER))
  15                                 {
  16                                         self.flags |= FL_INWATER;
  17                                         self.dmgtime = 0;
  18                                 }
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  20                                 {
  21                                         if(self.air_finished < time + 9)
  22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  23                                         self.air_finished = time + 12;
  24                                         self.dmg = 2;
  25                                 }
  26                                 else if (self.air_finished < time)
  27                                 {       // drown!
  28                                         if (!self.deadflag)
  29                                         if (self.pain_finished < time)
  30                                         {
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
  32                                                 self.pain_finished = time + 0.5;
  33                                         }
  34                                 }
  35                                 if (self.dmgtime < time)
  36                                 {
  37                                         self.dmgtime = time + 0.1;
  38                                         if (self.watertype == CONTENT_LAVA)
  39                                         {
  40                                                 if (self.watersound_finished < time)
  41                                                 {
  42                                                         self.watersound_finished = time + 0.5;
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  44                                                 }
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  46                                         }
  47                                         else if (self.watertype == CONTENT_SLIME)
  48                                         {
  49                                                 if (self.watersound_finished < time)
  50                                                 {
  51                                                         self.watersound_finished = time + 0.5;
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  53                                                 }
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                         }
  58                         else
  59                         {
  60                                 if (self.flags & FL_INWATER)
  61                                 {
  62                                         // play leave water sound
  63                                         self.flags &~= FL_INWATER;
  64                                         self.dmgtime = 0;
  65                                 }
  66                                 self.air_finished = time + 12;
  67                                 self.dmg = 2;
  68                         }
  69                         // check for falling damage
  70                         if(!self.hook.state)
  71                         {
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  73                                 if (self.deadflag)
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
  75                                 else
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
  77                                 if (dm > 0)
  78                                 {
  79                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  80                                 }
  81                                 else if(vlen(self.velocity) > 100000 && cvar("developer"))
  82                                 {
  83                                         dprint(strcat(self.netname, " became too fast, please investigate: ", vtos(self.spawnorigin), "\n"));
  84                                         Damage (self, world, world, 50000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
  85                                 }
  86                         }
  87
  88                         // play stupid sounds
  89                         if (g_footsteps)
  90                         if (!gameover)
  91                         if (self.flags & FL_ONGROUND)
  92                         if (vlen(self.velocity) > sv_maxspeed * 0.6)
  93                         if (!self.deadflag)
  94                         if (time < self.lastground + 0.2)
  95                         {
  96                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
  97                                 {
  98                                         self.nextstep = time + 0.3 + random() * 0.1;
  99                                         trace_dphitq3surfaceflags = 0;
 100                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 101                                         /*
 102                                         if(trace_fraction == 1)
 103                                                 dprint("nohit\n");
 104                                         else
 105                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 106                                         */
 107                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 108                                         {
 109                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 110                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 111                                                 else
 112                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 113                                         }
 114                                 }
 115                         }
 116                         self.oldvelocity = self.velocity;
 117                 }
 118                 self = findfloat(self, iscreature, TRUE);
 119         }
 120         self = oldself;
 121 }
 122
 123
 124 /*
 125 =============
 126 StartFrame
 127
 128 Called before each frame by the server
 129 =============
 130 */
 131 void RuneMatchGivePoints();
 132 float RedirectionThink();
 133 entity SelectSpawnPoint (float anypoint);
 134 void StartFrame (void)
 135 {
 136         remove = remove_unsafely; // not during spawning!
 137         serverprevtime = servertime;
 138         servertime = time;
 139         serverframetime = frametime;
 140
 141 #ifdef PROFILING
 142         if(time > client_cefc_accumulatortime + 1)
 143         {
 144                 float t, pp, c_seeing, c_seen;
 145                 entity cl;
 146                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 147                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 148                 c_seeing = 0;
 149                 c_seen = 0;
 150                 FOR_EACH_CLIENT(cl)
 151                 {
 152                         if(clienttype(cl) == CLIENTTYPE_REAL)
 153                                 ++c_seeing;
 154                         if(cl.classname == "player")
 155                                 ++c_seen;
 156                 }
 157                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 158                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 159
 160                 client_cefc_accumulatortime = time;
 161                 client_cefc_accumulator = 0;
 162         }
 163 #endif
 164
 165         dprint_load(); // load dprint status from cvar
 166
 167         entity e;
 168         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 169                 CSQCProjectile_Check(e);
 170
 171         if(RedirectionThink())
 172                 return;
 173
 174         UncustomizeEntitiesRun();
 175         InitializeEntitiesRun();
 176
 177         sv_gravity = cvar("sv_gravity");
 178         sv_maxairspeed = cvar("sv_maxairspeed");
 179         sv_maxspeed = cvar ("sv_maxspeed");
 180         sv_friction = cvar ("sv_friction");
 181         sv_accelerate = cvar ("sv_accelerate");
 182         sv_airaccelerate = cvar("sv_airaccelerate");
 183         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");
 184         sv_airaccel_qw = cvar("sv_airaccel_qw");
 185         sv_stopspeed = cvar ("sv_stopspeed");
 186         sv_airstopaccelerate = cvar("sv_airstopaccelerate");
 187         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");
 188         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");
 189         sv_aircontrol = cvar("sv_aircontrol");
 190         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");
 191         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");
 192         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");
 193         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");
 194         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");
 195         teamplay = cvar ("teamplay");
 196         sys_ticrate = cvar("sys_ticrate");
 197         orig_slowmo = cvar("slowmo");
 198
 199         if(teams_matter && !teamplay)
 200                 teamplay = 3;
 201         if(!teams_matter && teamplay)
 202                 teamplay = 0;
 203
 204         skill = cvar("skill");
 205
 206         Spawnqueue_Check();
 207
 208         // if in warmup stage and limit for warmup is hit start match
 209         if (inWarmupStage
 210             && 0 < g_warmup_limit
 211             && time >= g_warmup_limit)
 212         {
 213                 ReadyRestart();
 214                 return;
 215         }
 216
 217         CreatureFrame ();
 218         CheckRules_World ();
 219
 220         AuditTeams();
 221
 222         RuneMatchGivePoints();
 223         bot_serverframe();
 224
 225         if(cvar("spawn_debugview"))
 226         {
 227                 RandomSelection_Init();
 228                 for(self = world; (self = find(self, classname, "player")); )
 229                         RandomSelection_Add(self, 0, string_null, 1, 0);
 230                 self = RandomSelection_chosen_ent;
 231                 SelectSpawnPoint(0);
 232         }
 233
 234         FOR_EACH_PLAYER(self)
 235                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 236 }
 237
 238 .vector originjitter;
 239 .vector anglesjitter;
 240 .float anglejitter;
 241 .string gametypefilter;
 242 void SV_OnEntityPreSpawnFunction()
 243 {
 244         if(self.gametypefilter != "")
 245         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
 246         {
 247                 remove(self);
 248                 return;
 249         }
 250
 251         // support special -1 and -2 angle from radiant
 252         if (self.angles == '0 -1 0')
 253                 self.angles = '-90 0 0';
 254         else if (self.angles == '0 -2 0')
 255                 self.angles = '+90 0 0';
 256
 257         if(self.originjitter_x != 0)
 258                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 259         if(self.originjitter_y != 0)
 260                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 261         if(self.originjitter_z != 0)
 262                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 263         if(self.anglesjitter_x != 0)
 264                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 265         if(self.anglesjitter_y != 0)
 266                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 267         if(self.anglesjitter_z != 0)
 268                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 269         if(self.anglejitter != 0)
 270                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 271 }