data/qcsrc/server/portals.qc

   1 .vector portal_transform;
   2 .vector portal_safe_origin;
   3 .float portal_wants_to_vanish;
   4 .float portal_activatetime;
   5 .float portal_id;
   6
   7 .entity portal_in, portal_out;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward);
  22         m_up = Portal_Transform_Apply(t1, m_up);
  23         return vectoangles2(m_forward, m_up);
  24 }
  25
  26 vector Portal_Transform_Invert(vector transform)
  27 {
  28         vector i_forward, i_up;
  29         fixedmakevectors(transform);
  30         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  31         // but these are orthogonal unit vectors!
  32         // so to invert, we can simply vectoangles the TRANSPOSED matrix
  33         // TODO is this always -transform?
  34         i_forward_x = v_forward_x;
  35         i_forward_y = -v_right_x;
  36         i_forward_z = v_up_x;
  37         i_up_x = v_forward_z;
  38         i_up_y = -v_right_z;
  39         i_up_z = v_up_z;
  40 #ifdef DEBUG
  41         vector v;
  42         v = vectoangles2(i_forward, i_up);
  43         print("Transform: ", vtos(transform), "\n");
  44         print("Inverted: ", vtos(v), "\n");
  45         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  46         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  47         print("Verify: ", vtos(v_forward), "\n");
  48         print("Verify: ", vtos(v_right), "\n");
  49         print("Verify: ", vtos(v_up), "\n");
  50 #endif
  51         return vectoangles2(i_forward, i_up);
  52 }
  53
  54 vector Portal_Transform_TurnDirection(vector transform)
  55 {
  56         // turn 180 degrees around v_up
  57         // changes in-direction to out-direction
  58         fixedmakevectors(transform);
  59         return vectoangles2(-1 * v_forward, 1 * v_up);
  60 }
  61
  62 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  63 {
  64         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  65 }
  66
  67 float PlayerEdgeDistance(entity p, vector v)
  68 {
  69         vector vbest;
  70
  71         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  72         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  73         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  74
  75         return vbest * v;
  76 }
  77
  78 .vector right_vector;
  79 float Portal_TeleportPlayer(entity teleporter, entity player)
  80 {
  81         vector from, to, safe, step, transform, ang, newvel;
  82         float planeshift, s, t;
  83         from = teleporter.origin;
  84         transform = teleporter.portal_transform;
  85
  86         to = teleporter.enemy.origin;
  87         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  88         newvel = Portal_Transform_Apply(transform, player.velocity);
  89         // this now is INSIDE the plane... can't use that
  90
  91         // shift it out
  92         fixedmakevectors(teleporter.enemy.angles);
  93
  94         // first shift it ON the plane if needed
  95         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
  96         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
  97                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
  98                 to += newvel * (planeshift / (newvel * v_forward));
  99         else
 100                 to += trace_plane_normal * planeshift;
 101
 102         s = (to - teleporter.enemy.origin) * v_right;
 103         t = (to - teleporter.enemy.origin) * v_up;
 104         s = bound(-48, s, 48);
 105         t = bound(-48, t, 48);
 106         to = teleporter.enemy.origin
 107            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 108            +     s                                        * v_right
 109            +     t                                        * v_up;
 110
 111         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 112         step = to + ((safe - to) * v_forward) * v_forward;
 113         tracebox(safe, PL_MIN, PL_MAX, step, MOVE_NOMONSTERS, player);
 114         if(trace_startsolid)
 115         {
 116                 bprint("'safe' teleport location is not safe!\n");
 117                 // FAIL TODO why does this happen?
 118                 return 0;
 119         }
 120         safe = trace_endpos;
 121         tracebox(safe, PL_MIN, PL_MAX, to, MOVE_NOMONSTERS, player);
 122         if(trace_startsolid)
 123                 error("trace_endpos in solid!");
 124         to = trace_endpos;
 125
 126         // ang_x stuff works around weird quake angles
 127         if(player.classname == "player")
 128         {
 129                 ang = player.v_angle;
 130                 ang_x = -ang_x;
 131                 ang = Portal_Transform_Multiply(transform, ang);
 132                 ang_z = player.angles_z;
 133         }
 134         else
 135         {
 136                 ang = player.angles;
 137                 ang_x = -ang_x;
 138                 ang = Portal_Transform_Multiply(transform, player.angles);
 139         }
 140         ang_x = -ang_x;
 141
 142         // factor -1 allows chaining portals, but may be weird
 143         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 144
 145         if(player.flagcarried)
 146                 DropFlag(player.flagcarried);
 147         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 148
 149         // reset fade counter
 150         teleporter.portal_wants_to_vanish = 0;
 151         teleporter.fade_time = time + 15;
 152         teleporter.enemy.health = 300;
 153
 154         return 1;
 155 }
 156
 157 float Portal_FindSafeOrigin(entity portal)
 158 {
 159         vector o;
 160         o = portal.origin;
 161         portal.mins = PL_MIN - '8 8 8';
 162         portal.maxs = PL_MAX + '8 8 8';
 163         fixedmakevectors(portal.angles);
 164         portal.origin += 16 * v_forward;
 165         if(!move_out_of_solid(portal))
 166         {
 167 #ifdef DEBUG
 168                 print("NO SAFE ORIGIN\n");
 169 #endif
 170                 return 0;
 171         }
 172         portal.portal_safe_origin = portal.origin;
 173         setorigin(portal, o);
 174         return 1;
 175 }
 176
 177 void Portal_Touch()
 178 {
 179         if(trace_fraction < 1)
 180                 return; // only handle TouchAreaGrid ones (only these can teleport)
 181                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 182         if(!self.enemy)
 183         {
 184                 objerror("Portal_Touch called for [unconnected] portal\n");
 185                 return;
 186         }
 187         if(other.classname == "porto")
 188         {
 189                 if(other.portal_id == self.portal_id)
 190                         return;
 191         }
 192         if(time < self.portal_activatetime)
 193                 if(other == self.owner)
 194                 {
 195                         self.portal_activatetime = time + 0.1;
 196                         return;
 197                 }
 198         if(other != self.owner)
 199                 if(other.classname == "player")
 200                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 201                                 return; // cannot go through someone else's portal
 202         if(other.owner != self.owner)
 203                 if(other.owner.classname == "player")
 204                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 205                                 return; // cannot go through someone else's portal
 206         fixedmakevectors(self.angles);
 207         if((other.origin - self.origin) * v_forward < 0)
 208                 return;
 209         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 210         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 211         {
 212                 // can't teleport this
 213                 return;
 214         }
 215
 216         if(Portal_TeleportPlayer(self, other))
 217                 if(other.classname == "porto")
 218                         if(other.effects & EF_RED)
 219                                 other.effects += EF_BLUE - EF_RED;
 220 }
 221
 222 void Portal_MakeBrokenPortal(entity portal)
 223 {
 224         portal.solid = SOLID_NOT;
 225         portal.touch = SUB_Null;
 226         portal.effects = 0;
 227         //portal.colormod = '1 1 1';
 228         portal.nextthink = 0;
 229         portal.takedamage = DAMAGE_NO;
 230 }
 231
 232 void Portal_MakeWaitingPortal(entity portal)
 233 {
 234         portal.solid = SOLID_NOT;
 235         portal.touch = SUB_Null;
 236         portal.effects = EF_ADDITIVE;
 237         portal.colormod = '1 1 1';
 238         portal.nextthink = 0;
 239         portal.takedamage = DAMAGE_YES;
 240 }
 241
 242 void Portal_MakeInPortal(entity portal)
 243 {
 244         portal.solid = SOLID_TRIGGER;
 245         portal.touch = Portal_Touch;
 246         portal.effects = EF_RED;
 247         portal.colormod = '1 0 0';
 248         portal.nextthink = time;
 249         portal.takedamage = DAMAGE_NO;
 250 }
 251
 252 void Portal_MakeOutPortal(entity portal)
 253 {
 254         portal.solid = SOLID_NOT;
 255         portal.touch = SUB_Null;
 256         portal.effects = EF_STARDUST | EF_BLUE;
 257         portal.colormod = '0 0 1';
 258         portal.nextthink = 0;
 259         portal.takedamage = DAMAGE_YES;
 260 }
 261
 262 void Portal_Disconnect(entity teleporter, entity destination)
 263 {
 264         teleporter.enemy = world;
 265         destination.enemy = world;
 266         Portal_MakeBrokenPortal(teleporter);
 267         Portal_MakeBrokenPortal(destination);
 268 }
 269
 270 void Portal_Connect(entity teleporter, entity destination)
 271 {
 272         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 273
 274 #ifdef DEBUG
 275         {
 276                 // let's verify the transform
 277                 vector in_f, in_r, in_u;
 278                 vector out_f, out_r, out_u;
 279                 fixedmakevectors(teleporter.angles);
 280                 in_f = v_forward;
 281                 in_r = v_right;
 282                 in_u = v_up;
 283                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 284                 fixedmakevectors(destination.angles);
 285                 out_f = v_forward;
 286                 out_r = v_right;
 287                 out_u = v_up;
 288                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 289                 // INTENDED TRANSFORM:
 290                 //   in_f -> -out_f
 291                 //   in_r -> -out_r
 292                 //   in_u -> +out_u
 293                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 294                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 295                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 296
 297                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 298                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 299         }
 300 #endif
 301
 302         teleporter.enemy = destination;
 303         destination.enemy = teleporter;
 304         Portal_MakeInPortal(teleporter);
 305         Portal_MakeOutPortal(destination);
 306         teleporter.fade_time = time + 15;
 307         destination.fade_time = time + 15;
 308         teleporter.portal_wants_to_vanish = 0;
 309         destination.portal_wants_to_vanish = 0;
 310 }
 311
 312 void Portal_Remove(entity portal, float killed)
 313 {
 314         entity e;
 315         e = portal.enemy;
 316
 317         if(e)
 318         {
 319                 Portal_Disconnect(portal, e);
 320                 Portal_Remove(e, killed);
 321         }
 322
 323         if(portal == portal.owner.portal_in)
 324                 portal.owner.portal_in = world;
 325         if(portal == portal.owner.portal_out)
 326                 portal.owner.portal_out = world;
 327         portal.owner = world;
 328
 329         // makes the portal vanish
 330         if(killed)
 331         {
 332                 fixedmakevectors(portal.angles);
 333                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 334                 remove(portal);
 335         }
 336         else
 337         {
 338                 Portal_MakeBrokenPortal(portal);
 339                 SUB_SetFade(portal, time, 0.5);
 340         }
 341 }
 342
 343 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 344 {
 345         if(deathtype == DEATH_TELEFRAG)
 346                 return;
 347         if(attacker != self.owner)
 348                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 349                         return;
 350         self.health -= damage;
 351         if(self.health < 0)
 352         {
 353                 Portal_Remove(self, 1);
 354         }
 355 }
 356
 357 void Portal_Think()
 358 {
 359         entity e, o;
 360
 361         if(self.solid != SOLID_TRIGGER)
 362                 error("Portal_Think called for a portal that should not be thinking");
 363
 364         o = self.owner;
 365         self.solid = SOLID_BBOX;
 366         self.owner = world;
 367         FOR_EACH_PLAYER(e)
 368         {
 369                 if(time < self.portal_activatetime)
 370                         if(e == o)
 371                                 continue;
 372                 if(e != o)
 373                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 374                                 continue; // cannot go through someone else's portal
 375                 // if e would hit the portal in a frame...
 376                 // already teleport him
 377                 tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 378                 if(trace_ent == self)
 379                         Portal_TeleportPlayer(self, e);
 380         }
 381         self.solid = SOLID_TRIGGER;
 382         self.owner = o;
 383
 384         self.nextthink = time;
 385
 386         if(time > self.fade_time)
 387                 Portal_Remove(self, 0);
 388 }
 389
 390 float Portal_Customize()
 391 {
 392         if(other.classname == "spectator")
 393                 other = other.enemy;
 394         if(other == self.owner)
 395                 return TRUE;
 396         if(IS_INDEPENDENT_PLAYER(other))
 397                 return FALSE;
 398         if(IS_INDEPENDENT_PLAYER(self.owner))
 399                 return FALSE;
 400         return TRUE;
 401 }
 402
 403 // cleanup:
 404 //   when creating in-portal:
 405 //     disconnect
 406 //     clear existing in-portal
 407 //     set as in-portal
 408 //     connect
 409 //   when creating out-portal:
 410 //     disconnect
 411 //     clear existing out-portal
 412 //     set as out-portal
 413 //   when player dies:
 414 //     disconnect portals
 415 //     clear both portals
 416 //   after timeout of in-portal:
 417 //     disconnect portals
 418 //     clear both portals
 419 //   TODO: ensure only one portal shot at once
 420 float Portal_SetInPortal(entity own, entity portal)
 421 {
 422         if(own.portal_in)
 423         {
 424                 if(own.portal_out)
 425                         Portal_Disconnect(own.portal_in, own.portal_out);
 426                 Portal_Remove(own.portal_in, 0);
 427         }
 428         own.portal_in = portal;
 429         if(own.portal_out)
 430         {
 431                 own.portal_out.portal_id = portal.portal_id;
 432                 Portal_Connect(own.portal_in, own.portal_out);
 433         }
 434         return 2;
 435 }
 436 float Portal_SetOutPortal(entity own, entity portal)
 437 {
 438         if(own.portal_out)
 439         {
 440                 if(own.portal_in)
 441                         Portal_Disconnect(own.portal_in, own.portal_out);
 442                 Portal_Remove(own.portal_out, 0);
 443         }
 444         own.portal_out = portal;
 445         if(own.portal_in)
 446         {
 447                 own.portal_in.portal_id = portal.portal_id;
 448                 Portal_Connect(own.portal_in, own.portal_out);
 449         }
 450         return 1;
 451 }
 452 void Portal_ClearAll(entity own)
 453 {
 454         if(own.portal_in)
 455                 Portal_Remove(own.portal_in, 0);
 456         if(own.portal_out)
 457                 Portal_Remove(own.portal_out, 0);
 458 }
 459 void Portal_ClearWithID(entity own, float id)
 460 {
 461         if(own.portal_in)
 462                 if(own.portal_in.portal_id == id)
 463                 {
 464                         if(own.portal_out)
 465                                 Portal_Disconnect(own.portal_in, own.portal_out);
 466                         Portal_Remove(own.portal_in, 0);
 467                 }
 468         if(own.portal_out)
 469                 if(own.portal_out.portal_id == id)
 470                 {
 471                         if(own.portal_in)
 472                                 Portal_Disconnect(own.portal_in, own.portal_out);
 473                         Portal_Remove(own.portal_out, 0);
 474                 }
 475 }
 476
 477 entity Portal_Spawn(entity own, vector org, vector ang)
 478 {
 479         entity portal;
 480
 481         fixedmakevectors(ang);
 482         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 483                 return world;
 484
 485         portal = spawn();
 486         portal.classname = "portal";
 487         portal.owner = own;
 488         portal.origin = org;
 489         portal.angles = ang;
 490         portal.think = Portal_Think;
 491         portal.nextthink = 0;
 492         portal.fade_time = time + 15;
 493         portal.portal_activatetime = time + 0.1;
 494         portal.event_damage = Portal_Damage;
 495         portal.health = 300;
 496         setmodel(portal, "models/portal.md3");
 497         portal.customizeentityforclient = Portal_Customize;
 498
 499         if(!Portal_FindSafeOrigin(portal))
 500         {
 501                 remove(portal);
 502                 return world;
 503         }
 504
 505         setsize(portal, '-48 -48 -48', '48 48 48');
 506         Portal_MakeWaitingPortal(portal);
 507
 508         return portal;
 509 }
 510
 511 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 512 {
 513         entity portal;
 514         vector ang;
 515         vector org;
 516
 517         if(trace_ent.movetype == MOVETYPE_WALK)
 518         {
 519                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 520                 trace_plane_normal = '0 0 1';
 521                 dir = -1 * dir; // create telefrag portals the other way round
 522         }
 523
 524         org = trace_endpos;
 525         ang = vectoangles2(trace_plane_normal, dir);
 526         fixedmakevectors(ang);
 527
 528         portal = Portal_Spawn(own, org, ang);
 529         if(!portal)
 530         {
 531                 if(!self.portal_out || self.portal_out.portal_id == portal_id_val)
 532                         Portal_ClearAll(own);
 533                 return 0;
 534         }
 535
 536         portal.portal_id = portal_id_val;
 537         Portal_SetInPortal(own, portal);
 538         sound(portal, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 539
 540         return 1;
 541 }
 542
 543 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 544 {
 545         entity portal;
 546         vector ang;
 547         vector org;
 548
 549         if(trace_ent.movetype == MOVETYPE_WALK)
 550         {
 551                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 552                 trace_plane_normal = '0 0 1';
 553                 dir = -1 * dir; // create telefrag portals the other way round
 554         }
 555
 556         org = trace_endpos;
 557         ang = vectoangles2(trace_plane_normal, dir);
 558         fixedmakevectors(ang);
 559
 560         portal = Portal_Spawn(own, org, ang);
 561         if(!portal)
 562         {
 563                 if(!self.portal_in || self.portal_in.portal_id == portal_id_val)
 564                         Portal_ClearAll(own);
 565                 return 0;
 566         }
 567
 568         portal.portal_id = portal_id_val;
 569         Portal_SetOutPortal(own, portal);
 570         sound(portal, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 571
 572         return 1;
 573 }