data/qcsrc/server/portals.qc

   1 .vector portal_transform;
   2 .vector portal_safe_origin;
   3 .float portal_wants_to_vanish;
   4 .float portal_activatetime;
   5 .float portal_id;
   6
   7 .entity portal_in, portal_out;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward);
  22         m_up = Portal_Transform_Apply(t1, m_up);
  23         return vectoangles2(m_forward, m_up);
  24 }
  25
  26 vector Portal_Transform_Invert(vector transform)
  27 {
  28         vector i_forward, i_up;
  29         fixedmakevectors(transform);
  30         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  31         // but these are orthogonal unit vectors!
  32         // so to invert, we can simply vectoangles the TRANSPOSED matrix
  33         // TODO is this always -transform?
  34         i_forward_x = v_forward_x;
  35         i_forward_y = -v_right_x;
  36         i_forward_z = v_up_x;
  37         i_up_x = v_forward_z;
  38         i_up_y = -v_right_z;
  39         i_up_z = v_up_z;
  40 #ifdef DEBUG
  41         vector v;
  42         v = vectoangles2(i_forward, i_up);
  43         print("Transform: ", vtos(transform), "\n");
  44         print("Inverted: ", vtos(v), "\n");
  45         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  46         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  47         print("Verify: ", vtos(v_forward), "\n");
  48         print("Verify: ", vtos(v_right), "\n");
  49         print("Verify: ", vtos(v_up), "\n");
  50 #endif
  51         return vectoangles2(i_forward, i_up);
  52 }
  53
  54 vector Portal_Transform_TurnDirection(vector transform)
  55 {
  56         // turn 180 degrees around v_up
  57         // changes in-direction to out-direction
  58         fixedmakevectors(transform);
  59         return vectoangles2(-1 * v_forward, 1 * v_up);
  60 }
  61
  62 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  63 {
  64         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  65 }
  66
  67 float PlayerEdgeDistance(entity p, vector v)
  68 {
  69         vector vbest;
  70
  71         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  72         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  73         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  74
  75         return vbest * v;
  76 }
  77
  78 .vector right_vector;
  79 float Portal_TeleportPlayer(entity teleporter, entity player)
  80 {
  81         vector from, to, safe, step, transform, ang, newvel;
  82         float planeshift, s, t;
  83         from = teleporter.origin;
  84         transform = teleporter.portal_transform;
  85
  86         to = teleporter.enemy.origin;
  87         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  88         newvel = Portal_Transform_Apply(transform, player.velocity);
  89         // this now is INSIDE the plane... can't use that
  90
  91         // shift it out
  92         fixedmakevectors(teleporter.enemy.angles);
  93
  94         // first shift it ON the plane if needed
  95         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward);
  96         if(planeshift > 0)
  97                 to += newvel * (planeshift / (newvel * v_forward));
  98
  99         s = (to - teleporter.enemy.origin) * v_right;
 100         t = (to - teleporter.enemy.origin) * v_up;
 101         s = bound(-48, s, 48);
 102         t = bound(-48, t, 48);
 103         to = teleporter.enemy.origin
 104            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 105            +     s                                        * v_right
 106            +     t                                        * v_up;
 107
 108         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 109         step = to + ((safe - to) * v_forward) * v_forward;
 110         tracebox(safe, PL_MIN, PL_MAX, step, MOVE_NOMONSTERS, player);
 111         if(trace_startsolid)
 112         {
 113                 bprint("'safe' teleport location is not safe!\n");
 114                 // FAIL TODO why does this happen?
 115                 return 0;
 116         }
 117         safe = trace_endpos;
 118         tracebox(safe, PL_MIN, PL_MAX, to, MOVE_NOMONSTERS, player);
 119         if(trace_startsolid)
 120                 error("trace_endpos in solid!");
 121         to = trace_endpos;
 122
 123         // ang_x stuff works around weird quake angles
 124         if(player.classname == "player")
 125         {
 126                 ang = player.v_angle;
 127                 ang_x = -ang_x;
 128                 ang = Portal_Transform_Multiply(transform, ang);
 129                 ang_z = player.angles_z;
 130         }
 131         else
 132         {
 133                 ang = player.angles;
 134                 ang_x = -ang_x;
 135                 ang = Portal_Transform_Multiply(transform, player.angles);
 136         }
 137         ang_x = -ang_x;
 138
 139         // factor -1 allows chaining portals, but may be weird
 140         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 141
 142         if(player.flagcarried)
 143                 DropFlag(player.flagcarried);
 144         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 145
 146         // reset fade counter
 147         teleporter.portal_wants_to_vanish = 0;
 148         teleporter.fade_time = time + 15;
 149         teleporter.enemy.health = 300;
 150
 151         return 1;
 152 }
 153
 154 float Portal_FindSafeOrigin(entity portal)
 155 {
 156         vector o;
 157         o = portal.origin;
 158         portal.mins = PL_MIN - '8 8 8';
 159         portal.maxs = PL_MAX + '8 8 8';
 160         fixedmakevectors(portal.angles);
 161         portal.origin += 16 * v_forward;
 162         if(!move_out_of_solid(portal))
 163         {
 164 #ifdef DEBUG
 165                 print("NO SAFE ORIGIN\n");
 166 #endif
 167                 return 0;
 168         }
 169         portal.portal_safe_origin = portal.origin;
 170         setorigin(portal, o);
 171         return 1;
 172 }
 173
 174 void Portal_Touch()
 175 {
 176         if(other.classname == "porto")
 177         {
 178                 if(other.portal_id == self.portal_id)
 179                         return;
 180         }
 181         if(time < self.portal_activatetime)
 182                 if(other == self.owner)
 183                 {
 184                         self.portal_activatetime = time + 0.1;
 185                         return;
 186                 }
 187         fixedmakevectors(self.angles);
 188         if((other.origin - self.origin) * v_forward < 0)
 189                 return;
 190         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 191         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 192         {
 193                 // can't teleport this
 194                 return;
 195         }
 196         if(Portal_TeleportPlayer(self, other))
 197                 if(other.classname == "porto")
 198                         if(other.cnt == 0)
 199                                 other.cnt = 1;
 200 }
 201
 202 void Portal_MakeBrokenPortal(entity portal)
 203 {
 204         portal.solid = SOLID_NOT;
 205         portal.touch = SUB_Null;
 206         portal.effects = 0;
 207         //portal.colormod = '1 1 1';
 208         portal.nextthink = 0;
 209         portal.takedamage = DAMAGE_NO;
 210 }
 211
 212 void Portal_MakeWaitingPortal(entity portal)
 213 {
 214         portal.solid = SOLID_NOT;
 215         portal.touch = SUB_Null;
 216         portal.effects = EF_ADDITIVE;
 217         portal.colormod = '1 1 1';
 218         portal.nextthink = 0;
 219         portal.takedamage = DAMAGE_YES;
 220 }
 221
 222 void Portal_MakeInPortal(entity portal)
 223 {
 224         portal.solid = SOLID_TRIGGER;
 225         portal.touch = Portal_Touch;
 226         portal.effects = EF_RED;
 227         portal.colormod = '1 0 0';
 228         portal.nextthink = time;
 229         portal.takedamage = DAMAGE_NO;
 230 }
 231
 232 void Portal_MakeOutPortal(entity portal)
 233 {
 234         portal.solid = SOLID_NOT;
 235         portal.touch = SUB_Null;
 236         portal.effects = EF_STARDUST | EF_BLUE;
 237         portal.colormod = '0 0 1';
 238         portal.nextthink = 0;
 239         portal.takedamage = DAMAGE_YES;
 240 }
 241
 242 void Portal_Disconnect(entity teleporter, entity destination)
 243 {
 244         teleporter.enemy = world;
 245         destination.enemy = world;
 246         Portal_MakeBrokenPortal(teleporter);
 247         Portal_MakeBrokenPortal(destination);
 248 }
 249
 250 void Portal_Connect(entity teleporter, entity destination)
 251 {
 252         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 253
 254 #ifdef DEBUG
 255         {
 256                 // let's verify the transform
 257                 vector in_f, in_r, in_u;
 258                 vector out_f, out_r, out_u;
 259                 fixedmakevectors(teleporter.angles);
 260                 in_f = v_forward;
 261                 in_r = v_right;
 262                 in_u = v_up;
 263                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 264                 fixedmakevectors(destination.angles);
 265                 out_f = v_forward;
 266                 out_r = v_right;
 267                 out_u = v_up;
 268                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 269                 // INTENDED TRANSFORM:
 270                 //   in_f -> -out_f
 271                 //   in_r -> -out_r
 272                 //   in_u -> +out_u
 273                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 274                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 275                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 276
 277                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 278                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 279         }
 280 #endif
 281
 282         teleporter.enemy = destination;
 283         destination.enemy = teleporter;
 284         Portal_MakeInPortal(teleporter);
 285         Portal_MakeOutPortal(destination);
 286         teleporter.fade_time = time + 15;
 287         destination.fade_time = time + 15;
 288         teleporter.portal_wants_to_vanish = 0;
 289         destination.portal_wants_to_vanish = 0;
 290 }
 291
 292 void Portal_Remove(entity portal, float killed)
 293 {
 294         entity e;
 295         e = portal.enemy;
 296
 297         if(e)
 298         {
 299                 Portal_Disconnect(portal, e);
 300                 Portal_Remove(e, killed);
 301         }
 302
 303         if(portal == portal.owner.portal_in)
 304                 portal.owner.portal_in = world;
 305         if(portal == portal.owner.portal_out)
 306                 portal.owner.portal_out = world;
 307         portal.owner = world;
 308
 309         // makes the portal vanish
 310         if(killed)
 311         {
 312                 fixedmakevectors(portal.angles);
 313                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 314                 remove(portal);
 315         }
 316         else
 317         {
 318                 Portal_MakeBrokenPortal(portal);
 319                 SUB_SetFade(portal, time, 0.5);
 320         }
 321 }
 322
 323 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 324 {
 325         if(deathtype == DEATH_TELEFRAG)
 326                 return;
 327         self.health -= damage;
 328         if(self.health < 0)
 329         {
 330                 Portal_Remove(self, 1);
 331         }
 332 }
 333
 334 void Portal_Think()
 335 {
 336         entity e, o;
 337
 338         if(self.solid != SOLID_TRIGGER)
 339                 error("Portal_Think called for a portal that should not be thinking");
 340
 341         o = self.owner;
 342         self.solid = SOLID_BBOX;
 343         self.owner = world;
 344         FOR_EACH_PLAYER(e)
 345         {
 346                 if(time < self.portal_activatetime)
 347                         if(e == o)
 348                                 continue;
 349                 // if e would hit the portal in a frame...
 350                 // already teleport him
 351                 tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 352                 if(trace_ent == self)
 353                         Portal_TeleportPlayer(self, e);
 354         }
 355         self.solid = SOLID_TRIGGER;
 356         self.owner = o;
 357
 358         self.nextthink = time;
 359
 360         if(time > self.fade_time)
 361                 Portal_Remove(self, 0);
 362 }
 363
 364
 365 // cleanup:
 366 //   when creating in-portal:
 367 //     disconnect
 368 //     clear existing in-portal
 369 //     set as in-portal
 370 //     connect
 371 //   when creating out-portal:
 372 //     disconnect
 373 //     clear existing out-portal
 374 //     set as out-portal
 375 //   when player dies:
 376 //     disconnect portals
 377 //     clear both portals
 378 //   after timeout of in-portal:
 379 //     disconnect portals
 380 //     clear both portals
 381 //   TODO: ensure only one portal shot at once
 382 float Portal_SetInPortal(entity own, entity portal)
 383 {
 384         if(own.portal_in)
 385         {
 386                 if(own.portal_out)
 387                         Portal_Disconnect(own.portal_in, own.portal_out);
 388                 Portal_Remove(own.portal_in, 0);
 389         }
 390         own.portal_in = portal;
 391         if(own.portal_out)
 392                 Portal_Connect(own.portal_in, own.portal_out);
 393         return 2;
 394 }
 395 float Portal_SetOutPortal(entity own, entity portal)
 396 {
 397         if(own.portal_out)
 398         {
 399                 if(own.portal_in)
 400                         Portal_Disconnect(own.portal_in, own.portal_out);
 401                 Portal_Remove(own.portal_out, 0);
 402         }
 403         own.portal_out = portal;
 404         if(own.portal_in)
 405                 Portal_Connect(own.portal_in, own.portal_out);
 406         return 1;
 407 }
 408 void Portal_ClearAll(entity own)
 409 {
 410         if(own.portal_in)
 411                 Portal_Remove(own.portal_in, 0);
 412         if(own.portal_out)
 413                 Portal_Remove(own.portal_out, 0);
 414 }
 415 void Portal_ClearWithID(entity own, float id)
 416 {
 417         if(own.portal_in)
 418                 if(own.portal_in.portal_id == id)
 419                 {
 420                         if(own.portal_out)
 421                                 Portal_Disconnect(own.portal_in, own.portal_out);
 422                         Portal_Remove(own.portal_in, 0);
 423                 }
 424         if(own.portal_out)
 425                 if(own.portal_out.portal_id == id)
 426                 {
 427                         if(own.portal_in)
 428                                 Portal_Disconnect(own.portal_in, own.portal_out);
 429                         Portal_Remove(own.portal_out, 0);
 430                 }
 431 }
 432
 433 entity Portal_Spawn(entity own, vector org, vector ang)
 434 {
 435         entity portal;
 436
 437         fixedmakevectors(ang);
 438         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 439                 return world;
 440
 441         portal = spawn();
 442         portal.classname = "portal";
 443         portal.owner = own;
 444         portal.origin = org;
 445         portal.angles = ang;
 446         portal.think = Portal_Think;
 447         portal.nextthink = 0;
 448         portal.fade_time = time + 15;
 449         portal.portal_activatetime = time + 0.1;
 450         portal.event_damage = Portal_Damage;
 451         portal.health = 300;
 452         setmodel(portal, "models/portal.md3");
 453
 454         if(!Portal_FindSafeOrigin(portal))
 455         {
 456                 remove(portal);
 457                 return world;
 458         }
 459
 460         setsize(portal, '-48 -48 -48', '48 48 48');
 461         Portal_MakeWaitingPortal(portal);
 462
 463         return portal;
 464 }
 465
 466 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 467 {
 468         entity portal;
 469         vector ang;
 470         vector org;
 471
 472         if(trace_ent.movetype == MOVETYPE_WALK)
 473         {
 474                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 475                 trace_plane_normal = '0 0 1';
 476                 dir = -1 * dir; // create telefrag portals the other way round
 477         }
 478
 479         org = trace_endpos;
 480         ang = vectoangles2(trace_plane_normal, dir);
 481         fixedmakevectors(ang);
 482
 483         portal = Portal_Spawn(own, org, ang);
 484         if(!portal)
 485         {
 486                 if(!self.portal_out || self.portal_out.portal_id == portal_id_val)
 487                         Portal_ClearAll(own);
 488                 return 0;
 489         }
 490
 491         portal.portal_id = portal_id_val;
 492         Portal_SetInPortal(own, portal);
 493
 494         return 1;
 495 }
 496
 497 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 498 {
 499         entity portal;
 500         vector ang;
 501         vector org;
 502
 503         if(trace_ent.movetype == MOVETYPE_WALK)
 504         {
 505                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 506                 trace_plane_normal = '0 0 1';
 507                 dir = -1 * dir; // create telefrag portals the other way round
 508         }
 509
 510         org = trace_endpos;
 511         ang = vectoangles2(trace_plane_normal, dir);
 512         fixedmakevectors(ang);
 513
 514         portal = Portal_Spawn(own, org, ang);
 515         if(!portal)
 516         {
 517                 if(!self.portal_in || self.portal_in.portal_id == portal_id_val)
 518                         Portal_ClearAll(own);
 519                 return 0;
 520         }
 521
 522         portal.portal_id = portal_id_val;
 523         Portal_SetOutPortal(own, portal);
 524
 525         return 1;
 526 }