data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float DistributeEvenly_amount;
  11 float DistributeEvenly_totalweight;
  12 void DistributeEvenly_Init(float amount, float totalweight)
  13 {
  14     if (DistributeEvenly_amount)
  15     {
  16         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  17         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  18     }
  19     if (totalweight == 0)
  20         DistributeEvenly_amount = 0;
  21     else
  22         DistributeEvenly_amount = amount;
  23     DistributeEvenly_totalweight = totalweight;
  24 }
  25 float DistributeEvenly_Get(float weight)
  26 {
  27     float f;
  28     if (weight <= 0)
  29         return 0;
  30     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  31     DistributeEvenly_totalweight -= weight;
  32     DistributeEvenly_amount -= f;
  33     return f;
  34 }
  35
  36 void move_out_of_solid_expand(entity e, vector by)
  37 {
  38     float eps = 0.0625;
  39     tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  40     if (trace_startsolid)
  41         return;
  42     if (trace_fraction < 1)
  43     {
  44         // hit something
  45         // adjust origin in the other direction...
  46         e.origin = e.origin - by * (1 - trace_fraction);
  47     }
  48 }
  49
  50 float move_out_of_solid(entity e)
  51 {
  52     vector o, m0, m1;
  53
  54     o = e.origin;
  55     traceline(o, o, MOVE_WORLDONLY, e);
  56     if (trace_startsolid)
  57         return 0;
  58
  59     tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  60     if (!trace_startsolid)
  61         return 1;
  62
  63     m0 = e.mins;
  64     m1 = e.maxs;
  65     e.mins = '0 0 0';
  66     e.maxs = '0 0 0';
  67     move_out_of_solid_expand(e, '1 0 0' * m0_x);
  68     e.mins_x = m0_x;
  69     move_out_of_solid_expand(e, '1 0 0' * m1_x);
  70     e.maxs_x = m1_x;
  71     move_out_of_solid_expand(e, '0 1 0' * m0_y);
  72     e.mins_y = m0_y;
  73     move_out_of_solid_expand(e, '0 1 0' * m1_y);
  74     e.maxs_y = m1_y;
  75     move_out_of_solid_expand(e, '0 0 1' * m0_z);
  76     e.mins_z = m0_z;
  77     move_out_of_solid_expand(e, '0 0 1' * m1_z);
  78     e.maxs_z = m1_z;
  79     setorigin(e, e.origin);
  80
  81     tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
  82     if (trace_startsolid)
  83     {
  84         setorigin(e, o);
  85         return 0;
  86     }
  87
  88     return 1;
  89 }
  90
  91 string STR_PLAYER = "player";
  92 string STR_SPECTATOR = "spectator";
  93 string STR_OBSERVER = "observer";
  94
  95 #if 0
  96 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  97 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  98 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  99 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 100 #else
 101 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 102 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 103 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 104 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 105 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 106 #endif
 107
 108 // copies a string to a tempstring (so one can strunzone it)
 109 string strcat1(string s) = #115; // FRIK_FILE
 110
 111 float logfile_open;
 112 float logfile;
 113
 114 void bcenterprint(string s)
 115 {
 116     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 117     entity head;
 118     FOR_EACH_PLAYER(head)
 119     if (clienttype(head) == CLIENTTYPE_REAL)
 120         centerprint(head, s);
 121 }
 122
 123 void GameLogEcho(string s)
 124 {
 125     string fn;
 126     float matches;
 127
 128     if (cvar("sv_eventlog_files"))
 129     {
 130         if (!logfile_open)
 131         {
 132             logfile_open = TRUE;
 133             matches = cvar("sv_eventlog_files_counter") + 1;
 134             cvar_set("sv_eventlog_files_counter", ftos(matches));
 135             fn = ftos(matches);
 136             if (strlen(fn) < 8)
 137                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 138             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 139             logfile = fopen(fn, FILE_APPEND);
 140             fputs(logfile, ":logversion:3\n");
 141         }
 142         if (logfile >= 0)
 143         {
 144             if (cvar("sv_eventlog_files_timestamps"))
 145                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 146             else
 147                 fputs(logfile, strcat(s, "\n"));
 148         }
 149     }
 150     if (cvar("sv_eventlog_console"))
 151     {
 152         print(s, "\n");
 153     }
 154 }
 155
 156 void GameLogInit()
 157 {
 158     logfile_open = 0;
 159     // will be opened later
 160 }
 161
 162 void GameLogClose()
 163 {
 164     if (logfile_open && logfile >= 0)
 165     {
 166         fclose(logfile);
 167         logfile = -1;
 168     }
 169 }
 170
 171 float spawnpoint_nag;
 172 void relocate_spawnpoint()
 173 {
 174     // nudge off the floor
 175     setorigin(self, self.origin + '0 0 1');
 176
 177     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 178     if (trace_startsolid)
 179     {
 180         vector o;
 181         o = self.origin;
 182         self.mins = PL_MIN;
 183         self.maxs = PL_MAX;
 184         if (!move_out_of_solid(self))
 185             objerror("could not get out of solid at all!");
 186         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 187         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 188         print(" ", ftos(self.origin_y - o_y));
 189         print(" ", ftos(self.origin_z - o_z), "'\n");
 190         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 191         {
 192             if (!spawnpoint_nag)
 193                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 194             spawnpoint_nag = 1;
 195         }
 196         else
 197         {
 198             self.origin = o;
 199             self.mins = self.maxs = '0 0 0';
 200             objerror("player spawn point in solid, mapper sucks!\n");
 201             return;
 202         }
 203     }
 204
 205     if (cvar("g_spawnpoints_autodrop"))
 206     {
 207         setsize(self, PL_MIN, PL_MAX);
 208         droptofloor();
 209     }
 210
 211     self.use = spawnpoint_use;
 212     self.team_saved = self.team;
 213     if (!self.cnt)
 214         self.cnt = 1;
 215
 216     if (g_ctf || g_assault || g_onslaught || g_domination || g_nexball)
 217         if (self.team)
 218             have_team_spawns = 1;
 219
 220     if (cvar("r_showbboxes"))
 221     {
 222         // show where spawnpoints point at too
 223         makevectors(self.angles);
 224         entity e;
 225         e = spawn();
 226         e.classname = "info_player_foo";
 227         setorigin(e, self.origin + v_forward * 24);
 228         setsize(e, '-8 -8 -8', '8 8 8');
 229         e.solid = SOLID_TRIGGER;
 230     }
 231 }
 232
 233 #define strstr strstrofs
 234 /*
 235 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 236 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 237 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 238 // BE CONSTANT OR strzoneD!
 239 float strstr(string haystack, string needle, float offset)
 240 {
 241         float len, endpos;
 242         string found;
 243         len = strlen(needle);
 244         endpos = strlen(haystack) - len;
 245         while(offset <= endpos)
 246         {
 247                 found = substring(haystack, offset, len);
 248                 if(found == needle)
 249                         return offset;
 250                 offset = offset + 1;
 251         }
 252         return -1;
 253 }
 254 */
 255
 256 float NUM_NEAREST_ENTITIES = 4;
 257 entity nearest_entity[NUM_NEAREST_ENTITIES];
 258 float nearest_length[NUM_NEAREST_ENTITIES];
 259 entity findnearest(vector point, .string field, string value, vector axismod)
 260 {
 261     entity localhead;
 262     float i;
 263     float j;
 264     float len;
 265     vector dist;
 266
 267     float num_nearest;
 268     num_nearest = 0;
 269
 270     localhead = find(world, field, value);
 271     while (localhead)
 272     {
 273         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 274             dist = localhead.oldorigin;
 275         else
 276             dist = localhead.origin;
 277         dist = dist - point;
 278         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 279         len = vlen(dist);
 280
 281         for (i = 0; i < num_nearest; ++i)
 282         {
 283             if (len < nearest_length[i])
 284                 break;
 285         }
 286
 287         // now i tells us where to insert at
 288         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 289         if (i < NUM_NEAREST_ENTITIES)
 290         {
 291             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 292             {
 293                 nearest_length[j + 1] = nearest_length[j];
 294                 nearest_entity[j + 1] = nearest_entity[j];
 295             }
 296             nearest_length[i] = len;
 297             nearest_entity[i] = localhead;
 298             if (num_nearest < NUM_NEAREST_ENTITIES)
 299                 num_nearest = num_nearest + 1;
 300         }
 301
 302         localhead = find(localhead, field, value);
 303     }
 304
 305     // now use the first one from our list that we can see
 306     for (i = 0; i < num_nearest; ++i)
 307     {
 308         traceline(point, nearest_entity[i].origin, TRUE, world);
 309         if (trace_fraction == 1)
 310         {
 311             if (i != 0)
 312             {
 313                 dprint("Nearest point (");
 314                 dprint(nearest_entity[0].netname);
 315                 dprint(") is not visible, using a visible one.\n");
 316             }
 317             return nearest_entity[i];
 318         }
 319     }
 320
 321     if (num_nearest == 0)
 322         return world;
 323
 324     dprint("Not seeing any location point, using nearest as fallback.\n");
 325     /* DEBUGGING CODE:
 326     dprint("Candidates were: ");
 327     for(j = 0; j < num_nearest; ++j)
 328     {
 329         if(j != 0)
 330                 dprint(", ");
 331         dprint(nearest_entity[j].netname);
 332     }
 333     dprint("\n");
 334     */
 335
 336     return nearest_entity[0];
 337 }
 338
 339 void spawnfunc_target_location()
 340 {
 341     self.classname = "target_location";
 342     // location name in netname
 343     // eventually support: count, teamgame selectors, line of sight?
 344 };
 345
 346 void spawnfunc_info_location()
 347 {
 348     self.classname = "target_location";
 349     self.message = self.netname;
 350 };
 351
 352 string NearestLocation(vector p)
 353 {
 354     entity loc;
 355     string ret;
 356     ret = "somewhere";
 357     loc = findnearest(p, classname, "target_location", '1 1 1');
 358     if (loc)
 359     {
 360         ret = loc.message;
 361     }
 362     else
 363     {
 364         loc = findnearest(p, target, "###item###", '1 1 4');
 365         if (loc)
 366             ret = loc.netname;
 367     }
 368     return ret;
 369 }
 370
 371 string formatmessage(string msg)
 372 {
 373     float p, p1, p2;
 374     float n;
 375     string escape;
 376     string replacement;
 377     p = 0;
 378     n = 7;
 379     while (1)
 380     {
 381         if (n < 1)
 382             break; // too many replacements
 383         n = n - 1;
 384         p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 385         p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 386
 387         if (p1 < 0)
 388             p1 = p2;
 389         if (p2 < 0)
 390             p2 = p1;
 391         p = min(p1, p2);
 392
 393         if (p < 0)
 394             break;
 395         replacement = substring(msg, p, 2);
 396         escape = substring(msg, p + 1, 1);
 397         if (escape == "%")
 398             replacement = "%";
 399         else if (escape == "\\")
 400             replacement = "\\";
 401         else if (escape == "n")
 402             replacement = "\n";
 403         else if (escape == "a")
 404             replacement = ftos(floor(self.armorvalue));
 405         else if (escape == "h")
 406             replacement = ftos(floor(self.health));
 407         else if (escape == "l")
 408             replacement = NearestLocation(self.origin);
 409         else if (escape == "y")
 410             replacement = NearestLocation(self.cursor_trace_endpos);
 411         else if (escape == "d")
 412             replacement = NearestLocation(self.death_origin);
 413         else if (escape == "w")
 414         {
 415             float wep;
 416             wep = self.weapon;
 417             if (!wep)
 418                 wep = self.switchweapon;
 419             if (!wep)
 420                 wep = self.cnt;
 421             replacement = W_Name(wep);
 422         }
 423         else if (escape == "W")
 424         {
 425             if (self.items & IT_SHELLS) replacement = "shells";
 426             else if (self.items & IT_NAILS) replacement = "bullets";
 427             else if (self.items & IT_ROCKETS) replacement = "rockets";
 428             else if (self.items & IT_CELLS) replacement = "cells";
 429             else replacement = "batteries"; // ;)
 430         }
 431         else if (escape == "x")
 432         {
 433             replacement = self.cursor_trace_ent.netname;
 434             if (!replacement || !self.cursor_trace_ent)
 435                 replacement = "nothing";
 436         }
 437         else if (escape == "p")
 438         {
 439             if (self.last_selected_player)
 440                 replacement = self.last_selected_player.netname;
 441             else
 442                 replacement = "(nobody)";
 443         }
 444         msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 445         p = p + strlen(replacement);
 446     }
 447     return msg;
 448 }
 449
 450 /*
 451 =============
 452 GetCvars
 453 =============
 454 Called with:
 455   0:  sends the request
 456   >0: receives a cvar from name=argv(f) value=argv(f+1)
 457 */
 458 void GetCvars_handleString(string thisname, float f, .string field, string name)
 459 {
 460     if (f < 0)
 461     {
 462         if (self.field)
 463             strunzone(self.field);
 464         self.field = string_null;
 465     }
 466     else if (f > 0)
 467     {
 468         if (thisname == name)
 469         {
 470             if (self.field)
 471                 strunzone(self.field);
 472             self.field = strzone(argv(f + 1));
 473         }
 474     }
 475     else
 476         stuffcmd(self, strcat("sendcvar ", name, "\n"));
 477 }
 478 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 479 {
 480     GetCvars_handleString(thisname, f, field, name);
 481     if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 482         if (thisname == name)
 483         {
 484             string s;
 485             s = func(strcat1(self.field));
 486             if (s != self.field)
 487             {
 488                 strunzone(self.field);
 489                 self.field = strzone(s);
 490             }
 491         }
 492 }
 493 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 494 {
 495     if (f < 0)
 496     {
 497     }
 498     else if (f > 0)
 499     {
 500         if (thisname == name)
 501             self.field = stof(argv(f + 1));
 502     }
 503     else
 504         stuffcmd(self, strcat("sendcvar ", name, "\n"));
 505 }
 506 string W_FixWeaponOrder_ForceComplete(string s);
 507 string W_FixWeaponOrder_AllowIncomplete(string s);
 508 float w_getbestweapon(entity e);
 509 void GetCvars(float f)
 510 {
 511     string s;
 512     if (f > 0)
 513         s = strcat1(argv(f));
 514     GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 515     GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 516     GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 517     GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 518     GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 519     GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 520     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 521     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 522     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 523     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 524     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 525     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 526     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 527     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 528     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 529     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 530     GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 531     GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 532     GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 533     GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 534     GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 535     GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 536     GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromnexuiz, "cl_forceplayermodelsfromnexuiz");
 537     GetCvars_handleFloat(s, f, cvar_cl_gunalign, "cl_gunalign");
 538
 539
 540     // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 541     if (f > 0)
 542     {
 543         if (s == "cl_weaponpriority")
 544             self.switchweapon = w_getbestweapon(self);
 545     }
 546 }
 547
 548 float fexists(string f)
 549 {
 550     float fh;
 551     fh = fopen(f, FILE_READ);
 552     if (fh < 0)
 553         return FALSE;
 554     fclose(fh);
 555     return TRUE;
 556 }
 557
 558 void backtrace(string msg)
 559 {
 560     float dev;
 561     dev = cvar("developer");
 562     cvar_set("developer", "1");
 563     dprint("\n");
 564     dprint("--- CUT HERE ---\nWARNING: ");
 565     dprint(msg);
 566     dprint("\n");
 567     remove(world); // isn't there any better way to cause a backtrace?
 568     dprint("\n--- CUT UNTIL HERE ---\n");
 569     cvar_set("developer", ftos(dev));
 570 }
 571
 572 string Team_ColorCode(float teamid)
 573 {
 574     if (teamid == COLOR_TEAM1)
 575         return "^1";
 576     else if (teamid == COLOR_TEAM2)
 577         return "^4";
 578     else if (teamid == COLOR_TEAM3)
 579         return "^3";
 580     else if (teamid == COLOR_TEAM4)
 581         return "^6";
 582     else
 583         return "^7";
 584 }
 585 string Team_ColorName(float t)
 586 {
 587     // fixme: Search for team entities and get their .netname's!
 588     if (t == COLOR_TEAM1)
 589         return "Red";
 590     if (t == COLOR_TEAM2)
 591         return "Blue";
 592     if (t == COLOR_TEAM3)
 593         return "Yellow";
 594     if (t == COLOR_TEAM4)
 595         return "Pink";
 596     return "Neutral";
 597 }
 598 string Team_ColorNameLowerCase(float t)
 599 {
 600     // fixme: Search for team entities and get their .netname's!
 601     if (t == COLOR_TEAM1)
 602         return "red";
 603     if (t == COLOR_TEAM2)
 604         return "blue";
 605     if (t == COLOR_TEAM3)
 606         return "yellow";
 607     if (t == COLOR_TEAM4)
 608         return "pink";
 609     return "neutral";
 610 }
 611
 612 #define CENTERPRIO_POINT 1
 613 #define CENTERPRIO_SPAM 2
 614 #define CENTERPRIO_VOTE 4
 615 #define CENTERPRIO_NORMAL 5
 616 #define CENTERPRIO_SHIELDING 7
 617 #define CENTERPRIO_MAPVOTE 9
 618 #define CENTERPRIO_IDLEKICK 50
 619 #define CENTERPRIO_ADMIN 99
 620 .float centerprint_priority;
 621 .float centerprint_expires;
 622 void centerprint_atprio(entity e, float prio, string s)
 623 {
 624     if (intermission_running)
 625         if (prio < CENTERPRIO_MAPVOTE)
 626             return;
 627     if (time > e.centerprint_expires)
 628         e.centerprint_priority = 0;
 629     if (prio >= e.centerprint_priority)
 630     {
 631         e.centerprint_priority = prio;
 632         if (timeoutStatus == 2)
 633             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 634         else
 635             e.centerprint_expires = time + e.cvar_scr_centertime;
 636         centerprint_builtin(e, s);
 637     }
 638 }
 639 void centerprint_expire(entity e, float prio)
 640 {
 641     if (prio == e.centerprint_priority)
 642     {
 643         e.centerprint_priority = 0;
 644         centerprint_builtin(e, "");
 645     }
 646 }
 647 void centerprint(entity e, string s)
 648 {
 649     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 650 }
 651
 652 // decolorizes and team colors the player name when needed
 653 string playername(entity p)
 654 {
 655     string t;
 656     if (teams_matter && !intermission_running && p.classname == "player")
 657     {
 658         t = Team_ColorCode(p.team);
 659         return strcat(t, strdecolorize(p.netname));
 660     }
 661     else
 662         return p.netname;
 663 }
 664
 665 vector randompos(vector m1, vector m2)
 666 {
 667     local vector v;
 668     m2 = m2 - m1;
 669     v_x = m2_x * random() + m1_x;
 670     v_y = m2_y * random() + m1_y;
 671     v_z = m2_z * random() + m1_z;
 672     return  v;
 673 };
 674
 675 float g_pickup_shells;
 676 float g_pickup_shells_max;
 677 float g_pickup_nails;
 678 float g_pickup_nails_max;
 679 float g_pickup_rockets;
 680 float g_pickup_rockets_max;
 681 float g_pickup_cells;
 682 float g_pickup_cells_max;
 683 float g_pickup_fuel;
 684 float g_pickup_fuel_jetpack;
 685 float g_pickup_fuel_max;
 686 float g_pickup_armorsmall;
 687 float g_pickup_armorsmall_max;
 688 float g_pickup_armormedium;
 689 float g_pickup_armormedium_max;
 690 float g_pickup_armorbig;
 691 float g_pickup_armorbig_max;
 692 float g_pickup_armorlarge;
 693 float g_pickup_armorlarge_max;
 694 float g_pickup_healthsmall;
 695 float g_pickup_healthsmall_max;
 696 float g_pickup_healthmedium;
 697 float g_pickup_healthmedium_max;
 698 float g_pickup_healthlarge;
 699 float g_pickup_healthlarge_max;
 700 float g_pickup_healthmega;
 701 float g_pickup_healthmega_max;
 702 float g_weaponarena;
 703 string g_weaponarena_list;
 704 float g_weaponspeedfactor;
 705 float g_weapondamagefactor;
 706
 707 float start_weapons;
 708 float start_items;
 709 float start_ammo_shells;
 710 float start_ammo_nails;
 711 float start_ammo_rockets;
 712 float start_ammo_cells;
 713 float start_ammo_fuel;
 714 float start_health;
 715 float start_armorvalue;
 716 float warmup_start_weapons;
 717 float warmup_start_ammo_shells;
 718 float warmup_start_ammo_nails;
 719 float warmup_start_ammo_rockets;
 720 float warmup_start_ammo_cells;
 721 float warmup_start_ammo_fuel;
 722 float warmup_start_health;
 723 float warmup_start_armorvalue;
 724 float g_weapon_stay;
 725
 726 entity get_weaponinfo(float w);
 727
 728 float NixNex_CanChooseWeapon(float wpn);
 729 void readplayerstartcvars()
 730 {
 731     entity e;
 732     float i, j, t;
 733     string s;
 734
 735     // initialize starting values for players
 736     start_weapons = 0;
 737     start_items = 0;
 738     start_ammo_shells = 0;
 739     start_ammo_nails = 0;
 740     start_ammo_rockets = 0;
 741     start_ammo_cells = 0;
 742     start_health = cvar("g_balance_health_start");
 743     start_armorvalue = cvar("g_balance_armor_start");
 744
 745     g_weaponarena = 0;
 746     s = cvar_string("g_weaponarena");
 747     if (s == "0")
 748     {
 749     }
 750     else if (s == "all")
 751     {
 752         g_weaponarena_list = "All Weapons";
 753         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 754         {
 755             e = get_weaponinfo(j);
 756             g_weaponarena |= e.weapons;
 757             weapon_action(e.weapon, WR_PRECACHE);
 758         }
 759     }
 760     else if (s == "most")
 761     {
 762         g_weaponarena_list = "Most Weapons";
 763         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 764         {
 765             e = get_weaponinfo(j);
 766             if (e.spawnflags & WEPSPAWNFLAG_NORMAL)
 767             {
 768                 g_weaponarena |= e.weapons;
 769                 weapon_action(e.weapon, WR_PRECACHE);
 770             }
 771         }
 772     }
 773     else if (s == "none")
 774     {
 775         g_weaponarena_list = "No Weapons";
 776         g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 777     }
 778     else
 779     {
 780         t = tokenize_console(s);
 781         g_weaponarena_list = "";
 782         for (i = 0; i < t; ++i)
 783         {
 784             s = argv(i);
 785             for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 786             {
 787                 e = get_weaponinfo(j);
 788                 if (e.netname == s)
 789                 {
 790                     g_weaponarena |= e.weapons;
 791                     weapon_action(e.weapon, WR_PRECACHE);
 792                     g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 793                     break;
 794                 }
 795             }
 796             if (j > WEP_LAST)
 797             {
 798                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 799             }
 800         }
 801         g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 802     }
 803
 804     if (g_nixnex)
 805     {
 806         start_weapons = 0;
 807         // will be done later
 808         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 809             if (NixNex_CanChooseWeapon(i))
 810                 weapon_action(i, WR_PRECACHE);
 811         if(!cvar("g_use_ammunition"))
 812                 start_items |= IT_UNLIMITED_AMMO;
 813     }
 814     else if (g_weaponarena)
 815     {
 816         start_weapons = g_weaponarena;
 817         start_ammo_rockets = 999;
 818         start_ammo_shells = 999;
 819         start_ammo_cells = 999;
 820         start_ammo_nails = 999;
 821         start_ammo_fuel = 999;
 822         start_items |= IT_UNLIMITED_AMMO;
 823     }
 824     else if (g_minstagib)
 825     {
 826         start_health = 100;
 827         start_armorvalue = 0;
 828         start_weapons = WEPBIT_MINSTANEX;
 829         weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 830         start_ammo_cells = cvar("g_minstagib_ammo_start");
 831         g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 832         start_ammo_fuel = cvar("g_start_ammo_fuel");
 833
 834         if (g_minstagib_invis_alpha <= 0)
 835             g_minstagib_invis_alpha = -1;
 836     }
 837     else
 838     {
 839         if (g_lms)
 840         {
 841             start_ammo_shells = cvar("g_lms_start_ammo_shells");
 842             start_ammo_nails = cvar("g_lms_start_ammo_nails");
 843             start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 844             start_ammo_cells = cvar("g_lms_start_ammo_cells");
 845             start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 846             start_health = cvar("g_lms_start_health");
 847             start_armorvalue = cvar("g_lms_start_armor");
 848         }
 849         else if (cvar("g_use_ammunition"))
 850         {
 851             start_ammo_shells = cvar("g_start_ammo_shells");
 852             start_ammo_nails = cvar("g_start_ammo_nails");
 853             start_ammo_rockets = cvar("g_start_ammo_rockets");
 854             start_ammo_cells = cvar("g_start_ammo_cells");
 855             start_ammo_fuel = cvar("g_start_ammo_fuel");
 856         }
 857         else
 858         {
 859             start_ammo_shells = cvar("g_pickup_shells_max");
 860             start_ammo_nails = cvar("g_pickup_nails_max");
 861             start_ammo_rockets = cvar("g_pickup_rockets_max");
 862             start_ammo_cells = cvar("g_pickup_cells_max");
 863             start_ammo_fuel = cvar("g_pickup_fuel_max");
 864             start_items |= IT_UNLIMITED_AMMO;
 865         }
 866
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869             e = get_weaponinfo(i);
 870             if (!(e.weapon))
 871                 continue;
 872
 873             t = cvar(strcat("g_start_weapon_", e.netname));
 874
 875             if (t < 0) // "default" weapon selection
 876             {
 877                 if (g_lms)
 878                     t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 879                 else if (g_race)
 880                     t = (i == WEP_LASER);
 881                 else if (g_nexball)
 882                     t = 0; // weapon is set a few lines later
 883                 else
 884                     t = (i == WEP_LASER || i == WEP_SHOTGUN);
 885                 if (g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 886                     t += (i == WEP_HOOK);
 887             }
 888
 889             if (g_nexball && i == WEP_PORTO)
 890                 t=1;
 891
 892             if (t)
 893             {
 894                 start_weapons |= e.weapons;
 895                 weapon_action(e.weapon, WR_PRECACHE);
 896             }
 897         }
 898     }
 899
 900     if (inWarmupStage)
 901     {
 902         warmup_start_ammo_shells = start_ammo_shells;
 903         warmup_start_ammo_nails = start_ammo_nails;
 904         warmup_start_ammo_rockets = start_ammo_rockets;
 905         warmup_start_ammo_cells = start_ammo_cells;
 906         warmup_start_health = start_health;
 907         warmup_start_armorvalue = start_armorvalue;
 908         warmup_start_weapons = start_weapons;
 909
 910         if (!g_weaponarena && !g_nixnex && !g_minstagib)
 911         {
 912             if (cvar("g_use_ammunition"))
 913             {
 914                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 915                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 916                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 917                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 918             }
 919             warmup_start_health = cvar("g_warmup_start_health");
 920             warmup_start_armorvalue = cvar("g_warmup_start_armor");
 921             if (cvar("g_warmup_allguns"))
 922             {
 923                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 924                 {
 925                     e = get_weaponinfo(i);
 926                     if (!(e.weapon))
 927                         continue;
 928                     if (e.spawnflags & WEPSPAWNFLAG_NORMAL)
 929                     {
 930                         warmup_start_weapons |= e.weapons;
 931                         weapon_action(e.weapon, WR_PRECACHE);
 932                     }
 933                 }
 934             }
 935         }
 936     }
 937
 938     if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
 939     {
 940         g_grappling_hook = 0; // these two can't coexist, as they use the same button
 941         start_items |= IT_FUEL_REGEN;
 942         start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 943     }
 944
 945     if (g_jetpack)
 946         start_items |= IT_JETPACK;
 947
 948     if (g_weapon_stay == 2)
 949     {
 950         if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 951         if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
 952         if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
 953         if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
 954         if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
 955         if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 956         if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
 957         if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
 958         if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
 959         if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
 960     }
 961
 962     start_ammo_shells = max(0, start_ammo_shells);
 963     start_ammo_nails = max(0, start_ammo_nails);
 964     start_ammo_cells = max(0, start_ammo_cells);
 965     start_ammo_rockets = max(0, start_ammo_rockets);
 966     start_ammo_fuel = max(0, start_ammo_fuel);
 967
 968     warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 969     warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 970     warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 971     warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 972     warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 973 }
 974
 975 float g_bugrigs;
 976 float g_bugrigs_planar_movement;
 977 float g_bugrigs_planar_movement_car_jumping;
 978 float g_bugrigs_reverse_spinning;
 979 float g_bugrigs_reverse_speeding;
 980 float g_bugrigs_reverse_stopping;
 981 float g_bugrigs_air_steering;
 982 float g_bugrigs_angle_smoothing;
 983 float g_bugrigs_friction_floor;
 984 float g_bugrigs_friction_brake;
 985 float g_bugrigs_friction_air;
 986 float g_bugrigs_accel;
 987 float g_bugrigs_speed_ref;
 988 float g_bugrigs_speed_pow;
 989 float g_bugrigs_steer;
 990
 991 float g_touchexplode;
 992 float g_touchexplode_radius;
 993 float g_touchexplode_damage;
 994 float g_touchexplode_edgedamage;
 995 float g_touchexplode_force;
 996
 997 void readlevelcvars(void)
 998 {
 999     g_bugrigs = cvar("g_bugrigs");
1000     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1001     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1002     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1003     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1004     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1005     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1006     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1007     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1008     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1009     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1010     g_bugrigs_accel = cvar("g_bugrigs_accel");
1011     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1012     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1013     g_bugrigs_steer = cvar("g_bugrigs_steer");
1014
1015     g_touchexplode = cvar("g_touchexplode");
1016     g_touchexplode_radius = cvar("g_touchexplode_radius");
1017     g_touchexplode_damage = cvar("g_touchexplode_damage");
1018     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1019     g_touchexplode_force = cvar("g_touchexplode_force");
1020
1021     sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1022     sv_loddistance1 = cvar("sv_loddistance1");
1023     sv_loddistance2 = cvar("sv_loddistance2");
1024         if(sv_loddistance2 <= sv_loddistance1)
1025                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1026     sv_clones = cvar("sv_clones");
1027     sv_cheats = cvar("sv_cheats");
1028     sv_gentle = cvar("sv_gentle");
1029     sv_foginterval = cvar("sv_foginterval");
1030     g_cloaked = cvar("g_cloaked");
1031     g_jump_grunt = cvar("g_jump_grunt");
1032     g_footsteps = cvar("g_footsteps");
1033     g_grappling_hook = cvar("g_grappling_hook");
1034     g_jetpack = cvar("g_jetpack");
1035     g_laserguided_missile = cvar("g_laserguided_missile");
1036     g_midair = cvar("g_midair");
1037     g_minstagib = cvar("g_minstagib");
1038     g_nixnex = cvar("g_nixnex");
1039     g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1040     g_norecoil = cvar("g_norecoil");
1041     g_vampire = cvar("g_vampire");
1042     g_bloodloss = cvar("g_bloodloss");
1043     sv_maxidle = cvar("sv_maxidle");
1044     sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1045     sv_pogostick = cvar("sv_pogostick");
1046     sv_doublejump = cvar("sv_doublejump");
1047     g_ctf_reverse = cvar("g_ctf_reverse");
1048
1049     inWarmupStage = cvar("g_warmup");
1050     g_warmup_limit = cvar("g_warmup_limit");
1051     g_warmup_allguns = cvar("g_warmup_allguns");
1052     g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1053
1054     if (g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1055         inWarmupStage = 0; // these modes cannot work together, sorry
1056
1057     g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1058     g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1059     g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1060     g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1061     g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1062     g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1063     g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1064     g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1065     g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1066     g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1067     g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1068     g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1069
1070     if (g_minstagib) g_nixnex = g_weaponarena = 0;
1071     if (g_nixnex) g_weaponarena = 0;
1072     g_weaponarena = 0;
1073
1074     g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1075     g_weapondamagefactor = cvar("g_weapondamagefactor");
1076
1077     g_pickup_shells                    = cvar("g_pickup_shells");
1078     g_pickup_shells_max                = cvar("g_pickup_shells_max");
1079     g_pickup_nails                     = cvar("g_pickup_nails");
1080     g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1081     g_pickup_rockets                   = cvar("g_pickup_rockets");
1082     g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1083     g_pickup_cells                     = cvar("g_pickup_cells");
1084     g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1085     g_pickup_fuel                     = cvar("g_pickup_fuel");
1086     g_pickup_fuel_jetpack             = cvar("g_pickup_fuel_jetpack");
1087     g_pickup_fuel_max                 = cvar("g_pickup_fuel_max");
1088     g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1089     g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1090     g_pickup_armormedium               = cvar("g_pickup_armormedium");
1091     g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1092     g_pickup_armorbig                  = cvar("g_pickup_armorbig");
1093     g_pickup_armorbig_max              = cvar("g_pickup_armorbig_max");
1094     g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1095     g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1096     g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1097     g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1098     g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1099     g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1100     g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1101     g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1102     g_pickup_healthmega                = cvar("g_pickup_healthmega");
1103     g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1104
1105     g_pinata = cvar("g_pinata");
1106
1107     g_weapon_stay = cvar("g_weapon_stay");
1108     if (!g_weapon_stay && (cvar("deathmatch") == 2))
1109         g_weapon_stay = 1;
1110
1111     if not(inWarmupStage)
1112         game_starttime                 = cvar("g_start_delay");
1113
1114     readplayerstartcvars();
1115 }
1116
1117 /*
1118 // TODO sound pack system
1119 string soundpack;
1120
1121 string precache_sound_builtin (string s) = #19;
1122 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1123 string precache_sound(string s)
1124 {
1125         return precache_sound_builtin(strcat(soundpack, s));
1126 }
1127 void play2(entity e, string filename)
1128 {
1129         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1130 }
1131 void sound(entity e, float chan, string samp, float vol, float atten)
1132 {
1133         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1134 }
1135 */
1136
1137 // Sound functions
1138 string precache_sound (string s) = #19;
1139 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1140 float precache_sound_index (string s) = #19;
1141
1142 #define SND_VOLUME      1
1143 #define SND_ATTENUATION 2
1144 #define SND_LARGEENTITY 8
1145 #define SND_LARGESOUND  16
1146
1147 float sound_allowed(float dest, entity e)
1148 {
1149     // sounds from world may always pass
1150     for (;;)
1151     {
1152         if (e.classname == "body")
1153             e = e.enemy;
1154         if (e.owner && e.owner != e)
1155             e = e.owner;
1156         else
1157             break;
1158     }
1159     // sounds to self may always pass
1160     if (dest == MSG_ONE)
1161         if (e == msg_entity)
1162             return TRUE;
1163     // sounds by players can be removed
1164     if (cvar("bot_sound_monopoly"))
1165         if (clienttype(e) == CLIENTTYPE_REAL)
1166             return FALSE;
1167     // anything else may pass
1168     return TRUE;
1169 }
1170
1171 void sound(entity e, float chan, string samp, float vol, float atten)
1172 {
1173     if (!sound_allowed(MSG_BROADCAST, e))
1174         return;
1175     sound_builtin(e, chan, samp, vol, atten);
1176 }
1177 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1178 {
1179     float entno, idx;
1180
1181     if (!sound_allowed(dest, e))
1182         return;
1183
1184     entno = num_for_edict(e);
1185     idx = precache_sound_index(samp);
1186
1187     float sflags;
1188     sflags = 0;
1189
1190     atten = floor(atten * 64);
1191     vol = floor(vol * 255);
1192
1193     if (vol != 255)
1194         sflags |= SND_VOLUME;
1195     if (atten != 64)
1196         sflags |= SND_ATTENUATION;
1197     if (entno >= 8192)
1198         sflags |= SND_LARGEENTITY;
1199     if (idx >= 256)
1200         sflags |= SND_LARGESOUND;
1201
1202     WriteByte(dest, SVC_SOUND);
1203     WriteByte(dest, sflags);
1204     if (sflags & SND_VOLUME)
1205         WriteByte(dest, vol);
1206     if (sflags & SND_ATTENUATION)
1207         WriteByte(dest, atten);
1208     if (sflags & SND_LARGEENTITY)
1209     {
1210         WriteShort(dest, entno);
1211         WriteByte(dest, chan);
1212     }
1213     else
1214     {
1215         WriteShort(dest, entno * 8 + chan);
1216     }
1217     if (sflags & SND_LARGESOUND)
1218         WriteShort(dest, idx);
1219     else
1220         WriteByte(dest, idx);
1221
1222     WriteCoord(dest, o_x);
1223     WriteCoord(dest, o_y);
1224     WriteCoord(dest, o_z);
1225 }
1226 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1227 {
1228     vector o;
1229
1230     if (!sound_allowed(dest, e))
1231         return;
1232
1233     o = e.origin + 0.5 * (e.mins + e.maxs);
1234     soundtoat(dest, e, o, chan, samp, vol, atten);
1235 }
1236 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1237 {
1238     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1239 }
1240 void stopsoundto(float dest, entity e, float chan)
1241 {
1242     float entno;
1243
1244     if (!sound_allowed(dest, e))
1245         return;
1246
1247     entno = num_for_edict(e);
1248
1249     if (entno >= 8192)
1250     {
1251         float idx, sflags;
1252         idx = precache_sound_index("misc/null.wav");
1253         sflags = SND_LARGEENTITY;
1254         if (idx >= 256)
1255             sflags |= SND_LARGESOUND;
1256         WriteByte(dest, SVC_SOUND);
1257         WriteByte(dest, sflags);
1258         WriteShort(dest, entno);
1259         WriteByte(dest, chan);
1260         if (sflags & SND_LARGESOUND)
1261             WriteShort(dest, idx);
1262         else
1263             WriteByte(dest, idx);
1264         WriteCoord(dest, e.origin_x);
1265         WriteCoord(dest, e.origin_y);
1266         WriteCoord(dest, e.origin_z);
1267     }
1268     else
1269     {
1270         WriteByte(dest, SVC_STOPSOUND);
1271         WriteShort(dest, entno * 8 + chan);
1272     }
1273 }
1274 void stopsound(entity e, float chan)
1275 {
1276     if (!sound_allowed(MSG_BROADCAST, e))
1277         return;
1278
1279     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1280     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1281 }
1282
1283 void play2(entity e, string filename)
1284 {
1285     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1286     msg_entity = e;
1287     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1288 }
1289
1290 .float announcetime;
1291 float announce(entity player, string msg)
1292 {
1293     if (time > player.announcetime)
1294         if (clienttype(player) == CLIENTTYPE_REAL)
1295         {
1296             player.announcetime = time + 0.8;
1297             play2(player, msg);
1298             return TRUE;
1299         }
1300     return FALSE;
1301 }
1302 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1303 float spamsound(entity e, float chan, string samp, float vol, float atten)
1304 {
1305     if (!sound_allowed(MSG_BROADCAST, e))
1306         return FALSE;
1307
1308     if (time > e.announcetime)
1309     {
1310         e.announcetime = time;
1311         sound(e, chan, samp, vol, atten);
1312         return TRUE;
1313     }
1314     return FALSE;
1315 }
1316
1317 void play2team(float t, string filename)
1318 {
1319     local entity head;
1320
1321     if (cvar("bot_sound_monopoly"))
1322         return;
1323
1324     FOR_EACH_REALPLAYER(head)
1325     {
1326         if (head.team == t)
1327             play2(head, filename);
1328     }
1329 }
1330
1331 void play2all(string samp)
1332 {
1333     if (cvar("bot_sound_monopoly"))
1334         return;
1335
1336     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1337 }
1338
1339 void PrecachePlayerSounds(string f);
1340 void precache_all_models(string pattern)
1341 {
1342     float globhandle, i, n;
1343     string f;
1344
1345     globhandle = search_begin(pattern, TRUE, FALSE);
1346     if (globhandle < 0)
1347         return;
1348     n = search_getsize(globhandle);
1349     for (i = 0; i < n; ++i)
1350     {
1351                 //print(search_getfilename(globhandle, i), "\n");
1352                 f = search_getfilename(globhandle, i);
1353                 if(sv_loddistance1)
1354                         precache_model(f);
1355                 if(substring(f, -9,5) == "_lod1")
1356                         continue;
1357                 if(substring(f, -9,5) == "_lod2")
1358                         continue;
1359                 if(!sv_loddistance1)
1360                         precache_model(f);
1361                 PrecachePlayerSounds(strcat(f, ".sounds"));
1362     }
1363     search_end(globhandle);
1364 }
1365
1366 void precache()
1367 {
1368     // gamemode related things
1369     precache_model ("models/misc/chatbubble.spr");
1370     precache_model ("models/misc/teambubble.spr");
1371     if (g_runematch)
1372     {
1373         precache_model ("models/runematch/curse.mdl");
1374         precache_model ("models/runematch/rune.mdl");
1375     }
1376
1377 #ifdef TTURRETS_ENABLED
1378     if (cvar("g_turrets"))
1379         turrets_precash();
1380 #endif
1381
1382     // Precache all player models if desired
1383     if (cvar("sv_precacheplayermodels"))
1384     {
1385         PrecachePlayerSounds("sound/player/default.sounds");
1386         precache_all_models("models/player/*.zym");
1387         precache_all_models("models/player/*.dpm");
1388         precache_all_models("models/player/*.md3");
1389         precache_all_models("models/player/*.psk");
1390         //precache_model("models/player/carni.zym");
1391         //precache_model("models/player/crash.zym");
1392         //precache_model("models/player/grunt.zym");
1393         //precache_model("models/player/headhunter.zym");
1394         //precache_model("models/player/insurrectionist.zym");
1395         //precache_model("models/player/jeandarc.zym");
1396         //precache_model("models/player/lurk.zym");
1397         //precache_model("models/player/lycanthrope.zym");
1398         //precache_model("models/player/marine.zym");
1399         //precache_model("models/player/nexus.zym");
1400         //precache_model("models/player/pyria.zym");
1401         //precache_model("models/player/shock.zym");
1402         //precache_model("models/player/skadi.zym");
1403         //precache_model("models/player/specop.zym");
1404         //precache_model("models/player/visitant.zym");
1405     }
1406
1407     if (cvar("sv_defaultcharacter"))
1408     {
1409         string s;
1410         s = cvar_string("sv_defaultplayermodel_red");
1411         if (s != "")
1412         {
1413             precache_model(s);
1414             PrecachePlayerSounds(strcat(s, ".sounds"));
1415         }
1416         s = cvar_string("sv_defaultplayermodel_blue");
1417         if (s != "")
1418         {
1419             precache_model(s);
1420             PrecachePlayerSounds(strcat(s, ".sounds"));
1421         }
1422         s = cvar_string("sv_defaultplayermodel_yellow");
1423         if (s != "")
1424         {
1425             precache_model(s);
1426             PrecachePlayerSounds(strcat(s, ".sounds"));
1427         }
1428         s = cvar_string("sv_defaultplayermodel_pink");
1429         if (s != "")
1430         {
1431             precache_model(s);
1432             PrecachePlayerSounds(strcat(s, ".sounds"));
1433         }
1434         s = cvar_string("sv_defaultplayermodel");
1435         if (s != "")
1436         {
1437             precache_model(s);
1438             PrecachePlayerSounds(strcat(s, ".sounds"));
1439         }
1440     }
1441
1442     if (g_footsteps)
1443     {
1444         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1445         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1446     }
1447
1448     // gore and miscellaneous sounds
1449     //precache_sound ("misc/h2ohit.wav");
1450     precache_model ("models/hook.md3");
1451     precache_sound ("misc/armorimpact.wav");
1452     precache_sound ("misc/bodyimpact1.wav");
1453     precache_sound ("misc/bodyimpact2.wav");
1454     precache_sound ("misc/gib.wav");
1455     precache_sound ("misc/gib_splat01.wav");
1456     precache_sound ("misc/gib_splat02.wav");
1457     precache_sound ("misc/gib_splat03.wav");
1458     precache_sound ("misc/gib_splat04.wav");
1459     precache_sound ("misc/hit.wav");
1460     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1461     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1462     precache_sound ("misc/null.wav");
1463     precache_sound ("misc/spawn.wav");
1464     precache_sound ("misc/talk.wav");
1465     precache_sound ("misc/teleport.wav");
1466     precache_sound ("misc/poweroff.wav");
1467     precache_sound ("player/lava.wav");
1468     precache_sound ("player/slime.wav");
1469
1470     if (g_jetpack)
1471         precache_sound ("misc/jetpack_fly.wav");
1472
1473     // announcer sounds - male
1474     precache_sound ("announcer/male/electrobitch.wav");
1475     precache_sound ("announcer/male/airshot.wav");
1476     precache_sound ("announcer/male/03kills.wav");
1477     precache_sound ("announcer/male/05kills.wav");
1478     precache_sound ("announcer/male/10kills.wav");
1479     precache_sound ("announcer/male/15kills.wav");
1480     precache_sound ("announcer/male/20kills.wav");
1481     precache_sound ("announcer/male/25kills.wav");
1482     precache_sound ("announcer/male/30kills.wav");
1483     precache_sound ("announcer/male/botlike.wav");
1484     precache_sound ("announcer/male/yoda.wav");
1485     precache_sound ("announcer/male/amazing.wav");
1486     precache_sound ("announcer/male/awesome.wav");
1487     precache_sound ("announcer/male/headshot.wav");
1488     precache_sound ("announcer/male/impressive.wav");
1489
1490     // announcer sounds - robotic
1491     precache_sound ("announcer/robotic/prepareforbattle.wav");
1492     precache_sound ("announcer/robotic/begin.wav");
1493     precache_sound ("announcer/robotic/timeoutcalled.wav");
1494     precache_sound ("announcer/robotic/1fragleft.wav");
1495     precache_sound ("announcer/robotic/2fragsleft.wav");
1496     precache_sound ("announcer/robotic/3fragsleft.wav");
1497     if (g_minstagib)
1498     {
1499         precache_sound ("announcer/robotic/lastsecond.wav");
1500         precache_sound ("announcer/robotic/narrowly.wav");
1501     }
1502
1503     precache_model ("models/sprites/1.spr32");
1504     precache_model ("models/sprites/2.spr32");
1505     precache_model ("models/sprites/3.spr32");
1506     precache_model ("models/sprites/4.spr32");
1507     precache_model ("models/sprites/5.spr32");
1508     precache_model ("models/sprites/6.spr32");
1509     precache_model ("models/sprites/7.spr32");
1510     precache_model ("models/sprites/8.spr32");
1511     precache_model ("models/sprites/9.spr32");
1512     precache_model ("models/sprites/10.spr32");
1513     precache_sound ("announcer/robotic/1.wav");
1514     precache_sound ("announcer/robotic/2.wav");
1515     precache_sound ("announcer/robotic/3.wav");
1516     precache_sound ("announcer/robotic/4.wav");
1517     precache_sound ("announcer/robotic/5.wav");
1518     precache_sound ("announcer/robotic/6.wav");
1519     precache_sound ("announcer/robotic/7.wav");
1520     precache_sound ("announcer/robotic/8.wav");
1521     precache_sound ("announcer/robotic/9.wav");
1522     precache_sound ("announcer/robotic/10.wav");
1523
1524     // common weapon precaches
1525     precache_sound ("weapons/weapon_switch.wav");
1526     precache_sound ("weapons/weaponpickup.wav");
1527     precache_sound ("weapons/unavailable.wav");
1528     if (g_grappling_hook)
1529     {
1530         precache_sound ("weapons/hook_fire.wav"); // hook
1531         precache_sound ("weapons/hook_impact.wav"); // hook
1532     }
1533
1534     if (cvar("sv_precacheweapons") || g_nixnex)
1535     {
1536         //precache weapon models/sounds
1537         local float wep;
1538         wep = WEP_FIRST;
1539         while (wep <= WEP_LAST)
1540         {
1541             weapon_action(wep, WR_PRECACHE);
1542             wep = wep + 1;
1543         }
1544     }
1545
1546     precache_model("models/elaser.mdl");
1547     precache_model("models/laser.mdl");
1548     precache_model("models/ebomb.mdl");
1549
1550 #if 0
1551     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1552
1553     if (!self.noise && self.music) // quake 3 uses the music field
1554         self.noise = self.music;
1555
1556     // plays music for the level if there is any
1557     if (self.noise)
1558     {
1559         precache_sound (self.noise);
1560         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1561     }
1562 #endif
1563 }
1564
1565 // sorry, but using \ in macros breaks line numbers
1566 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1567 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1568 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1569
1570 vector ExactTriggerHit_mins;
1571 vector ExactTriggerHit_maxs;
1572 float ExactTriggerHit_Recurse()
1573 {
1574     float s;
1575     entity se;
1576     float f;
1577
1578     tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1579     if not(trace_ent)
1580         return 0;
1581     if (trace_ent == self)
1582         return 1;
1583
1584     se = trace_ent;
1585     s = se.solid;
1586     se.solid = SOLID_NOT;
1587     f = ExactTriggerHit_Recurse();
1588     se.solid = s;
1589
1590     return f;
1591 }
1592
1593 float ExactTriggerHit()
1594 {
1595     float f, s;
1596
1597     if not(self.modelindex)
1598         return 1;
1599
1600     s = self.solid;
1601     self.solid = SOLID_BSP;
1602     ExactTriggerHit_mins = other.absmin;
1603     ExactTriggerHit_maxs = other.absmax;
1604     f = ExactTriggerHit_Recurse();
1605     self.solid = s;
1606
1607     return f;
1608 }
1609
1610 // WARNING: this kills the trace globals
1611 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1612 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1613
1614 #define INITPRIO_FIRST              0
1615 #define INITPRIO_GAMETYPE           0
1616 #define INITPRIO_GAMETYPE_FALLBACK  1
1617 #define INITPRIO_CVARS              5
1618 #define INITPRIO_FINDTARGET        10
1619 #define INITPRIO_DROPTOFLOOR       20
1620 #define INITPRIO_SETLOCATION       90
1621 #define INITPRIO_LINKDOORS         91
1622 #define INITPRIO_LAST              99
1623
1624 .void(void) initialize_entity;
1625 .float initialize_entity_order;
1626 .entity initialize_entity_next;
1627 entity initialize_entity_first;
1628
1629 void make_safe_for_remove(entity e)
1630 {
1631     if (e.initialize_entity)
1632     {
1633         entity ent, prev;
1634         for (ent = initialize_entity_first; ent; )
1635         {
1636             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1637             {
1638                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1639                 // skip it in linked list
1640                 if (prev)
1641                 {
1642                     prev.initialize_entity_next = ent.initialize_entity_next;
1643                     ent = prev.initialize_entity_next;
1644                 }
1645                 else
1646                 {
1647                     initialize_entity_first = ent.initialize_entity_next;
1648                     ent = initialize_entity_first;
1649                 }
1650             }
1651             else
1652             {
1653                 prev = ent;
1654                 ent = ent.initialize_entity_next;
1655             }
1656         }
1657     }
1658 }
1659
1660 void objerror(string s)
1661 {
1662     make_safe_for_remove(self);
1663     objerror_builtin(s);
1664 }
1665
1666 void remove_unsafely(entity e)
1667 {
1668     remove_builtin(e);
1669 }
1670
1671 void remove_safely(entity e)
1672 {
1673     make_safe_for_remove(e);
1674     remove_builtin(e);
1675 }
1676
1677 void InitializeEntity(entity e, void(void) func, float order)
1678 {
1679     entity prev, cur;
1680
1681     if (!e || e.initialize_entity)
1682     {
1683         // make a proxy initializer entity
1684         entity e_old;
1685         e_old = e;
1686         e = spawn();
1687         e.classname = "initialize_entity";
1688         e.enemy = e_old;
1689     }
1690
1691     e.initialize_entity = func;
1692     e.initialize_entity_order = order;
1693
1694     cur = initialize_entity_first;
1695     for (;;)
1696     {
1697         if (!cur || cur.initialize_entity_order > order)
1698         {
1699             // insert between prev and cur
1700             if (prev)
1701                 prev.initialize_entity_next = e;
1702             else
1703                 initialize_entity_first = e;
1704             e.initialize_entity_next = cur;
1705             return;
1706         }
1707         prev = cur;
1708         cur = cur.initialize_entity_next;
1709     }
1710 }
1711 void InitializeEntitiesRun()
1712 {
1713     entity startoflist;
1714     startoflist = initialize_entity_first;
1715     initialize_entity_first = world;
1716     for (self = startoflist; self; )
1717     {
1718         entity e;
1719         var void(void) func;
1720         e = self.initialize_entity_next;
1721         func = self.initialize_entity;
1722         self.initialize_entity_order = 0;
1723         self.initialize_entity = func_null;
1724         self.initialize_entity_next = world;
1725         if (self.classname == "initialize_entity")
1726         {
1727             entity e_old;
1728             e_old = self.enemy;
1729             remove_builtin(self);
1730             self = e_old;
1731         }
1732         //dprint("Delayed initialization: ", self.classname, "\n");
1733         func();
1734         self = e;
1735     }
1736 }
1737
1738 .float uncustomizeentityforclient_set;
1739 .void(void) uncustomizeentityforclient;
1740 void(void) SUB_Nullpointer = #0;
1741 void UncustomizeEntitiesRun()
1742 {
1743     entity oldself;
1744     oldself = self;
1745     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1746         self.uncustomizeentityforclient();
1747     self = oldself;
1748 }
1749 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1750 {
1751     e.customizeentityforclient = customizer;
1752     e.uncustomizeentityforclient = uncustomizer;
1753     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1754 }
1755
1756 .float nottargeted;
1757 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1758
1759 void() SUB_Remove;
1760 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1761 {
1762     vector mi, ma;
1763
1764     if (e.classname == "")
1765         e.classname = "net_linked";
1766
1767     if (e.model == "" || self.modelindex == 0)
1768     {
1769         mi = e.mins;
1770         ma = e.maxs;
1771         setmodel(e, "null");
1772         setsize(e, mi, ma);
1773     }
1774
1775     e.SendEntity = sendfunc;
1776     e.SendFlags = 0xFFFFFF;
1777
1778     if (!docull)
1779         e.effects |= EF_NODEPTHTEST;
1780
1781     if (dt)
1782     {
1783         e.nextthink = time + dt;
1784         e.think = SUB_Remove;
1785     }
1786 }
1787
1788 void adaptor_think2touch()
1789 {
1790     entity o;
1791     o = other;
1792     other = world;
1793     self.touch();
1794     other = o;
1795 }
1796
1797 void adaptor_think2use()
1798 {
1799     entity o, a;
1800     o = other;
1801     a = activator;
1802     activator = world;
1803     other = world;
1804     self.use();
1805     other = o;
1806     activator = a;
1807 }
1808
1809 // deferred dropping
1810 void DropToFloor_Handler()
1811 {
1812     droptofloor_builtin();
1813     self.dropped_origin = self.origin;
1814 }
1815
1816 void droptofloor()
1817 {
1818     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1819 }
1820
1821
1822
1823 float trace_hits_box_a0, trace_hits_box_a1;
1824
1825 float trace_hits_box_1d(float end, float thmi, float thma)
1826 {
1827     if (end == 0)
1828     {
1829         // just check if x is in range
1830         if (0 < thmi)
1831             return FALSE;
1832         if (0 > thma)
1833             return FALSE;
1834     }
1835     else
1836     {
1837         // do the trace with respect to x
1838         // 0 -> end has to stay in thmi -> thma
1839         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1840         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1841         if (trace_hits_box_a0 > trace_hits_box_a1)
1842             return FALSE;
1843     }
1844     return TRUE;
1845 }
1846
1847 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1848 {
1849     end -= start;
1850     thmi -= start;
1851     thma -= start;
1852     // now it is a trace from 0 to end
1853
1854     trace_hits_box_a0 = 0;
1855     trace_hits_box_a1 = 1;
1856
1857     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1858         return FALSE;
1859     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1860         return FALSE;
1861     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1862         return FALSE;
1863
1864     return TRUE;
1865 }
1866
1867 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1868 {
1869     return trace_hits_box(start, end, thmi - ma, thma - mi);
1870 }
1871
1872 float SUB_NoImpactCheck()
1873 {
1874     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1875         return 1;
1876     if (other == world && self.size != '0 0 0')
1877     {
1878         vector tic;
1879         tic = self.velocity * sys_ticrate;
1880         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1881         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1882         if (trace_fraction >= 1)
1883         {
1884             dprint("Odd... did not hit...?\n");
1885         }
1886         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1887         {
1888             dprint("Detected and prevented the sky-grapple bug.\n");
1889             return 1;
1890         }
1891     }
1892
1893     return 0;
1894 }
1895
1896 #define SUB_OwnerCheck() (other && (other == self.owner))
1897
1898 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } if(trace_ent && trace_ent.solid > SOLID_TRIGGER) UpdateCSQCProjectileNextFrame(self); } while(0)
1899
1900 float MAX_IPBAN_URIS = 16;
1901
1902 float URI_GET_DISCARD   = 0;
1903 float URI_GET_IPBAN     = 1;
1904 float URI_GET_IPBAN_END = 16;
1905
1906 void URI_Get_Callback(float id, float status, string data)
1907 {
1908     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
1909     dprint(data);
1910     dprint("\nEnd of data.\n");
1911
1912     if (id == URI_GET_DISCARD)
1913     {
1914         // discard
1915     }
1916     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1917     {
1918         // online ban list
1919         OnlineBanList_URI_Get_Callback(id, status, data);
1920     }
1921     else
1922     {
1923         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1924     }
1925 }
1926
1927 void print_to(entity e, string s)
1928 {
1929     if (e)
1930         sprint(e, strcat(s, "\n"));
1931     else
1932         print(s, "\n");
1933 }
1934
1935 string getrecords()
1936 {
1937     float rec;
1938     string h;
1939     float r;
1940     float i;
1941     string s;
1942
1943     rec = 0;
1944
1945     s = "";
1946
1947     if (g_ctf)
1948     {
1949         for (i = 0; i < MapInfo_count; ++i)
1950         {
1951             if (MapInfo_Get_ByID(i))
1952             {
1953                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1954                 if (r == 0)
1955                     continue;
1956                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1957                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1958                 ++rec;
1959             }
1960         }
1961     }
1962
1963     if (g_race)
1964     {
1965         for (i = 0; i < MapInfo_count; ++i)
1966         {
1967             if (MapInfo_Get_ByID(i))
1968             {
1969                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1970                 if (r == 0)
1971                     continue;
1972                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1973                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1974                 ++rec;
1975             }
1976         }
1977     }
1978     MapInfo_ClearTemps();
1979
1980     if (s == "")
1981         return "No records are available on this server.\n";
1982     else
1983         return strcat("Records on this server:\n", s);
1984 }
1985
1986 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1987 {
1988     float m, i;
1989     vector start, org, delta, end, enddown, mstart;
1990
1991     m = e.dphitcontentsmask;
1992     e.dphitcontentsmask = goodcontents | badcontents;
1993
1994     org = world.mins;
1995     delta = world.maxs - world.mins;
1996
1997     for (i = 0; i < attempts; ++i)
1998     {
1999         start_x = org_x + random() * delta_x;
2000         start_y = org_y + random() * delta_y;
2001         start_z = org_z + random() * delta_z;
2002
2003         // rule 1: start inside world bounds, and outside
2004         // solid, and don't start from somewhere where you can
2005         // fall down to evil
2006         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2007         if (trace_fraction >= 1)
2008             continue;
2009         if (trace_startsolid)
2010             continue;
2011         if (trace_dphitcontents & badcontents)
2012             continue;
2013         if (trace_dphitq3surfaceflags & badsurfaceflags)
2014             continue;
2015
2016         // rule 2: if we are too high, lower the point
2017         if (trace_fraction * delta_z > maxaboveground)
2018             start = trace_endpos + '0 0 1' * maxaboveground;
2019         enddown = trace_endpos;
2020
2021         // rule 3: make sure we aren't outside the map. This only works
2022         // for somewhat well formed maps. A good rule of thumb is that
2023         // the map should have a convex outside hull.
2024         // these can be traceLINES as we already verified the starting box
2025         mstart = start + 0.5 * (e.mins + e.maxs);
2026         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2027         if (trace_fraction >= 1)
2028             continue;
2029         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2030         if (trace_fraction >= 1)
2031             continue;
2032         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2033         if (trace_fraction >= 1)
2034             continue;
2035         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2036         if (trace_fraction >= 1)
2037             continue;
2038         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2039         if (trace_fraction >= 1)
2040             continue;
2041
2042         // find a random vector to "look at"
2043         end_x = org_x + random() * delta_x;
2044         end_y = org_y + random() * delta_y;
2045         end_z = org_z + random() * delta_z;
2046         end = start + normalize(end - start) * vlen(delta);
2047
2048         // rule 4: start TO end must not be too short
2049         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2050         if (trace_startsolid)
2051             continue;
2052         if (trace_fraction < minviewdistance / vlen(delta))
2053             continue;
2054
2055         // rule 5: don't want to look at sky
2056         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2057             continue;
2058
2059         // rule 6: we must not end up in trigger_hurt
2060         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2061         {
2062             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2063             continue;
2064         }
2065
2066         break;
2067     }
2068
2069     e.dphitcontentsmask = m;
2070
2071     if (i < attempts)
2072     {
2073         setorigin(e, start);
2074         e.angles = vectoangles(end - start);
2075         dprint("Needed ", ftos(i + 1), " attempts\n");
2076         return TRUE;
2077     }
2078     else
2079         return FALSE;
2080 }
2081
2082 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2083 {
2084     WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2085     WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2086     WriteShort(MSG_BROADCAST, effectno);
2087     WriteCoord(MSG_BROADCAST, start_x);
2088     WriteCoord(MSG_BROADCAST, start_y);
2089     WriteCoord(MSG_BROADCAST, start_z);
2090     WriteCoord(MSG_BROADCAST, end_x);
2091     WriteCoord(MSG_BROADCAST, end_y);
2092     WriteCoord(MSG_BROADCAST, end_z);
2093     WriteCoord(MSG_BROADCAST, end_dz);
2094     WriteShort(MSG_BROADCAST, spd / 16);
2095 }
2096
2097 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2098 {
2099     float end_dz;
2100     vector vecxy, velxy;
2101
2102     vecxy = end - start;
2103     vecxy_z = 0;
2104     velxy = vel;
2105     velxy_z = 0;
2106
2107     if (vlen(velxy) < 0.000001 * fabs(vel_z))
2108     {
2109         trailparticles(world, effectno, start, end);
2110         return;
2111     }
2112
2113     end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2114     zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2115 }
2116
2117 string GetGametype(); // g_world.qc
2118 void write_recordmarker(entity pl, float tstart, float dt)
2119 {
2120     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt / 10)));
2121
2122     // also write a marker into demo files for demotc-race-record-extractor to find
2123     stuffcmd(pl,
2124              strcat(
2125                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", mmsss(dt * 10)),
2126                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2127 }
2128
2129 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2130 {
2131         string s;
2132         vector v;
2133
2134         if (cvar("g_shootfromclient"))
2135         {
2136                 switch(self.owner.cvar_cl_gunalign)
2137                 {
2138                         case 1: // right
2139                                 break;
2140
2141                         case 2: // left
2142                                 vecs_y = -vecs_y;
2143                                 break;
2144
2145                         default:
2146                         case 3: // center
2147                                 vecs_y = 0;
2148                                 vecs_z -= 4;
2149                                 break;
2150                 }
2151         }
2152         else if (cvar("g_shootfromeye"))
2153         {
2154                 if (visual)
2155                 {
2156                         vecs_y = 0;
2157                         vecs_z -= 4;
2158                 }
2159                 else
2160                 {
2161                         vecs_y = 0;
2162                         vecs_z = 0;
2163                 }
2164         }
2165         else if (cvar("g_shootfromcenter"))
2166         {
2167                 vecs_y = 0;
2168                 vecs_z -= 4;
2169         }
2170         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2171         {
2172                 v = stov(s);
2173                 if (y_is_right)
2174                         v_y = -v_y;
2175                 if (v_x != 0)
2176                         vecs_x = v_x;
2177                 vecs_y = v_y;
2178                 vecs_z = v_z;
2179         }
2180         return vecs;
2181 }
2182
2183
2184
2185 void attach_sameorigin(entity e, entity to, string tag)
2186 {
2187     vector org, t_forward, t_left, t_up, e_forward, e_up;
2188     vector org0, ang0;
2189     float tagscale;
2190
2191     ang0 = e.angles;
2192     org0 = e.origin;
2193
2194     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2195     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2196     t_forward = v_forward * tagscale;
2197     t_left = v_right * -tagscale;
2198     t_up = v_up * tagscale;
2199
2200     e.origin_x = org * t_forward;
2201     e.origin_y = org * t_left;
2202     e.origin_z = org * t_up;
2203
2204     // current forward and up directions
2205     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2206         e.angles_x = -e.angles_x;
2207     fixedmakevectors(e.angles);
2208
2209     // untransform forward, up!
2210     e_forward_x = v_forward * t_forward;
2211     e_forward_y = v_forward * t_left;
2212     e_forward_z = v_forward * t_up;
2213     e_up_x = v_up * t_forward;
2214     e_up_y = v_up * t_left;
2215     e_up_z = v_up * t_up;
2216
2217     e.angles = fixedvectoangles2(e_forward, e_up);
2218     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2219         e.angles_x = -e.angles_x;
2220
2221     setattachment(e, to, tag);
2222     setorigin(e, e.origin);
2223 }
2224
2225 void detach_sameorigin(entity e)
2226 {
2227     vector org;
2228     org = gettaginfo(e, 0);
2229     e.angles = fixedvectoangles2(v_forward, v_up);
2230     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2231         e.angles_x = -e.angles_x;
2232     e.origin = org;
2233     setattachment(e, world, "");
2234     setorigin(e, e.origin);
2235 }
2236
2237 void follow_sameorigin(entity e, entity to)
2238 {
2239     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2240     e.aiment = to; // make the hole follow bmodel
2241     e.punchangle = to.angles; // the original angles of bmodel
2242     e.view_ofs = e.origin - to.origin; // relative origin
2243     e.v_angle = e.angles - to.angles; // relative angles
2244 }
2245
2246 void unfollow_sameorigin(entity e)
2247 {
2248     e.movetype = MOVETYPE_NONE;
2249 }
2250
2251 entity gettaginfo_relative_ent;
2252 vector gettaginfo_relative(entity e, float tag)
2253 {
2254     if (!gettaginfo_relative_ent)
2255     {
2256         gettaginfo_relative_ent = spawn();
2257         gettaginfo_relative_ent.effects = EF_NODRAW;
2258     }
2259     gettaginfo_relative_ent.model = e.model;
2260     gettaginfo_relative_ent.modelindex = e.modelindex;
2261     gettaginfo_relative_ent.frame = e.frame;
2262     return gettaginfo(gettaginfo_relative_ent, tag);
2263 }
2264
2265 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2266 {
2267     float p;
2268     p = pow(2, chan);
2269     if (pl.soundentity.cnt & p)
2270         return;
2271     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2272     pl.soundentity.cnt |= p;
2273 }
2274
2275 void SoundEntity_StopSound(entity pl, float chan)
2276 {
2277     float p;
2278     p = pow(2, chan);
2279     if (pl.soundentity.cnt & p)
2280     {
2281         stopsoundto(MSG_ALL, pl.soundentity, chan);
2282         pl.soundentity.cnt &~= p;
2283     }
2284 }
2285
2286 void SoundEntity_Attach(entity pl)
2287 {
2288     pl.soundentity = spawn();
2289     pl.soundentity.classname = "soundentity";
2290     pl.soundentity.owner = pl;
2291     setattachment(pl.soundentity, pl, "");
2292     setmodel(pl.soundentity, "null");
2293 }
2294
2295 void SoundEntity_Detach(entity pl)
2296 {
2297     float i;
2298     for (i = 0; i <= 7; ++i)
2299         SoundEntity_StopSound(pl, i);
2300 }
2301
2302
2303 float ParseCommandPlayerSlotTarget_firsttoken;
2304 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2305 {
2306     string s;
2307     entity e, head;
2308     float n;
2309
2310     s = string_null;
2311
2312     ParseCommandPlayerSlotTarget_firsttoken = -1;
2313
2314     if (tokens > idx)
2315     {
2316         if (substring(argv(idx), 0, 1) == "#")
2317         {
2318             s = substring(argv(idx), 1, -1);
2319             ++idx;
2320             if (s == "")
2321                 if (tokens > idx)
2322                 {
2323                     s = argv(idx);
2324                     ++idx;
2325                 }
2326             if (s == ftos(stof(s)))
2327             {
2328                 e = edict_num(stof(s));
2329                 if (e.flags & FL_CLIENT)
2330                 {
2331                     ParseCommandPlayerSlotTarget_firsttoken = idx;
2332                     return e;
2333                 }
2334             }
2335         }
2336         else
2337         {
2338             // it must be a nick name
2339             s = argv(idx);
2340             ++idx;
2341
2342             n = 0;
2343             FOR_EACH_CLIENT(head)
2344             if (head.netname == s)
2345             {
2346                 e = head;
2347                 ++n;
2348             }
2349             if (n == 1)
2350             {
2351                 ParseCommandPlayerSlotTarget_firsttoken = idx;
2352                 return e;
2353             }
2354
2355             s = strdecolorize(s);
2356             n = 0;
2357             FOR_EACH_CLIENT(head)
2358             if (strdecolorize(head.netname) == s)
2359             {
2360                 e = head;
2361                 ++n;
2362             }
2363             if (n == 1)
2364             {
2365                 ParseCommandPlayerSlotTarget_firsttoken = idx;
2366                 return e;
2367             }
2368         }
2369     }
2370
2371     return world;
2372 }