data/qcsrc/server/portals.qc

   1 #define SAFENUDGE '1 1 1'
   2 #define SAFERNUDGE '8 8 8'
   3
   4 .vector portal_transform;
   5 .vector portal_safe_origin;
   6 .float portal_wants_to_vanish;
   7 .float portal_activatetime;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward); m_up = Portal_Transform_Apply(t1, m_up);
  22         return fixedvectoangles2(m_forward, m_up);
  23 }
  24
  25 vector Portal_Transform_Invert(vector transform)
  26 {
  27         vector i_forward, i_up;
  28         fixedmakevectors(transform);
  29         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  30         // but these are orthogonal unit vectors!
  31         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
  32         // TODO is this always -transform?
  33         i_forward_x = v_forward_x;
  34         i_forward_y = -v_right_x;
  35         i_forward_z = v_up_x;
  36         i_up_x = v_forward_z;
  37         i_up_y = -v_right_z;
  38         i_up_z = v_up_z;
  39 #ifdef DEBUG
  40         vector v;
  41         v = fixedvectoangles2(i_forward, i_up);
  42         print("Transform: ", vtos(transform), "\n");
  43         print("Inverted: ", vtos(v), "\n");
  44         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  45         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  46         print("Verify: ", vtos(v_forward), "\n");
  47         print("Verify: ", vtos(v_right), "\n");
  48         print("Verify: ", vtos(v_up), "\n");
  49 #endif
  50         return fixedvectoangles2(i_forward, i_up);
  51 }
  52
  53 vector Portal_Transform_TurnDirection(vector transform)
  54 {
  55         // turn 180 degrees around v_up
  56         // changes in-direction to out-direction
  57         fixedmakevectors(transform);
  58         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
  59 }
  60
  61 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  62 {
  63         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  64 }
  65
  66 float PlayerEdgeDistance(entity p, vector v)
  67 {
  68         vector vbest;
  69
  70         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  71         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  72         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  73
  74         return vbest * v;
  75 }
  76
  77 .vector right_vector;
  78 float Portal_TeleportPlayer(entity teleporter, entity player)
  79 {
  80         vector from, to, safe, step, transform, ang, newvel;
  81         vector new_forward, new_up;
  82         vector old_forward, old_up;
  83         vector new_yawforward;
  84         vector old_yawforward;
  85         float planeshift, s, t;
  86
  87         from = teleporter.origin;
  88         transform = teleporter.portal_transform;
  89
  90         to = teleporter.enemy.origin;
  91         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  92         newvel = Portal_Transform_Apply(transform, player.velocity);
  93         // this now is INSIDE the plane... can't use that
  94
  95         // shift it out
  96         fixedmakevectors(teleporter.enemy.angles);
  97
  98         // first shift it ON the plane if needed
  99         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 100         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 101                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 102                 to += newvel * (planeshift / (newvel * v_forward));
 103         else
 104                 to += trace_plane_normal * planeshift;
 105
 106         s = (to - teleporter.enemy.origin) * v_right;
 107         t = (to - teleporter.enemy.origin) * v_up;
 108         s = bound(-48, s, 48);
 109         t = bound(-48, t, 48);
 110         to = teleporter.enemy.origin
 111            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 112            +     s                                        * v_right
 113            +     t                                        * v_up;
 114
 115         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 116         step = to + ((safe - to) * v_forward) * v_forward;
 117         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 118         if(trace_startsolid)
 119         {
 120                 print("'safe' teleport location is not safe!\n");
 121                 // FAIL TODO why does this happen?
 122                 return 0;
 123         }
 124         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 125         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 126         if(trace_startsolid)
 127         {
 128                 print("trace_endpos in solid, this can't be!\n");
 129                 // FAIL TODO why does this happen? (reported by MrBougo)
 130                 return 0;
 131         }
 132         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 133         //print(vtos(to), "\n");
 134
 135         // ang_x stuff works around weird quake angles
 136         if(player.classname == "player")
 137         {
 138                 ang = player.v_angle;
 139                 /*
 140                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
 141                 ang = Portal_Transform_Multiply(transform, ang);
 142                 */
 143
 144                 // PLAYERS use different math
 145                 ang_x = -ang_x;
 146
 147                 //print("reference: ", vtos(Portal_Transform_Multiply(transform, ang)), "\n");
 148
 149                 fixedmakevectors(ang);
 150                 old_forward = v_forward;
 151                 old_up = v_up;
 152                 fixedmakevectors(ang_y * '0 1 0');
 153                 old_yawforward = v_forward;
 154
 155                 // their aiming directions are portalled...
 156                 new_forward = Portal_Transform_Apply(transform, old_forward);
 157                 new_up = Portal_Transform_Apply(transform, old_up);
 158                 new_yawforward = Portal_Transform_Apply(transform, old_yawforward);
 159
 160                 // but now find a new sense of direction
 161                 // this is NOT easy!
 162                 // assume new_forward points straight up.
 163                 // What is our yaw?
 164                 //
 165                 // new_up could now point forward OR backward... which direction to choose?
 166
 167                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 168                 {
 169                         // new_yawforward and new_yawup define the new aiming half-circle
 170                         // we "just" need to find out whether new_up or -new_up is in that half circle
 171                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 172                         if(new_up * new_yawforward < 0)
 173                                 new_up = -1 * new_up;
 174                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 175                         //print("UP/DOWN path: ", vtos(ang), "\n");
 176                 }
 177                 else
 178                 {
 179                         // good angles; here, "forward" suffices
 180                         ang = fixedvectoangles(new_forward);
 181                         //print("GOOD path: ", vtos(ang), "\n");
 182                 }
 183
 184                 ang_x = -ang_x;
 185                 ang_z = player.angles_z;
 186         }
 187         else
 188         {
 189                 ang = player.angles;
 190                 ang = Portal_Transform_Multiply(transform, player.angles);
 191         }
 192
 193         // factor -1 allows chaining portals, but may be weird
 194         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 195
 196         if(player.flagcarried)
 197                 DropFlag(player.flagcarried, player, world);
 198         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 199
 200         // reset fade counter
 201         teleporter.portal_wants_to_vanish = 0;
 202         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 203         teleporter.health = cvar("g_balance_portal_health");
 204         teleporter.enemy.health = cvar("g_balance_portal_health");
 205
 206         return 1;
 207 }
 208
 209 float Portal_FindSafeOrigin(entity portal)
 210 {
 211         vector o;
 212         o = portal.origin;
 213         portal.mins = PL_MIN - SAFERNUDGE;
 214         portal.maxs = PL_MAX + SAFERNUDGE;
 215         fixedmakevectors(portal.angles);
 216         portal.origin += 16 * v_forward;
 217         if(!move_out_of_solid(portal))
 218         {
 219 #ifdef DEBUG
 220                 print("NO SAFE ORIGIN\n");
 221 #endif
 222                 return 0;
 223         }
 224         portal.portal_safe_origin = portal.origin;
 225         setorigin(portal, o);
 226         return 1;
 227 }
 228
 229 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 230 {
 231         float dist, distpersec, delta;
 232         vector v;
 233
 234         dist = (eorg - porg) * pnorm;
 235         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 236         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 237         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 238         if(dist < -1) // other side?
 239                 return 0;
 240         distpersec = evel * pnorm;
 241         if(distpersec >= 0) // going away from the portal?
 242                 return 0;
 243         delta = dist / distpersec;
 244         v = eorg - evel * delta - porg;
 245         v = v - pnorm * (pnorm * v);
 246         return vlen(v) < psize;
 247 }
 248
 249 void Portal_Touch()
 250 {
 251         vector g;
 252
 253         // portal is being removed?
 254         if(self.solid != SOLID_TRIGGER)
 255                 return; // possibly engine bug
 256
 257         if(other.classname == "player")
 258                 return; // handled by think
 259
 260         if(other.classname == "item_flag_team")
 261                 return; // never portal these
 262
 263         if(other.classname == "grapplinghook")
 264                 return; // handled by think
 265
 266         if(!self.enemy)
 267                 error("Portal_Touch called for a broken portal\n");
 268
 269         if(trace_fraction < 1)
 270                 return; // only handle TouchAreaGrid ones (only these can teleport)
 271                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 272
 273         if(other.classname == "porto")
 274         {
 275                 if(other.portal_id == self.portal_id)
 276                         return;
 277         }
 278         if(time < self.portal_activatetime)
 279                 if(other == self.owner)
 280                 {
 281                         self.portal_activatetime = time + 0.1;
 282                         return;
 283                 }
 284         if(other != self.owner)
 285                 if(other.classname == "player")
 286                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 287                                 return; // cannot go through someone else's portal
 288         if(other.owner != self.owner)
 289                 if(other.owner.classname == "player")
 290                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 291                                 return; // cannot go through someone else's portal
 292         fixedmakevectors(self.angles);
 293         g = frametime * '0 0 -1' * cvar("sv_gravity");
 294         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 295                 return;
 296
 297         /*
 298         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 299         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 300         {
 301                 // can't teleport this
 302                 return;
 303         }
 304         */
 305
 306         if(Portal_TeleportPlayer(self, other))
 307                 if(other.classname == "porto")
 308                         if(other.effects & EF_RED)
 309                                 other.effects += EF_BLUE - EF_RED;
 310 }
 311
 312 void Portal_Think();
 313 void Portal_MakeBrokenPortal(entity portal)
 314 {
 315         portal.skin = 2;
 316         portal.solid = SOLID_NOT;
 317         portal.touch = SUB_Null;
 318         portal.think = SUB_Null;
 319         portal.effects = 0;
 320         portal.nextthink = 0;
 321         portal.takedamage = DAMAGE_NO;
 322 }
 323
 324 void Portal_MakeWaitingPortal(entity portal)
 325 {
 326         portal.skin = 2;
 327         portal.solid = SOLID_NOT;
 328         portal.touch = SUB_Null;
 329         portal.think = SUB_Null;
 330         portal.effects = EF_ADDITIVE;
 331         portal.nextthink = 0;
 332         portal.takedamage = DAMAGE_YES;
 333 }
 334
 335 void Portal_MakeInPortal(entity portal)
 336 {
 337         portal.skin = 0;
 338         portal.solid = SOLID_TRIGGER;
 339         portal.touch = Portal_Touch;
 340         portal.think = Portal_Think;
 341         portal.effects = EF_RED;
 342         portal.nextthink = time;
 343         portal.takedamage = DAMAGE_NO;
 344 }
 345
 346 void Portal_MakeOutPortal(entity portal)
 347 {
 348         portal.skin = 1;
 349         portal.solid = SOLID_NOT;
 350         portal.touch = SUB_Null;
 351         portal.think = SUB_Null;
 352         portal.effects = EF_STARDUST | EF_BLUE;
 353         portal.nextthink = 0;
 354         portal.takedamage = DAMAGE_YES;
 355 }
 356
 357 void Portal_Disconnect(entity teleporter, entity destination)
 358 {
 359         teleporter.enemy = world;
 360         destination.enemy = world;
 361         Portal_MakeBrokenPortal(teleporter);
 362         Portal_MakeBrokenPortal(destination);
 363 }
 364
 365 void Portal_Connect(entity teleporter, entity destination)
 366 {
 367         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 368
 369 #ifdef DEBUG
 370         {
 371                 // let's verify the transform
 372                 vector in_f, in_r, in_u;
 373                 vector out_f, out_r, out_u;
 374                 fixedmakevectors(teleporter.angles);
 375                 in_f = v_forward;
 376                 in_r = v_right;
 377                 in_u = v_up;
 378                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 379                 fixedmakevectors(destination.angles);
 380                 out_f = v_forward;
 381                 out_r = v_right;
 382                 out_u = v_up;
 383                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 384                 // INTENDED TRANSFORM:
 385                 //   in_f -> -out_f
 386                 //   in_r -> -out_r
 387                 //   in_u -> +out_u
 388                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 389                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 390                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 391
 392                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 393                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 394         }
 395 #endif
 396
 397         teleporter.enemy = destination;
 398         destination.enemy = teleporter;
 399         Portal_MakeInPortal(teleporter);
 400         Portal_MakeOutPortal(destination);
 401         teleporter.fade_time = time + 15;
 402         destination.fade_time = time + 15;
 403         teleporter.portal_wants_to_vanish = 0;
 404         destination.portal_wants_to_vanish = 0;
 405 }
 406
 407 void Portal_Remove(entity portal, float killed)
 408 {
 409         entity e;
 410         e = portal.enemy;
 411
 412         if(e)
 413         {
 414                 Portal_Disconnect(portal, e);
 415                 Portal_Remove(e, killed);
 416         }
 417
 418         if(portal == portal.owner.portal_in)
 419                 portal.owner.portal_in = world;
 420         if(portal == portal.owner.portal_out)
 421                 portal.owner.portal_out = world;
 422         //portal.owner = world;
 423
 424         // makes the portal vanish
 425         if(killed)
 426         {
 427                 fixedmakevectors(portal.angles);
 428                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 429                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 430                 remove(portal);
 431         }
 432         else
 433         {
 434                 Portal_MakeBrokenPortal(portal);
 435                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 436                 SUB_SetFade(portal, time, 0.5);
 437         }
 438 }
 439
 440 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 441 {
 442         if(deathtype == DEATH_TELEFRAG)
 443                 return;
 444         if(attacker != self.owner)
 445                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 446                         return;
 447         self.health -= damage;
 448         if(self.health < 0)
 449                 Portal_Remove(self, 1);
 450 }
 451
 452 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 453 {
 454         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 455                 return;
 456
 457         // if e would hit the portal in a frame...
 458         // already teleport him
 459         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 460         if(trace_ent == self)
 461                 Portal_TeleportPlayer(self, e);
 462 }
 463
 464 void Portal_Think()
 465 {
 466         entity e, o;
 467         vector g;
 468
 469         // portal is being removed?
 470         if(self.solid != SOLID_TRIGGER)
 471                 return; // possibly engine bug
 472
 473         if(!self.enemy)
 474                 error("Portal_Think called for a broken portal\n");
 475
 476         o = self.owner;
 477         self.solid = SOLID_BBOX;
 478         self.owner = world;
 479
 480         g = frametime * '0 0 -1' * cvar("sv_gravity");
 481
 482         fixedmakevectors(self.angles);
 483
 484         FOR_EACH_PLAYER(e)
 485         {
 486                 if(e != o)
 487                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 488                                 continue; // cannot go through someone else's portal
 489
 490                 if(e != o || time >= self.portal_activatetime)
 491                         Portal_Think_TryTeleportPlayer(e, g);
 492
 493                 if(e.hook)
 494                         Portal_Think_TryTeleportPlayer(e.hook, g);
 495         }
 496         self.solid = SOLID_TRIGGER;
 497         self.owner = o;
 498
 499         self.nextthink = time;
 500
 501         if(time > self.fade_time)
 502                 Portal_Remove(self, 0);
 503 }
 504
 505 float Portal_Customize()
 506 {
 507         if(other.classname == "spectator")
 508                 other = other.enemy;
 509         if(other == self.owner)
 510         {
 511                 self.modelindex = self.modelindex_lod0;
 512         }
 513         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 514         {
 515                 self.modelindex = 0;
 516         }
 517         else
 518         {
 519                 self.modelindex = self.modelindex_lod0;
 520         }
 521         return TRUE;
 522 }
 523
 524 // cleanup:
 525 //   when creating in-portal:
 526 //     disconnect
 527 //     clear existing in-portal
 528 //     set as in-portal
 529 //     connect
 530 //   when creating out-portal:
 531 //     disconnect
 532 //     clear existing out-portal
 533 //     set as out-portal
 534 //   when player dies:
 535 //     disconnect portals
 536 //     clear both portals
 537 //   after timeout of in-portal:
 538 //     disconnect portals
 539 //     clear both portals
 540 //   TODO: ensure only one portal shot at once
 541 float Portal_SetInPortal(entity own, entity portal)
 542 {
 543         if(own.portal_in)
 544         {
 545                 if(own.portal_out)
 546                         Portal_Disconnect(own.portal_in, own.portal_out);
 547                 Portal_Remove(own.portal_in, 0);
 548         }
 549         own.portal_in = portal;
 550         if(own.portal_out)
 551         {
 552                 own.portal_out.portal_id = portal.portal_id;
 553                 Portal_Connect(own.portal_in, own.portal_out);
 554         }
 555         return 2;
 556 }
 557 float Portal_SetOutPortal(entity own, entity portal)
 558 {
 559         if(own.portal_out)
 560         {
 561                 if(own.portal_in)
 562                         Portal_Disconnect(own.portal_in, own.portal_out);
 563                 Portal_Remove(own.portal_out, 0);
 564         }
 565         own.portal_out = portal;
 566         if(own.portal_in)
 567         {
 568                 own.portal_in.portal_id = portal.portal_id;
 569                 Portal_Connect(own.portal_in, own.portal_out);
 570         }
 571         return 1;
 572 }
 573 void Portal_ClearAll_PortalsOnly(entity own)
 574 {
 575         if(own.portal_in)
 576                 Portal_Remove(own.portal_in, 0);
 577         if(own.portal_out)
 578                 Portal_Remove(own.portal_out, 0);
 579 }
 580 void Portal_ClearAll(entity own)
 581 {
 582         Portal_ClearAll_PortalsOnly(own);
 583         W_Porto_Remove(own);
 584 }
 585 void Portal_RemoveLater_Think()
 586 {
 587         Portal_Remove(self, self.cnt);
 588 }
 589 void Portal_RemoveLater(entity portal, float kill)
 590 {
 591         Portal_MakeBrokenPortal(portal);
 592         portal.cnt = kill;
 593         portal.think = Portal_RemoveLater_Think;
 594         portal.nextthink = time;
 595 }
 596 void Portal_ClearAllLater_PortalsOnly(entity own)
 597 {
 598         if(own.portal_in)
 599                 Portal_RemoveLater(own.portal_in, 0);
 600         if(own.portal_out)
 601                 Portal_RemoveLater(own.portal_out, 0);
 602 }
 603 void Portal_ClearAllLater(entity own)
 604 {
 605         Portal_ClearAllLater_PortalsOnly(own);
 606         W_Porto_Remove(own);
 607 }
 608 void Portal_ClearWithID(entity own, float id)
 609 {
 610         if(own.portal_in)
 611                 if(own.portal_in.portal_id == id)
 612                 {
 613                         if(own.portal_out)
 614                                 Portal_Disconnect(own.portal_in, own.portal_out);
 615                         Portal_Remove(own.portal_in, 0);
 616                 }
 617         if(own.portal_out)
 618                 if(own.portal_out.portal_id == id)
 619                 {
 620                         if(own.portal_in)
 621                                 Portal_Disconnect(own.portal_in, own.portal_out);
 622                         Portal_Remove(own.portal_out, 0);
 623                 }
 624 }
 625
 626 entity Portal_Spawn(entity own, vector org, vector ang)
 627 {
 628         entity portal;
 629
 630         fixedmakevectors(ang);
 631         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 632                 return world;
 633
 634         portal = spawn();
 635         portal.classname = "portal";
 636         portal.owner = own;
 637         portal.origin = org;
 638         portal.angles = ang;
 639         portal.think = Portal_Think;
 640         portal.nextthink = 0;
 641         portal.portal_activatetime = time + 0.1;
 642         portal.event_damage = Portal_Damage;
 643         portal.health = 200;
 644         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 645         portal.health = cvar("g_balance_portal_health");
 646         setmodel(portal, "models/portal.md3");
 647         portal.modelindex_lod0 = portal.modelindex;
 648         portal.customizeentityforclient = Portal_Customize;
 649
 650         if(!Portal_FindSafeOrigin(portal))
 651         {
 652                 remove(portal);
 653                 return world;
 654         }
 655
 656         setsize(portal, '-48 -48 -48', '48 48 48');
 657         Portal_MakeWaitingPortal(portal);
 658
 659         return portal;
 660 }
 661
 662 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 663 {
 664         entity portal;
 665         vector ang;
 666         vector org;
 667
 668         org = trace_endpos;
 669         ang = fixedvectoangles2(trace_plane_normal, dir);
 670         fixedmakevectors(ang);
 671
 672         portal = Portal_Spawn(own, org, ang);
 673         if(!portal)
 674         {
 675                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 676                         Portal_ClearAll_PortalsOnly(own);
 677                 return 0;
 678         }
 679
 680         portal.portal_id = portal_id_val;
 681         Portal_SetInPortal(own, portal);
 682
 683         return 1;
 684 }
 685
 686 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 687 {
 688         entity portal;
 689         vector ang;
 690         vector org;
 691
 692         org = trace_endpos;
 693         ang = fixedvectoangles2(trace_plane_normal, dir);
 694         fixedmakevectors(ang);
 695
 696         portal = Portal_Spawn(own, org, ang);
 697         if(!portal)
 698         {
 699                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 700                         Portal_ClearAll_PortalsOnly(own);
 701                 return 0;
 702         }
 703
 704         portal.portal_id = portal_id_val;
 705         Portal_SetOutPortal(own, portal);
 706
 707         return 1;
 708 }