data/qcsrc/server/scores.qc

   1 .float scores[MAX_SCORE];
   2 .float teamscores[MAX_TEAMSCORE];
   3
   4 .entity scorekeeper;
   5 entity teamscorekeepers[16];
   6 string scores_label[MAX_SCORE];
   7 float scores_flags[MAX_SCORE];
   8 string teamscores_label[MAX_TEAMSCORE];
   9 float teamscores_flags[MAX_TEAMSCORE];
  10 float teamscores_entities_count;
  11 var .float scores_primary;
  12 var .float teamscores_primary;
  13 float scores_initialized;
  14
  15 void Net_LinkEntity(entity e)
  16 {
  17         e.model = "net_entity";
  18         e.modelindex = 1;
  19         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
  20 }
  21
  22 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous) // returns: cmp value, best prio
  23 {
  24         if(!(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  25                 return previous;
  26         if(fieldflags & SFL_SORT_PRIO_MASK < previous_y)
  27                 return previous;
  28         if(t1.field == t2.field)
  29                 return previous;
  30
  31         previous_y = fieldflags & SFL_SORT_PRIO_MASK;
  32
  33         if(fieldflags & SFL_DECREASING)
  34                 previous_x = (t1.field - t2.field);
  35         else
  36                 previous_x = (t2.field - t1.field);
  37
  38         return previous;
  39 }
  40
  41 /*
  42  * teamscore entities
  43  */
  44
  45 float TeamScore_SendEntity(entity to)
  46 {
  47         float i;
  48
  49         WriteByte(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  50         WriteByte(MSG_ENTITY, self.team);
  51         for(i = 0; i < MAX_TEAMSCORE; ++i)
  52                 WriteShort(MSG_ENTITY, self.teamscores[i]);
  53
  54         return TRUE;
  55 }
  56
  57 void TeamScore_Spawn(float t, string name)
  58 {
  59         entity ts;
  60         ts = spawn();
  61         ts.classname = "csqc_score_team";
  62         ts.SendEntity = TeamScore_SendEntity;
  63         ts.netname = name; // not used yet, FIXME
  64         ts.Version = 1; // immediately send, so csqc knows about the team
  65         ts.team = t;
  66         Net_LinkEntity(ts);
  67         teamscorekeepers[t] = ts;
  68         ++teamscores_entities_count;
  69 }
  70
  71 void TeamScore_Add(entity player, float scorefield, float score)
  72 {
  73         entity s;
  74         if(!scores_initialized) return; // FIXME remove this when everything uses this system
  75         s = teamscorekeepers[player.team];
  76         if(!s)
  77                 error("Adding score to unknown team!");
  78         s.(teamscores[scorefield]) += score;
  79         s.Version += 1;
  80 }
  81
  82 float TeamScore_Compare(entity t1, entity t2)
  83 {
  84         if(!t1 || !t2) return (!t2) - !t1;
  85
  86         vector result;
  87         float i;
  88         for(i = 0; i < MAX_TEAMSCORE; ++i)
  89                 result = ScoreField_Compare(t1, t2, teamscores[i], teamscores_flags[i], result);
  90         return result_x;
  91 }
  92
  93 /*
  94  * the scoreinfo entity
  95  */
  96
  97 void ScoreInfo_SetLabel_PlayerScore(float i, string label, float scoreflags)
  98 {
  99         scores_label[i] = label;
 100         scores_flags[i] = scoreflags;
 101         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 102                 scores_primary = scores[i];
 103 }
 104
 105 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 106 {
 107         teamscores_label[i] = label;
 108         teamscores_flags[i] = scoreflags;
 109         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 110                 teamscores_primary = teamscores[i];
 111 }
 112
 113 float ScoreInfo_SendEntity(entity to)
 114 {
 115         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 116         float i;
 117         WriteByte(MSG_ENTITY, game);
 118         for(i = 0; i < MAX_SCORE; ++i)
 119         {
 120                 WriteString(MSG_ENTITY, scores_label[i]);
 121                 WriteByte(MSG_ENTITY, scores_flags[i]);
 122         }
 123         for(i = 0; i < MAX_TEAMSCORE; ++i)
 124         {
 125                 WriteString(MSG_ENTITY, teamscores_label[i]);
 126                 WriteByte(MSG_ENTITY, teamscores_flags[i]);
 127         }
 128         return TRUE;
 129 }
 130
 131 void ScoreInfo_Init(float teams)
 132 {
 133         scores_initialized = 1;
 134         if(teams >= 1)
 135                 TeamScore_Spawn(COLOR_TEAM1, "Red");
 136         if(teams >= 2)
 137                 TeamScore_Spawn(COLOR_TEAM2, "Blue");
 138         if(teams >= 3)
 139                 TeamScore_Spawn(COLOR_TEAM3, "Yellow");
 140         if(teams >= 4)
 141                 TeamScore_Spawn(COLOR_TEAM4, "Pink");
 142         entity si;
 143         si = spawn();
 144         Net_LinkEntity(si);
 145         si.classname = "csqc_score_info";
 146         si.SendEntity = ScoreInfo_SendEntity;
 147         si.Version = 1;
 148 }
 149
 150 /*
 151  * per-player score entities
 152  */
 153
 154 float PlayerScore_SendEntity()
 155 {
 156         float i;
 157
 158         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES);
 159         WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 160         for(i = 0; i < MAX_SCORE; ++i)
 161                 WriteShort(MSG_ENTITY, self.scores[i]);
 162
 163         return TRUE;
 164 }
 165
 166 void PlayerScore_Clear(entity player)
 167 {
 168         entity sk;
 169         float i;
 170
 171         if(!teamscores_entities_count)
 172         {
 173                 sk = player.scorekeeper;
 174                 for(i = 0; i < MAX_SCORE; ++i)
 175                         sk.(scores[i]) = 0;
 176                 sk.Version += 1;
 177         }
 178 }
 179
 180 void Score_ClearAll()
 181 {
 182         entity p, sk;
 183         float i;
 184         FOR_EACH_CLIENTSLOT(p)
 185         {
 186                 sk = p.scorekeeper;
 187                 if(!sk)
 188                         continue;
 189                 for(i = 0; i < MAX_SCORE; ++i)
 190                         sk.(scores[i]) = 0;
 191                 sk.Version += 1;
 192         }
 193         for(i = 0; i < 16; ++i)
 194         {
 195                 sk = teamscorekeepers[i];
 196                 if(!sk)
 197                         continue;
 198                 for(i = 0; i < MAX_SCORE; ++i)
 199                         sk.(teamscores[i]) = 0;
 200                 sk.Version += 1;
 201         }
 202 }
 203
 204 void PlayerScore_Attach(entity player)
 205 {
 206         entity sk;
 207         if(player.scorekeeper)
 208                 error("player already has a scorekeeper");
 209         sk = spawn();
 210         sk.owner = player;
 211         sk.Version = 1;
 212         sk.SendEntity = PlayerScore_SendEntity;
 213         Net_LinkEntity(sk);
 214         player.scorekeeper = sk;
 215 }
 216
 217 void PlayerScore_Detach(entity player)
 218 {
 219         if(!player.scorekeeper)
 220                 error("player has no scorekeeper");
 221         remove(player.scorekeeper);
 222         player.scorekeeper = world;
 223 }
 224
 225 void PlayerScore_Add(entity player, float scorefield, float score)
 226 {
 227         entity s;
 228         if(!scores_initialized) return; // FIXME remove this when everything uses this system
 229         s = player.scorekeeper;
 230         if(!s)
 231                 error("Adding score to unknown player!");
 232         s.(scores[scorefield]) += score;
 233         s.Version += 1;
 234 }
 235
 236 void PlayerTeamScore_Add(entity player, float pscorefield, float tscorefield, float score)
 237 {
 238         PlayerScore_Add(player, pscorefield, score);
 239         if(teamscores_entities_count) // only for teamplay
 240                 TeamScore_Add(player, tscorefield, score);
 241 }
 242
 243 float PlayerScore_Compare(entity t1, entity t2)
 244 {
 245         if(!t1 || !t2) return (!t2) - !t1;
 246
 247         vector result;
 248         float i;
 249         for(i = 0; i < MAX_TEAMSCORE; ++i)
 250                 result = ScoreField_Compare(t1, t2, scores[i], scores_flags[i], result);
 251         return result_x;
 252 }
 253
 254 void WinningConditionHelper()
 255 {
 256         float c;
 257         if(teamscores_entities_count)
 258         {
 259                 float t;
 260                 WinningConditionHelper_equality = 1;
 261                 WinningConditionHelper_winnerteam = 0;
 262                 for(t = 1; t < 16; ++t)
 263                 {
 264                         c = TeamScore_Compare(teamscorekeepers[WinningConditionHelper_winnerteam], teamscorekeepers[t]);
 265                         if(c == 0)
 266                                 WinningConditionHelper_equality = 1;
 267                         else if(c < 0)
 268                         {
 269                                 WinningConditionHelper_equality = 0;
 270                                 WinningConditionHelper_winnerteam = t;
 271                         }
 272                 }
 273
 274                 WinningConditionHelper_topscore = teamscorekeepers[WinningConditionHelper_winnerteam].teamscores_primary;
 275
 276                 WinningConditionHelper_winner = world;
 277                 if(WinningConditionHelper_equality)
 278                         WinningConditionHelper_winnerteam = -1;
 279         }
 280         else
 281         {
 282                 entity p;
 283                 WinningConditionHelper_equality = 1;
 284                 WinningConditionHelper_winner = world;
 285                 FOR_EACH_PLAYER(p)
 286                 {
 287                         c = PlayerScore_Compare(WinningConditionHelper_winner.scorekeeper, p.scorekeeper);
 288                         if(c == 0)
 289                                 WinningConditionHelper_equality = 1;
 290                         else if(c < 0)
 291                         {
 292                                 WinningConditionHelper_equality = 0;
 293                                 WinningConditionHelper_winner = p;
 294                         }
 295                 }
 296
 297                 WinningConditionHelper_topscore = WinningConditionHelper_winner.scorekeeper.scores_primary;
 298
 299                 if(WinningConditionHelper_equality)
 300                         WinningConditionHelper_winner = world;
 301                 WinningConditionHelper_winnerteam = -1;
 302         }
 303 }
 304
 305 void Score_DebugPrint()
 306 {
 307         entity p, sk;
 308         float i, t;
 309
 310         print("netname");
 311         for(i = 0; i < MAX_SCORE; ++i)
 312                 print(":", scores_label[i]);
 313         print("\n");
 314         FOR_EACH_PLAYER(p)
 315         {
 316                 sk = p.scorekeeper;
 317                 print(p.netname);
 318                 for(i = 0; i < MAX_SCORE; ++i)
 319                         print(":", ftos(sk.(scores[i])));
 320                 print("\n");
 321         }
 322
 323         print("teamname");
 324         for(i = 0; i < MAX_TEAMSCORE; ++i)
 325                 print(":", teamscores_label[i]);
 326         print("\n");
 327         for(t = 0; t < 16; ++t)
 328         {
 329                 sk = teamscorekeepers[t];
 330                 if(sk)
 331                 {
 332                         print(ftos(t));
 333                         for(i = 0; i < MAX_TEAMSCORE; ++i)
 334                                 print(":", ftos(sk.(teamscores[i])));
 335                         print("\n");
 336                 }
 337         }
 338 }