data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58
  59 string kh_sound_capture = "sound/kh/capture.wav";
  60 string kh_sound_destroy = "sound/kh/destroy.wav";
  61 string kh_sound_drop = "sound/kh/drop.wav";
  62 string kh_sound_collect = "sound/kh/collect.wav";
  63 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  64
  65 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  66 float kh_key_dropped, kh_key_carried;
  67
  68 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  69 {
  70         if(t == e)           return kh_sprite_friend;
  71         if(t == COLOR_TEAM1) return kh_sprite_red;
  72         if(t == COLOR_TEAM2) return kh_sprite_blue;
  73         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  74         if(t == COLOR_TEAM4) return kh_sprite_pink;
  75         return 0;
  76 }
  77
  78 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  79 {
  80         kh_Controller_Thinkfunc = func;
  81         kh_controller.cnt = t;
  82         if(kh_Controller_Waitmsg != "")
  83                 strunzone(kh_Controller_Waitmsg);
  84         if(msg == "")
  85                 kh_Controller_Waitmsg = "";
  86         else
  87                 kh_Controller_Waitmsg = strzone(msg);
  88         if(t == 0)
  89                 kh_controller.nextthink = time; // force
  90 }
  91
  92 void kh_Controller_Think()  // called a lot
  93 {
  94         entity e;
  95         if(intermission_running)
  96                 return;
  97         if(self.cnt > 0)
  98         {
  99                 if(kh_Controller_Waitmsg != "")
 100                 {
 101                         string s;
 102                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 103                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 104                         else
 105                                 s = kh_Controller_Waitmsg;
 106
 107                         //dprint(s, "\n");
 108
 109                         FOR_EACH_PLAYER(e)
 110                                 if(clienttype(e) == CLIENTTYPE_REAL)
 111                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 112                 }
 113                 self.cnt -= 1;
 114         }
 115         else if(self.cnt == 0)
 116         {
 117                 self.cnt -= 1;
 118                 kh_Controller_Thinkfunc();
 119         }
 120         self.nextthink = time + 1;
 121 }
 122
 123 // frags f: take from cvar * f
 124 // frags 0: no frags
 125 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 126 {
 127         string s;
 128         if(intermission_running)
 129                 return;
 130         if(frags_player)
 131                 UpdateFrags(player, frags_player);
 132         if(key && key.owner && frags_owner)
 133                 UpdateFrags(key.owner, frags_owner);
 134         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 135                 return;
 136         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 137         s = strcat(s, ":", ftos(frags_player));
 138         if(key && key.owner)
 139                 s = strcat(s, ":", ftos(key.owner.playerid));
 140         else
 141                 s = strcat(s, ":0");
 142         s = strcat(s, ":", ftos(frags_owner), ":");
 143         if(key)
 144                 s = strcat(s, key.netname);
 145         GameLogEcho(s, FALSE);
 146 }
 147
 148 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 149 {
 150         if(e.tag_entity)
 151         {
 152                 makevectors(e.tag_entity.angles);
 153                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 154         }
 155         else
 156                 return e.origin;
 157 }
 158
 159 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 160 {
 161 #ifdef KH_PLAYER_USE_ATTACHMENT
 162         entity first;
 163         first = key.owner.kh_next;
 164         if(key == first)
 165         {
 166                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 167                 if(key.kh_next)
 168                 {
 169                         setattachment(key.kh_next, key, "");
 170                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 171                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 172                         key.kh_next.angles = '0 0 0';
 173                 }
 174                 else
 175                         setorigin(key, KH_PLAYER_ATTACHMENT);
 176                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 177         }
 178         else
 179         {
 180                 setattachment(key, key.kh_prev, "");
 181                 if(key.kh_next)
 182                         setattachment(key.kh_next, key, "");
 183                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 184                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 185                 key.angles = '0 0 0';
 186         }
 187 #else
 188         setattachment(key, key.owner, "");
 189         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 190         key.angles_y -= key.owner.angles_y;
 191 #endif
 192         key.flags = 0;
 193         key.solid = SOLID_NOT;
 194         key.movetype = MOVETYPE_NONE;
 195         key.team = key.owner.team;
 196         key.nextthink = time;
 197         key.damageforcescale = 0;
 198         key.modelindex = kh_key_carried;
 199 }
 200
 201 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 202 {
 203         float i;
 204         i = test[key.owner.playerid];
 205                 if(key.netname == "^1red key")
 206                         i -= 1;
 207                 if(key.netname == "^4blue key")
 208                         i -= 2;
 209                 if(key.netname == "^3yellow key")
 210                         i -= 4;
 211                 if(key.netname == "^6pink key")
 212                         i -= 8;
 213         test[key.owner.playerid] = i;
 214
 215         kh_show_temp();
 216         if(key.owner)
 217                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 218         //key.owner.kh_state += test[key.owner.playerid];
 219
 220 #ifdef KH_PLAYER_USE_ATTACHMENT
 221         entity first;
 222         first = key.owner.kh_next;
 223         if(key == first)
 224         {
 225                 if(key.kh_next)
 226                 {
 227                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 228                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 229                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 230                 }
 231         }
 232         else
 233         {
 234                 if(key.kh_next)
 235                         setattachment(key.kh_next, key.kh_prev, "");
 236                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 237         }
 238         // in any case:
 239         setattachment(key, world, "");
 240         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 241         key.angles = key.owner.angles;
 242 #else
 243         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 244         setattachment(key, world, "");
 245         key.angles_y += key.owner.angles_y;
 246 #endif
 247         key.aiment = world;
 248         key.flags = FL_ITEM;
 249         key.solid = SOLID_TRIGGER;
 250         key.movetype = MOVETYPE_TOSS;
 251         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 252         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 253         // let key.team stay
 254         key.modelindex = kh_key_dropped;
 255         key.kh_previous_owner = key.owner;
 256 }
 257
 258 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 259 {
 260         if(key.owner == player)
 261                 return;
 262
 263         if(key.owner)
 264         {
 265                 kh_Key_Detach(key);
 266
 267                 // remove from linked list
 268                 if(key.kh_next)
 269                         key.kh_next.kh_prev = key.kh_prev;
 270                 key.kh_prev.kh_next = key.kh_next;
 271                 key.kh_next = world;
 272                 key.kh_prev = world;
 273
 274                 if(key.owner.kh_next == world)
 275                 {
 276                         // No longer a key carrier
 277                         WaypointSprite_DetachCarrier(key.owner);
 278                 }
 279         }
 280
 281         key.owner = player;
 282
 283         if(player)
 284         {
 285                 // insert into linked list
 286                 key.kh_next = player.kh_next;
 287                 key.kh_prev = player;
 288                 player.kh_next = key;
 289                 if(key.kh_next)
 290                         key.kh_next.kh_prev = key;
 291
 292                 float i;
 293                 i = test[key.owner.playerid];
 294                         if(key.netname == "^1red key")
 295                                 i += 1;
 296                         if(key.netname == "^4blue key")
 297                                 i += 2;
 298                         if(key.netname == "^3yellow key")
 299                                 i += 4;
 300                         if(key.netname == "^6pink key")
 301                                 i += 8;
 302                 test[key.owner.playerid] = i;
 303
 304                 kh_Key_Attach(key);
 305
 306                 if(key.kh_next == world)
 307                 {
 308                         // player is now a key carrier
 309                         WaypointSprite_AttachCarrier("", player);
 310                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 311                         player.waypointsprite_attachedforcarrier.team = player.team;
 312                 }
 313         }
 314
 315         // moved that here, also update if there's no player
 316         kh_show_temp();
 317         if(key.owner)
 318                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 319
 320         key.pusher = world;
 321 }
 322
 323 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 324 {
 325         if(self.owner)
 326                 return;
 327         if(vlen(force) <= 0)
 328                 return;
 329         if(time > self.pushltime)
 330                 if(attacker.classname == "player")
 331                         self.team = attacker.team;
 332 }
 333
 334 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 335 {
 336         entity key;
 337         key = spawn();
 338         key.classname = STR_ITEM_KH_KEY;
 339         key.touch = kh_Key_Touch;
 340         key.think = kh_Key_Think;
 341         key.nextthink = time;
 342         key.items = IT_KEY1 | IT_KEY2;
 343         key.cnt = angle;
 344         key.angles = '0 360 0' * random();
 345         key.event_damage = kh_Key_Damage;
 346         key.takedamage = DAMAGE_YES;
 347         key.modelindex = kh_key_dropped;
 348         key.model = "key";
 349         key.kh_dropperteam = 0;
 350         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 351         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 352         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 353
 354         switch(initial_owner.team)
 355         {
 356                 case COLOR_TEAM1:
 357                         key.netname = "^1red key";
 358                         break;
 359                 case COLOR_TEAM2:
 360                         key.netname = "^4blue key";
 361                         break;
 362                 case COLOR_TEAM3:
 363                         key.netname = "^3yellow key";
 364                         break;
 365                 case COLOR_TEAM4:
 366                         key.netname = "^6pink key";
 367                         break;
 368                 default:
 369                         key.netname = "NETGIER key";
 370                         break;
 371         }
 372
 373         // link into key list
 374         key.kh_worldkeynext = kh_worldkeylist;
 375         kh_worldkeylist = key;
 376
 377         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 378
 379         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 380         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 381
 382         kh_Key_AssignTo(key, initial_owner);
 383 }
 384
 385 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 386 {
 387         entity o;
 388         o = key.owner;
 389         kh_Key_AssignTo(key, world);
 390         if(o) // it was attached
 391                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 392         else // it was dropped
 393                 WaypointSprite_DetachCarrier(key);
 394
 395         // remove key from key list
 396         if (kh_worldkeylist == key)
 397                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 398         else
 399         {
 400                 o = kh_worldkeylist;
 401                 while (o)
 402                 {
 403                         if (o.kh_worldkeynext == key)
 404                         {
 405                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 406                                 break;
 407                         }
 408                         o = o.kh_worldkeynext;
 409                 }
 410         }
 411
 412         remove(key);
 413 }
 414
 415 // -1 when no team completely owns all keys yet
 416 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 417 {
 418         entity key;
 419         float teem;
 420
 421         teem = -1;
 422         FOR_EACH_KH_KEY(key)
 423         {
 424                 if(!key.owner)
 425                         return -1;
 426                 if(teem == -1)
 427                         teem = key.team;
 428                 else if(teem != key.team)
 429                         return -1;
 430         }
 431         return teem;
 432 }
 433
 434 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 435 {
 436         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 437
 438         if(key.kh_dropperteam != player.team)
 439         {
 440                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 441                 PlayerScore_Add(player, SP_KH_COLLECT, 1);
 442         }
 443         key.kh_dropperteam = 0;
 444         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 445
 446         kh_Key_AssignTo(key, player); // this also updates .kh_state
 447
 448         if(kh_Key_AllOwnedByWhichTeam() != -1)
 449         {
 450                 kh_interferemsg_time = time + 0.2;
 451                 kh_interferemsg_team = player.team;
 452         }
 453 }
 454
 455 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 456 {
 457         entity key;
 458         entity mypusher;
 459         if(player.kh_next)
 460         {
 461                 mypusher = world;
 462                 if(player.pusher)
 463                         if(time < player.pushltime)
 464                                 mypusher = player.pusher;
 465                 while((key = player.kh_next))
 466                 {
 467                         kh_Scores_Event(player, key, "losekey", 0, 0);
 468                         PlayerScore_Add(player, SP_KH_LOSEKEY, 1);
 469                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 470                         kh_Key_AssignTo(key, world);
 471                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 472                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 473                         key.pusher = mypusher;
 474                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 475                         if(suicide)
 476                                 key.kh_dropperteam = player.team;
 477                 }
 478                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 479         }
 480 }
 481
 482 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 483 {
 484         if(intermission_running)
 485                 return;
 486
 487         if(self.owner) // already carried
 488                 return;
 489         if(other.classname != "player")
 490                 return;
 491         if(other.deadflag != DEAD_NO)
 492                 return;
 493         if(other == self.enemy)
 494                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 495                         return;  // you just dropped it!
 496         kh_Key_Collect(self, other);
 497 }
 498
 499 void kh_Key_Think()  // runs all the time
 500 {
 501         entity head;
 502         //entity player;  // needed by FOR_EACH_PLAYER
 503
 504         if(intermission_running)
 505                 return;
 506         /*
 507         if(time > self.stuff_time)
 508         {
 509                 FOR_EACH_PLAYER(player)
 510                         player.kh_state = test[0]*256 + (player.kh_state&255);
 511
 512                 self.stuff_time = time + 1;  // repeat in 1 second
 513         }
 514         */
 515
 516 #ifdef KH_KEY_ATTACHMENT_DEBUG
 517         if(self.kh_prev == self.owner)
 518         {
 519                 if(cvar_string("_angles") != "")
 520                 {
 521                         self.angles = stov(cvar_string("_angles"));
 522                         self.origin = stov(cvar_string("_origin"));
 523                 }
 524         }
 525 #endif
 526
 527         if(self.owner)
 528         {
 529 #ifndef KH_PLAYER_USE_ATTACHMENT
 530                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 531                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 532 #endif
 533
 534                 if(self.owner.BUTTON_USE)
 535                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 536                 {
 537                         self.owner.kh_droptime = time;
 538                         self.kh_droptime = time;  // prevent collecting this one for some time
 539                         self.enemy = self.owner;
 540                         self.pusher = world;
 541                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 542                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 543                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 544                         makevectors(self.owner.v_angle);
 545                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 546                         kh_Key_AssignTo(self, world);
 547                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 548                         self.kh_dropperteam = self.team;
 549                 }
 550         }
 551
 552         // if in nodrop or time over, end the round
 553         if(!self.owner)
 554                 if(time > self.pain_finished)
 555                         kh_LoserTeam(self.team, self);
 556
 557         if(self.owner)
 558         if(kh_Key_AllOwnedByWhichTeam() != -1)
 559         {
 560                 if(self.siren_time < time)
 561                 {
 562                         sound(world, CHAN_AUTO, kh_sound_alarm, 1, ATTN_NORM);  // play a simple alarm
 563                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 564                 }
 565
 566                 entity key;
 567                 vector p;
 568                 p = self.owner.origin;
 569                 FOR_EACH_KH_KEY(key)
 570                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 571                                 goto not_winning;
 572                 kh_WinnerTeam(self.team);
 573 :not_winning
 574         }
 575
 576         if(kh_interferemsg_time && time > kh_interferemsg_time)
 577         {
 578                 kh_interferemsg_time = 0;
 579                 FOR_EACH_PLAYER(head)
 580                 {
 581                         if(head.team == kh_interferemsg_team)
 582                                 if(head.kh_next)
 583                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 584                                 else
 585                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 586                         else
 587                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 588                 }
 589         }
 590
 591         self.nextthink = time + 0.05;
 592 }
 593
 594 void kh_WinnerTeam(float teem)  // runs when a team wins
 595 {
 596         // all key carriers get some points
 597         vector firstorigin, lastorigin, midpoint;
 598         float first;
 599         entity key;
 600         float score;
 601         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 602         DistributeEvenly_Init(score, kh_teams);
 603         // twice the score for 3 team games, three times the score for 4 team games!
 604         // note: for a win by destroying the key, this should NOT be applied
 605         FOR_EACH_KH_KEY(key)
 606         {
 607                 float f;
 608                 f = DistributeEvenly_Get(1);
 609                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 610                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 611         }
 612
 613         first = TRUE;
 614         FOR_EACH_KH_KEY(key)
 615                 if(key.owner.kh_next == key)
 616                 {
 617                         if(!first)
 618                                 bprint("^7, ");
 619                         bprint(key.owner.netname);
 620                         first = FALSE;
 621                 }
 622         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 623
 624         first = TRUE;
 625         midpoint = '0 0 0';
 626         FOR_EACH_KH_KEY(key)
 627         {
 628                 vector thisorigin;
 629
 630                 thisorigin = kh_AttachedOrigin(key);
 631                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 632                 midpoint += thisorigin;
 633
 634                 if(!first)
 635                         te_lightning2(world, lastorigin, thisorigin);
 636                 lastorigin = thisorigin;
 637                 if(first)
 638                         firstorigin = thisorigin;
 639                 first = FALSE;
 640         }
 641         if(kh_teams > 2)
 642         {
 643                 te_lightning2(world, lastorigin, firstorigin);
 644         }
 645         midpoint = midpoint * (1 / kh_teams);
 646         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 647
 648         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 649         kh_FinishRound();
 650 }
 651
 652 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 653 {
 654         entity player, key, attacker;
 655         float players;
 656         float keys;
 657         float f;
 658
 659         attacker = world;
 660         if(lostkey.pusher)
 661                 if(lostkey.pusher.team != teem)
 662                         if(lostkey.pusher.classname == "player")
 663                                 attacker = lostkey.pusher;
 664
 665         players = keys = 0;
 666
 667         if(attacker)
 668         {
 669                 if(lostkey.kh_previous_owner)
 670                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 671                         // don't actually GIVE him the -nn points, just log
 672                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 673                 PlayerScore_Add(attacker, SP_KH_PUSH, 1);
 674                 centerprint(attacker, "Your push is the best!\n\n\n");
 675                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 676         }
 677         else
 678         {
 679                 float of, fragsleft, i, j, thisteam;
 680                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 681
 682                 FOR_EACH_PLAYER(player)
 683                         if(player.team != teem)
 684                                 ++players;
 685
 686                 FOR_EACH_KH_KEY(key)
 687                         if(key.owner && key.team != teem)
 688                                 ++keys;
 689
 690                 if(lostkey.kh_previous_owner)
 691                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 692                         // don't actually GIVE him the -nn points, just log
 693
 694                 PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYED, 1);
 695
 696                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 697
 698                 FOR_EACH_KH_KEY(key)
 699                         if(key.owner && key.team != teem)
 700                         {
 701                                 f = DistributeEvenly_Get(of);
 702                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 703                         }
 704
 705                 fragsleft = DistributeEvenly_Get(players);
 706
 707                 // Now distribute these among all other teams...
 708                 j = kh_teams - 1;
 709                 for(i = 0; i < kh_teams; ++i)
 710                 {
 711                         thisteam = kh_Team_ByID(i);
 712                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 713                                 continue;
 714
 715                         players = 0;
 716                         FOR_EACH_PLAYER(player)
 717                                 if(player.team == thisteam)
 718                                         ++players;
 719
 720                         DistributeEvenly_Init(fragsleft, j);
 721                         fragsleft = DistributeEvenly_Get(j - 1);
 722                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 723
 724                         FOR_EACH_PLAYER(player)
 725                                 if(player.team == thisteam)
 726                                 {
 727                                         f = DistributeEvenly_Get(1);
 728                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 729                                 }
 730
 731                         --j;
 732                 }
 733
 734                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 735         }
 736         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 737         te_tarexplosion(lostkey.origin);
 738
 739         kh_FinishRound();
 740 }
 741
 742 void kh_FinishRound()  // runs when a team captures the keys
 743 {
 744         // prepare next round
 745         kh_interferemsg_time = 0;
 746         entity key;
 747         FOR_EACH_KH_KEY(key)
 748                 kh_Key_Remove(key);
 749
 750         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 751 }
 752
 753 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 754 {
 755         float i, players, teem;
 756         entity player;
 757         string result;
 758         result = "";
 759
 760         // find a random player per team
 761         for(i = 0; i < kh_teams; ++i)
 762         {
 763                 teem = kh_Team_ByID(i);
 764                 players = 0;
 765                 FOR_EACH_PLAYER(player)
 766                         if(player.deadflag == DEAD_NO)
 767                                 if(!player.BUTTON_CHAT)
 768                                         if(player.team == teem)
 769                                                 ++players;
 770                 if(players == 0)
 771                 {
 772                         if(result != "")
 773                                 result = strcat(result, ", ");
 774                         result = strcat(result, ColoredTeamName(teem));
 775                 }
 776         }
 777         return result;
 778 }
 779
 780 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 781 {
 782         string teams_missing;
 783         teams_missing = kh_CheckEnoughPlayers();
 784         if(teams_missing == "")
 785                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 786         else
 787                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 788 }
 789
 790 void kh_StartRound()  // runs at the start of each round
 791 {
 792         string teams_missing;
 793         float i, players, teem;
 794         entity player;
 795
 796         teams_missing = kh_CheckEnoughPlayers();
 797         if(teams_missing != "")
 798         {
 799                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 800                 return;
 801         }
 802
 803         FOR_EACH_PLAYER(player)
 804                 if(clienttype(player) == CLIENTTYPE_REAL)
 805                         centerprint_expire(player, CENTERPRIO_SPAM);
 806
 807         for(i = 0; i < kh_teams; ++i)
 808         {
 809                 teem = kh_Team_ByID(i);
 810                 players = 0;
 811                 entity my_player;
 812                 FOR_EACH_PLAYER(player)
 813                         if(player.deadflag == DEAD_NO)
 814                                 if(!player.BUTTON_CHAT)
 815                                         if(player.team == teem)
 816                                         {
 817                                                 ++players;
 818                                                 if(random() * players <= 1)
 819                                                         my_player = player;
 820                                         }
 821                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 822                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 823                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 824         }
 825
 826         kh_tracking_enabled = FALSE;
 827         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 828 }
 829
 830 void kh_setstatus()  // runs all the time
 831 {
 832         if(kh_teams)
 833         {
 834                 float kh_KEY;
 835                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 836                 if(self.kh_next)
 837                         self.items = self.items | kh_KEY;
 838                 else
 839                         self.items = self.items - (self.items & kh_KEY);
 840         }
 841 }
 842
 843 void kh_EnableTrackingDevice()  // runs after each round
 844 {
 845         entity player;
 846
 847         FOR_EACH_PLAYER(player)
 848                 if(clienttype(player) == CLIENTTYPE_REAL)
 849                         centerprint_expire(player, CENTERPRIO_SPAM);
 850
 851         kh_tracking_enabled = TRUE;
 852 }
 853
 854 float kh_Key_waypointsprite_for_player(entity e) // ??
 855 {
 856         if(!kh_tracking_enabled)
 857                 return 0;
 858         if(!self.owner)
 859                 return kh_sprite_dropped;
 860         if(!self.owner.owner)
 861                 return kh_sprite_dropped;
 862         return 0;  // draw only when key is not owned
 863 }
 864
 865 float kh_KeyCarrier_waypointsprite_for_player(entity e)  // runs all the time
 866 {
 867         if(e.classname != "player" || self.team != e.team)
 868                 if(!kh_tracking_enabled)
 869                         return 0;
 870
 871         // e is spectator? That's no team mate...
 872         if(e.classname != "player")
 873                 return kh_GetCarrierSprite(self.team, -1);
 874
 875         // e is no key carrier: simple case...
 876         if(!e.kh_next)
 877                 return kh_GetCarrierSprite(self.team, e.team);
 878
 879         // e is a key carrier: if any key is dropped or owned by another team, show
 880         // the carrier sprite; otherwise show run here
 881         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 882                 return kh_sprite_finish;
 883
 884         return kh_GetCarrierSprite(self.team, e.team);
 885 }
 886
 887 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 888 {
 889         if(attacker == targ)
 890                 return f;
 891
 892         if(targ.kh_next)
 893         {
 894                 if(attacker.team == targ.team)
 895                 {
 896                         entity k;
 897                         float nk;
 898                         nk = 0;
 899                         for(k = targ.kh_next; k != world; k = k.kh_next)
 900                                 ++nk;
 901                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 902                 }
 903                 else
 904                 {
 905                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 906                         PlayerScore_Add(attacker, SP_KH_KCFRAG, 1);
 907                         // the frag gets added later
 908                 }
 909         }
 910
 911         return f;
 912 }
 913
 914 void kh_init()  // sets up th KH environment
 915 {
 916         precache_sound(kh_sound_capture);
 917         precache_sound(kh_sound_destroy);
 918         precache_sound(kh_sound_drop);
 919         precache_sound(kh_sound_collect);
 920         precache_sound(kh_sound_alarm);  // the new siren
 921
 922         precache_model("models/sprites/key-dropped.sp2");
 923         precache_model("models/sprites/keycarrier-finish.sp2");
 924         precache_model("models/sprites/keycarrier-friend.sp2");
 925         precache_model("models/sprites/keycarrier-red.sp2");
 926         precache_model("models/sprites/keycarrier-blue.sp2");
 927         precache_model("models/sprites/keycarrier-yellow.sp2");
 928         precache_model("models/sprites/keycarrier-pink.sp2");
 929 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 930         precache_model("models/keyhunt/key-carried.md3");
 931 #endif
 932         precache_model("models/keyhunt/key.md3");
 933
 934         // setup variables
 935         kh_teams = cvar("g_keyhunt_teams_override");
 936         if(kh_teams < 2)
 937                 kh_teams = cvar("g_keyhunt_teams");
 938         kh_teams = bound(2, kh_teams, 4);
 939
 940         // make a KH entity for controlling the game
 941         kh_controller = spawn();
 942         kh_controller.think = kh_Controller_Think;
 943         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 944
 945         setmodel(kh_controller, "models/keyhunt/key.md3");
 946         kh_key_dropped = kh_controller.modelindex;
 947         /*
 948         dprint(vtos(kh_controller.mins));
 949         dprint(vtos(kh_controller.maxs));
 950         dprint("\n");
 951         */
 952 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 953         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 954         kh_key_carried = kh_controller.modelindex;
 955 #else
 956         kh_key_carried = kh_key_dropped;
 957 #endif
 958         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 959         kh_sprite_dropped = kh_controller.modelindex;
 960         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 961         kh_sprite_finish = kh_controller.modelindex;
 962         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 963         kh_sprite_friend = kh_controller.modelindex;
 964         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 965         kh_sprite_red = kh_controller.modelindex;
 966         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 967         kh_sprite_blue = kh_controller.modelindex;
 968         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 969         kh_sprite_pink = kh_controller.modelindex;
 970         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 971         kh_sprite_yellow = kh_controller.modelindex;
 972         setmodel(kh_controller, "");
 973
 974         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 975
 976         ScoreInfo_Init(kh_teams);
 977         ScoreInfo_SetLabel_TeamScore  (ST_SCORE,        "score",     SFL_SORT_PRIO_PRIMARY);
 978         ScoreInfo_SetLabel_TeamScore  (ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 979         ScoreInfo_SetLabel_PlayerScore(SP_KILLS,        "kills",     0);
 980         ScoreInfo_SetLabel_PlayerScore(SP_DEATHS,       "deaths",    0);
 981         ScoreInfo_SetLabel_PlayerScore(SP_SUICIDES,     "suicides",  SFL_DECREASING);
 982         ScoreInfo_SetLabel_PlayerScore(SP_SCORE,        "score",     SFL_SORT_PRIO_PRIMARY);
 983         ScoreInfo_SetLabel_PlayerScore(SP_KH_COLLECT,   "collect",   0);
 984         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSEKEY,   "losekey",   SFL_DECREASING);
 985         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 986         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSH,      "push",      0);
 987         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYED, "destroyed", SFL_DECREASING);
 988         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCFRAG,    "kcfrag",    0);
 989 }
 990
 991 void kh_finalize()
 992 {
 993         // to be called before intermission
 994         kh_FinishRound();
 995         remove(kh_controller);
 996         kh_controller = world;
 997 }
 998
 999 /**
1000  * kh_show_temp originally by victim.
1001  * changed it to use the kh_state stat var
1002  * Updates the general key stat bits for each player
1003  */
1004 void kh_show_temp()
1005 {
1006         entity player;
1007         float i, j;
1008
1009         j = 0;  // reset/blank j
1010         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1011                 j += test[i];
1012
1013         test[0] = j;
1014
1015         j *= 256;
1016         FOR_EACH_PLAYER(player)
1017                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1018 }