data/qcsrc/server/scores.qc

   1 .float scores[MAX_SCORE];
   2 .float teamscores[MAX_TEAMSCORE];
   3
   4 .entity scorekeeper;
   5 entity teamscorekeepers[16];
   6 string scores_label[MAX_SCORE];
   7 float scores_flags[MAX_SCORE];
   8 string teamscores_label[MAX_TEAMSCORE];
   9 float teamscores_flags[MAX_TEAMSCORE];
  10 float teamscores_entities_count;
  11 var .float scores_primary;
  12 var .float teamscores_primary;
  13
  14 void Net_LinkEntity(entity e)
  15 {
  16         e.model = "net_entity";
  17         e.modelindex = 1;
  18         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
  19 }
  20
  21 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous) // returns: cmp value, best prio
  22 {
  23         if(!(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  24                 return previous;
  25         if(fieldflags & SFL_SORT_PRIO_MASK < previous_y)
  26                 return previous;
  27         if(t1.field == t2.field)
  28                 return previous;
  29
  30         previous_y = fieldflags & SFL_SORT_PRIO_MASK;
  31
  32         if(fieldflags & SFL_LOWER_IS_BETTER)
  33                 previous_x = (t2.field - t1.field);
  34         else
  35                 previous_x = (t1.field - t2.field);
  36
  37         return previous;
  38 }
  39
  40 /*
  41  * teamscore entities
  42  */
  43
  44 float TeamScore_SendEntity(entity to)
  45 {
  46         float i;
  47
  48         WriteByte(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  49         WriteByte(MSG_ENTITY, self.team);
  50         for(i = 0; i < MAX_TEAMSCORE; ++i)
  51                 WriteShort(MSG_ENTITY, self.teamscores[i]);
  52
  53         return TRUE;
  54 }
  55
  56 void TeamScore_Spawn(float t, string name)
  57 {
  58         entity ts;
  59         ts = spawn();
  60         ts.classname = "csqc_score_team";
  61         ts.SendEntity = TeamScore_SendEntity;
  62         ts.netname = name; // not used yet, FIXME
  63         ts.Version = 1; // immediately send, so csqc knows about the team
  64         ts.team = t;
  65         Net_LinkEntity(ts);
  66         teamscorekeepers[t] = ts;
  67         ++teamscores_entities_count;
  68 }
  69
  70 float TeamScore_AddToTeam(float t, float scorefield, float score)
  71 {
  72         entity s;
  73         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
  74         s = teamscorekeepers[t];
  75         if(!s)
  76                 error("Adding score to unknown team!");
  77         if(score)
  78                 s.Version += 1;
  79         return (s.(teamscores[scorefield]) += score);
  80 }
  81
  82 float TeamScore_Add(entity player, float scorefield, float score)
  83 {
  84         return TeamScore_AddToTeam(player.team, scorefield, score);
  85 }
  86
  87 float TeamScore_Compare(entity t1, entity t2)
  88 {
  89         if(!t1 || !t2) return (!t2) - !t1;
  90
  91         vector result;
  92         float i;
  93         for(i = 0; i < MAX_TEAMSCORE; ++i)
  94         {
  95                 var .float f;
  96                 f = teamscores[i];
  97                 result = ScoreField_Compare(t1, t2, f, teamscores_flags[i], result);
  98         }
  99         return result_x;
 100 }
 101
 102 /*
 103  * the scoreinfo entity
 104  */
 105
 106 void ScoreInfo_SetLabel_PlayerScore(float i, string label, float scoreflags)
 107 {
 108         scores_label[i] = label;
 109         scores_flags[i] = scoreflags;
 110         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 111                 scores_primary = scores[i];
 112 }
 113
 114 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 115 {
 116         teamscores_label[i] = label;
 117         teamscores_flags[i] = scoreflags;
 118         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 119                 teamscores_primary = teamscores[i];
 120 }
 121
 122 float ScoreInfo_SendEntity(entity to)
 123 {
 124         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 125         float i;
 126         WriteByte(MSG_ENTITY, game);
 127         for(i = 0; i < MAX_SCORE; ++i)
 128         {
 129                 WriteString(MSG_ENTITY, scores_label[i]);
 130                 WriteByte(MSG_ENTITY, scores_flags[i]);
 131         }
 132         for(i = 0; i < MAX_TEAMSCORE; ++i)
 133         {
 134                 WriteString(MSG_ENTITY, teamscores_label[i]);
 135                 WriteByte(MSG_ENTITY, teamscores_flags[i]);
 136         }
 137         return TRUE;
 138 }
 139
 140 void ScoreInfo_Init(float teams)
 141 {
 142         scores_initialized = 1;
 143         if(teams >= 1)
 144                 TeamScore_Spawn(COLOR_TEAM1, "Red");
 145         if(teams >= 2)
 146                 TeamScore_Spawn(COLOR_TEAM2, "Blue");
 147         if(teams >= 3)
 148                 TeamScore_Spawn(COLOR_TEAM3, "Yellow");
 149         if(teams >= 4)
 150                 TeamScore_Spawn(COLOR_TEAM4, "Pink");
 151         entity si;
 152         si = spawn();
 153         Net_LinkEntity(si);
 154         si.classname = "csqc_score_info";
 155         si.SendEntity = ScoreInfo_SendEntity;
 156         si.Version = 1;
 157 }
 158
 159 /*
 160  * per-player score entities
 161  */
 162
 163 float PlayerScore_SendEntity()
 164 {
 165         float i;
 166
 167         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES);
 168         WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 169         for(i = 0; i < MAX_SCORE; ++i)
 170                 WriteShort(MSG_ENTITY, self.scores[i]);
 171
 172         return TRUE;
 173 }
 174
 175 void PlayerScore_Clear(entity player)
 176 {
 177         entity sk;
 178         float i;
 179
 180         if(teamscores_entities_count)
 181                 return;
 182         if(g_lms)
 183                 return;
 184
 185         sk = player.scorekeeper;
 186         for(i = 0; i < MAX_SCORE; ++i)
 187                 sk.(scores[i]) = 0;
 188         sk.Version += 1;
 189 }
 190
 191 void Score_ClearAll()
 192 {
 193         entity p, sk;
 194         float i;
 195         FOR_EACH_CLIENTSLOT(p)
 196         {
 197                 sk = p.scorekeeper;
 198                 if(!sk)
 199                         continue;
 200                 for(i = 0; i < MAX_SCORE; ++i)
 201                         sk.(scores[i]) = 0;
 202                 sk.Version += 1;
 203         }
 204         for(i = 0; i < 16; ++i)
 205         {
 206                 sk = teamscorekeepers[i];
 207                 if(!sk)
 208                         continue;
 209                 for(i = 0; i < MAX_SCORE; ++i)
 210                         sk.(teamscores[i]) = 0;
 211                 sk.Version += 1;
 212         }
 213 }
 214
 215 void PlayerScore_Attach(entity player)
 216 {
 217         entity sk;
 218         if(player.scorekeeper)
 219                 error("player already has a scorekeeper");
 220         sk = spawn();
 221         sk.owner = player;
 222         sk.Version = 1;
 223         sk.SendEntity = PlayerScore_SendEntity;
 224         Net_LinkEntity(sk);
 225         player.scorekeeper = sk;
 226 }
 227
 228 void PlayerScore_Detach(entity player)
 229 {
 230         if(!player.scorekeeper)
 231                 error("player has no scorekeeper");
 232         remove(player.scorekeeper);
 233         player.scorekeeper = world;
 234 }
 235
 236 float PlayerScore_Add(entity player, float scorefield, float score)
 237 {
 238         entity s;
 239         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 240         s = player.scorekeeper;
 241         if(!s)
 242                 error("Adding score to unknown player!");
 243         if(score)
 244                 s.Version += 1;
 245         return (s.(scores[scorefield]) += score);
 246 }
 247
 248 void PlayerTeamScore_Add(entity player, float pscorefield, float tscorefield, float score)
 249 {
 250         PlayerScore_Add(player, pscorefield, score);
 251         if(teamscores_entities_count) // only for teamplay
 252                 TeamScore_Add(player, tscorefield, score);
 253 }
 254
 255 float PlayerScore_Compare(entity t1, entity t2)
 256 {
 257         if(!t1 || !t2) return (!t2) - !t1;
 258
 259         vector result;
 260         float i;
 261         for(i = 0; i < MAX_SCORE; ++i)
 262         {
 263                 var .float f;
 264                 f = scores[i];
 265                 result = ScoreField_Compare(t1, t2, f, scores_flags[i], result);
 266         }
 267         return result_x;
 268 }
 269
 270 void WinningConditionHelper()
 271 {
 272         float c;
 273         if(teamscores_entities_count)
 274         {
 275                 float t;
 276                 WinningConditionHelper_equality = 1;
 277                 WinningConditionHelper_winnerteam = 0;
 278                 for(t = 1; t < 16; ++t)
 279                 {
 280                         c = TeamScore_Compare(teamscorekeepers[WinningConditionHelper_winnerteam], teamscorekeepers[t]);
 281                         if(c == 0)
 282                                 WinningConditionHelper_equality = 1;
 283                         else if(c < 0)
 284                         {
 285                                 WinningConditionHelper_equality = 0;
 286                                 WinningConditionHelper_winnerteam = t;
 287                         }
 288                 }
 289
 290                 WinningConditionHelper_topscore = teamscorekeepers[WinningConditionHelper_winnerteam].teamscores_primary;
 291
 292                 WinningConditionHelper_winner = world;
 293                 if(WinningConditionHelper_equality)
 294                         WinningConditionHelper_winnerteam = -1;
 295         }
 296         else
 297         {
 298                 entity p;
 299                 WinningConditionHelper_equality = 1;
 300                 WinningConditionHelper_winner = world;
 301                 FOR_EACH_PLAYER(p)
 302                 {
 303                         c = PlayerScore_Compare(WinningConditionHelper_winner.scorekeeper, p.scorekeeper);
 304                         if(c == 0)
 305                                 WinningConditionHelper_equality = 1;
 306                         else if(c < 0)
 307                         {
 308                                 WinningConditionHelper_equality = 0;
 309                                 WinningConditionHelper_winner = p;
 310                         }
 311                 }
 312
 313                 WinningConditionHelper_topscore = WinningConditionHelper_winner.scorekeeper.scores_primary;
 314
 315                 if(WinningConditionHelper_equality)
 316                         WinningConditionHelper_winner = world;
 317                 WinningConditionHelper_winnerteam = -1;
 318         }
 319 }
 320
 321 void Score_DebugPrint()
 322 {
 323         entity p, sk;
 324         float i, t;
 325
 326         print("netname");
 327         for(i = 0; i < MAX_SCORE; ++i)
 328                 print(":", scores_label[i]);
 329         print("\n");
 330         FOR_EACH_PLAYER(p)
 331         {
 332                 sk = p.scorekeeper;
 333                 print(p.netname);
 334                 for(i = 0; i < MAX_SCORE; ++i)
 335                         print(":", ftos(sk.(scores[i])));
 336                 print("\n");
 337         }
 338
 339         print("teamname");
 340         for(i = 0; i < MAX_TEAMSCORE; ++i)
 341                 print(":", teamscores_label[i]);
 342         print("\n");
 343         for(t = 0; t < 16; ++t)
 344         {
 345                 sk = teamscorekeepers[t];
 346                 if(sk)
 347                 {
 348                         print(ftos(t));
 349                         for(i = 0; i < MAX_TEAMSCORE; ++i)
 350                                 print(":", ftos(sk.(teamscores[i])));
 351                         print("\n");
 352                 }
 353         }
 354 }