data/qcsrc/server/portals.qc

   1 #define SAFENUDGE '1 1 1'
   2 #define SAFERNUDGE '8 8 8'
   3
   4 .vector portal_transform;
   5 .vector portal_safe_origin;
   6 .float portal_wants_to_vanish;
   7 .float portal_activatetime;
   8
   9 float PlayerEdgeDistance(entity p, vector v)
  10 {
  11         vector vbest;
  12
  13         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  14         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  15         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  16
  17         return vbest * v;
  18 }
  19
  20 .vector right_vector;
  21 float Portal_TeleportPlayer(entity teleporter, entity player)
  22 {
  23         vector from, to, safe, step, transform, ang, newvel;
  24         vector new_forward, new_up;
  25         vector old_forward, old_up;
  26         vector new_yawforward;
  27         vector old_yawforward;
  28         float planeshift, s, t;
  29
  30         if not(teleporter.enemy)
  31         {
  32                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  33                 return 0;
  34         }
  35
  36         from = teleporter.origin;
  37         transform = teleporter.portal_transform;
  38
  39         to = teleporter.enemy.origin;
  40         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
  41         newvel = AnglesTransform_Apply(transform, player.velocity);
  42         // this now is INSIDE the plane... can't use that
  43
  44         // shift it out
  45         fixedmakevectors(teleporter.enemy.angles);
  46
  47         // first shift it ON the plane if needed
  48         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
  49         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
  50                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
  51                 to += newvel * (planeshift / (newvel * v_forward));
  52         else
  53                 to += trace_plane_normal * planeshift;
  54
  55         s = (to - teleporter.enemy.origin) * v_right;
  56         t = (to - teleporter.enemy.origin) * v_up;
  57         s = bound(-48, s, 48);
  58         t = bound(-48, t, 48);
  59         to = teleporter.enemy.origin
  60            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
  61            +     s                                        * v_right
  62            +     t                                        * v_up;
  63
  64         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
  65         step = to + ((safe - to) * v_forward) * v_forward;
  66         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
  67         if(trace_startsolid)
  68         {
  69                 print("'safe' teleport location is not safe!\n");
  70                 // FAIL TODO why does this happen?
  71                 return 0;
  72         }
  73         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
  74         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
  75         if(trace_startsolid)
  76         {
  77                 print("trace_endpos in solid, this can't be!\n");
  78                 // FAIL TODO why does this happen? (reported by MrBougo)
  79                 return 0;
  80         }
  81         to = trace_endpos + normalize(safe - trace_endpos) * 0;
  82         //print(vtos(to), "\n");
  83
  84         // ang_x stuff works around weird quake angles
  85         if(player.classname == "player")
  86         {
  87                 ang = player.v_angle;
  88                 /*
  89                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  90                 ang = AnglesTransform_Multiply(transform, ang);
  91                 */
  92
  93                 // PLAYERS use different math
  94                 ang_x = -ang_x;
  95
  96                 //print("reference: ", vtos(AnglesTransform_Multiply(transform, ang)), "\n");
  97
  98                 fixedmakevectors(ang);
  99                 old_forward = v_forward;
 100                 old_up = v_up;
 101                 fixedmakevectors(ang_y * '0 1 0');
 102                 old_yawforward = v_forward;
 103
 104                 // their aiming directions are portalled...
 105                 new_forward = AnglesTransform_Apply(transform, old_forward);
 106                 new_up = AnglesTransform_Apply(transform, old_up);
 107                 new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
 108
 109                 // but now find a new sense of direction
 110                 // this is NOT easy!
 111                 // assume new_forward points straight up.
 112                 // What is our yaw?
 113                 //
 114                 // new_up could now point forward OR backward... which direction to choose?
 115
 116                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 117                 {
 118                         // new_yawforward and new_yawup define the new aiming half-circle
 119                         // we "just" need to find out whether new_up or -new_up is in that half circle
 120                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 121                         if(new_up * new_yawforward < 0)
 122                                 new_up = -1 * new_up;
 123                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 124                         //print("UP/DOWN path: ", vtos(ang), "\n");
 125                 }
 126                 else
 127                 {
 128                         // good angles; here, "forward" suffices
 129                         ang = fixedvectoangles(new_forward);
 130                         //print("GOOD path: ", vtos(ang), "\n");
 131                 }
 132
 133                 ang_x = -ang_x;
 134                 ang_z = player.angles_z;
 135         }
 136         else
 137         {
 138                 ang = player.angles;
 139                 ang = AnglesTransform_Multiply(transform, player.angles);
 140         }
 141
 142         // factor -1 allows chaining portals, but may be weird
 143         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 144
 145         if(player.flagcarried)
 146                 DropFlag(player.flagcarried, player, world);
 147
 148         if not(teleporter.enemy)
 149         {
 150                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 151                 return 0;
 152         }
 153
 154         tdeath_hit = 0;
 155         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 156         if(tdeath_hit)
 157         {
 158                 // telefrag within 1 second of portal creation = amazing
 159                 if(time < teleporter.teleport_time + 1)
 160                         announce(player, "announcer/male/amazing.wav");
 161         }
 162
 163         if not(teleporter.enemy)
 164         {
 165                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 166                 return 0;
 167         }
 168
 169         // reset fade counter
 170         teleporter.portal_wants_to_vanish = 0;
 171         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 172         teleporter.health = cvar("g_balance_portal_health");
 173         teleporter.enemy.health = cvar("g_balance_portal_health");
 174
 175         return 1;
 176 }
 177
 178 float Portal_FindSafeOrigin(entity portal)
 179 {
 180         vector o;
 181         o = portal.origin;
 182         portal.mins = PL_MIN - SAFERNUDGE;
 183         portal.maxs = PL_MAX + SAFERNUDGE;
 184         fixedmakevectors(portal.angles);
 185         portal.origin += 16 * v_forward;
 186         if(!move_out_of_solid(portal))
 187         {
 188 #ifdef DEBUG
 189                 print("NO SAFE ORIGIN\n");
 190 #endif
 191                 return 0;
 192         }
 193         portal.portal_safe_origin = portal.origin;
 194         setorigin(portal, o);
 195         return 1;
 196 }
 197
 198 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 199 {
 200         float dist, distpersec, delta;
 201         vector v;
 202
 203         dist = (eorg - porg) * pnorm;
 204         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 205         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 206         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 207         if(dist < -1) // other side?
 208                 return 0;
 209         distpersec = evel * pnorm;
 210         if(distpersec >= 0) // going away from the portal?
 211                 return 0;
 212         delta = dist / distpersec;
 213         v = eorg - evel * delta - porg;
 214         v = v - pnorm * (pnorm * v);
 215         return vlen(v) < psize;
 216 }
 217
 218 void Portal_Touch()
 219 {
 220         vector g;
 221
 222         // portal is being removed?
 223         if(self.solid != SOLID_TRIGGER)
 224                 return; // possibly engine bug
 225
 226         if(other.classname == "player")
 227                 return; // handled by think
 228
 229         if(other.classname == "item_flag_team")
 230                 return; // never portal these
 231
 232         if(other.classname == "grapplinghook")
 233                 return; // handled by think
 234
 235         if(!self.enemy)
 236                 error("Portal_Touch called for a broken portal\n");
 237
 238         if(trace_fraction < 1)
 239                 return; // only handle TouchAreaGrid ones (only these can teleport)
 240                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 241
 242         if(other.classname == "porto")
 243         {
 244                 if(other.portal_id == self.portal_id)
 245                         return;
 246         }
 247         if(time < self.portal_activatetime)
 248                 if(other == self.owner)
 249                 {
 250                         self.portal_activatetime = time + 0.1;
 251                         return;
 252                 }
 253         if(other != self.owner)
 254                 if(other.classname == "player")
 255                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 256                                 return; // cannot go through someone else's portal
 257         if(other.owner != self.owner)
 258                 if(other.owner.classname == "player")
 259                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 260                                 return; // cannot go through someone else's portal
 261         fixedmakevectors(self.angles);
 262         g = frametime * '0 0 -1' * cvar("sv_gravity");
 263         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 264                 return;
 265
 266         /*
 267         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 268         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 269         {
 270                 // can't teleport this
 271                 return;
 272         }
 273         */
 274
 275         if(Portal_TeleportPlayer(self, other))
 276                 if(other.classname == "porto")
 277                         if(other.effects & EF_RED)
 278                                 other.effects += EF_BLUE - EF_RED;
 279 }
 280
 281 void Portal_Think();
 282 void Portal_MakeBrokenPortal(entity portal)
 283 {
 284         portal.skin = 2;
 285         portal.solid = SOLID_NOT;
 286         portal.touch = SUB_Null;
 287         portal.think = SUB_Null;
 288         portal.effects = 0;
 289         portal.nextthink = 0;
 290         portal.takedamage = DAMAGE_NO;
 291 }
 292
 293 void Portal_MakeWaitingPortal(entity portal)
 294 {
 295         portal.skin = 2;
 296         portal.solid = SOLID_NOT;
 297         portal.touch = SUB_Null;
 298         portal.think = SUB_Null;
 299         portal.effects = EF_ADDITIVE;
 300         portal.nextthink = 0;
 301         portal.takedamage = DAMAGE_YES;
 302 }
 303
 304 void Portal_MakeInPortal(entity portal)
 305 {
 306         portal.skin = 0;
 307         portal.solid = SOLID_TRIGGER;
 308         portal.touch = Portal_Touch;
 309         portal.think = Portal_Think;
 310         portal.effects = EF_RED;
 311         portal.nextthink = time;
 312         portal.takedamage = DAMAGE_NO;
 313 }
 314
 315 void Portal_MakeOutPortal(entity portal)
 316 {
 317         portal.skin = 1;
 318         portal.solid = SOLID_NOT;
 319         portal.touch = SUB_Null;
 320         portal.think = SUB_Null;
 321         portal.effects = EF_STARDUST | EF_BLUE;
 322         portal.nextthink = 0;
 323         portal.takedamage = DAMAGE_YES;
 324 }
 325
 326 void Portal_Disconnect(entity teleporter, entity destination)
 327 {
 328         teleporter.enemy = world;
 329         destination.enemy = world;
 330         Portal_MakeBrokenPortal(teleporter);
 331         Portal_MakeBrokenPortal(destination);
 332 }
 333
 334 void Portal_Connect(entity teleporter, entity destination)
 335 {
 336         teleporter.portal_transform = AnglesTransform_Divide(AnglesTransform_TurnDirection(destination.angles), teleporter.angles);
 337
 338         teleporter.enemy = destination;
 339         destination.enemy = teleporter;
 340         Portal_MakeInPortal(teleporter);
 341         Portal_MakeOutPortal(destination);
 342         teleporter.fade_time = time + 15;
 343         destination.fade_time = time + 15;
 344         teleporter.portal_wants_to_vanish = 0;
 345         destination.portal_wants_to_vanish = 0;
 346         teleporter.teleport_time = time;
 347 }
 348
 349 void Portal_Remove(entity portal, float killed)
 350 {
 351         entity e;
 352         e = portal.enemy;
 353
 354         if(e)
 355         {
 356                 Portal_Disconnect(portal, e);
 357                 Portal_Remove(e, killed);
 358         }
 359
 360         if(portal == portal.owner.portal_in)
 361                 portal.owner.portal_in = world;
 362         if(portal == portal.owner.portal_out)
 363                 portal.owner.portal_out = world;
 364         //portal.owner = world;
 365
 366         // makes the portal vanish
 367         if(killed)
 368         {
 369                 fixedmakevectors(portal.angles);
 370                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 371                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 372                 remove(portal);
 373         }
 374         else
 375         {
 376                 Portal_MakeBrokenPortal(portal);
 377                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 378                 SUB_SetFade(portal, time, 0.5);
 379         }
 380 }
 381
 382 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 383 {
 384         if(deathtype == DEATH_TELEFRAG)
 385                 return;
 386         if(attacker != self.owner)
 387                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 388                         return;
 389         self.health -= damage;
 390         if(self.health < 0)
 391                 Portal_Remove(self, 1);
 392 }
 393
 394 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 395 {
 396         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 397                 return;
 398
 399         // if e would hit the portal in a frame...
 400         // already teleport him
 401         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 402         if(trace_ent == self)
 403                 Portal_TeleportPlayer(self, e);
 404 }
 405
 406 void Portal_Think()
 407 {
 408         entity e, o;
 409         vector g;
 410
 411         // portal is being removed?
 412         if(self.solid != SOLID_TRIGGER)
 413                 return; // possibly engine bug
 414
 415         if(!self.enemy)
 416                 error("Portal_Think called for a broken portal\n");
 417
 418         o = self.owner;
 419         self.solid = SOLID_BBOX;
 420         self.owner = world;
 421
 422         g = frametime * '0 0 -1' * cvar("sv_gravity");
 423
 424         fixedmakevectors(self.angles);
 425
 426         FOR_EACH_PLAYER(e)
 427         {
 428                 if(e != o)
 429                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 430                                 continue; // cannot go through someone else's portal
 431
 432                 if(e != o || time >= self.portal_activatetime)
 433                         Portal_Think_TryTeleportPlayer(e, g);
 434
 435                 if(e.hook)
 436                         Portal_Think_TryTeleportPlayer(e.hook, g);
 437         }
 438         self.solid = SOLID_TRIGGER;
 439         self.owner = o;
 440
 441         self.nextthink = time;
 442
 443         if(time > self.fade_time)
 444                 Portal_Remove(self, 0);
 445 }
 446
 447 float Portal_Customize()
 448 {
 449         if(other.classname == "spectator")
 450                 other = other.enemy;
 451         if(other == self.owner)
 452         {
 453                 self.modelindex = self.modelindex_lod0;
 454         }
 455         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 456         {
 457                 self.modelindex = 0;
 458         }
 459         else
 460         {
 461                 self.modelindex = self.modelindex_lod0;
 462         }
 463         return TRUE;
 464 }
 465
 466 // cleanup:
 467 //   when creating in-portal:
 468 //     disconnect
 469 //     clear existing in-portal
 470 //     set as in-portal
 471 //     connect
 472 //   when creating out-portal:
 473 //     disconnect
 474 //     clear existing out-portal
 475 //     set as out-portal
 476 //   when player dies:
 477 //     disconnect portals
 478 //     clear both portals
 479 //   after timeout of in-portal:
 480 //     disconnect portals
 481 //     clear both portals
 482 //   TODO: ensure only one portal shot at once
 483 float Portal_SetInPortal(entity own, entity portal)
 484 {
 485         if(own.portal_in)
 486         {
 487                 if(own.portal_out)
 488                         Portal_Disconnect(own.portal_in, own.portal_out);
 489                 Portal_Remove(own.portal_in, 0);
 490         }
 491         own.portal_in = portal;
 492         if(own.portal_out)
 493         {
 494                 own.portal_out.portal_id = portal.portal_id;
 495                 Portal_Connect(own.portal_in, own.portal_out);
 496         }
 497         return 2;
 498 }
 499 float Portal_SetOutPortal(entity own, entity portal)
 500 {
 501         if(own.portal_out)
 502         {
 503                 if(own.portal_in)
 504                         Portal_Disconnect(own.portal_in, own.portal_out);
 505                 Portal_Remove(own.portal_out, 0);
 506         }
 507         own.portal_out = portal;
 508         if(own.portal_in)
 509         {
 510                 own.portal_in.portal_id = portal.portal_id;
 511                 Portal_Connect(own.portal_in, own.portal_out);
 512         }
 513         return 1;
 514 }
 515 void Portal_ClearAll_PortalsOnly(entity own)
 516 {
 517         if(own.portal_in)
 518                 Portal_Remove(own.portal_in, 0);
 519         if(own.portal_out)
 520                 Portal_Remove(own.portal_out, 0);
 521 }
 522 void Portal_ClearAll(entity own)
 523 {
 524         Portal_ClearAll_PortalsOnly(own);
 525         W_Porto_Remove(own);
 526 }
 527 void Portal_RemoveLater_Think()
 528 {
 529         Portal_Remove(self, self.cnt);
 530 }
 531 void Portal_RemoveLater(entity portal, float kill)
 532 {
 533         Portal_MakeBrokenPortal(portal);
 534         portal.cnt = kill;
 535         portal.think = Portal_RemoveLater_Think;
 536         portal.nextthink = time;
 537 }
 538 void Portal_ClearAllLater_PortalsOnly(entity own)
 539 {
 540         if(own.portal_in)
 541                 Portal_RemoveLater(own.portal_in, 0);
 542         if(own.portal_out)
 543                 Portal_RemoveLater(own.portal_out, 0);
 544 }
 545 void Portal_ClearAllLater(entity own)
 546 {
 547         Portal_ClearAllLater_PortalsOnly(own);
 548         W_Porto_Remove(own);
 549 }
 550 void Portal_ClearWithID(entity own, float id)
 551 {
 552         if(own.portal_in)
 553                 if(own.portal_in.portal_id == id)
 554                 {
 555                         if(own.portal_out)
 556                                 Portal_Disconnect(own.portal_in, own.portal_out);
 557                         Portal_Remove(own.portal_in, 0);
 558                 }
 559         if(own.portal_out)
 560                 if(own.portal_out.portal_id == id)
 561                 {
 562                         if(own.portal_in)
 563                                 Portal_Disconnect(own.portal_in, own.portal_out);
 564                         Portal_Remove(own.portal_out, 0);
 565                 }
 566 }
 567
 568 entity Portal_Spawn(entity own, vector org, vector ang)
 569 {
 570         entity portal;
 571
 572         fixedmakevectors(ang);
 573         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 574                 return world;
 575
 576         portal = spawn();
 577         portal.classname = "portal";
 578         portal.owner = own;
 579         portal.origin = org;
 580         portal.angles = ang;
 581         portal.think = Portal_Think;
 582         portal.nextthink = 0;
 583         portal.portal_activatetime = time + 0.1;
 584         portal.event_damage = Portal_Damage;
 585         portal.health = 200;
 586         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 587         portal.health = cvar("g_balance_portal_health");
 588         setmodel(portal, "models/portal.md3");
 589         portal.modelindex_lod0 = portal.modelindex;
 590         portal.customizeentityforclient = Portal_Customize;
 591
 592         if(!Portal_FindSafeOrigin(portal))
 593         {
 594                 remove(portal);
 595                 return world;
 596         }
 597
 598         setsize(portal, '-48 -48 -48', '48 48 48');
 599         Portal_MakeWaitingPortal(portal);
 600
 601         return portal;
 602 }
 603
 604 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 605 {
 606         entity portal;
 607         vector ang;
 608         vector org;
 609
 610         org = trace_endpos;
 611         ang = fixedvectoangles2(trace_plane_normal, dir);
 612         fixedmakevectors(ang);
 613
 614         portal = Portal_Spawn(own, org, ang);
 615         if(!portal)
 616         {
 617                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 618                         Portal_ClearAll_PortalsOnly(own);
 619                 return 0;
 620         }
 621
 622         portal.portal_id = portal_id_val;
 623         Portal_SetInPortal(own, portal);
 624
 625         return 1;
 626 }
 627
 628 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 629 {
 630         entity portal;
 631         vector ang;
 632         vector org;
 633
 634         org = trace_endpos;
 635         ang = fixedvectoangles2(trace_plane_normal, dir);
 636         fixedmakevectors(ang);
 637
 638         portal = Portal_Spawn(own, org, ang);
 639         if(!portal)
 640         {
 641                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 642                         Portal_ClearAll_PortalsOnly(own);
 643                 return 0;
 644         }
 645
 646         portal.portal_id = portal_id_val;
 647         Portal_SetOutPortal(own, portal);
 648
 649         return 1;
 650 }